Finance Program (FINANCE.BAS)

Finance Program by Philip W. Bate, 67

Description

Finance Program by Philip W. Bate, 67

From the Antic disk of Antic: April/May 1990 - Vol. 9 No. 1.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 8.1 KB

Dialect
Atari BASIC
Lines
159
Variables
SPC$, MSG$, YEAR$, HEAD$, HEAD2$, HEAD3$, FINANCE$, D$, MONEY$, MON$, AMT$, MNY$, I$, PRIN$, BAL$, LINE$, PMT$, CHRG$, A, N, P, NUM, PMT, AMT, MONEY, IN, B, C, Q, X, MON, PRIN, Z, O, M, L, I, CHRG, BAL, CP, APR, Y, R, D, DOL
BASIC listing (159 lines)
10 REM FINANCE
20 REM BY Philip W. Bate PhD
25 REM (c)1990, ANTIC PUBLISHING INC.
30 CLOSE #1:OPEN #1,4,0,"K":SETCOLOR 2,13,0:SETCOLOR 0,0,0:POKE 82,1
40 DIM SPC$(39),MSG$(28),YEAR$(4),HEAD$(39),HEAD2$(39),HEAD3$(39),FINANCE$(1100),D$(2)
50 DIM MONEY$(10),MON$(2),AMT$(10),MNY$(10),I$(7),PRIN$(7),BAL$(10),LINE$(39),PMT$(7),CHRG$(7)
60 SPC$=" ":SPC$(39)=" ":SPC$(2)=SPC$:MSG$="PRESS 'RETURN' FOR MAIN MENU"
70 HEAD3$="MON  PYMNT   IN+CHGS PRIN"
80 REM *** MAIN MENU***
90 A=0:N=0:P=0:MNY$="":NUM=0:PMT=0:I$="":PRIN$="":BAL$="":LINE$="":PMT$=""
100 ? "↰":? :? "    MAIN MENU "
110 ? :? "1 - AMOUNT OF PAYMENT"
120 ? :? "2 - NUMBER OF PAYMENTS"
130 ? :? "3 - AMORTIZATION SCHEDULE"
140 ? :? "4 - AMORTIZATION W/ VARYING PAYMENTS"
150 ? :? "5 - APPRECIATION SCHEDULE"
160 ? :? "6 - SAVINGS SCHEDULE"
170 ? :? :? "    CHOOSE ONE ":GOSUB 1090
180 TRAP 1430:ON A-48 GOTO 190,240,290,520,870,930
190 REM ***PAYMENT AMOUNT***
200 ? "↰":GOSUB 1200:GOSUB 1220
210 AMT=INT(MONEY*IN*(1/(1-(1+IN)^(-NUM)))*100+0.5)/100:PMT=AMT:GOSUB 1460
220 ? :? :? "PAYMENTS ARE $";MNY$:? :? "INTEREST IS $";:AMT=PMT*NUM-MONEY:GOSUB 1460:? MNY$
230 POSITION 4,15:? MSG$:GOSUB 1090
240 REM *** NUMBER OF PAYMENTS ***
250 ? "↰":GOSUB 1200:GOSUB 1230
260 NUM=INT(-(LOG(1-MONEY/PMT*IN))/LOG(IN+1)+0.9999)
270 ? :? :? "NUMBER OF PAYMENTS IS ";NUM:? :? "INTEREST IS $";:AMT=PMT*NUM-MONEY:GOSUB 1460:? MNY$
280 POSITION 4,15:? MSG$:GOSUB 1090
290 REM *** AMORTIZATION SCHEDULE ***
300 ? "↰":? "This schedule is automatic given the   data required below, and will print"
310 GOSUB 1170:GOSUB 1220:GOSUB 1230:GOSUB 1270:GOSUB 1300:GOSUB 480
320 B=0:C=0:Q=0
330 FOR X=MON TO NUM+MON-1
340 AMT=INT((MONEY*IN)*100+0.5)/100:GOSUB 1460:I$=MNY$:AMT=PMT-VAL(I$):GOSUB 1460
350 PRIN$=MNY$:PRIN=VAL(PRIN$):AMT=MONEY-PRIN:GOSUB 1530:BAL$=MNY$
360 B=B+PMT:C=C+VAL(I$):Q=Q+PRIN
370 LINE$=SPC$:LINE$(1,2)=MON$:LINE$(4,10)=PMT$:LINE$(12,18)=I$:LINE$(20,26)=PRIN$:LINE$(30,39)=BAL$
380 ? LINE$;:IF P=80 THEN GOSUB 1400
390 MONEY=INT(VAL(BAL$)*100+0.5)/100:MON=MON+1:GOSUB 1280
400 Z=INT(MONEY*(1+IN)*100+0.5)/100:IF PMT>=Z THEN AMT=Z:GOSUB 1460:PMT$=MNY$:PMT=Z
410 IF INT(MON/13)=MON/13 THEN 430
420 TRAP 80:NEXT X
430 ? :? YEAR$;" INTEREST=";C;"    PRIN=";Q:C=0:Q=0
440 IF P=80 THEN GOSUB 1410
450 MON=1:GOSUB 1280:YEAR$=STR$(VAL(YEAR$)+1):X=X+1
460 GOSUB 1140:GOSUB 480
470 GOTO 340
480 HEAD$(1,4)=YEAR$:HEAD$(5,29)=" AMORTIZATION - BALANCE= "
490 HEAD2$="MON  PYMNT   INTRST  PRIN       BALANCE"
500 IF P=80 THEN GOSUB 1370
510 ? "↰":? :? HEAD$;MONEY:? :? HEAD2$:RETURN
520 REM *** AMORTIZATION VARYING PMTS***
530 ? "↰":? "This program is very flexible as it    allows for differing payments and also for various charges."
540 ? "It isn't necessary to enter a zero if  no payment or charge is to be assessed.Simply press the RETURN."
550 ? :? "INPUT STARTING YEAR (PRESS 'RETURN' FOR 1990)";:INPUT YEAR$:IF LEN(YEAR$)=0 THEN YEAR$="1990"
560 GOSUB 1190:GOSUB 1270:GOSUB 1300:GOSUB 770
570 GOSUB 810:B=O:C=0:M=0:L=6
580 IF PMT>=MONEY THEN CHRG$="***":PRIN$="***":AMT=MONEY-PMT:GOSUB 1460:BAL$=MNY$
590 I=(INT((MONEY*IN)*100+0.5)/100):AMT=I+CHRG:GOSUB 1460:CHRG$=MNY$:AMT=PMT-VAL(CHRG$):GOSUB 1460
600 PRIN$=MNY$:PRIN=VAL(PRIN$):IF PMT=0 THEN PRIN=-VAL(CHRG$):PRIN$=PMT$
610 AMT=MONEY-PRIN:GOSUB 1530:BAL$=MNY$
620 B=B+PRIN:C=C+I:M=M+CHRG
630 LINE$(1,38)=SPC$:LINE$(1,2)=MON$:LINE$(4,10)=PMT$:LINE$(12,18)=CHRG$:LINE$(20,26)=PRIN$:LINE$(29,38)=BAL$
640 POSITION 1,L:? LINE$;:IF P=80 THEN GOSUB 1400
650 IF VAL(BAL$)<0 THEN 860
660 IF VAL(BAL$)=0 THEN 710
670 MONEY=INT(VAL(BAL$)*100+0.5)/100:MON=MON+1:GOSUB 1280
680 Z=INT((MONEY*(1+IN)+CHRG)*100+0.5)/100:IF PMT>=Z THEN AMT=Z:GOSUB 1460:PMT$=MNY$:PMT=Z
690 IF INT(MON/13)=MON/13 THEN 710
700 GOSUB 810:L=L+1:PRIN=0:GOTO 580
710 ? :? :? YEAR$;" INTEREST=";C;"    CHARGES=";M:? "PRINCIPAL PAID= ";B
720 IF P=80 THEN GOSUB 1410
730 IF VAL(BAL$)<=O THEN GOSUB 1140:GOTO 80
740 MON=1:GOSUB 1280:YEAR$=STR$(VAL(YEAR$)+1)
750 GOSUB 1140:GOSUB 770
760 GOTO 570
770 HEAD$(1,4)=YEAR$:HEAD$(5,29)=" AMORTIZATION - BALANCE="
780 HEAD2$="MON  PYMNT   IN/CHRG PRIN       BALANCE"
790 IF P=80 THEN GOSUB 1360
800 ? "↰":? :? HEAD$;MONEY:? :? HEAD2$:RETURN
810 POSITION 1,22:? "ENTER PAYMENT";:INPUT PMT$:IF LEN(PMT$)=0 THEN PMT=0:PMT$="   -   ":GOTO 830
820 AMT=VAL(PMT$):GOSUB 1460:PMT$=MNY$:PMT=VAL(PMT$)
830 POSITION 22,22:? "CHARGES";:INPUT CHRG$:IF LEN(CHRG$)=0 THEN CHRG=0:GOTO 850
840 CHRG=VAL(CHRG$)
850 POSITION 1,22:? SPC$;:RETURN
860 ? :? " LOAN OVERPAID BY: ";ABS(VAL(BAL$)):GOTO 710
870 REM *** APPRECIATION ***
880 ? "↰":GOSUB 1200:GOSUB 1250
890 BAL=INT(MONEY*(1+IN)^(CP*NUM)*100+0.5)/100
900 ? :? :? "YOUR INVESTMENT WILL BE WORTH ";BAL
910 POSITION 2,22:? MSG$:GET #1,N:IF N=155 THEN 80
920 GOTO 80
930 REM *** SAVINGS SCHEDULE ***
940 ? "↰":GOSUB 1200:GOSUB 1230:GOSUB 1260:GOSUB 1270:GOSUB 1300
950 B=0:C=0:IN=APR/(1200)
960 GOSUB 1070
970 Y=MON+NUM*12:FOR X=MON TO Y
980 AMT=INT((MONEY*IN)*100+0.5)/100:GOSUB 1460:I$=MNY$:R=AMT:IF AMT=0 THEN I$="   0.00"
990 AMT=MONEY+R+PMT:GOSUB 1530:BAL$=MNY$:MONEY=VAL(BAL$)
1000 ? "  ";MON,PMT$;"  ";I$;"  ";BAL$:IF P=80 THEN GOSUB 1390
1010 MON=MON+1:B=B+VAL(I$):C=C+PMT:IF MON=13 THEN MON=1:GOTO 1040
1020 IF X=Y THEN ? :? "END OF PROGRAM":? MSG$:GET #1,N:GOTO 80
1030 NEXT X
1040 ? :? "INTEREST=";B;"  PAYMENTS=";C:IF P=80 THEN ? #4;CHR$(13);"INTEREST=";B;"  PAYMENTS=";C:REM PRINTS TOTALS
1050 GOSUB 1140:GOSUB 1070:NEXT X
1060 GOSUB 1070:GOTO 1030
1070 ? "↰":? :? "MONTH     PAYMENT  INTEREST   AMOUNT":? :IF P=80 THEN GOSUB 1380
1080 RETURN
1090 REM *** PAUSE ROUTINES ***
1100 GET #1,A:IF A=255 THEN 1100
1110 IF A=155 THEN 80
1120 IF A<48 OR A>89 THEN 1420
1130 RETURN
1140 POSITION 2,22:? MSG$:? "  PRESS ANY KEY TO CONTINUE ":GET #1,N:IF N=255 THEN 1140
1150 IF N=155 THEN 80
1160 RETURN
1170 REM ***INPUTS***
1180 ? "↰":? :? "INPUT STARTING YEAR (PRESS 'RETURN' FOR 1990)";:INPUT YEAR$:IF LEN(YEAR$)=0 THEN YEAR$="1990"
1190 IF VAL(YEAR$)>2050 OR VAL(YEAR$)<1970 THEN 1420
1200 ? :? "ENTER STARTING MONEY AMOUNT";:GOSUB 1510:MONEY$=MNY$:MONEY=VAL(MONEY$)
1210 ? :? "ENTER INTEREST RATE";:INPUT APR:IN=APR/1200:RETURN
1220 ? :? "ENTER NUMBER OF PAYMENTS";:INPUT NUM:RETURN
1230 ? :? "ENTER MONTHLY PAYMENT";
1240 GOSUB 1440:PMT$=MNY$:PMT=VAL(PMT$):RETURN
1250 ? :? "ENTER # OF COMPOUNDING PERIODS/YEAR";:INPUT CP:IN=APR/(100*CP)
1260 ? :? "HOW MANY YEARS TO COMPOUND";:INPUT NUM:RETURN
1270 ? :? "ENTER STARTING MONTH (1-12)";:INPUT MON
1280 D$=STR$(MON):IF MON<1 OR MON>13 THEN 1420
1290 MON$="  ":MON$(3-LEN(D$),2)=D$:RETURN
1300 ? :? " HARDCOPY Y/N ":GOSUB 1090:IF A<>89 THEN 1350
1310 REM *** PRINTER SUBROUTINE***
1320 ? "↰":? :? "IF PRINTER IS READY PRESS 'P'":GET #1,P
1330 IF P<>80 THEN 1420
1340 CLOSE #4:OPEN #4,8,0,"P":? #4;CHR$(27);"@";CHR$(27);"l";CHR$(15);CHR$(27);"Q";CHR$(55)
1350 RETURN :REM ABOVE SETS PRINTER TO DEFAULT, SETS LEFT MARGIN AT 15 AND RIGHT MARGIN AT 55
1360 ? #4;CHR$(13);CHR$(13):REM THIS LINE JUST ADDS TWO 'RETURNS'
1370 ? #4;HEAD$;MONEY;CHR$(13);CHR$(13);HEAD2$;CHR$(13):RETURN :REM THIS ADDS THE HEADINGS WITH RETURNS
1380 ? #4;CHR$(13);"MONTH","PAYMENT","INTEREST","AMOUNT";CHR$(13):RETURN
1390 ? #4;MON,PMT$,I$,BAL$:RETURN :REM THESE TWO LINES PRINT THE HEADING,'RETURNS',& EACH LINE OF THE SAVINGS PROGRAM
1400 ? #4;LINE$:RETURN
1410 ? #4;CHR$(13);YEAR$;" INTEREST=";C;"    PRIN=";B:? #4;"CHARGES= ";M:RETURN :REM PRINTS TOTALS AT BOTTOM OF PAGE
1420 REM *** ERROR ROUTINE ***
1430 ? "↰":? :? "INPUT MISTAKE - START OVER":FOR I=1 TO 100:NEXT I:GOTO 80
1440 REM ***CONVERT ROUTINE ***
1450 INPUT AMT
1460 AMT$=STR$(INT(AMT*100)):IF LEN(AMT$)>6 THEN 1530
1470 IF AMT=0 THEN MNY$="    0.00":GOTO 1580
1480 D=LEN(AMT$):DOL=INT(AMT)
1490 MNY$="   0.00":MNY$(6,7)=AMT$(D-1,D):IF INT(AMT)=0 THEN 1580
1500 MNY$(7-D,4)=STR$(DOL):GOTO 1580
1510 REM *** CONVERT LARGE ***
1520 INPUT AMT
1530 AMT$=STR$(INT(AMT*100))
1540 IF AMT=0 THEN MNY$="      0.00":GOTO 1580
1550 D=LEN(AMT$):DOL=INT(AMT)
1560 MNY$="      0.00":MNY$(9,10)=AMT$(D-1,D):IF INT(AMT)=0 THEN MNY$(7,8)="0.":GOTO 1580
1570 MNY$(10-D,7)=STR$(DOL)
1580 RETURN