Pulldown Menus, programming demo (PULLDOWN.BAS)

Pulldown Menus, programming demo by Marc Abramowitz, 21

Description

Pulldown Menus, programming demo by Marc Abramowitz, 21

From the Antic disk of Antic: February/March 1990 - Vol. 8 No. 8 — disk A.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.5 KB

Dialect
Atari BASIC
Lines
49
Variables
B, T, X, A$, I$, M$, N, XM, A, FL, D, INV, FL2, ST, TR, K, I, Y, Y2, LOO
BASIC listing (49 lines)
10 REM PULLDOWN MENUS
11 REM BY MARC ABRAMOWITZ
12 REM (C)1990, ANTIC PUBLISHING INC.
20 REM Pulldown Menu Subroutine DEMO
30 REM User to modify and use these subroutines in his/her own programs
100 B=0:T=14:X=1:DIM A$(99),M$(99)
110 GRAPHICS 0:POKE 709,T:POKE 710,B:POKE 752,1:GOSUB 470
120 M$="  DRAW     EDIT    LAYER  ":N=3:XM=5:GOSUB 180:REM GO TO MAIN MENU
130 IF X=1 THEN M$="LINE     CIRCLE   SQUARE              ":N=3:XM=5
140 IF X=2 THEN M$="ERASE    COPY     MOVE                ":N=3:XM=14
150 IF X=3 THEN M$="MAKE     SET      LTYPE    COLOR      ":N=4:XM=23
160 GOSUB 300:REM GO TO SUB-MENU
170 POSITION XM+1,12:? M$(A+1,A+6):REM PRINT CHOICE
171 FOR LOO=1 TO 100:NEXT LOO
172 IF STRIG(0)=0 OR PEEK(764)=12 THEN RUN
173 GOTO 172
175 REM * MAIN MENU (TOP) *
180 POSITION 0,1:? "↑↑↑↑↑↑↑":IF FL THEN GOTO 240
190 A=(X*9)-9:A$=M$:D=USR(INV,ADR(A$)+A,8):POSITION XM,0:? A$
200 IF FL AND FL2 THEN FL=0:FL2=0:RETURN
205 REM * MAKE A SELECTION *
210 ST=STICK(0):TR=STRIG(0):K=PEEK(764)
220 IF K=255 AND ST=15 AND TR=1 THEN 210
230 IF K=12 OR K=15 OR TR=0 THEN RETURN
240 IF K=6 OR K=134 OR ST=11 THEN X=X-1
250 IF K=7 OR K=135 OR ST=7 THEN X=X+1
260 IF X<1 THEN X=N
270 IF X>N THEN X=1
280 POKE 764,255:GOTO 190
290 REM * DRAW SUB-MENU *
300 POSITION 0,1:? "↓";:POSITION XM,1:? "▝▄▄▄▄▄▄▘"
310 FOR I=1 TO N
320 A=(I*9)-9:POSITION 0,1:? "↓";:POSITION XM,1:? "▎";M$(A+1,A+6);"▕":NEXT I
330 POSITION 0,1:? "↓";:POSITION XM,1:? "▗▄▄▄▄▄▄▖"
340 POKE 764,255:Y=1:GOTO 440
345 REM * MAKE A SELECTION *
350 ST=STICK(0):TR=STRIG(0):K=PEEK(764):IF K=255 AND ST=15 AND TR=1 THEN 350
360 POKE 764,255:POSITION XM+1,Y+1:? M$(A+1,A+6)
370 IF K=12 OR TR=0 THEN RETURN
380 IF K=6 OR K=7 OR K=134 OR K=135 OR ST=7 OR ST=11 THEN FL=1:FL2=1:POP :GOTO 120
390 IF K=28 THEN FL=1:FL2=0:POP :GOTO 120
400 IF K=14 OR K=142 OR ST=14 THEN Y=Y-1
410 IF K=15 OR K=143 OR ST=13 THEN Y=Y+1
420 IF Y<1 THEN Y=N
430 IF Y>N THEN Y=1
440 Y2=N-Y+1:A=(Y2*9)-9
450 A$=M$:POSITION XM+1,Y+1:D=USR(INV,ADR(A$)+A,8):? A$(A+1,A+6):GOTO 350
460 REM * ML INVERT ROUTINE *
470 INV=ADR("hX┴h┐Lh┐Kh┐Oh┐N ♥1Ki♥┌KHDNPu◆"):RETURN