Statwhiz (STATWHIZ.BAS)

Statwhiz by Bernard I. Sparks, 137

Description

Statwhiz by Bernard I. Sparks, 137

From the Antic disk of Antic: February/March 1990 - Vol. 8 No. 8 — disk A.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 16.7 KB

Dialect
Atari BASIC
Lines
232
Variables
O, DATA, T$, D$, ANALYZE, HEAD1, MENU2, ANTIC, RL1, RL2, CLEAR, TS$, DL, X, ZERO, HEAD2, NSG, YP, D, SUBJ(, AO$, RES3, Y, SV(, TOT(, SSQ(, HV(, LV(, M(, SD$, WR, LOOP, RD, Z, W, HC, A$, T, T(, VR(, SD(, O$, HC$, EA$, SMP(, SA, SB, S2, ST, DF, R, RC, R2, RS, P, A, B, C, N, NS, DAT, S(, TS, F, V1, V2, PF, PT, VA, VB, XT, PZ, TT(, TTS(, TB(, TBS(, TT, TTS, TB, TBS, BTS, CMS, RWS, SS, WC, IT, E, G, V, N(, TS(, B(, H, HV, LV, M, VR, SD, TOT, E(, EV, J, SR2, Q, ER, TITLE, MENU1, RES, H1, H2, ZER0, S, IN, A(, ZERO2, INT, NS(, EV(, SX, SY, SEB, CD, AN, CH, U, RETURN
BASIC listing (232 lines)
1 REM STATWHIZ (Ver. 1)
2 REM BY Bernard I. Sparks, III
3 REM (c)1990, ANTIC PUBLISHING INC.
5 RAD :GOSUB 2650:GOSUB 10:GOTO 30
6 POKE 16,64:POKE 53774,64:RETURN
7 GRAPHICS 16:SETCOLOR 2,7,0:DL=PEEK(560)+PEEK(561)*256:POKE 559,0:POKE DL+3,70:POKE DL+6,6
8 POKE DL+7,2:POKE DL+29,65:POKE DL+30,PEEK(560):POKE DL+31,PEEK(561):POKE 752,1:GOSUB 6:RETURN
9 IF NSG<2 THEN GOSUB 1180:GOTO 140
10 FOR X=1 TO 8:A(X)=0:B(X)=0:TT(X)=0:TTS(X)=0:TB(X)=0:TBS(X)=0:T(X)=0:NEXT X:T=0:A=0:B=0:C=0:D=0:E=0:F=0:TT=0
11 R=0:TB=0:TTS=0:TBS=0:TOT=0:RETURN
15 FOR X=1 TO 8:M(X)=0:TOT(X)=0:SSQ(X)=0:SD(X)=0:VR(X)=0:HV(X)=-9999999:LV(X)=9999999:NEXT X:RETURN
30 GOSUB 2580:GOSUB 6:U=0
40 GET #2,Q:IF Q<65 OR Q>72 THEN 40
50 IF Q=65 THEN T$="GENERAL STATISTICS":D$="D:GN.SW":AN=700:GOTO 140
60 IF Q=66 THEN T$="  T-TEST (INDPD)":D$="D:TI.SW":AN=900:U=2:V=0:GOTO 140
65 IF Q=67 THEN T$="  T-TEST (DEPND)":D$="D:TD.SW":AN=1150:U=2:V=0:GOTO 140
70 IF Q=68 THEN T$="  ONE-WAY ANOVA":D$="D:A1.SW":AN=1310:GOTO 140
75 IF Q=69 THEN T$="  TWO-WAY ANOVA":D$="D:A2.SW":AN=1550:GOTO 140
80 IF Q=70 THEN T$="    CHI-SQUARE":D$="D:CH.SW":AN=1800:U=2:V=1:GOTO 140
90 IF Q=71 THEN T$="    CORRELATION":D$="D:CR.SW":AN=2100:U=2:V=0:GOTO 140
120 IF Q=72 THEN D$="D:RG.SW":T$="    REGRESSION":AN=2200:U=2:GOTO 140
140 GOSUB 250:GOSUB 2620:POKE 559,ANTIC:GOSUB 6:O$="S:":HC=0:TOT=0
150 GET #2,Q:IF Q<65 OR Q>69 THEN 150
160 IF Q=65 THEN GOSUB 300:GOTO 140
170 IF Q=66 THEN GOSUB 500:GOTO 140
180 IF Q=67 THEN GOSUB 630:GOTO 140
190 IF Q=68 THEN GOSUB AN:GOTO 140
195 IF Q=69 THEN GOTO 30
210 GET #2,Q:IF Q=89 THEN GOTO RL1
230 IF Q=78 THEN GOTO RL2
240 GOTO 210
250 GOSUB 7:POSITION 1,0:? T$:RETURN
260 ? CHR$(125):POSITION 1,0:? TS$:GOSUB 6:RETURN
295 ? CHR$(125):POSITION 13,10:? "Disk Error!":? CHR$(253):POKE 559,ANTIC:FOR X=1 TO 400:NEXT X:CLOSE #1:GOTO 140
300 GOSUB 15:TRAP 300:TS$=" CREATE DATABASE":GOSUB 260:POSITION 5,4:? "Number of Sample Groups:";:POKE 559,ANTIC
306 INPUT NSG:IF U=2 AND V=1 THEN 322
308 IF U=2 THEN 314
309 IF U=4 THEN 318
310 IF NSG<1 OR NSG>8 THEN 300
312 GOTO 320
314 IF NSG<>2 THEN 300
316 GOTO 320
318 IF NSG<2 OR NSG>4 THEN 300
320 YP=6:FOR X=1 TO NSG:POSITION 8,YP:? "Subjects in Group #";:? X;:? ":";:INPUT D
321 GOTO 324
322 IF NSG<2 OR NSG>4 THEN 300
323 GOTO 320
324 IF U=2 AND V=1 THEN 327
325 IF D<1 OR D>225 THEN 300
326 GOTO 330
327 IF D<2 OR D>4 THEN 300
330 SUBJ(X)=D:YP=YP+1:NEXT X:POSITION 7,21:? AO$:RL1=340:RL2=300:GOTO 210
340 FOR X=1 TO NSG:FOR Y=1 TO SUBJ(X)
350 TRAP 350:GOSUB 260:POSITION 10,8:? "GROUP #";:? X
360 POSITION 8,10:? "SUBJECT #";:? Y:POSITION 11,12:? "DATA:";:POKE 559,ANTIC:INPUT D:SV(X,Y)=D:TOT(X)=TOT(X)+D
365 SSQ(X)=SSQ(X)+(D*D):IF D>=HV(X) THEN HV(X)=D
375 IF D<=LV(X) THEN LV(X)=D
380 NEXT Y:M(X)=TOT(X)/SUBJ(X):POSITION 7,21:? AO$:RL1=395:RL2=390:GOTO 210
390 M(X)=0:TOT(X)=0:SSQ(X)=0:HV(X)=-9999999:LV(X)=9999999:FOR Y=1 TO SUBJ(X):GOTO 350
395 NEXT X:LOOP=1:POSITION 7,21:? SD$:RL1=410:RL2=600:GOTO 210
410 OPEN #1,8,0,D$:? #1;NSG:FOR X=1 TO NSG:? #1;SUBJ(X):? #1;M(X):? #1;TOT(X):? #1;SSQ(X):? #1;HV(X):? #1;LV(X)
420 NEXT X:FOR X=1 TO NSG:FOR Y=1 TO SUBJ(X):? #1;SV(X,Y):NEXT Y:NEXT X:CLOSE #1:RETURN
500 TS$=" modify database":GOSUB 260:GOSUB 710
520 TRAP 500:POSITION 6,7:? "Modify which group? ";:POKE 559,ANTIC:INPUT Z:IF Z<1 OR Z>NSG THEN 500
540 POSITION 6,9:? "Modify which subj.? ";:INPUT W:IF W<1 OR W>SUBJ(Z) THEN 500
560 TRAP 560:GOSUB 260:POSITION 10,8:? "Subject #:     ";:? W:POSITION 10,10:? "Previous Data: ";:? SV(Z,W)
565 POSITION 10,12:? "Modified Data: ";:POKE 559,ANTIC:INPUT X:POSITION 7,21:? AO$:RL1=570:RL2=560:GOTO 210
570 TOT(Z)=TOT(Z)-SV(Z,W):SSQ(Z)=SSQ(Z)-(SV(Z,W)*SV(Z,W)):SV(Z,W)=X:TOT(Z)=TOT(Z)+X:SSQ(Z)=SSQ(Z)+(X*X)
575 HV(Z)=-9999999:LV(Z)=9999999:FOR X=1 TO SUBJ(Z):IF SV(Z,X)>=HV(Z) THEN HV(Z)=SV(Z,X)
576 IF SV(Z,X)<=LV(Z) THEN LV(Z)=SV(Z,X)
578 NEXT X:M(Z)=TOT(Z)/SUBJ(Z):POSITION 5,21:? " End Modifying?  (Y)es  (N)o ":RL1=590:RL2=500:LOOP=1:GOTO 210
590 POSITION 6,21:? SD$:RL1=410:RL2=600:GOTO 210
600 RETURN
630 TRAP 295:GOSUB 10:OPEN #1,4,0,D$:INPUT #1;NSG:FOR X=1 TO NSG:INPUT #1;D:SUBJ(X)=D:INPUT #1;D:M(X)=D
640 INPUT #1;D:TOT(X)=D:INPUT #1;D:SSQ(X)=D:INPUT #1;D:HV(X)=D:INPUT #1;D:LV(X)=D:NEXT X:LOOP=1:FOR X=1 TO NSG
645 FOR Y=1 TO SUBJ(X):INPUT #1;D:SV(X,Y)=D:NEXT Y:NEXT X:CLOSE #1:RETURN
700 GOSUB 710:TRAP 700:GOSUB 250:POSITION 6,4:? "Analyze which sample group: ";:POKE 559,ANTIC:INPUT Z:GOTO 720
710 IF LOOP=0 THEN GOSUB 630
715 RETURN
720 IF Z<1 OR Z>NSG THEN 700
750 POKE 559,0:FOR X=1 TO SUBJ(Z):T(Z)=T(Z)+((SV(Z,X)-M(Z))*(SV(Z,X)-M(Z))):NEXT X:VR(Z)=T(Z)/SUBJ(Z)
760 SD(Z)=SQR(VR(Z))
770 OPEN #3,8,0,O$:GOSUB 250
780 POSITION 3,6:? #3;"Sample Group:",:? #3;Z:POSITION 3,8:? #3;"Mean:",,:? #3;M(Z)
790 POSITION 3,10:? #3;"Variance:",:? #3;VR(Z):POSITION 3,12:? #3;"Std. Dev.:",:? #3;SD(Z):POSITION 3,14
800 ? #3;"Max. Value:",:? #3;HV(Z):POSITION 3,16:? #3;"Min. Value:",:? #3;LV(Z)
810 IF HC=O THEN CLOSE #3:POSITION 7,21:? HC$:POKE 559,ANTIC:RL1=830:RL2=820:GOTO 210
820 CLOSE #3:RETURN
830 LPRINT :O$="P:":HC=1:GOTO 770
900 GOSUB 710:GOSUB 9:POKE 559,0:GOSUB 990:GOSUB 1060:RETURN
990 SA=SSQ(1)-(TOT(1)*TOT(1))/SUBJ(1):SB=SSQ(2)-(TOT(2)*TOT(2))/SUBJ(2)
1000 S2=(SA+SB)/(SUBJ(1)+SUBJ(2)-2):T=ABS((M(1)-M(2))/SQR(S2/SUBJ(1)+S2/SUBJ(2))):ST=T:DF=SUBJ(1)+SUBJ(2)-2
1021 TRAP 1055:R=ATN(ST/SQR(DF)):RC=COS(R):X=1:R2=RC*RC:RS=SIN(R)
1022 IF DF/2=INT(DF/2) THEN 1040
1025 IF DF=1 THEN Y=R:GOTO 1050
1030 Y=RC:FOR Z=3 TO (DF-2) STEP 2:X=X*R2*(Z-1)/Z:Y=Y+X*RC:NEXT Z:Y=R+RS*Y:GOTO 1050
1040 Y=1:FOR Z=2 TO (DF-2) STEP 2:X=X*R2*(Z-1)/Z:Y=Y+X:NEXT Z:P=1-Y*RS:RETURN
1050 P=1-Y*0.63661977:RETURN
1055 P=O
1060 TOT=0:TS$="T-Value: "
1065 OPEN #3,8,0,O$:GOSUB 250
1070 IF P=0 THEN POSITION 5,8:? #3;TS$,:? #3;T:POSITION 5,10:? #3;"P-Value: ",:? #3;"<.001":GOTO 1072
1071 POSITION 5,8:? #3;TS$,:? #3;T:POSITION 5,10:? #3;"P-Value: ",:? #3;P
1072 IF TOT=1 THEN POSITION 11,14:? "Cell count of N<5!":POSITION 3,16:? "Chi-Square may not be appropriate!"
1073 IF TOT=1 THEN ? CHR$(253)
1080 IF HC=0 THEN CLOSE #3:POSITION 7,21:? HC$:POKE 559,ANTIC:RL1=1090:RL2=820:GOTO 210
1085 CLOSE #3:RETURN
1090 LPRINT :O$="P:":HC=1:GOTO 1065
1150 POKE 559,0:B=0:C=0:GOSUB 710:GOSUB 9
1160 IF SUBJ(1)<>SUBJ(2) THEN GOSUB 1180:RETURN
1170 N=SUBJ(1):DF=N-1:GOTO 1190
1180 GOSUB 250:? CHR$(253):POSITION 6,8:? "Sample groups are not equal!":POSITION 6,10
1181 ? "The data cannot be analyzed!":POKE 559,ANTIC:FOR X=1 TO 250:NEXT X:RETURN
1190 FOR X=1 TO SUBJ(1):A=SV(1,X)-SV(2,X):B=B+A:C=C+A*A:NEXT X:T=ABS(B/SQR(((N*C)-(B*B))/(N-1))):ST=T
1210 GOSUB 1021:GOSUB 1060:RETURN
1310 N=0:T=0:TS=0:B=0:GOSUB 710:GOSUB 9
1320 POKE 559,0:FOR X=1 TO NSG:N=N+SUBJ(X):T=T+TOT(X):TS=TS+SSQ(X):NEXT X:A=T*T/N:FOR X=1 TO NSG
1330 B=B+(TOT(X)*TOT(X)/SUBJ(X)):NEXT X:C=B-A:D=TS-B:F=((B-A)/(NSG-1))/((TS-B)/(N-NSG)):T=F
1350 V1=NSG-1:V2=N-NSG:X=1/(V1/V2*F+1):Y=1-X:PF=1:PT=1:VA=V1:VB=V2
1360 IF V1/2<>INT(V1/2) AND V2/2=INT(V2/2) THEN 1390
1365 IF V1/2<>INT(V1/2) AND V2/2<>INT(V2/2) THEN 1400
1370 IF V2/2=INT(V2/2) AND V2>=V1 THEN 1390
1380 FOR Z=1 TO (V1/2-1):PF=PF*(0.5/Z*Y*VB):PT=PT+PF:VB=VB+2:NEXT Z:P=X^(V2*0.5)*PT:GOTO 1475
1390 FOR Z=1 TO (V2/2-1):PF=PF*(0.5/Z*X*VA):PT=PT+PF:VA=VA+2:NEXT Z:P=1-Y^(V1*0.5)*PT:GOTO 1475
1400 XT=ATN(SQR(F*V1/V2)):X=SIN(XT):Y=COS(XT):PT=Y:PF=Y
1410 IF V2=1 THEN 1425
1420 FOR Z=2 TO (V2-3) STEP 2:PF=PF*Y*Y*Z/(Z+1):PT=PT+PF:NEXT Z:PT=PT*X:XT=XT+PT
1425 PT=1:PF=1
1430 IF V1=1 THEN 1470
1440 FOR Z=2 TO (V2-1) STEP 2:PF=PF*Z/(Z-1):NEXT Z
1450 PF=PF*Y^V2*X:PZ=1:PT=1:VB=V2+1:FOR Z=3 TO (V1-2) STEP 2:PZ=PZ*VB*X*X/Z:PT=PT+PZ:VB=VB+2:NEXT Z
1460 XT=XT-PT*PF
1470 P=1-XT*2/3.14159265
1475 TS$="F-Value: ":GOSUB 1065:RETURN
1550 GOSUB 710:GOSUB 9:POKE 559,0:FOR X=1 TO NSG:D=SUBJ(X)
1570 IF D/2<>INT(D/2) THEN 1590
1580 NEXT X:GOTO 1595
1590 GOSUB 1180:RETURN
1595 GOSUB 10:FOR X=1 TO NSG:FOR Y=1 TO SUBJ(X)/2:TT=TT+SV(X,Y):TTS=TTS+(SV(X,Y)*SV(X,Y)):T(X)=T(X)+SV(X,Y)
1600 NEXT Y:T=T+T(X)*T(X):T(X)=0:NEXT X:FOR X=1 TO NSG:FOR Y=(SUBJ(X)/2)+1 TO SUBJ(X):TB=TB+SV(X,Y)
1602 TBS=TBS+(SV(X,Y)*SV(X,Y)):T(X)=T(X)+SV(X,Y):NEXT Y:T=T+T(X)*T(X):NEXT X:FOR X=1 TO NSG:FOR Y=1 TO SUBJ(X)
1605 A(X)=A(X)+SV(X,Y):B=B+SV(X,Y)*SV(X,Y):NEXT Y:A=A+(A(X)*A(X)):NEXT X
1616 CMS=(A/SUBJ(1))-((TT+TB)*(TT+TB))/(NSG*SUBJ(1))
1620 RWS=((TT*TT)+(TB*TB))/(((SUBJ(1))/2)*NSG)-((TT+TB)*(TT+TB))/((NSG*SUBJ(1)))
1630 WC=B-(T/(SUBJ(1)/2)):IT=(B-((TT+TB)*(TT+TB)/(NSG*SUBJ(1))))-RWS-CMS-WC
1640 C=(IT/(NSG-1))/(WC/(2*NSG*((SUBJ(1)/2)-1)))
1660 A=RWS/(WC/(2*NSG*((SUBJ(1)/2)-1))):B=(CMS/(NSG-1))/(WC/(2*NSG*((SUBJ(1)/2)-1))):DF=1:ST=A:GOSUB 1021
1670 D=P:ST=B:DF=NSG-1:GOSUB 1021:E=P:ST=C:DF=2*NSG*((SUBJ(1)/2)-1):GOSUB 1021:G=P
1680 OPEN #3,8,0,O$:GOSUB 250
1690 POSITION 3,5:? #3;"F(rows):",,:? #3;A:POSITION 3,7:? #3;"P(r) Value:",:? #3;D:POSITION 3,9:? #3;"F(cols):",,
1700 ? #3;B:POSITION 3,11:? #3;"P(c) Value:",:? #3;E:POSITION 3,13:? #3;"F(int):",,:? #3;C:POSITION 3,15
1710 ? #3;"P(i) Value:",:? #3;G
1720 IF HC=0 THEN CLOSE #3:POSITION 7,21:? HC$:POKE 559,ANTIC:RL1=1730:RL2=820:GOTO 210
1725 RETURN
1730 LPRINT :O$="P:":HC=1:GOTO 1680
1800 GOSUB 710:GOSUB 9:POKE 559,0:GOSUB 10
1805 Q=SUBJ(1):FOR X=1 TO NSG:FOR Y=1 TO SUBJ(X):TB(X)=TB(X)+SV(X,Y):TT(Y)=TT(Y)+SV(X,Y):IF SV(X,Y)<=5 THEN TOT=1
1811 IF SUBJ(X)<>Q THEN 1815
1813 NEXT Y:T=T+TB(X):NEXT X
1814 GOTO 1820
1815 GOSUB 1180:RETURN
1820 FOR X=1 TO NSG:FOR Y=1 TO SUBJ(X):IF TOT=1 THEN C=C+((ABS(SV(X,Y)-(TB(X)*TT(Y)/T))-0.5))^2/(TB(X)*TT(Y)/T)
1830 IF TOT=0 THEN C=C+((SV(X,Y)-(TB(X)*TT(Y))/T)^2)/(TB(X)*TT(Y)/T)
1840 NEXT Y:NEXT X:DF=(SUBJ(1)-1)*(NSG-1)
1860 IF C<31 OR DF>2 THEN A=DF/2-1:R=1:GOTO 1880
1870 P=O:GOTO 2020
1880 IF DF=2 THEN R=1:GOTO 1895
1881 IF DF>1 THEN FOR B=1 TO (DF/2-0.5):R=R*A:A=A-1:NEXT B
1890 IF DF/2<>INT(DF/2) THEN R=R*1.77245374
1895 D=1:F=1:G=((C/2)^(DF/2))*2/(EXP(C/2)*R*DF):X=DF+2
1897 F=F*C/X:X=X+2:D=D+F
2000 IF F>9.99999999E-31 THEN 1897
2010 P=1-G*D:T=C
2020 TS$="Chi-Square:":O$="S:":GOSUB 1065:RETURN
2100 GOSUB 710:GOSUB 9:POKE 559,0:GOSUB 10
2101 IF SUBJ(1)<>SUBJ(2) THEN GOSUB 1180:RETURN
2105 FOR X=1 TO SUBJ(1):A=A+(SV(1,X)*SV(2,X)):B=B+(SV(1,X)*SV(1,X))
2110 C=C+(SV(2,X)*SV(2,X)):D=D+SV(1,X):E=E+SV(2,X):NEXT X:N=SUBJ(1)
2120 F=((N*A)-(D*E))/SQR(((N*B)-(D*D))*((N*C)-(E*E))):R=F
2130 TRAP 2145:SR2=R*R:DF=N-2:ST=SQR(SR2*DF/(1-SR2)):R=ATN(ST/SQR(DF)):RC=COS(R):R2=RC*RC:RS=SIN(R):X=1
2132 IF DF/2=INT(DF/2) THEN 2140
2134 IF DF=1 THEN Y=R:GOTO 2142
2136 Y=RC:FOR Z=3 TO (DF-2) STEP 2:X=X*R2*(Z-1)/Z:Y=Y+X*RC:NEXT Z
2138 Y=R+RS*Y:GOTO 2142
2140 Y=1:FOR Z=2 TO (DF-2) STEP 2:X=X*R2*(Z-1)/Z:Y=Y+X:NEXT Z:P=1-Y*RS:GOTO 2150
2142 P=1-Y*0.63661977:GOTO 2150
2145 P=0
2150 T=F:TS$="Coefficient:":O$="S:":GOSUB 1065:RETURN
2200 T$="    REGRESSION":GOSUB 710:GOSUB 9
2201 GOSUB 250:A=0:POSITION 6,5:? "Calculate which regression?":POSITION 9,7:? "A) Group 1 on Group 2"
2202 POSITION 9,9:? "B) Group 2 on Group 1":POSITION 7,21:? A$:POKE 559,ANTIC:GET #2,Q:IF Q<65 OR Q>66 THEN 2202
2203 IF Q=65 THEN Q=2:Z=1
2204 IF Q=66 THEN Q=1:Z=2
2210 POKE 559,0:IF SUBJ(1)<>SUBJ(2) THEN GOSUB 1180:RETURN
2220 FOR X=1 TO SUBJ(1):A=A+SV(1,X)*SV(2,X):NEXT X:N=SUBJ(1):B=A-TOT(1)*TOT(2)/N
2230 C=SSQ(Q)-(TOT(Q)^2)/N:D=B/C:E=(TOT(Z)-D*TOT(Q))/N
2243 DF=N-2:SX=SSQ(Q)-(TOT(Q)*TOT(Q)/N):SY=SSQ(Z)-TOT(Z)*TOT(Z)/N
2244 TRAP 2255:SB=B/SX:S2=(SY-B*B/SX)/DF:ST=ABS(SB)/SQR(S2/SX):GOSUB 1021:GOTO 2260
2255 P=O
2260 OPEN #3,8,0,O$:GOSUB 250
2270 IF Q=2 THEN POSITION 5,8:? #3;"Regression of Gr. #1 on Gr. #2":T$="X'":TS$="(Y)":GOTO 2290
2280 IF Q=1 THEN POSITION 5,8:? #3;"Regression of Gr. #2 on Gr. #1":T$="Y'":TS$="(X)"
2290 IF E>0 THEN POSITION 6,10:? #3;T$;:? #3;" = ";:? #3;D;:POSITION 18,10:? #3;TS$;:? #3;" + ";:? #3;E
2292 IF E>0 THEN POSITION 30,10:? #3;"             ":GOTO 2305
2300 POSITION 6,10:? #3;T$;:? #3;" = ";:? #3;D;:POSITION 18,10:? #3;TS$;:? #3;" - ";:? #3;ABS(E)
2303 POSITION 30,10:? #3;"           "
2305 IF P=0 THEN POSITION 6,12:? #3;"P-Value:",:? #3;"<.001":GOTO 2310
2306 POSITION 6,12:? #3;"P-Value:",:? #3;P
2310 IF HC=0 THEN HC=1:POSITION 7,21:? HC$:POKE 559,ANTIC:RL1=2330:RL2=2320:GOTO 210
2320 CLOSE #3:T$="    REGRESSION":RETURN
2330 LPRINT :CLOSE #3:O$="P:":GOTO 2260
2500 GRAPHICS 17:SETCOLOR 2,0,0:DL=PEEK(560)+PEEK(561)*256:POKE 559,0:POKE DL+13,2:POKE DL+21,2:POKE DL+23,2
2510 POKE DL+15,2:POKE DL+19,2:POKE DL+28,65:POKE DL+29,PEEK(560):POKE DL+30,PEEK(561):POSITION 6,5
2520 ? #6;"statwhiz":POSITION 6,8:? #6;"Statistical Analysis Program":POSITION 15,11:? #6;"(Ver. 1.0)"
2530 POSITION 19,19:? #6;"by":POSITION 9,22:? #6;"Bernard I. Sparks, III"
2540 POKE 559,ANTIC
2550 FOR V=10 TO 0 STEP -4:FOR X=1 TO 16:READ Z:SOUND 0,Z+30,10,V:SOUND 1,Z,10,V:FOR D=1 TO 6
2560 NEXT D:NEXT X:RESTORE 2570:NEXT V:SOUND 0,0,0,0:SOUND 1,0,0,0:RETURN
2570 DATA 230,20,210,40,190,60,170,800,150,100,130,120,110,140,90,160
2580 GRAPHICS 0:POKE 559,0:POKE 752,1:SETCOLOR 2,13,1:POSITION 15,0:? "MAIN MENU:":POSITION 9,3
2590 ? "A) General Statistics":POSITION 9,5:? "B) T-test (Indpd)":POSITION 9,7:? "C) T-test (Depnd)":POSITION 9,9
2600 ? "D) One-way ANOVA":POSITION 9,11:? "E) Two-way ANOVA":POSITION 9,13:? "F) Chi-Square":POSITION 9,15
2610 ? "G) Pearson Correlation":POSITION 9,17:? "H) Regression":POSITION 8,22:? A$:POKE 559,ANTIC:RETURN
2620 POSITION 9,7:? "A) Create Database":POSITION 9,9:? "B) Modify Database":POSITION 9,11:? "C) Load Database"
2630 POSITION 9,13:? "D) Analyze Database":POSITION 9,15:? "E) Return to Main Menu"
2640 POSITION 7,21:? A$:RETURN
2650 DIM D$(8):DIM SV(8,225):DIM SUBJ(225):DIM A$(28):DIM TS$(20):DIM T$(20):OPEN #2,4,0,"K:":ANTIC=PEEK(559)
2660 A$="Press letter of selection":DIM SD$(28):SD$=" Save to disk?  (Y)es  (N)o ":DIM HC$(28):DIM O$(2):DIM N(8)
2670 HC$=" Hard Copy?  (Y)es  (N)o ":DIM EA$(28):EA$=" End Analysis?  (Y)es  (N)o ":DIM AO$(28):DIM SMP(2)
2680 AO$=" All O.K.?  (Y)es  (N)o  ":DIM HV(8):DIM S(8):DIM SSQ(8):DIM LV(8):DIM TOT(8):DIM M(8):DIM T(8)
2690 DIM SD(8):DIM VR(8):DIM TS(8):DIM B(8):DIM TT(8):DIM TTS(8):DIM TB(8):DIM TBS(8):DIM E(4,4):DIM A(8)
2800 CH=0:U=0:V=0:GOSUB 2500:RETURN