The Gold Mine And The Princess (GOLDMINE.BAS)
The Gold Mine And The Princess, game by 431 (BASIC, text)
Description
The Gold Mine And The Princess, game by 431 (BASIC, text)
From the Antic disk of Antic: April/May 1990 - Vol. 9 No. 1.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 31.2 KB
- Dialect
- Atari BASIC
- Lines
- 619
- Variables
QQ,QX,X,A$,N$,S,Q,DOWRY,F,H1,H2,BELL,H,A,REST,F1,E,V,C,CL,K,L,WTRAP,D,WI,B1,W,I,EMCO,BELLRING,R,G,Y,O,P1,AA,XYZ,CG,CN,PH,B,P,HV,M,Z,CM,RA,T,RF,GF,BF,WF,N,CAN,XY,D1,FALL,U,ER,BOX,WC,PIT,VOL,XXX,NA,J,XX,RING,HOME,MEET,TIMES,XG,OB,BX,BY,CW,PD,PO,SE,SP
BASIC listing (619 lines)
1 REM The Gold Mine
2 REM BY WILLIAM A. AUSTIN
3 REM C. 1987-WILLIAM A. AUSTIN
4 REM VERSION 13.5
5 GRAPHICS 0:? "↰":POKE 752,1:POKE 710,195
10 QQ=1000:QX=100:X=INT(10*RND(1))+1:IF X=1 THEN QQ=50:QX=50
12 IF X=10 THEN QQ=5000:QX=1000
50 DIM A$(1),N$(15):S=25:Q=INT(QQ*RND(1))+QX:DOWRY=Q*INT(75*RND(1))+15:F=S
1000 REM VILL
1010 ? "↰":H1=0:H2=0:POKE 710,195:IF BELL=1 THEN BELL=0
1050 ? " YOU ARE IN THE VILLAGE "
1100 POKE 710,195:GOSUB 3050:GOSUB 10020:IF H<0 THEN H=0
1150 GOSUB 11000:OPEN #5,4,0,"K":GET #5,A:CLOSE #5
1205 IF A=49 THEN IF REST=1 THEN ? "↰":POSITION 2,12:? "YOU CAN'T REST, YOU'RE NOT TIRED!":GOSUB 10020:GOTO 1999
1210 IF A=49 THEN F=S:F1=0:E=0:? "↰":POSITION 2,12:? "YOU FEEL RESTED, AND READY FOR WORK.":IF V>0 THEN V=V-1
1212 IF A=49 THEN GOSUB 10020:? "↰":REST=1
1220 IF A=50 THEN GOTO 4000
1230 IF A=51 THEN ? "↰":GOSUB 4500
1240 IF A=52 THEN ? "↰":C=C+CL:CL=0:GOSUB 4600
1250 IF A=53 THEN ? "↰":K=K+C+CL:C=0:CL=0:POSITION 2,12:? "YOU HAVE ";K;" COINS CACHED.":GOSUB 10010:? "↰"
1260 IF A=54 THEN ? "↰":C=C+K+CL:K=0:POSITION 2,12:? "YOU HAVE ";C;" COINS.":GOSUB 10010:? "↰"
1270 IF A=55 THEN ? "↰":GOSUB 4700
1280 IF A=56 THEN GOSUB 12000
1285 IF A=57 THEN ? "↰":POSITION 2,6:? "GOLD ORE: ";L:? :? :? "COINS ON HAND: ";CL+C:? :? :? "COINS CACHED: ";K
1287 IF A=57 THEN ? :? :? "HERD SIZE: ";H:GOSUB 10010
1999 ? "↰":GOTO 1100
2000 REM MINE
2010 ? "↰":S=S+1:REST=0:IF WTRAP=1 THEN GOTO 2060
2012 IF D=0 THEN GOTO 4000
2025 IF WI>0 THEN GOSUB 9400
2050 GOSUB 4050
2060 GOSUB 4200:IF WTRAP=1 THEN GOTO 2100
2062 IF B1=1 THEN GOSUB 9015
2063 IF W=1 THEN ? :IF D=15 THEN ? "THE SHAFT WOLF IS CRAWLING BEHIND YOU.":GOTO 2067
2065 IF W=1 THEN IF D>1 THEN IF D<21 THEN ? "A LARGE SHAFT WOLF IS BEHIND YOU."
2067 IF W=1 THEN IF D=1 THEN ? "THE SHAFT WOLF IS CURLED UP, ASLEEP."
2068 IF W=1 THEN IF D>20 THEN IF D<25 THEN ? "THE SHAFT WOLF IS CRAWLING BEHIND YOU."
2069 IF W=1 THEN IF D=25 THEN ? "THE SHAFT WOLF IS SITTING QUIETLY,":? "WATCHING YOU..."
2070 GOSUB 4400
2100 GOSUB 10040:OPEN #5,4,0,"K":GET #5,A:CLOSE #5:GOSUB 11000:? "↰"
2150 IF A=85 THEN IF WTRAP=1 THEN ? "YOU'RE IN A SHAFT WOLF TRAP, ";N$:GOSUB 10040:FOR I=1 TO 250:NEXT I:GOTO 2000
2152 IF A=68 THEN IF WTRAP=1 THEN ? "YOU'RE IN A SHAFT WOLF TRAP, ";N$:GOSUB 10040:FOR I=1 TO 250:NEXT I:GOTO 2000
2154 IF D=0 THEN IF A=85 THEN GOSUB 10110:GOTO 1000
2200 IF A=85 THEN D=D-1:IF EMCO=1 THEN H=H-D
2202 IF A=85 THEN GOSUB 10110:GOTO 2000
2210 IF A=68 THEN D=D+1:IF EMCO=1 THEN H=H+D
2212 IF A=68 THEN GOSUB 10100:GOTO 2000
2220 IF A=71 THEN GOSUB 4300
2230 IF A=76 THEN ? "↰":? "YOU ARE CARRYING ";L;" GOLD NUGGETS.":?
2235 IF A=67 THEN GOSUB 9050:? :GOSUB 4915
2240 IF A=80 THEN GOSUB 9100
2243 IF A=89 THEN IF D=10 THEN GOSUB 9300
2245 IF A=82 THEN IF D=20 THEN BELLRING=1:GOSUB 15000
2250 IF A=89 THEN IF D=25 THEN GOSUB 9210
2255 IF A=72 THEN GOTO 2300
2266 IF A=79 THEN IF D=10 THEN GOSUB 9325
2267 IF A=79 THEN IF D=14 THEN GOSUB 17000
2268 IF A=79 THEN IF D<>10 THEN IF D<>14 THEN ? "↰":? "THERE IS NOTHING HERE TO OPEN, ";N$
2270 IF A=82 THEN IF D<>20 THEN ? "↰":? "THERE IS NOTHING HERE TO RING, ";N$
2272 IF A=69 THEN IF D<>25 THEN ? "↰":? "THERE IS NOTHING TO EMPTY, ";N$
2274 IF A=69 THEN IF D=25 THEN GOSUB 9210
2278 IF B1=1 THEN GOSUB 9015
2280 IF A=84 THEN IF WTRAP=0 THEN ? "YOU'RE NOT IN A TRAP, ";N$:GOSUB 10040:FOR I=1 TO 100:NEXT I:GOTO 2000
2282 IF A=84 THEN GOSUB 7105
2283 IF WTRAP=1 THEN GOTO 2100
2290 GOSUB 4400
2299 GOTO 2100
2300 REM HELP
2302 ? "↰":POSITION 2,3:? "YOU CAN...":?
2304 ? "GO UP OR DOWN,":?
2305 ? "CLIMB OUT OF A TRAP,":?
2306 ? "SEARCH FOR GOLD, RING A BELL,":?
2307 ? "OPEN A CHEST, EMPTY A SACK,":?
2308 ? "SEARCH YOUR PACK,":?
2309 ? "SEE HOW HEAVY YOUR GOLD LOAD IS,":?
2310 ? "CHECK YOUR PHYSICAL CONDITION,":?
2312 ? "OR, DECIDE YES OR NO."
2349 GOTO 2100
3000 REM MISC MENU
3050 ? :? "WHAT WOULD YOU LIKE TO DO?"
3055 ? :? "(1) REST AND RECUPERATE?"
3060 ? :? "(2) GO TO THE MINE?"
3065 ? :? "(3) EXCHANGE YOUR ORE FOR COINS?"
3070 ? :? "(4) GO TO CATTLE AUCTION?"
3075 ? :? "(5) HIDE YOUR COINS IN A SECRET CACHE?"
3080 ? "(6) TAKE YOUR COINS FROM THE CACHE?"
3085 ? :? "(7) COUNT YOUR CATTLE?"
3090 ? :? "(8) TRY TO BUY THE PRINCESS?"
3095 ? :? "(9) CURRENT ASSETS?"
3099 RETURN
4000 REM ENT
4010 ? "↰":POKE 710,4:? "YOU ARE AT THE MINE ENTRANCE.":GOSUB 11000:F=S
4015 IF C>0 THEN C=0:? :? "SOMEONE STOLE YOUR COINS!! YOU SHOULD HAVE HIDDEN THEM!":GOSUB 10000
4020 GOTO 2100
4050 REM DEEP
4054 POKE 710,0
4055 ? :IF D>0 THEN IF D<3 THEN ? "YOU ARE IN A WIDE PASSAGE."
4060 IF D>2 THEN IF D<5 THEN ? "YOU ARE IN A LARGE CAVERN."
4065 IF D=5 THEN ? "YOU ARE AT A NARROW SHAFT."
4070 IF D>5 THEN IF D<9 THEN ? "YOU ARE IN A NARROW, SLOPING PASSAGE."
4075 IF D>8 THEN IF D<10 THEN ? "YOU ARE AT A STEEPLY SLOPED SHAFT."
4080 IF D=10 THEN ? "YOU ARE IN A LARGE, CRUDELY MINED CAVERN. THIS IS THE MINE BOTTOM."
4082 IF D=10 THEN ? :? "THERE IS A SMALL TUNNEL SLOPING DOWN."
4083 IF D=10 THEN ? :? "THERE ARE WOODEN CHESTS PILED":? "AGAINST THE WALL."
4085 IF D>10 THEN IF D<13 THEN ? "YOU ARE IN A TWISTING CAVE."
4090 IF D>12 THEN IF D<15 THEN ? "YOU ARE IN A SLOPED, NARROW SHAFT."
4092 IF D=14 THEN ? :? "THERE ARE CHESTS NEAR THE WALL."
4095 IF D=15 THEN ? "YOU ARE IN A TUNNEL SO SMALL, YOU MUSTCRAWL ON YOUR HANDS AND KNEES."
4100 IF D>15 THEN IF D<20 THEN ? "YOU ARE IN A SERIES OF NATURAL TUNNELSAND SHAFTS."
4105 IF D=20 THEN ? "YOU ARE IN A LARGE, NATURAL CAVERN.":?
4107 IF D=20 THEN ? "THERE IS AN IRON BELL HANGING FROM":? "THE CEILING.":?
4115 IF D>20 THEN IF D<25 THEN ? "YOU ARE IN A NARROW CREVICE."
4120 IF D=25 THEN ? "YOU ARE IN A HUGE, NATURAL CAVERN.":?
4122 IF D=25 THEN ? "ALONG ONE WALL ARE HUNDREDS OF CANVAS BAGS.":IF BELL=1 THEN BELL=0:RETURN
4123 IF D=25 THEN RETURN
4125 IF D>25 THEN ? :? "YOU CAN'T GO FURTHER DOWN. YOU ARE AT THE BOTTOM.":D=25:RETURN
4149 RETURN
4200 REM FAT
4205 IF R=1 THEN RETURN
4210 IF D>0 THEN IF D<11 THEN F=F-1
4215 IF D>10 THEN IF D<16 THEN F=F-2
4220 IF D>15 THEN IF D<21 THEN F=F-3
4225 IF D>20 THEN F=F-5
4250 ? :IF F<21 THEN IF F>15 THEN ? "YOU ARE SHORT OF BREATH.":? :GOSUB 10130
4255 IF F>10 THEN IF F<16 THEN ? "YOU ARE HAVING TROUBLE BREATHING.":? :FOR I=1 TO 2:GOSUB 10130:NEXT I
4260 IF F>5 THEN IF F<11 THEN ? "YOU ARE GASPING FOR BREATH.":? :FOR I=1 TO 3:GOSUB 10130:NEXT I
4265 IF F>2 THEN IF F<6 THEN ? "YOUR THROAT IS CLOSING!":? :FOR I=1 TO 4:GOSUB 10130:NEXT I
4270 IF F>0 THEN IF F<3 THEN ? "YOU CANNOT BREATH!!":? :FOR I=1 TO 5:GOSUB 10130:NEXT I
4275 IF F<=0 THEN GOTO 13010
4299 RETURN
4300 REM GOLD
4302 ? "↰"
4305 GOSUB 4200
4308 IF G=1 THEN GOTO 4350
4310 Y=D*4:X=INT(100*RND(0))+1
4320 IF X<=Y THEN GOTO 4350
4330 POSITION 14,10:? "NO GOLD HERE.":FOR I=1 TO 75:NEXT I:? "↰":RETURN
4350 X=INT(5*RND(0))+2:O=D*X
4355 IF P1=1 THEN O=O*10
4357 IF AA=1 THEN AA=0:O=O*INT(25*RND(1))+2
4360 ? :? "YOU HAVE FOUND ";O;" NUGGETS 0F GOLD!!"
4375 L=L+O:O=0
4377 IF L<=S THEN RETURN
4380 IF L>S THEN O=L-S:L=L-O
4390 ? :? "YOU CAN'T CARRY THAT MUCH.":? :? "YOU ARE CARRYING ";L;" NUGGETS.":? :? "YOU LEFT ";O;" BEHIND."
4399 RETURN
4400 REM ENC
4410 IF D>0 THEN IF D<6 THEN Y=10
4415 IF D>5 THEN IF D<11 THEN Y=5
4420 IF D>10 THEN IF D<16 THEN Y=4
4425 IF D>15 THEN IF D<21 THEN Y=3
4430 IF D>20 THEN Y=2
4450 X=INT(Y*RND(0))+1:IF X=1 THEN GOTO 4470
4455 RETURN
4470 XYZ=INT(4*RND(0))+1
4475 IF XYZ=1 THEN GOSUB 5000
4477 IF XYZ=2 THEN GOSUB 6000
4479 IF XYZ=3 THEN GOSUB 7000
4481 IF XYZ=4 THEN GOSUB 8000
4499 RETURN
4500 ? "↰":POKE 710,50:REM ORE EX
4502 GOSUB 11000:POSITION 14,1:? "Assay Office"
4505 IF L=0 THEN POSITION 2,12:? "YOU HAVE NO ORE TO EXCHANGE, ";N$;""
4507 IF L=0 THEN GOSUB 10000:? "↰":POKE 710,195:RETURN
4510 X=INT(7*RND(0)):CG=X*L:L=0
4515 POSITION 2,5:? "ORE GRADE: ";
4520 IF X=0 THEN ? "FOOL'S GOLD"
4530 IF X=1 THEN ? "VERY POOR"
4535 IF X=2 THEN ? "POOR"
4540 IF X=3 THEN ? "AVERAGE"
4545 IF X=4 THEN ? "GOOD"
4550 IF X=5 THEN ? "VERY GOOD"
4555 IF X=6 THEN ? "MOTHER LODE!"
4560 GOSUB 10020:GOSUB 10020
4575 C=C+CG+CL:CL=0
4580 POSITION 2,12:? "COINS RECEIVED: ";CG:CG=0
4599 GOSUB 10020:? "↰":POKE 710,195:RETURN
4600 POKE 710,64:? "↰":POSITION 14,1:? "Cattle Sale":REM BUY CATTLE
4605 GOSUB 11000:IF H1=1 THEN POSITION 2,12:? "THE CATTLE SALE IS OVER, ";N$:GOSUB 10000:? "↰":RETURN
4608 CN=INT(115*RND(1))+5:POSITION 2,6:? "CATTLE FOR SALE: ";CN;" HEAD"
4610 PH=INT(46*RND(0))+5:POSITION 2,10:? "PRICE PER HEAD: ";PH;" GOLD COINS"
4620 IF H1=0 THEN H1=1
4625 GOSUB 10020
4630 POSITION 2,14:? "HOW MANY WOULD YOU LIKE TO BUY";:INPUT B:IF B=0 THEN ? "↰":GOTO 17100
4632 IF B>CN THEN ? "↰":POSITION 2,12:? "NOT THAT MANY AVAILABLE, ";N$:GOSUB 10000:? "↰":RETURN
4635 ? "↰":P=B*PH
4640 IF P>C THEN POSITION 2,12:? "YOU DON'T HAVE ENOUGH GOLD, ";N$:GOSUB 10000:? "↰":RETURN
4650 POSITION 2,12:Y=B:B=0:? "YOU JUST BOUGHT ";Y;" HEAD OF CATTLE.":H=H+Y:C=C-P:HV=H*PH:GOSUB 10500
4699 ? "↰":RETURN
4700 ? "↰":REM COUNT CATTLE
4702 POSITION 2,12:POKE 710,47
4710 IF H2=1 THEN ? "YOU HAVE ";H;" HEAD OF CATTLE.":GOSUB 10020:GOTO 4795
4720 IF H2=0 THEN H2=1:IF H<5 THEN ? "YOU HAVE ";H;" HEAD OF CATTLE.":GOTO 4795
4730 X=INT(6*RND(0))+1:Y=INT(5*RND(1))+2:IF H>50 THEN IF H<101 THEN Y=Y*2
4732 IF H<6 THEN Y=2
4734 POSITION 2,8
4735 IF H>100 THEN Y=Y*5
4740 IF X=1 THEN GOTO 4750
4741 IF X=2 THEN GOTO 4755
4742 IF X=3 THEN GOTO 4760
4744 IF X=4 THEN GOTO 4765
4746 IF X=5 THEN GOTO 4770
4748 IF X=6 THEN GOTO 4755
4750 ? "WOLVES ATE ";Y;" OF YOUR HERD.":H=H-Y:? :? :? "YOU HAVE ";H;" HEAD OF CATTLE.":GOSUB 10000:GOTO 4795
4755 H=H+Y:? "YOU HAD ";Y;" CALVES BORN.":? :? :? "YOU HAVE ";H;" HEAD OF CATTLE.":GOSUB 10030:GOTO 4795
4760 ? "YOU HAVE ";H;" HEAD OF CATTLE.":GOSUB 10020:GOTO 4795
4765 ? :? "RUSTLERS STOLE ";Y;" OF YOUR HERD.":H=H-Y:? :? :? "YOU HAVE ";H;" HEAD OF CATTLE.":GOSUB 10000:GOTO 4795
4770 ? :? Y;" WILD CATTLE JOINED YOUR HERD.":H=H+Y:? :? :? "YOU HAVE ";H;" HEAD OF CATTLE.":GOSUB 10030:GOTO 4795
4795 HV=H*PH:POSITION 2,16:? "VALUE OF THE HERD: ";HV;" GOLD PIECES":GOSUB 10500:? "↰":RETURN
4800 REM E
4810 E=E+1:GOTO 4850
4815 E=E+2:GOTO 4850
4820 E=E+3:GOTO 4850
4825 E=E+5:GOTO 4850
4830 E=E+9:GOTO 4850
4850 IF E>=20 THEN GOTO 13020
4860 RETURN
4900 REM VEN
4910 V=V+1
4915 ? :IF V=1 THEN ? "YOUR STOMACH CRAMPS."
4920 IF V=2 THEN ? "YOU FEEL A LITTLE NAUSEOUS."
4925 IF V=3 THEN ? "YOUR STOMACH CRAMPS SEVERELY."
4930 IF V=4 THEN ? "YOU FEEL VERY NAUSEATED."
4935 IF V=5 THEN ? "YOU HAVE A HEADACHE."
4940 IF V=6 THEN ? "YOU ARE HAVING PROBLEMS WITH YOUR VISION."
4945 IF V=7 THEN ? "YOU ARE HAVING PROBLEMS WITH YOUR BALANCE."
4950 IF V=8 THEN ? "YOU ARE ALMOST BLIND."
4955 IF V=9 THEN ? "YOU CAN BARELY WALK."
4960 IF V>=10 THEN GOTO 13030
4999 RETURN
5000 REM MON
5005 IF W=1 THEN ? :? "YOU HEAR SOMETHING RUNNING AWAY.":RETURN
5010 ? :M=INT(15*RND(1))+1
5020 IF M=1 THEN ? "A RAT RAN OVER YOUR FOOT, AND BIT YOU!":XYZ=INT(3*RND(1))+1:IF XYZ=1 THEN B1=1
5025 IF M=2 THEN ? "A RAT RAN OVER AND LICKED YOU!":B1=0
5030 IF M=3 THEN GOSUB 5100
5035 IF M=4 THEN ? "YOU BRUSHED AGAINST A SPIDER WEB.":? :? "A LARGE BLACK SPIDER BIT YOU!":V=V+2:GOSUB 4900
5040 IF M=5 THEN ? "SOMETHING SLIMY FELL ON YOU!! IT STUNGYOU AND FELL OFF."
5042 IF M=5 THEN GOSUB 4900
5045 IF M=6 THEN ? "A SMALL BROWN SNAKE BIT YOUR FOOT!":V=V+6:GOSUB 4900
5050 IF M=7 THEN GOSUB 5120
5055 IF M=8 THEN GOSUB 5130
5057 IF M=9 THEN GOSUB 5155
5060 IF M=10 THEN GOSUB 5165
5065 IF M=11 THEN GOSUB 5200
5070 IF M=12 THEN ? "YOU BRUSHED AGAINST A SPIDER WEB."
5072 IF M=13 THEN ? "A SMALL RED SNAKE BIT YOUR FOOT!":V=V+3:GOSUB 4900
5074 IF M=14 THEN ? "YOU BRUSHED AGAINST A SPIDER WEB.":? :? "A SMALL RED SPIDER BIT YOU!":? :V=9:GOSUB 4950
5076 IF M=15 THEN GOSUB 16000
5099 RETURN
5100 Z=INT(3*RND(1))+1
5105 IF Z=1 THEN ? "A SHAFT WOLF RUNS OUT OF THE DARKNESS,LOOKS AT YOU AND THEN LOPES AWAY."
5110 IF Z=2 THEN ? "A SHAFT WOLF RUNS BY, NIPS YOU AND RUNS OFF.":GOSUB 4810
5115 IF Z=3 THEN ? "A SHAFT WOLF JUMPS OUT, SLASHES AT YOUWITH HIS TEETH AND RUNS ON!":GOSUB 4825
5119 RETURN
5120 IF D<11 THEN ? "YOU HEAR SCRATCHING AND SCAMPERING BELOW YOU.":RETURN
5122 Z=INT(5*RND(1))+2:? "YOU ARE ATTACKED BY ";Z;" GIANT RATS!!"
5125 ? "THEY BITE YOU AND RUN AWAY!!":E=E+Z:GOSUB 4800
5127 RETURN
5130 IF D<21 THEN ? "YOU HEAR SCREAMING FROM BELOW.":RETURN
5135 ? "↰":? "AHEAD OF YOU IS A HUGE, SLOBBERING,":? "SIX-LEGGED THING..."
5137 ? :? :? :? " The Beast Of The Deep!":GOSUB 10200
5140 Z=INT(3*RND(1))+1:IF Z=1 THEN GOSUB 13050
5145 ? :? :? "HE BEGINS TO GIBBER AND SCREAM,":? "AND THEN RUNS AWAY!!":GOSUB 10200
5147 CM=INT(2000*RND(1))+500:? :? "HE LEFT BEHIND ";CM;" GOLD COINS!!":GOSUB 10200
5150 CL=CL+CM:RETURN
5155 IF D<6 THEN ? "YOU HEAR SCAMPERING AND SQUEAKING BELOW YOU.!":RETURN
5160 ? "HUNDREDS OF RATS ATTACK YOU, BITING AND SCRATCHING!! SUDDENLY, THEY RUN AWAY!":B1=1:E=E+5:GOSUB 4800
5162 RETURN
5165 IF D<16 THEN ? "YOU HEAR A WHISPER OF WINGS.":RETURN
5167 X=INT(10*RND(1))+2
5170 ? "SUDDENLY, ";X;" BATS SWOOP DOWN ON YOU, SUCKING YOUR BLOOD!!":? "THEY BITE, AND FLY AWAY!!"
5171 E=E+X:GOSUB 4800
5172 X=X*15:S=S-X:IF S<1 THEN GOTO 13020
5175 IF L>S THEN Y=L-S:L=S
5180 ? "YOU ARE SO WEAK YOU MUST LEAVE ":? Y;" NUGGETS.":? "YOU ARE NOW CARRYING ";L;" NUGGETS."
5187 RETURN
5200 IF WI>0 THEN GOTO 5000
5210 ? "A SMALL, WIZENED OLD MAN STEPS OUT OF THE SHADOWS.":?
5215 IF RA=1 THEN ? "HE LOOKS AT YOU, GRUMBLES AND DISAPPEARS INTO THE DARKNESS.":RETURN
5220 ? "HE GESTURES AT YOU AND VANISHES INTO THE GLOOM."
5225 WI=INT(7*RND(1))+1
5249 RETURN
5999 RETURN
6000 REM TR
6010 T=INT(13*RND(0))+1:?
6020 IF T=1 THEN GOSUB 6100
6022 IF T=2 THEN GOSUB 6120
6024 IF T=3 THEN GOSUB 6150
6026 IF T=4 THEN GOSUB 6170
6028 IF T=5 THEN GOSUB 6200
6030 IF T=6 THEN GOSUB 6270
6032 IF T=7 THEN GOSUB 6300
6034 IF T=8 THEN GOSUB 6330
6036 IF T=9 THEN GOSUB 6350
6038 IF T=10 THEN GOSUB 6370
6040 IF T=11 THEN GOSUB 6240
6050 IF T=12 THEN GOSUB 6390
6060 IF T=13 THEN GOSUB 14500
6099 RETURN
6100 IF P1=1 THEN ? "YOUR GOLDEN PICK-AXE IS GONE!":P1=0:RETURN
6110 IF P1=0 THEN ? "YOU FOUND A GOLDEN PICK AXE!":P1=1:RETURN
6120 IF G=1 THEN ? "YOUR BEETLE CRAWLED AWAY!":G=0:RETURN
6125 IF G=0 THEN ? "YOU FOUND A GOLD BEETLE!":?
6135 X=INT(10*RND(0))+1:IF X=1 THEN ? "HE BIT YOU AND RAN AWAY!":GOSUB 4900:RETURN
6140 ? "HE IS IN YOUR POCKET.":G=1:RETURN
6150 IF W=1 THEN ? "THE SHAFT WOLF DISAPPEARED.":W=0:RETURN
6155 IF W=0 THEN ? "A LARGE, SHAGGY SHAFT WOLF HAS BEGUN FOLLOWING YOU!!":W=1:RETURN
6170 IF RF=1 THEN ? "THERE IS DEAD RED FUNGUS ON THE WALL.":RETURN
6175 IF RF=0 THEN ? "THERE IS SOME RED FUNGUS GROWING ON THE WALL.":GOSUB 9200
6180 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:IF A=89 THEN IF B1=1 THEN ? :? "MMMMM!! GOOD!":B1=0:RETURN
6181 IF A=89 THEN IF B1=0 THEN GOSUB 4900:RETURN
6182 GOSUB 9202:OPEN #5,4,0,"K":GET #5,A:CLOSE #5:IF A=78 THEN RETURN
6185 ? "↰":RF=1:RETURN
6200 IF GF=1 THEN ? "THERE IS SOME DEAD GREEN FUNGUS ON THEWALL.":RETURN
6202 ? "THERE IS GREEN FUNGUS ON THE WALL":GOSUB 9200
6205 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:IF A=89 THEN 6215
6210 GOSUB 9202:OPEN #5,4,0,"K":GET #5,A:CLOSE #5:IF A=89 THEN ? "↰":GF=1:RETURN
6212 RETURN
6215 GF=0:? "↰":V=0:RETURN
6240 IF R=1 THEN ? "YOUR RING IS GONE!!":R=0:RETURN
6245 IF R=0 THEN ? "YOU FOUND A BONE RING.":R=1:RETURN
6270 CM=INT(200*RND(0))+1:? "YOU HAVE FOUND ";CM;" GOLD COINS."
6280 CL=CL+CM:CM=0:RETURN
6300 IF BF=1 THEN ? "THERE IS SOME DEAD BLACK FUNGUS ON THE WALL.":RETURN
6310 IF BF=0 THEN ? "THERE IS BLACK FUNGUS ON THE WALL":GOSUB 9200
6315 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:IF A=89 THEN POP :BF=0:D=25:GOTO 2000
6320 GOSUB 9202:OPEN #5,4,0,"K":GET #5,A:CLOSE #5:IF A=89 THEN BF=1
6325 ? "↰":RETURN
6330 IF WF=1 THEN ? "THERE IS SOME DEAD WHITE FUNGUS ON THEWALL.":RETURN
6335 ? "THERE IS WHITE FUNGUS ON THE WALL":GOSUB 9200
6340 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:IF A=89 THEN POP :WF=0:D=0:GOTO 1000
6345 GOSUB 9202:OPEN #5,4,0,"K":GET #5,A:CLOSE #5:IF A=89 THEN WF=1
6348 ? "↰":RETURN
6350 IF N=1 THEN ? "YOUR CATS-EYE NECKLACE IS GONE!!":N=0:RETURN
6355 ? "YOU FOUND A CATS-EYE NECKLACE.":N=1:RETURN
6370 IF RA=0 THEN ? "YOU FOUND A RUBY AMULET.":RA=1:RETURN
6380 IF RA=1 THEN ? "YOUR AMULET IS GONE!":RA=0:? :GOSUB 5200
6390 IF CAN=1 THEN ? "THE CANARY FLEW AWAY.":CAN=0:GOSUB 10400:RETURN
6392 XY=INT(2*RND(1))+1:IF XY=1 THEN GOSUB 10410:? "A CANARY LIT ON YOUR SHOULDER!":CAN=1:RETURN
6394 GOSUB 10410:? "A CANARY FLEW BY!":GOSUB 10400:RETURN
6399 RETURN
7000 ? :REM DIS
7005 IF N=1 THEN ? "YOU HEAR A RUMBLING AND HISSING.":RETURN
7010 D1=INT(7*RND(1))+1
7020 IF D1=1 THEN ? "SOME ROCKS FELL FROM THE CEILING AND STRUCK YOU.":GOSUB 4810:GOSUB 10120
7022 IF D1=2 THEN ? "YOU SLIPPED AND FELL";:GOSUB 10000:? " INTO AN OPEN SHAFT!":GOSUB 10120:FALL=INT(10*RND(1))+3
7023 IF D1=2 THEN GOSUB 4820:D=D+FALL:IF D>25 THEN D=25
7024 IF D1=3 THEN ? "A GREEN GAS!":GOSUB 10300:? "↰":IF CAN=1 THEN RETURN
7025 IF D1=3 THEN V=V+INT(6*RND(1))+1:GOSUB 4915
7026 IF D1=4 THEN ? "A RED GAS!":GOSUB 10300:? "↰":IF CAN=1 THEN RETURN
7027 IF D1=4 THEN F=F/10:F=INT(F):RETURN
7028 IF D1=5 THEN GOSUB 7100
7030 IF D1=6 THEN GOSUB 7120
7032 IF D1=7 THEN ? "A PURPLE GAS!":GOSUB 10300:? "↰":IF CAN=1 THEN RETURN
7034 IF D1=7 THEN D=INT(25*RND(1))+1
7099 RETURN
7100 ? "YOU HAVE FALLEN":GOSUB 10000:? " INTO":GOSUB 10000
7102 ? " A SHAFT WOLF TRAP!!":GOSUB 10120:WTRAP=1:RETURN
7105 Z=INT(3*RND(0))+1:GOSUB 4810:? "↰":IF B1=1 THEN GOSUB 9015
7110 GOSUB 10110:IF Z=1 THEN ? "YOU CLIMBED OUT.":WTRAP=0:RETURN
7112 GOSUB 10100:? "YOU SLIPPED AND FELL BACK IN! ":GOSUB 4200:RETURN
7120 ? "A YELLOW GAS!":GOSUB 10300:? "↰":IF CAN=1 THEN RETURN
7121 IF L>0 THEN ? :? "YOU FEEL AS IF YOU HAD LOST WEIGHT!!"
7122 L=0:CL=0:IF P1=1 THEN ? "THE GOLDEN PICK-AXE VANISHED!":P1=0
7124 RETURN
8000 REM MISC
8010 U=INT(6*RND(0))+1:?
8020 IF U=1 THEN ? "THERE ARE WOLF PRINTS IN THE DIRT."
8022 IF U=2 THEN ? "YOU HEAR HOWLING FROM BELOW."
8024 IF U=3 THEN ? "YOU HEAR THE SOUND OF ROCKS FALLING BENEATH YOU.":GOSUB 10120
8026 IF U=4 THEN ? "YOU SEE EYES GLOWING IN THE DARKNESS AHEAD..."
8028 IF U=5 THEN ? "YOU HEAR SQUEAKING AND THE RUSTLE OF WINGS BELOW YOU."
8030 IF U=6 THEN ? "YOU HEAR A GHOSTLY VOICE FROM BELOW, CALLING 'COME FURTHER DOWN, ";N$;",":? "FURTHER DOWN!'"
8999 RETURN
9000 REM MISC MAT II
9015 ? :F1=F1+1
9020 IF F1>2 THEN IF F1<6 THEN ? "YOU FEEL A LITTLE FEVERISH.":GOSUB 10130
9025 IF F1>5 THEN IF F1<9 THEN ? "YOU FEEL VERY FEVERISH.":FOR I=1 TO 2:GOSUB 10130:NEXT I
9030 IF F1>8 THEN IF F1<12 THEN ? "YOU FEEL UNSTEADY ON YOUR FEET!":FOR I=1 TO 3:GOSUB 10130:NEXT I
9035 IF F1>11 THEN IF F1<15 THEN ? "YOU'RE ABOUT TO COLLAPSE!":FOR I=1 TO 4:GOSUB 10130:NEXT I
9040 IF F1>=15 THEN GOTO 13040
9049 RETURN
9050 REM PHY CH
9055 ? "↰":IF E<=0 THEN ? "YOU ARE UNHARMED."
9060 IF E>0 THEN IF E<3 THEN ? "YOU HAVE A FEW SCRATCHES."
9065 IF E>2 THEN IF E<6 THEN ? "YOU ARE CUT AND BRUISED."
9070 IF E>5 THEN IF E<11 THEN ? "YOU HAVE A FEW SERIOUS WOUNDS."
9075 IF E>10 THEN IF E<16 THEN ? "YOU ARE WOUNDED AND BLEEDING."
9080 IF E>15 THEN IF E<20 THEN ? "YOU HAVE SOME NEAR LETHAL WOUNDS!!"
9090 IF E>=20 THEN GOTO 13020
9099 RETURN
9100 REM PACK
9105 ? "↰"
9110 IF CAN+GF+RF+G+CL+BF+WF+RA+R+P1+N+ER+EMCO=0 THEN ? "YOU HAVE NOTHING.":RETURN
9120 IF GF=1 THEN ? "YOU HAVE A PIECE OF GREEN FUNGUS":? "DO YOU WISH TO EAT IT?":OPEN #5,4,0,"K":GET #5,A:CLOSE #5
9121 IF A=78 THEN ? "↰":GOTO 9125
9122 V=0:GF=0:? "↰"
9125 IF RF=0 THEN 9150
9127 ? "YOU HAVE A PIECE OF RED FUNGUS.":? "DO YOU WISH TO EAT IT?":OPEN #5,4,0,"K":GET #5,A:CLOSE #5
9129 IF A=78 THEN ? "↰":GOTO 9150
9130 ? "MMMMM! GOOD!!":B1=0:RF=0:? :? "↰":GOTO 9150
9150 IF BF=0 THEN 9160
9152 ? "YOU HAVE A PIECE OF BLACK FUNGUS.":? "DO YOU WISH TO EAT IT?":OPEN #5,4,0,"K":GET #5,A:CLOSE #5
9155 IF A=78 THEN ? "↰":GOTO 9160
9157 POP :BF=0:D=25:WTRAP=0:GOTO 2000
9160 IF WF=0 THEN 9166
9162 ? "YOU HAVE A PIECE OF WHITE FUNGUS.":? "DO YOU WISH TO EAT IT?":OPEN #5,4,0,"K":GET #5,A:CLOSE #5
9163 IF A=78 THEN ? "↰":GOTO 9166
9164 WF=0:POP :D=0:WTRAP=0:GOTO 1000
9166 IF GF=0 THEN 9170
9170 IF RA=1 THEN ? "YOU HAVE A RUBY AMULET.":?
9172 IF P1=1 THEN ? "YOU'RE CARRYING A GOLDEN PICK AXE.":?
9174 IF R=1 THEN ? "YOU'RE WEARING A BONE RING.":?
9176 IF N=1 THEN ? "YOU'RE WEARING A CATS-EYE NECKLACE.":?
9177 IF EMCO=1 THEN ? "YOU HAVE A SMALL EMERALD COW!":?
9178 IF CAN=1 THEN ? "THERE'S A CANARY ON YOUR SHOULDER!":?
9180 IF G=1 THEN ? "THERE'S A BEETLE IN YOUR POCKET!":?
9181 IF ER=1 THEN ? "YOU HAVE A DIAMOND RING!":?
9182 IF CL<1 THEN 9199
9184 ? "YOU'RE CARRYING ";CL;" COINS."
9199 RETURN
9200 ? "DO YOU WANT TO EAT IT?":RETURN
9202 ? "↰":? "DO YOU WANT TO PICK IT?":RETURN
9210 REM BAGS
9220 Y=INT(25*RND(1))+1:IF Y=1 THEN GOTO 13060
9221 IF Y>12 THEN IF ER=0 THEN ER=1:? :? "YOU HAVE FOUND A DIAMOND RING!":RETURN
9225 CM=INT(899*RND(1))+100
9245 ? "THERE ARE ";CM;" GOLD PIECES IN THE BAG!!"
9248 CL=CL+CM:CM=0:IF CL<=S*10 THEN RETURN
9249 IF CL>S*10 THEN ? :? "THAT'S ALL YOU CAN CARRY!"
9251 CM=CL-S*10:? :? "YOU HAD TO LEAVE ";CM;" COINS."
9259 RETURN
9300 REM CHEST
9325 Z=INT(20*RND(1))+1:? "↰"
9326 BOX=BOX+1:IF BOX>12 THEN ? "THEY'RE ALL EMPTY!":RETURN
9327 IF Z=1 THEN GOTO 13060
9329 IF Z>1 THEN AA=1:GOSUB 4350
9349 RETURN
9400 REM WIZ
9410 ? "YOU HEAR LAUGHTER AND....."
9415 WI=WI+1
9420 IF WI=2 THEN GOSUB 7000
9425 IF WI=3 THEN GOSUB 5000
9430 IF WI=4 THEN M=2:GOSUB 5025
9435 IF WI=5 THEN M=6:GOSUB 5045
9440 IF WI=6 THEN GOSUB 4350
9445 IF WI=7 THEN GOSUB 6000
9450 IF WI=8 THEN CM=INT(200*RND(1))+1:? "YOU HAVE FOUND ";CM;" GOLD COINS."
9460 IF WI=8 THEN CL=CL+CM:CM=0
9465 IF WI>8 THEN ? "THERE IS A PUFF OF BLUE SMOKE!!":WI=0:WC=0:GOSUB 10250
9499 RETURN
10000 FOR PIT=100 TO 150:SOUND 0,PIT,10,14:NEXT PIT:SOUND 0,PIT,10,0:RETURN
10010 FOR I=1 TO 50:PIT=INT(25*RND(1))+200:SOUND 0,PIT,10,14:NEXT I:SOUND 0,PIT,10,0:RETURN
10020 FOR VOL=14 TO 0 STEP -0.5:SOUND 0,200,10,VOL:NEXT VOL:RETURN
10030 FOR PIT=150 TO 100 STEP -1:SOUND 0,PIT,10,14:NEXT PIT:SOUND 0,PIT,10,0:RETURN
10040 FOR VOL=14 TO 0 STEP -2:SOUND 0,50,10,VOL:NEXT VOL:RETURN
10100 FOR PIT=100 TO 110:SOUND 0,PIT,10,14:NEXT PIT:SOUND 0,PIT,10,0:RETURN
10110 FOR PIT=110 TO 100 STEP -1:SOUND 0,PIT,10,14:NEXT PIT:SOUND 0,PIT,10,0:RETURN
10120 FOR VOL=14 TO 0 STEP -0.2
10122 SOUND 0,200,8,VOL:SOUND 1,220,6,VOL:SOUND 2,50,4,VOL:NEXT VOL:RETURN
10130 FOR VOL=14 TO 0 STEP -7:SOUND 0,10,10,VOL:NEXT VOL:RETURN
10200 FOR VOL=14 TO 0 STEP -2:FOR PIT=200 TO 50 STEP -15
10210 SOUND 0,PIT,10,VOL:SOUND 1,PIT,4,VOL:NEXT PIT:NEXT VOL:RETURN
10250 FOR VOL=14 TO 0 STEP -2:FOR PIT=50 TO 200 STEP 15
10260 SOUND 0,PIT,10,VOL:SOUND 1,PIT,4,VOL:SOUND 2,PIT,6,VOL:NEXT PIT:NEXT VOL:RETURN
10300 FOR VOL=0 TO 14 STEP 0.2:SOUND 0,50,4,VOL:SOUND 1,100,8,VOL:NEXT VOL
10310 FOR VOL=14 TO 0 STEP -0.2:SOUND 0,50,4,VOL:SOUND 1,100,8,VOL:NEXT VOL:RETURN
10400 FOR VOL=14 TO 0 STEP -1:FOR XXX=1 TO 5:PIT=INT(25*RND(1))+10:SOUND 0,PIT,10,VOL:SOUND 1,PIT+5,10,VOL
10402 SOUND 2,PIT+10,10,VOL:NEXT XXX:NEXT VOL:RETURN
10410 FOR VOL=0 TO 14:FOR XXX=1 TO 5:PIT=INT(25*RND(1))+10:SOUND 0,PIT,10,VOL:SOUND 1,PIT+5,10,VOL
10412 SOUND 2,PIT+10,10,VOL:NEXT XXX:NEXT VOL:SOUND 0,PIT,10,0:SOUND 1,PIT,10,0:SOUND 2,PIT,10,0:RETURN
10500 REM MOO
10515 FOR VOL=0 TO 14 STEP 2:SOUND 0,255,10,VOL:SOUND 1,250,10,VOL:SOUND 2,255,8,VOL:NEXT VOL
10520 FOR PIT=255 TO 200 STEP -3
10530 SOUND 0,PIT,10,14:SOUND 1,PIT-5,10,14:SOUND 2,PIT,8,14:NEXT PIT
10540 FOR I=1 TO 25:NEXT I
10550 FOR VOL=10 TO 0 STEP -1
10560 SOUND 0,200,10,VOL:SOUND 1,195,10,VOL:SOUND 2,200,8,VOL
10570 NEXT VOL:FOR I=1 TO 25:NEXT I:RETURN
11000 NA=INT(10*RND(1))+1:IF NA=1 THEN N$="BOZO!"
11002 IF NA=2 THEN N$="SUCKER!"
11004 IF NA=3 THEN N$="TURKEY!"
11006 IF NA=4 THEN N$="FRIEND!"
11008 IF NA=5 THEN N$="MINER!"
11010 IF NA=6 THEN N$="CHEAPO!"
11012 IF NA=7 THEN N$="COWBOY!"
11014 IF NA=8 THEN N$="JERK!"
11016 IF NA=9 THEN N$="COWPOO!"
11018 IF NA=10 THEN N$="CHUMP!"
11049 RETURN
12000 POKE 710,99:? "↰":REM TRY/BUY
12005 IF BELLRING=0 THEN POSITION 2,10:? "THE PRINCESS SAYS:":? :? "YOU'RE NO BELL-RINGER, ";N$:GOSUB 10000:RETURN
12010 IF ER=0 THEN POSITION 2,10:? "THE PRINCESS SAYS:":? :? "I HAVE NO RING, ";N$:GOSUB 10000:RETURN
12012 IF ER=1 THEN ER=2
12015 IF HV<DOWRY THEN GOTO 12100
12020 ? "↰":GOSUB 10030:? :? :? "THE KING IS VERY PLEASED WITH YOUR GENEROUS OFFER!!!"
12025 ? :? :? "CONGRATULATIONS!":GOSUB 10030
12030 ? :? :? "HERE ";:GOSUB 12090:? "COMES ";:GOSUB 12090:? "THE ";:GOSUB 12094:? "BRIDE!!!":GOSUB 12090:GOSUB 10200
12040 GOTO 14012
12090 FOR VOL=14 TO 0 STEP -0.5:SOUND 0,250,10,VOL:SOUND 1,200,10,VOL:SOUND 2,150,10,VOL:SOUND 3,100,10,VOL
12092 NEXT VOL:RETURN
12094 FOR VOL=14 TO 0 STEP -2:SOUND 0,250,10,VOL:SOUND 1,200,10,VOL:SOUND 2,150,10,VOL:SOUND 3,100,10,VOL
12095 NEXT VOL:RETURN
12100 GOSUB 11000:REM NO BUY
12110 J=J+1:? "↰":GOSUB 10000
12120 IF J=1 THEN ? "THE KING SMILES AND SAYS, 'NOT NEARLY ENOUGH, ";N$;"!'":GOSUB 10000
12125 IF J=2 THEN ? "THE KING FROWNS AND SAYS 'NOT ENOUGH,":? N$;:? " ";N$
12130 IF J=3 THEN ? "THE KING SAYS ANGRILY, 'AN INSULTING OFFER, ";N$
12135 IF J=4 THEN ? "THE KING FROWNS AND SILENTLY TURNS AWAY."
12140 IF J=5 THEN ? "HE MOTIONS TO A GUARD, WHO SMITES YOU WITH A CLUB.":GOSUB 4810
12145 IF J=6 THEN ? "THE KING SHAKES HIS HEAD AND WALKS AWAY, MUTTERING."
12150 IF J=7 THEN ? "THE KING SHOUTS 'YOU INSULT MY DAUGHTER!' AND HITS YOU WITH HIS SCEPTRE!"
12152 IF J=7 THEN GOSUB 4810
12155 IF J=8 THEN ? "THE KING NODS TO HIS EXECUTIONER,"
12156 IF J=8 THEN ? "AND YOU FEEL THE AXE HIT YOUR NECK...":GOSUB 10000:GOTO 14010
12199 GOSUB 10000:GOSUB 10000:? "↰":RETURN
13010 ? "↰":? "YOU JUST DIED OF ASPHYXIATION, ";N$:? :GOSUB 10000:GOTO 14010
13020 ? :? "YOU JUST DIED OF YOUR WOUNDS, ";N$:? :GOSUB 10000:GOTO 14010
13030 ? :? "YOU JUST DIED FROM POISONING, ";N$:? :GOSUB 10000:GOTO 14010
13040 ? "YOU DIED OF RAT-BITE FEVER, ";N$:? :GOSUB 10000:GOTO 14010
13050 ? :? :? "THE Beast TORE YOUR THROAT OUT AND RAN AWAY, GIBBERING AND SCREAMING!":GOSUB 10200
13051 ? :? "TOUGH LUCK, ";N$:GOSUB 10000:GOTO 14010
13060 ? "↰":? "THAT ONE WAS FULL OF DYNAMITE, ";N$:Z=INT(1000*RND(1))+100:GOSUB 10120
13062 POSITION 2,12:? "YOU BLEW YOURSELF INTO ";Z;" PIECES!!":GOSUB 10120:? :? :GOSUB 10000:GOTO 14010
14010 ? :? "YOUR PRINCESS DIED A WIDOW BEFORE SHE WAS A BRIDE!!":GOSUB 10000
14012 GOSUB 11000:POSITION 9,22:? "ANOTHER GAME, ";N$;"?":GOSUB 10040:OPEN #5,4,0,"K":GET #5,A:IF A=89 THEN RUN
14013 IF A=32 THEN ? "↰":? :? :? :? "HERD VALUE: ";HV:? :? :? "DOWRY: ";DOWRY:CLOSE #5:GOTO 14012
14014 ? "↰":GOTO 14014
14500 REM VISION
14510 XX=INT(10*RND(1))+1
14512 ? "YOU HAVE A VISION OF...":? :GOSUB 10010
14520 IF XX=1 THEN ? "A GOLD COIN!":K=K+5000
14522 IF XX=2 THEN ? "AN EMPTY COIN SACK!":K=0
14524 IF XX=3 THEN IF EMCO=1 THEN ? "A SHATTERED EMERALD COW!":EMCO=0:RETURN
14526 IF XX=3 THEN EMCO=1:? "AN EMERALD SHAPED LIKE A COW!"
14530 IF XX=4 THEN ? "A HUGE BELL!":D=20
14532 IF XX=5 THEN ? "A DEEP PIT!":D=25
14534 IF XX=6 THEN ? "A HUGE SKULL!":GOSUB 10010:GOTO 14010
14536 IF XX=7 THEN ? "YOUR HOME!":GOSUB 10010:POP :D=0:GOTO 1000
14537 IF XX=8 THEN IF ER>0 THEN XX=1:GOTO 14520
14538 IF XX=8 THEN IF ER=0 THEN ER=1:? "A DIAMOND RING!"
14540 IF XX=9 THEN ? "A DEAD COW!":H=1
14542 IF XX=10 THEN ? "A SMILING BULL!":H=H+H*INT(10*RND(1))+1:IF H<100 THEN H=INT(50*RND(1))+100
14599 RETURN
15000 REM BELL
15010 IF BELL=2 THEN ? :? "THE BELL IS BROKEN.":RETURN
15020 IF BELL=1 THEN ? :? "THE BELL IS SILENT.":RETURN
15100 BELL=1:RING=INT(18*RND(1))+1:POSITION 2,10:? "WRITING APPEARS ON THE BELL...":?
15110 IF RING=1 THEN ? "A pox on your cows...":H=0
15120 IF RING=2 THEN ? "May your herd multiply...":H=H*3
15130 IF RING=3 THEN ? "May your strength be as ten...":S=S*3
15140 IF RING=4 THEN ? "May you weaken as a child...":S=25
15150 IF RING=5 THEN ? "May your riches grow...":L=S:K=K*10:IF K<1000 THEN K=1000
15160 IF RING=6 THEN ? "May you be blessed with health...":F=S:F1=0:V=0:E=0:B1=0
15170 IF RING=7 THEN ? "May you be cursed with the plague...":B1=1:V=9:E=16:F1=3
15180 IF RING=8 THEN RING=2:GOTO 15120
15190 IF RING=9 THEN RING=3:GOTO 15130
15195 IF RING=10 THEN ? "May I speak no more...":BELL=2
15200 IF RING=11 THEN ? "May you have a safe trip home...":D=0:HOME=1
15210 IF RING=12 THEN ? "May you have many things...":L=S:CL=S*10:RF=1:GF=1:WF=1:BF=1:G=1:RA=1:R=1:P1=1:N=1:EMCO=1
15220 IF RING=13 THEN ? "May your life and breath be short...":F=20
15222 IF RING=14 THEN ? "May you meet new people...":MEET=1
15224 IF RING=15 THEN ? "May many rustlers visit your cows...":H=1
15226 IF RING=16 THEN ? "May fungus grow in your pack...":GF=1:RF=1:WF=1:BF=1
15228 IF RING=17 THEN RING=5:GOTO 15150
15230 IF RING=18 THEN RING=6:GOTO 15160
15300 FOR TIMES=1 TO 3
15310 FOR VOL=14 TO 0 STEP -0.5:SOUND 0,243,10,VOL:SOUND 1,182,10,VOL:SOUND 2,162,10,VOL:SOUND 3,121,10,VOL
15320 NEXT VOL:NEXT TIMES
15330 IF HOME=1 THEN HOME=0:GOTO 2000
15332 IF MEET=1 THEN MEET=0:GOSUB 5135
15399 ? "↰":RETURN
16000 REM GOBLIN
16050 ? "↰"
16075 IF D>10 THEN 16200
16100 IF D<11 THEN ? "YOU HAVE FOUND THE ROTTING BODY OF A MINER."
16105 X=D*100:O=INT(X*RND(1))+100
16110 ? :? "BESIDE HIM IS A SACK WITH ";O:? "GOLD NUGGETS."
16112 L=L+O:O=0
16114 IF L<=S THEN RETURN
16116 IF L>S THEN O=L-S:L=L-O
16118 ? :? "YOU CAN'T CARRY THAT MUCH.":? :? "YOU ARE CARRYING ";L;" NUGGETS.":? :? "YOU LEFT ";O;" BEHIND."
16199 GOSUB 10010:RETURN
16200 XG=INT(5*RND(1))+1:IF XG=1 THEN 16100
16210 ? "A CAVE GOBLIN STEPS OUT OF THE":? "SHADOWS...":GOSUB 10010
16220 IF D=25 THEN 16300
16230 XG=INT(2*RND(1))+1
16232 IF XG=1 THEN 16400
16234 IF XG=2 THEN 16500
16299 GOTO 16199
16300 ? :? "HE TEARS YOUR HEART OUT AND EATS IT!":? :? :GOSUB 10010:GOTO 14010
16399 RETURN
16400 ? :? "HE BITES YOUR FACE, AND THEN":? :? "RUNS AWAY, LAUGHING!":E=E+15:GOSUB 10010:GOSUB 4850
16499 RETURN
16500 ? :? "HE TAKES YOUR HAND AND LEADS YOU DOWN INTO THE MINE.":D=25
16599 RETURN
17000 REM BOX
17005 OB=OB+1:IF OB>10 THEN ? :? "THEY'VE ALL BEEN OPENED!":RETURN
17010 BX=INT(10*RND(1))+1:IF BX=1 THEN 13060
17020 BX=INT(4*RND(1))+1:? "↰":? "YOU HAVE FOUND...":?
17030 IF BX=1 THEN IF G=1 THEN BX=4
17032 IF BX=2 THEN IF P1=1 THEN BX=4
17034 IF BX=3 THEN ? "FUNGUS!":GF=1:RF=1:WF=1:BF=1
17036 IF BX=4 THEN ? "NOTHING!"
17038 IF BX=2 THEN ? "A GOLDEN PICK AXE!":P1=1
17040 IF BX=1 THEN ? "A BEETLE!":G=1
17049 RETURN
17100 REM SELL
17150 BY=INT(3*RND(0))+1:IF BY=1 THEN POSITION 12,12:? "NO BUYERS TODAY.":GOSUB 10500:GOTO 17299
17200 CW=INT(65*RND(1))+5:POSITION 2,6:? "CATTLE WANTED: ";CW;" HEAD"
17210 PD=INT(4*RND(0)):PO=PH-PD:POSITION 2,10:? "OFFER PER HEAD: ";PO;" GOLD COINS"
17225 GOSUB 10020
17230 POSITION 2,14:? "HOW MANY WOULD YOU LIKE TO SELL";:INPUT SE:IF SE=0 THEN ? "↰":RETURN
17232 IF SE>CW THEN ? "↰":POSITION 2,12:? "NOT THAT MANY WANTED, ";N$:GOSUB 10000:? "↰":RETURN
17235 ? "↰":SP=SE*PO
17240 IF SE>H THEN POSITION 2,12:? "YOU DON'T HAVE ENOUGH COWS, ";N$:GOSUB 10000:? "↰":RETURN
17250 POSITION 2,12:Y=SE:? "YOU SOLD ";Y;" HEAD OF CATTLE.":H=H-Y:C=C+SP:HV=H*PH:GOSUB 10500
17299 ? "↰":RETURN
