Space Station Multiplication (MULTI.BAS)
Space Station Multiplication by Bob Follett, 198
Description
Space Station Multiplication by Bob Follett, 198
From the Antic disk of Antic: June/July 1990 - Vol. 9 No. 2 — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 14.0 KB
- Dialect
- Atari BASIC
- Lines
- 219
- Variables
N,B,C,D(,X,K,Y,ANS$,ANS,XS,I,W,WRONG(,R,D2,CORRECT,BROW(,T,SKILL(,COL,ROW,N2,Q,Q2,CH,O,STAR(,J,S,X2,A(,B(,C(,E(,IO$,PAGE,X3,X4
BASIC listing (219 lines)
5 REM SPACE STATION MULTIPLICATION
7 REM BY BOB FOLLETT
9 REM (c)1990, ANTIC PUBLISHING, INC
40 POKE 559,0:GOTO 9000
45 REM TIMER/KEYBOARD
50 N=PEEK(764):PLOT B,181:PLOT B,182:B=B+C:IF N=255 THEN 50
60 POKE 764,255:POKE 53279,0:D(X)=PEEK(K+N):X=X+4
70 ON PEEK(K+N) GOTO 95,150,250,350,450,550,650,750,850,950,1050,1100,1200,2400
80 REM ZERO
90 PLOT X,Y:DRAWTO X+2,Y:DRAWTO X+2,Y+9:DRAWTO X,Y+9:DRAWTO X,Y:PLOT X+1,Y+1:PLOT X+1,Y+8:RETURN
95 PLOT X,Y:DRAWTO X+2,Y:DRAWTO X+2,Y+8:DRAWTO X,Y+8:DRAWTO X,Y:GOTO 50
99 REM ONE
100 PLOT X,Y+2:PLOT X,Y+1:PLOT X+1,Y:DRAWTO X+1,Y+9:PLOT X,Y+8:PLOT X,Y+9:PLOT X+2,Y+8:PLOT X+2,Y+9:RETURN
110 PLOT X+2,Y:DRAWTO X+2,Y+9:RETURN
150 PLOT X,Y+1:PLOT X+1,Y:DRAWTO X+1,Y+8:PLOT X,Y+8:PLOT X+2,Y+8:GOTO 50
190 REM TWO
200 PLOT X,Y:DRAWTO X+2,Y:DRAWTO X+2,Y+5:DRAWTO X,Y+4:DRAWTO X,Y+8:DRAWTO X+2,Y+8:PLOT X,Y+1:PLOT X+1,Y+1
210 PLOT X+1,Y+5:PLOT X,Y+9:DRAWTO X+2,Y+9:RETURN
250 PLOT X,Y:DRAWTO X+2,Y:DRAWTO X+2,Y+4:DRAWTO X,Y+4:DRAWTO X,Y+8:DRAWTO X+2,Y+8:GOTO 50
290 REM THREE
300 PLOT X,Y:DRAWTO X+2,Y:DRAWTO X+2,Y+9:DRAWTO X,Y+9:PLOT X,Y+8:PLOT X+1,Y+8:PLOT X,Y+4:PLOT X+1,Y+4
310 PLOT X,Y+5:PLOT X+1,Y+5:PLOT X+1,Y+1:PLOT X,Y+1:RETURN
350 PLOT X,Y:DRAWTO X+2,Y:DRAWTO X+2,Y+8:DRAWTO X,Y+8:PLOT X,Y+4:PLOT X+1,Y+4:GOTO 50
390 REM FOUR
400 PLOT X,Y:DRAWTO X,Y+4:DRAWTO X+2,Y+4:DRAWTO X+2,Y:DRAWTO X+2,Y+9:PLOT X,Y+5:PLOT X+1,Y+5:RETURN
450 PLOT X,Y:DRAWTO X,Y+4:DRAWTO X+2,Y+4:PLOT X+2,Y:DRAWTO X+2,Y+8:GOTO 50
490 REM FIVE
500 PLOT X+2,Y:DRAWTO X,Y:DRAWTO X,Y+5:DRAWTO X+2,Y+4:DRAWTO X+2,Y+9:DRAWTO X,Y+9:PLOT X+1,Y+1:PLOT X+2,Y+1
510 PLOT X+1,Y+8:PLOT X+1,Y+5:PLOT X,Y+8:RETURN
550 PLOT X+2,Y:DRAWTO X,Y:DRAWTO X,Y+4:DRAWTO X+2,Y+4:DRAWTO X+2,Y+8:DRAWTO X,Y+8:GOTO 50
590 REM SIX
600 PLOT X,Y:DRAWTO X,Y+9:DRAWTO X+2,Y+9:DRAWTO X+2,Y+4:PLOT X+1,Y+5:PLOT X+1,Y+8:PLOT X+1,Y+4:RETURN
650 PLOT X,Y:DRAWTO X,Y+8:DRAWTO X+2,Y+8:DRAWTO X+2,Y+4:PLOT X+1,Y+4:GOTO 50
690 REM SEVEN
700 PLOT X,Y:DRAWTO X+2,Y:DRAWTO X+2,Y+9:PLOT X,Y+1:PLOT X+1,Y+1:RETURN
750 PLOT X,Y:DRAWTO X+2,Y:DRAWTO X+2,Y+8:GOTO 50
790 REM EIGHT
800 PLOT X,Y:DRAWTO X+2,Y:DRAWTO X+2,Y+9:DRAWTO X,Y+9:DRAWTO X,Y:PLOT X+1,Y+1:PLOT X+1,Y+4:PLOT X+1,Y+5
810 PLOT X+1,Y+8:RETURN
850 PLOT X,Y:DRAWTO X+2,Y:DRAWTO X+2,Y+8:DRAWTO X,Y+8:DRAWTO X,Y:PLOT X+1,Y+4:GOTO 50
890 REM NINE
900 PLOT X+2,Y+9:DRAWTO X+2,Y:DRAWTO X,Y:DRAWTO X,Y+5:PLOT X+1,Y+1:PLOT X+1,Y+4:PLOT X+1,Y+5:RETURN
950 PLOT X+2,Y+8:DRAWTO X+2,Y:DRAWTO X,Y:DRAWTO X,Y+4:PLOT X+1,Y+4:GOTO 50
990 REM TEN
1000 PLOT X-2,Y:DRAWTO X-2,Y+9:GOTO 90
1005 REM ELEVEN
1010 PLOT X-1,Y:DRAWTO X-1,Y+9:PLOT X+1,Y:DRAWTO X+1,Y+9:RETURN
1015 REM TWELVE
1020 PLOT X-2,Y:DRAWTO X-2,Y+9:GOTO 200
1040 REM RETURN
1050 ANS$=STR$(ANS):IF LEN(ANS$)<>(X-XS)/4 THEN 1400
1060 X=X-4:FOR I=LEN(ANS$) TO 1 STEP -1:X=X-4:IF D(X)-1=VAL(ANS$(I,I)) THEN NEXT I:GOTO 1450
1065 POP :GOTO 1400
1099 REM DELETE
1100 IF X=XS THEN 1200
1105 COLOR 7:X=X-8
1110 PLOT X+4,Y:DRAWTO X+4,Y+8:PLOT X+5,Y:DRAWTO X+5,Y+8:PLOT X+6,Y:DRAWTO X+6,Y+8:COLOR 8:GOTO 50
1190 REM INVALID KEY
1200 SOUND 0,230,10,8:PLOT B,181:PLOT B,182:X=X-4:B=B+C:SOUND 0,0,0,0:GOTO 50
1290 REM ERRORS
1300 TRAP 1300:IF B>79 THEN 1400
1310 X=X+4:IF PEEK(K+N)=12 THEN 1100
1320 IF PEEK(K+N)=11 THEN 1050
1330 IF PEEK(K+N)<>14 THEN 1200
1340 GOTO 2400
1390 REM WRONG ANSWER
1400 SOUND 0,78,12,8:W=W+1:WRONG(W,1)=R+1:WRONG(W,2)=D2:GOTO 1800
1440 REM CORRECT ANSWER
1450 CORRECT=CORRECT+1:X=BROW(CORRECT):Y=153:SOUND 0,18,10,8
1460 ON CORRECT GOSUB 110,200,300,400,500,600,700,800,900,1000,1010,1020:GOTO 1800
1490 REM SETUP MULTIPLICATION PROBLEM
1500 POP :GOSUB 9400
1530 FOR I=1 TO 12:D(I)=I:NEXT I:T=12
1600 B=1:C=SKILL(COL/2):X=33:Y=38:COLOR 6:R=ROW-2:IF ROW=14 THEN R=INT(RND(0)*11)+1
1610 IF T=0 THEN 3000
1620 POKE 764,255:IF R>8 THEN X=34
1630 ON R GOSUB 200,300,400,500,600,700,800,900,1000,1010,1020
1640 X=38:Y=38:PLOT X,Y:DRAWTO X+2,Y+9:PLOT X+2,Y:DRAWTO X,Y+9
1645 X=43:Y=38:N2=INT(RND(0)*T)+1:D2=D(N2):D(N2)=D(T):IF COL<8 THEN D2=13-T
1650 T=T-1:ANS=(R+1)*D2:IF D2>9 THEN X=44
1660 XS=36:IF ANS>99 THEN XS=34
1670 IF ANS<10 THEN XS=38
1690 ON D2 GOSUB 100,200,300,400,500,600,700,800,900,1000,1010,1020
1700 X=XS-4:Y=153:COLOR 8:PLOT 0,180:DRAWTO 0,183:GOTO 50
1790 REM ERASE DISPLAYS
1800 COLOR 1:FOR I=38 TO 47:PLOT 32,I:DRAWTO 46,I:NEXT I:COLOR 7
1810 FOR I=153 TO 161:PLOT 32,I:DRAWTO 46,I:NEXT I:COLOR 2:PLOT 0,180:DRAWTO 0,183:PLOT 1,181:DRAWTO 79,181
1820 PLOT 1,182:DRAWTO 79,182:SOUND 0,0,0,0:GOTO 1600
1990 REM MENU SCREEN
2000 GOSUB 9300:POKE 708,198:POKE 709,152:POKE 710,42:POKE 711,50
2020 ? #6;" select"
2030 ? #6;"multiplication table"
2040 ? #6;" 2 "
2050 FOR Y=4 TO 13:POSITION 9,Y:? #6;Y-1:NEXT Y:Y=19
2060 ? #6;" MIX"
2070 POSITION 1,17:? #6;"option skill level"
2080 POSITION 2,19:? #6;"1 2 3 4 5 6 7 8 9";
2090 POSITION 3,23:? #6;"start to begin":GOTO 2100
2095 POSITION 3,23:? #6;"START":POP
2096 POSITION 3,23:? #6;"start"
2100 Q=PEEK(53279):ON Q GOSUB 2095,2095,2300,2095,2200,1500,2095
2150 FOR I=1 TO 24:IF PEEK(53279)<>Q THEN POP :GOTO 2100
2160 NEXT I
2170 Q2=PEEK(53279):IF Q=Q2 THEN ON Q GOSUB 2170,2170,2300,2170,2200,1500,2170:GOTO 2170
2180 GOTO 2100
2190 REM SELECT TABLE
2200 FOR X=9 TO 11:LOCATE X,ROW,CH:POKE 85,X:? #6;CHR$(CH-128):NEXT X:ROW=ROW+1:IF ROW=15 THEN ROW=3
2210 SOUND 0,N-(12*ROW),10,8
2220 FOR X=9 TO 11:LOCATE X,ROW,CH:POKE 85,X:? #6;CHR$(CH+128);:NEXT X:SOUND 0,0,0,0:RETURN
2290 REM OPTION SKILL
2300 LOCATE COL,Y,CH:POSITION COL,Y:? #6;CHR$(CH-128):COL=COL+2:IF COL=20 THEN COL=2
2310 LOCATE COL,Y,CH:POSITION COL,Y:? #6;CHR$(CH+128)
2320 SOUND 0,N-(COL/2*16),10,8:FOR I=1 TO 13:NEXT I:SOUND 0,0,0,0:RETURN
2390 REM M KEY>MENU
2400 COLOR 1:FOR I=38 TO 47:PLOT 32,I:DRAWTO 46,I:NEXT I:COLOR 7
2410 FOR I=153 TO 161:PLOT 32,I:DRAWTO 46,I:NEXT I:COLOR 2:PLOT 0,180:DRAWTO 0,183:PLOT 1,181:DRAWTO 79,181
2420 PLOT 1,182:DRAWTO 79,182:SOUND 0,0,0,0
2430 COLOR 1:FOR I=1 TO CORRECT:X=BROW(I):ON I GOSUB 110,200,300,400,500,600,700,800,900,1000,1010,1020:NEXT I
2450 W=0:CORRECT=0:N=220:COL=2:ROW=3:GOTO 2000
2990 REM GAME FINISH
3000 FOR I=1 TO 50:NEXT I
3010 COLOR 8:X=BROW(CORRECT):Y=153:FOR I=1 TO 20:IF PEEK(200)=7 THEN COLOR 8:SOUND 0,30,10,6:GOTO 3020
3015 COLOR 7:SOUND O,200,10,8
3020 ON CORRECT GOSUB 110,200,300,400,500,600,700,800,900,1000,1010,1020:NEXT I:SOUND 0,0,0,0
3050 COLOR 1:FOR I=1 TO CORRECT:X=BROW(I):ON I GOSUB 110,200,300,400,500,600,700,800,900,1000,1010,1020:NEXT I
3055 REM WRONG ANSWERS SCREEN
3060 GOSUB 9300:POKE 708,88:POKE 709,38:POKE 710,26:POKE 711,50:POKE 712,4
3065 IF CORRECT=12 THEN 3150
3070 IF CORRECT<>11 THEN 3075
3072 ? #6;" answer to wrong problem":GOTO 3078
3075 ? #6;" answers to wrong problems"
3078 ? #6;"____________________":IF CORRECT<7 THEN POKE 84,3
3080 FOR I=1 TO 12-CORRECT:POKE 85,5-LEN(STR$(WRONG(I,1))):? #6;WRONG(I,1);
3090 POKE 85,6:? #6;"X ";WRONG(I,2);:POKE 85,11:? #6;"=";:POKE 85,13:? #6;WRONG(I,1)*WRONG(I,2)
3095 IF CORRECT>2 THEN ? #6;"____________________":IF CORRECT<7 THEN POKE 84,PEEK(84)-1
3098 NEXT I:IF CORRECT<3 THEN ? #6;"____________________"
3099 IF CORRECT>3 THEN ? #6
3100 ? #6;" start to continue "
3105 ? #6;" option for menu"
3110 IF CORRECT=12 THEN X=PEEK(708):POKE 708,PEEK(710):POKE 710,X
3120 FOR I=1 TO 12:X=PEEK(53279):IF X=6 OR X=3 THEN POP :GOTO 3200
3130 NEXT I:GOTO 3110
3150 FOR X=0 TO 20 STEP 4:POKE 84,X:? #6;"____________________":? #6;"____________________":NEXT X
3170 POSITION 5,5:? #6;" EXCELLENT ":POKE 84,11:GOTO 3100
3200 IF X=6 THEN 3500
3202 GOTO 2450
3205 REM SETUP TO PLAY AGAIN
3300 COLOR 7:FOR I=152 TO 162:PLOT 31,I:DRAWTO 47,I:NEXT I
3310 FOR I=1 TO 77 STEP 4:PLOT I,178:PLOT I,185:NEXT I:GOTO 2450
3490 REM 8/9 CORRECT
3500 GOSUB 9400:IF CORRECT<8 THEN FOR I=1 TO 150:NEXT I:GOTO 2450
3510 CH=1:N=4
3520 COLOR 0:FOR I=152 TO 162:PLOT 31,I:DRAWTO 47,I:NEXT I
3525 COLOR 2:FOR I=1 TO 77 STEP 4:PLOT I,178:PLOT I,185:NEXT I
3530 FOR I=1 TO 16:IF CORRECT<9 THEN 3560
3540 IF CH=1 THEN POKE 711,66:POKE 712,24:CH=0:GOTO 3560
3550 POKE 711,24:POKE 712,66:CH=1
3560 FOR X=1 TO 14:COLOR N:PLOT STAR(X,1),STAR(X,2):N=N+1:IF N=9 THEN N=4
3562 NEXT X:NEXT I:COLOR 0:FOR I=1 TO 14:PLOT STAR(I,1),STAR(I,2):NEXT I
3565 IF CORRECT<10 THEN 3300
3568 REM 10 CORRECT
3570 FOR X=0 TO 255 STEP 2:SOUND 0,X/2,10,8:POKE 708,X:SOUND O,X,10,8:NEXT X
3580 FOR X=255 TO 0 STEP -2:SOUND 0,X/2,10,8:POKE 708,X:SOUND O,X,10,8:NEXT X
3590 SOUND 0,0,0,0:FOR X=1 TO 100:NEXT X
3600 IF CORRECT<11 THEN 3300
3605 REM 11/12 CORRECT
3610 J=0:SOUND 0,37,4,8
3620 X=S+3337:FOR I=S+8105 TO S+8024 STEP -9:FOR J=0 TO 4:POKE X+J,PEEK(I+J):NEXT J:X=X-40:FOR J=1 TO 18:NEXT J
3630 NEXT I:SOUND 0,0,0,0:COLOR 3:FOR Y=1 TO 100:NEXT Y
3640 IF CORRECT=11 THEN 3720
3650 FOR N=1 TO 2:I=35:J=43:FOR ROW=83 TO 80 STEP -1:COLOR 8:PLOT I,ROW:PLOT J,ROW:FOR X=1 TO 18:NEXT X:COLOR 6
3660 PLOT I,ROW:PLOT J,ROW:I=I+1:J=J-1:NEXT ROW:FOR X=1 TO 18:NEXT X
3670 NEXT N:COLOR 3
3680 X2=82:FOR N=1 TO 5:I=35:J=43:FOR ROW=83 TO 80 STEP -1:COLOR 8:PLOT I,ROW:PLOT J,ROW:SOUND 0,X2,0,8:X2=X2-2
3690 FOR X=1 TO 17:NEXT X:COLOR 6
3700 PLOT I,ROW:PLOT J,ROW:I=I+1:J=J-1:NEXT ROW:SOUND 0,X2,0,8:X2=X2-2:FOR X=1 TO 17:NEXT X
3710 NEXT N:COLOR 3:GOTO 3740
3720 FOR I=82 TO 40 STEP -2:SOUND 0,I,0,8:FOR X=1 TO 18:NEXT X:NEXT I
3740 FOR I=1 TO 8:Q=USR(1536,A(I),B(I),C(I),40-C(I),E(I)):SOUND 0,29+I*3,0,8:FOR X=1 TO 15:NEXT X:NEXT I
3750 FOR I=1 TO 30:NEXT I:SOUND 0,0,0,0:FOR I=1 TO 100:NEXT I
3760 SOUND 0,37,4,8:COLOR 3
3770 FOR I=74 TO 83:PLOT 35,I:DRAWTO 43,I:FOR X=1 TO 25:NEXT X:NEXT I:SOUND 0,0,0,0
3780 FOR I=1 TO 150:NEXT I
3790 IF CORRECT=11 THEN 3300
3795 REM 12 CORRECT
3800 SOUND 0,37,4,8:COLOR 3
3810 X=S+3337:FOR I=S+9898 TO S+9849 STEP -5:FOR J=0 TO 4:POKE X+J,PEEK(I+J):NEXT J:X=X-40:FOR J=1 TO 18:NEXT J
3820 NEXT I:SOUND 0,0,0,0:FOR Y=1 TO 100:NEXT Y
3855 FOR X=1 TO 30:NEXT X:SOUND 0,58,0,8:FOR X=1 TO 60:NEXT X
3860 FOR I=7 TO 0 STEP -1:Q=USR(1536,A(I),B(I),C(I),40-C(I),E(I)):SOUND 0,I*3+34,0,8:FOR X=1 TO 15:NEXT X:NEXT I
3870 SOUND 0,32,0,8:FOR X=1 TO 40:NEXT X:SOUND 0,0,0,0:FOR X=1 TO 50:NEXT X
3900 SOUND 0,37,4,8
3910 FOR I=74 TO 83:PLOT 35,I:DRAWTO 43,I:FOR X=1 TO 25:NEXT X:NEXT I:SOUND 0,0,0,0
3920 FOR I=1 TO 50:NEXT I:GOTO 3300
8990 REM INITIALIZE
9000 DIM IO$(39),A(8),B(8),C(8),D(40),E(8),SKILL(9),BROW(12),WRONG(12,2),STAR(14,2),ANS$(3)
9010 IO$="hhh◣◣◣◣*hh↓B┘h↓E┘h↓D┘h↓I┘h↓H┘ Vd┤T)♥┐U◆":PAGE=PEEK(106)
9020 POKE 106,PAGE-16:GRAPHICS 10:S=PEEK(88)+256*PEEK(89):POKE 106,PAGE:GRAPHICS 2+16:POKE 84,1
9030 ? #6;" SPACE STATION- MULTIPLICATION":? #6;" ________________"
9035 POKE 84,5:? #6;" PROGRAM BY:":? #6;" bob follett":POKE 84,7
9040 ? #6;" ________________ ":? #6;" ANTIC (C) 1990 ":? #6;" -one moment-"
9050 OPEN #1,4,0,"D1:MULTI.PIC":Q=USR(ADR(IO$),1,7,S,10348):Q=USR(ADR(IO$),1,7,1536,151)
9060 CLOSE #1:FOR I=1 TO 9:READ X:SKILL(I)=X:NEXT I
9070 DATA .1,.125,.16,.25,.3,.45,.6,.8,1
9100 FOR I=1 TO 12:READ X:BROW(I)=X:NEXT I:POKE 559,0
9110 DATA 1,5,9,13,17,21,25,51,55,62,68,74
9120 FOR I=1 TO 14:READ X,X2:STAR(I,1)=X:STAR(I,2)=X2:NEXT I
9130 DATA 67,93,50,137,7,124,21,13,58,16,44,9,38,125,72,131,72,43,22,134,7,32,58,115,12,91,19,109
9200 FOR I=0 TO 8:READ X,X2,X3,X4:A(I)=S+X:B(I)=S+X2:C(I)=X3:E(I)=X4:NEXT I
9210 DATA 9903,4815,9,21,7680,4135,9,38,8022,2975,9,67,8625,2975,9,56,9129,2895,9,34,9435,2896,7,29
9220 DATA 9638,2896,7,20,9778,2897,5,15,9853,2977,5,10
9240 ROW=3:COL=2:N=220:K=S+10092
9250 TRAP 1300:POKE 729,0:GOTO 2000
9290 REM SCREEN CALLS
9300 POKE 106,PAGE:GRAPHICS 17:GOTO 9500
9400 POKE 106,PAGE-16:POKE 704,8:POKE 705,2:POKE 706,4:POKE 707,6
9410 GRAPHICS 42:POKE 708,0:POKE 709,10:POKE 710,12:POKE 711,24:POKE 712,66
9490 REM DISABLE BREAK KEY
9500 POKE 16,64:POKE 53774,64:RETURN
