Collapsing Deck Solitaire (COLLDECK.BAS)
Collapsing Deck Solitaire by A. R. Miller, 55
Description
Collapsing Deck Solitaire by A. R. Miller, 55
From the Antic disk of Antic: June/July 1990 - Vol. 9 No. 2 — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 6.8 KB
- Dialect
- Atari BASIC
- Lines
- 119
- Variables
DK(,CD(,PT(,F$,V$,L$,I,Y,X,KC,KP,ED,F,V,Z,F1,V1,E,QQ
BASIC listing (119 lines)
100 REM **********************
110 REM * COLLAPSING DECK *
120 REM * BY A. R. MILLER *
140 REM **********************
150 REM (c)1990, ANTIC PUBLISHING,INC.
160 REM TITLE PAGE
170 GRAPHICS 1+16:POSITION 1,4:? #6;"*******************"
180 POSITION 1,5:? #6;"* COLLAPSING DECK *"
190 POSITION 1,6:? #6;"* a. r. miller *"
200 POSITION 1,7:? #6;"* 1989 *"
210 POSITION 1,8:? #6;"*******************"
220 REM SET UP
230 DIM DK(54),CD(4,13),PT(2,56),F$(4),V$(26),L$(2):OPEN #1,4,0,"K:"
240 F$="♠♥◆♣":V$="A 2 3 4 5 6 7 8 9 10J Q K "
250 REM SET UP POINTERS
260 I=1:FOR Y=4 TO 16 STEP 2:FOR X=0 TO 35 STEP 5:PT(1,I)=X:PT(2,I)=Y:I=I+1:NEXT X:NEXT Y
270 REM SHUFFLE DECK
280 FOR I=1 TO 53:DK(I)=0:NEXT I:GRAPHICS 1+16:POSITION 3,6:? #6;"SHUFFLING DECK"
290 FOR X=1 TO 4:FOR Y=1 TO 13:CD(X,Y)=0:NEXT Y:NEXT X
300 FOR I=1 TO 52
310 X=INT(RND(0)*4+0.5):Y=INT(RND(0)*13+0.5):IF CD(X,Y) THEN 310
320 IF X<1 OR X>4 THEN 310
330 IF Y<1 OR Y>13 THEN 310
340 CD(X,Y)=1:DK(I)=X*100+Y:NEXT I:KC=2:KP=2:ED=52
350 REM MAIN PRINTING LOOP
360 GRAPHICS 0:POSITION 0,1:? "***********COLLAPSING DECK***********";
370 POSITION 0,19:? "............... COMMANDS .............";
380 POSITION 1,20:? "1 BACK ONE";:POSITION 1,21:? "3 BACK THREE";
390 POSITION 15,20:? "N NEXT CARD";:POSITION 15,21:? "A ALL CARDS";
400 POSITION 1,22:? "E END GAME";:POSITION 15,22:? "L MOVE TO END"
410 POSITION 1,23:? "< MOVE LEFT";:POSITION 15,23:? "> MOVE RIGHT"
420 POSITION 32,20:? "CARDS":POSITION 32,21:? "LEFT":POSITION 33,22:? ED-KC
430 FOR I=1 TO KC:F=INT(DK(I)/100):V=(DK(I)-F*100)
440 POSITION PT(1,I),PT(2,I):? F$(F,F);V$(2*V-1,2*V);:NEXT I
450 POSITION PT(1,KP)+1,PT(2,KP)+1:? "^";:POKE 752,1
460 GET #1,Z:REM DO WHAT?
470 IF Z=49 THEN 570:REM BACK ONE CARD
480 IF Z=51 THEN 660:REM BACK THREE CARDS
490 IF Z=78 OR Z=110 THEN 860:REM NEXT CARD
500 IF Z=65 OR Z=97 THEN 890:REM ALL CARDS
510 IF Z=69 OR Z=101 THEN 920:REM END GAME
520 IF Z=76 OR Z=108 THEN 810:REM MOVE TO LAST CARD
530 IF Z=60 THEN 740:REM MOVE LEFT
540 IF Z=62 THEN 780:REM MOVE RIGHT
550 FOR I=1 TO 30:SOUND 1,29,10,10:SOUND 1,243,10,10:NEXT I:SOUND 1,0,0,0:GOTO 460
560 REM BACK ONE CARD
570 IF KP=1 THEN 550:REM YOU CANNOT DO THAT
580 F=INT(DK(KP)/100):V=DK(KP)-F*100:F1=INT(DK(KP-1)/100):V1=DK(KP-1)-F1*100
590 IF F=F1 THEN 620
600 IF V=V1 THEN 620
610 GOTO 550:REM YOU CANNOT DO THAT
620 FOR I=KP-1 TO ED-1:DK(I)=DK(I+1):NEXT I:KP=KP-1:KC=KC-1:ED=ED-1
630 IF ED=1 THEN 920:REM GO TO END OF GAME
640 GOTO 360
650 REM BACK THREE CARDS
660 IF KP<4 THEN 550:REM YOU CANNOT DO THAT
670 F=INT(DK(KP)/100):V=DK(KP)-F*100:F1=INT(DK(KP-3)/100):V1=DK(KP-3)-F1*100:IF F=F1 THEN 700
680 IF V=V1 THEN 700
690 GOTO 550:REM YOU CANNOT DO THAT
700 DK(KP-3)=DK(KP):FOR I=KP TO ED-1:DK(I)=DK(I+1):NEXT I:DK(ED)=0:KP=KP-3:KC=KC-1:ED=ED-1
710 IF ED=1 THEN 920:REM GO TO END OF GAME
720 GOTO 360
730 REM MOVE LEFT
740 IF KP=1 THEN 550:REM YOU CANNOT DO THAT
750 POSITION PT(1,KP)+1,PT(2,KP)+1:? " ";:SOUND 1,200,10,10:SOUND 1,0,0,0:KP=KP-1
760 POSITION PT(1,KP)+1,PT(2,KP)+1:? "^";:SOUND 1,200,10,10:SOUND 1,0,0,0:GOTO 460
770 REM MOVE RIGHT
780 IF KP=KC THEN 550:REM YOU CANNOT DO THAT
790 POSITION PT(1,KP)+1,PT(2,KP)+1:? " ";:SOUND 1,200,10,10:SOUND 1,0,0,0:KP=KP+1
800 POSITION PT(1,KP)+1,PT(2,KP)+1:? "^";:SOUND 1,200,10,10:SOUND 1,0,0,0:GOTO 460
810 REM MOVE TO LAST CARD
820 IF KP=KC THEN SOUND 1,200,10,10:SOUND 1,0,0,0:GOTO 460
830 POSITION PT(1,KP)+1,PT(2,KP)+1:? " ";:SOUND 1,200,10,10:SOUND 1,0,0,0:KP=KC
840 POSITION PT(1,KP)+1,PT(2,KP)+1:? "^";:SOUND 1,200,10,10:SOUND 1,0,0,0:GOTO 460
850 REM NEXT CARD
860 IF KC=ED THEN 550:REM YOU CANNOT DO THAT
870 KC=KC+1:GOTO 360
880 REM ALL CARDS
890 IF KC=ED THEN 550:REM YOU CANNOT DO THAT
900 KC=ED:GOTO 360
910 REM END GAME
920 Z=0:FOR I=1 TO ED-1:F=INT(DK(I)/100):V=DK(I)-F*100:F1=INT(DK(I-1)/100):V1=DK(I-1)-F1*100
930 IF F=F1 THEN 960
940 IF V=V1 THEN 960
950 GOTO 970
960 Z=1:I=ED
970 NEXT I:IF Z=1 THEN 1060
980 IF E<4 THEN 1110:REM SKIP
990 FOR I=1 TO ED-3
1000 F=INT(DK(I)/100):V=DK(I)-F*100:F1=INT(DK(I-1)/100):V1=DK(I-1)-F1*100:IF F=F1 THEN 1030
1010 IF V=V1 THEN 1030
1020 GOTO 1040
1030 Z=1:I=ED-2
1040 NEXT I:IF Z=1 THEN 1060
1050 GOTO 1110:REM FINAL SCORE
1060 GRAPHICS 1+16:POSITION 3,4:? #6;"PLEASE RECHECK"
1070 POSITION 5,5:? #6;"YOUR HAND":POSITION 4,6:? #6;"I HAVE FOUND"
1080 POSITION 2,7:? #6;"AT LEAST ONE MORE":POSITION 7,8:? #6;"PLAY!!"
1090 FOR I=1 TO 50:SOUND 1,99,10,10:SOUND 1,0,0,0:NEXT I:FOR QQ=1 TO 400:NEXT QQ:GOTO 360
1100 REM END OF GAME
1110 GRAPHICS 1+16:POSITION 1,2:? #6;"YOU HAVE SUCCEEDED":POSITION 1,3:? #6;"COLLAPSING THE"
1120 POSITION 4,4:? #6;"DECK DOWN TO":POSITION 9,5:? #6;ED:POSITION 7,6:? #6;"CARDS"
1130 IF ED=1 THEN POSITION 4,8:? #6;"none better!":GOTO 1240
1140 IF ED<3 THEN POSITION 5,8:? #6;"fantastic":GOTO 1240
1150 IF ED<5 THEN POSITION 7,8:? #6;"great!":GOTO 1240
1160 IF ED<7 THEN POSITION 4,8:? #6;"you're good":GOTO 1240
1170 IF ED<9 THEN POSITION 6,8:? #6;"not bad":GOTO 1240
1180 IF ED<11 THEN POSITION 0,8:? #6;"You've played before":GOTO 1240
1190 IF ED<15 THEN POSITION 1,8:? #6;"you've got promise":GOTO 1240
1200 IF ED<20 THEN POSITION 4,8:? #6;"keep trying":GOTO 1240
1210 IF ED<25 THEN POSITION 7,8:? #6;"rookie!":GOTO 1240
1220 IF ED<30 THEN POSITION 3,8:? #6;"are you sick?":GOTO 1240
1230 POSITION 7,8:? #6;"novice!"
1240 FOR I=1 TO 300:NEXT I:POSITION 0,10:? #6;"DO YOU WANT TO PLAY":POSITION 7,11:? #6;"AGAIN?";
1250 POKE 752,1:GET #1,Z
1260 IF Z=89 OR Z=121 THEN 280:REM YES
1270 IF Z=78 OR Z=110 THEN POSITION 0,10:? #6;"you CAN'T STAND ANOTHER CHALLENGE?":REM END
1280 FOR I=1 TO 400:NEXT I:END
1290 GOTO 1250
