Photo Labelmaker (PHOTOLBL.BAS)

Photo Labelmaker by Gary Coppola, 164

Description

Photo Labelmaker by Gary Coppola, 164

From the Antic disk of Antic: February/March 1990 - Vol. 8 No. 8 — disk A.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 20.0 KB

Dialect
Atari BASIC
Lines
361
Variables
ULBL1$, ULBL2$, ULBL3$, ULBL4$, LLBL1$, LLBL2$, LLBL3$, SKIP$, PROMPT1$, PROMPT2$, PROMPT3$, FOUR1$, FOUR2$, FOUR3$, FOUR4$, DL, GT, PICK, LABEL, Q, OPT1, OPT2, LT, LPOS, E, MT, CHBAS, CHSET, A, J, OC, B, I, FIX1$, FIX2$, FIX3$, FIXF1$, FIXF2$, FIXF3$, FIXF4$, FPMT1$, FPMT2$, FPMT3$, F4PMT1$, F4PMT2$, F4PMT3$, F4PMT4$, FRM1$, FRM2$, FRM3$, FRM41$, FRM42$, FRM43$, FRM44$, CHC, K, CPR, RUN, FL, LNUM$, LNUM, TNUM, W, X, A$, B$, Z, H, U, G, MOVE$
BASIC listing (361 lines)
1 REM PHOTO LABELMAKER
2 REM BY GARY COPPOLA
3 REM (c)1990, ANTIC PUBLISHING INC.
8 DIM ULBL1$(28),ULBL2$(28),ULBL3$(28),ULBL4$(28),LLBL1$(28),LLBL2$(28),LLBL3$(28),LNUM$(2),PROMPT1$(9)
9 DIM PROMPT2$(9),PROMPT3$(9),FOUR1$(9),FOUR2$(9),FOUR3$(9),FOUR4$(9),MOVE$(20)
10 DIM FPMT1$(9),FPMT2$(9),FPMT3$(9),F4PMT1$(9),F4PMT2$(9),F4PMT3$(9),F4PMT4$(9)
11 DIM FIX1$(28),FIX2$(28),FIX3$(28),FIXF1$(28),FIXF2$(28),FIXF3$(28),FIXF4$(28)
12 DIM FRM1$(28),FRM2$(28),FRM3$(28),FRM41$(28),FRM42$(28),FRM43$(28),FRM44$(28),A$(7),B$(7)
13 ULBL1$=" ":ULBL2$=" ":ULBL3$=" ":ULBL4$=" ":LLBL1$=" ":LLBL2$=" ":LLBL3$=" ":A$=" LABEL ":B$=" MAKER "
14 GOTO 7510
15 FIX1$=" A FIXED LABEL has not been"
16 FIX2$="        created yet"
17 FIX3$="  Please go to LABEL SETUP"
18 FIXF1$=" A FIXED LABEL has not been"
19 FIXF2$="        created yet"
20 FIXF3$="   This can be done under"
21 FIXF4$="        LABEL SETUP"
22 FRM1$=" A FORM LABEL has not been"
23 FRM2$=" created yet. Press [RETURN]"
24 FRM3$=" (3x) then go to LABEL SETUP"
25 FRM41$=" A FORM LABEL has not been"
26 FRM42$="        created yet"
27 FRM43$="   Press [RETURN] 4 times"
28 FRM44$="   then go to LABEL SETUP"
30 PROMPT1$=" Line #1 ":PROMPT2$=" Line #2 "
31 PROMPT3$=" Line #3 "
32 FPMT1$=" Line #1":FPMT2$=" Line #2"
33 FPMT3$=" Line #3"
34 FOUR1$=" Line #1":FOUR2$=" Line #2"
35 FOUR3$=" Line #3":FOUR4$=" Line #4"
36 F4PMT1$=" Line #1 ":F4PMT2$=" Line #2 "
37 F4PMT3$=" Line #3 ":F4PMT4$=" Line #4 "
40 GRAPHICS 0:DL=PEEK(560)+256*PEEK(561):POKE 756,GT:POKE DL+8,6
50 POKE 82,0:POKE 83,39:POKE 764,255:POKE 752,1:SETCOLOR 2,0,2:CLOSE #1:OPEN #1,4,0,"K:"
60 POSITION 11,1:? "PHOTO LABELMAKER":POSITION 5,3:? "MAIN MENU"
70 POSITION 31,6:? "1 - SINGLE LABEL":POSITION 31,8:? "2 - DOUBLE LABEL":POSITION 31,10:? "3 - 4-LINE LABEL"
80 POSITION 31,12:? "4 - LABEL SETUP":POSITION 31,14:? "5 - QUIT"
90 POSITION 25,18:? "PICK THE NUMBER OF YOUR CHOICE"
100 PICK=PEEK(764):GET #1,PICK:TRAP 60:IF PICK=255 THEN 100
110 IF PICK-48>5 OR PICK-48<1 THEN 60
120 ON PICK-48 GOTO 140,200,300,6000,7800
130 TRAP 40000:POKE 764,255:POKE 752,1:CLOSE #1:OPEN #1,4,0,"K:":RETURN
139 REM SINGLE LABEL
140 LABEL=1:GOSUB 2000:GOSUB 2035:FOR Q=1 TO 100:NEXT Q:GOSUB 2050:GOSUB 2100
150 GOSUB 500
160 GOSUB 130
170 OPT1=PEEK(764):GET #1,OPT1:TRAP 160:IF OPT1=255 THEN 170
180 IF OPT1-48>4 OR OPT1-48<1 THEN 160
190 ON OPT1-48 GOTO 1000,2500,7100,40
199 REM DOUBLE LABEL
200 LABEL=2:GOSUB 2000:GOSUB 2035:GOSUB 2040:GOSUB 2050:GOSUB 2100:GOSUB 2120:GOSUB 2160
210 GOSUB 600
220 GOSUB 130
230 OPT2=PEEK(764):GET #1,OPT2:TRAP 220:IF OPT2=255 THEN 230
240 IF OPT2-48>5 OR OPT2-48<1 THEN 220
250 ON OPT2-48 GOTO 1000,1050,2500,7100,40
299 REM 4-LINE LABEL
300 LABEL=4:GOSUB 2000:GOSUB 2035:FOR Q=1 TO 100:NEXT Q:GOSUB 2180:GOSUB 2220:GOTO 150
499 REM SINGLE AND 4-LINE OPTION MENU
500 POKE 82,2:POSITION 2,7:? "┌───OPTIONS───┐":GOSUB 520:? "|1-LABEL INPUT|":GOSUB 520:? "|2-SHOW  LABEL|"
510 GOSUB 520:? "|3-PRINT LABEL|":GOSUB 520:? "|4-MAIN MENU  |":? "└─────────────┘":RETURN
520 ? "|             |":RETURN
600 POKE 82,2:POKE 752,1
610 POSITION 2,6:? "┌───OPTIONS───┐":? "|1-UPPER LABEL|":GOSUB 520:? "|2-LOWER LABEL|":GOSUB 520
620 ? "|3-SHOW  LABEL|":GOSUB 520:? "|4-PRINT LABEL|":GOSUB 520:? "|5-MAIN MENU  |":? "└─────────────┘":RETURN
650 POKE 82,3:POSITION 3,7:? "┌──────────┐":? "|LABEL TYPE|":? "├──────────┤":? "| 1- BLANK |":? "|          |"
660 ? "| 2- FIXED |":? "|          |":? "| 3- FORM  |":? "└──────────┘":RETURN
670 GOSUB 130
680 LT=PEEK(764):GET #1,LT:TRAP 670:IF LT=255 THEN 680
690 IF LT-48>3 OR LT-48<1 THEN 670
700 ON LT-48 GOTO 5000,5380,5560
800 FOR W=1 TO 320:NEXT W:RETURN
820 FOR J=1 TO 4:SOUND 0,10,8,20-J*5:NEXT J:SOUND 0,0,0,0:FOR W=1 TO 50:NEXT W:X=X+1:RETURN
830 FOR J=15 TO 0 STEP -1:SOUND 0,120,10,J:NEXT J:RETURN
999 REM UPPER LABEL INPUT
1000 LPOS=1
1010 GOSUB 2260:GOSUB 650:GOTO 670
1049 REM LOWER LABEL INPUT
1050 LPOS=19:GOSUB 2260:GOSUB 650:GOTO 670
1999 REM DRAWING ROUTINES
2000 GRAPHICS 0:POKE 752,1:POKE 756,GT:POKE 712,44:POKE 710,44:POKE 709,2:POKE 16,112:POKE 53774,112
2005 POSITION 20,6:? "┌──────────┐":POSITION 20,7:? "|          |":POSITION 20,8:? "|          |"
2010 POSITION 20,9:? "| ♥▔▔▔▔▔▔▗ |":FOR Q=10 TO 12:POSITION 20,Q:? "| ▎      ▕ |":NEXT Q
2020 POSITION 20,13:? "| ▘▂▂▂▂▂▂▝ |":POSITION 20,14:? "|          |":POSITION 20,15:? "|          |"
2030 POSITION 20,16:? "└──────────┘":POKE 82,0:RETURN
2035 POSITION 21,7:? "◣◣◣◣◣◣◣◣◣◣":POSITION 21,8:? "●●●●●●●●●●":RETURN
2040 POSITION 21,14:? "◢◢◢◢◢◢◢◢◢◢":POSITION 21,15:? "♣♣♣♣♣♣♣♣♣♣":RETURN
2050 POSITION 31,7:? "▖──┘":POSITION 34,6:? "|":POSITION 34,5:? "|"
2060 POSITION 9,4:? "└────────────────────────┬───┘"
2070 FOR Q=3 TO 1 STEP -1:POSITION 9,Q:? "|":POSITION 38,Q:? "|":NEXT Q
2080 POSITION 9,0:? "┌────────────────────────────┐":RETURN
2100 FOR Q=1 TO 3:POSITION 10,Q:? "◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣":NEXT Q:RETURN
2120 POSITION 31,15:? "▖──┐":POSITION 34,16:? "|":POSITION 34,17:? "|"
2130 POSITION 9,18:? "┌────────────────────────┴───┐":FOR Q=19 TO 21:POSITION 9,Q:? "|":POSITION 38,Q:? "|"
2140 NEXT Q:POSITION 9,22:? "└────────────────────────────┘↑↑":RETURN
2160 FOR Q=19 TO 21:POSITION 10,Q:? "♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣♣":NEXT Q:RETURN
2180 POSITION 31,7:? "▖──┘":POSITION 34,6:? "|"
2190 POSITION 9,5:? "└────────────────────────┬───┘"
2200 FOR Q=4 TO 1 STEP -1:POSITION 9,Q:? "|":POSITION 38,Q:? "|":NEXT Q
2210 POSITION 9,0:? "┌────────────────────────────┐":RETURN
2220 FOR Q=1 TO 4:POSITION 10,Q:? "◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣◣":NEXT Q:RETURN
2230 FOR E=1 TO 3:POSITION 10,E:? "                            ":NEXT E:RETURN
2240 FOR E=19 TO 21:POSITION 10,E:? "                            ":NEXT E:RETURN
2250 FOR E=1 TO 4:POSITION 10,E:? "                            ":NEXT E:RETURN
2260 FOR E=6 TO 16:POSITION 0,E:? "                  ":NEXT E:RETURN
2270 FOR E=0 TO 4:POSITION 0,E:? "         ":NEXT E:RETURN
2280 FOR E=18 TO 21:POSITION 0,E:? "         ":NEXT E:RETURN
2290 POSITION 15,17:? "         ":RETURN
2300 POSITION 8,14:? "Enter your FIRST prompt"
2310 POSITION 14,16:? "┌─────────┐":? "|         |":? "└─────────┘"
2320 POSITION 5,21:? "Press RETURN after each entry":POKE 752,0:RETURN
2330 POSITION 16,6:? " CHOOSE ":POSITION 3,8:? "1 3-LINE   2 4-LINE   3 SETUP MENU":RETURN
2340 POSITION 1,12:? " INPUT  ┌────────────────────────────┐"
2345 IF FL-48=1 THEN POSITION 9,16
2350 IF FL-48=2 THEN POSITION 9,17
2355 ? "└────────────────────────────┘":POSITION 1,13:? "Line #1":POKE 752,0:RETURN
2360 POSITION 1,14:? "Line #2":RETURN
2365 POSITION 1,15:? "Line #3":RETURN
2370 POSITION 1,16:? "Line #4":RETURN
2400 POSITION 19,14:? "SECOND prompt":RETURN
2410 POSITION 19,14:? "THIRD prompt ":RETURN
2420 POSITION 19,14:? "FOURTH prompt":RETURN
2490 REM SHOW LABEL
2500 POKE 82,10:IF LABEL=1 OR LABEL=2 THEN GOSUB 2230:GOSUB 2240:FOR J=1 TO 20:NEXT J
2510 IF LABEL=4 THEN GOSUB 2250:FOR J=1 TO 30:NEXT J
2520 POSITION 10,1:? ULBL1$:? ULBL2$:? ULBL3$
2530 IF LABEL=4 THEN ? ULBL4$
2540 IF LABEL=2 THEN POSITION 10,19:? LLBL1$:? LLBL2$:? LLBL3$
2550 POKE 82,0:GOTO 5190
4999 REM INPUT BLANK LABEL
5000 TRAP 40000:POKE 82,0:POSITION 8,10:? "BLANK"
5002 IF LPOS=19 THEN GOTO 5200
5004 IF LABEL=1 OR LABEL=2 THEN GOSUB 2230
5007 IF LABEL=4 THEN GOSUB 2250
5010 GOSUB 2270:POKE 752,0:POSITION 1,0:? " INPUT "
5020 IF LABEL=1 OR LABEL=2 THEN POSITION 0,LPOS:? PROMPT1$
5030 IF LABEL=4 THEN POSITION 0,LPOS:? FOUR1$
5040 TRAP 8000:POSITION 9,LPOS:INPUT ULBL1$
5060 IF LABEL=1 OR LABEL=2 THEN ? PROMPT2$
5070 IF LABEL=4 THEN ? FOUR2$
5080 POSITION 9,LPOS+1:INPUT ULBL2$
5100 IF LABEL=1 OR LABEL=2 THEN ? PROMPT3$
5110 IF LABEL=4 THEN ? FOUR3$
5120 POSITION 9,LPOS+2:INPUT ULBL3$
5140 IF LABEL=4 THEN ? FOUR4$
5150 IF LABEL=4 THEN POSITION 9,LPOS+3:INPUT ULBL4$
5170 POKE 752,1:GOSUB 2270
5180 IF LABEL=1 OR LABEL=2 THEN GOSUB 2050
5185 IF LABEL=4 THEN GOSUB 2180
5190 IF LABEL=1 OR LABEL=4 THEN GOTO 150
5195 IF LABEL=2 THEN GOTO 210
5199 REM INPUT BLANK LOWER LABEL
5200 TRAP 40000:POKE 82,0
5210 GOSUB 2280:GOSUB 2240:POKE 752,0:POSITION 1,18:? " INPUT "
5220 TRAP 8000:POSITION 0,LPOS:? PROMPT1$:POSITION 9,LPOS:INPUT LLBL1$
5240 ? PROMPT2$:POSITION 9,LPOS+1:INPUT LLBL2$
5260 ? PROMPT3$:POSITION 9,LPOS+2:INPUT LLBL3$
5280 POKE 752,1:GOSUB 2280:GOSUB 2120
5290 GOTO 210
5370 REM FIXED LABEL
5380 POKE 82,10:POKE 752,1:POSITION 8,12:? "FIXED"
5390 IF LABEL=4 THEN GOSUB 2250:FOR Q=1 TO 50:NEXT Q:ULBL1$=FIXF1$:ULBL2$=FIXF2$:ULBL3$=FIXF3$:ULBL4$=FIXF4$
5400 IF LABEL=4 THEN POSITION 10,LPOS:? FIXF1$:? FIXF2$:? FIXF3$:? FIXF4$:GOTO 5440
5410 IF LPOS=1 THEN GOSUB 2230:FOR Q=1 TO 40:NEXT Q:ULBL1$=FIX1$:ULBL2$=FIX2$:ULBL3$=FIX3$
5420 IF LPOS=19 THEN GOSUB 2240:FOR Q=1 TO 40:NEXT Q:LLBL1$=FIX1$:LLBL2$=FIX2$:LLBL3$=FIX3$
5430 IF LABEL=1 OR LABEL=2 THEN POSITION 10,LPOS:? FIX1$:? FIX2$:? FIX3$
5440 FOR Q=1 TO 150:NEXT Q:POKE 82,0
5450 GOTO 5190
5550 REM FORM LABEL
5560 POKE 82,2:POSITION 8,14:? "FORM":FOR J=1 TO 75:NEXT J:GOSUB 2260
5570 POSITION 2,8:? "Use CTRL ";CHR$(27);CHR$(159);" or ";CHR$(27);CHR$(158):? "keys to position"
5580 ? "cursor on line":? :? "Press RETURN key":? "after each line":POKE 82,10
5590 IF LPOS=19 THEN GOTO 5740
5600 IF LABEL=1 OR LABEL=2 THEN GOSUB 2230
5610 IF LABEL=4 THEN GOSUB 2250
5620 GOSUB 2270:POSITION 1,0:? " INPUT ":POKE 752,0:TRAP 8000
5630 IF LABEL=1 OR LABEL=2 THEN POSITION 10,LPOS:? FRM1$:? FRM2$:? FRM3$
5640 IF LABEL=4 THEN POSITION 10,LPOS:? FRM41$:? FRM42$:? FRM43$:? FRM44$
5650 POKE 82,0:IF LABEL=1 OR LABEL=2 THEN POSITION 0,LPOS:? FPMT1$:POSITION 9,LPOS:INPUT ULBL1$
5660 IF LABEL=4 THEN POSITION 0,LPOS:? F4PMT1$:POSITION 9,LPOS:INPUT ULBL1$
5670 IF LABEL=1 OR LABEL=2 THEN POSITION 0,LPOS+1:? FPMT2$:POSITION 9,LPOS+1:INPUT ULBL2$
5680 IF LABEL=4 THEN POSITION 0,LPOS+1:? F4PMT2$:POSITION 9,LPOS+1:INPUT ULBL2$
5690 IF LABEL=1 OR LABEL=2 THEN POSITION 0,LPOS+2:? FPMT3$:POSITION 9,LPOS+2:INPUT ULBL3$
5700 IF LABEL=4 THEN POSITION 0,LPOS+2:? F4PMT3$:POSITION 9,LPOS+2:INPUT ULBL3$
5710 IF LABEL=4 THEN POSITION 0,LPOS+3:? F4PMT4$:POSITION 9,LPOS+3:INPUT ULBL4$
5720 POKE 752,1:GOSUB 2270:GOSUB 2260
5730 GOTO 5180
5740 TRAP 40000:GOSUB 2280:GOSUB 2240:POSITION 10,LPOS:? FRM1$:? FRM2$:? FRM3$:POKE 82,0
5750 TRAP 8000:POSITION 1,18:? " INPUT ":POKE 752,0:POSITION 0,LPOS:? FPMT1$:POSITION 9,LPOS:INPUT LLBL1$
5760 POSITION 0,LPOS+1:? FPMT2$:POSITION 9,LPOS+1:INPUT LLBL2$
5770 POSITION 0,LPOS+2:? FPMT3$:POSITION 9,LPOS+2:INPUT LLBL3$
5780 POKE 752,1:GOSUB 2280:GOSUB 2120:GOSUB 2260:GOTO 210
5999 REM LABEL SETUP
6000 GRAPHICS 1:DL=PEEK(560)+256*PEEK(561):POKE DL+6,7:POKE 709,198:POKE 710,96:POKE 711,68:POKE 712,96
6005 POKE 756,GT:GOSUB 130
6010 POSITION 5,1:? #6;"setup menu"
6020 POSITION 2,4:? #6;"1 summary":POSITION 2,6:? #6;"2 custom prompts":POSITION 2,8:? #6;"3 fixed label"
6030 POSITION 2,10:? #6;"4 custom form":POSITION 2,12:? #6;"5 save to disk":POSITION 2,14:? #6;"6 main menu"
6040 ? "        CHOOSE TOPIC BY NUMBER"
6050 CHC=PEEK(764):GET #1,CHC:TRAP 6050:IF CHC=255 THEN 6050
6060 IF CHC-48>6 OR CHC-48<1 THEN 6050
6070 ON CHC-48 GOTO 6100,6250,6540,6800,7850,40
6100 GRAPHICS 0:POKE 82,12:POKE 709,10:POKE 710,176:POKE 712,176:POKE 752,1:POKE 756,GT
6110 ? "↰":POSITION 12,0:? "┌──────────────┐":? "|CUSTOM PROMPTS|":? "└──────────────┘"
6120 POSITION 3,4:? "  3-LINE BLANK      3-LINE FORM  ":POSITION 3,12:? "  4-LINE BLANK      4-LINE FORM  "
6130 POSITION 7,21:? "Press ANY KEY to continue":POKE 82,6:POSITION 6,6:? PROMPT1$:? PROMPT2$:? PROMPT3$
6140 POSITION 6,14:? FOUR1$:? FOUR2$:? FOUR3$:? FOUR4$:POKE 82,24:POSITION 24,6:? FPMT1$:? FPMT2$:? FPMT3$
6150 POSITION 24,14:? F4PMT1$:? F4PMT2$:? F4PMT3$:? F4PMT4$:CLOSE #1:OPEN #1,4,0,"K:":GET #1,K:CLOSE #1
6160 POKE 82,12:? "↰":POSITION 12,0:? "┌─────────────┐":? "|CUSTOM LABELS|":? "└─────────────┘"
6170 POSITION 5,3:? "         3-LINE FIXED         ":POSITION 5,7:? "         4-LINE FIXED         "
6180 POSITION 5,12:? "         3-LINE FORM          ":POSITION 5,16:? "         4-LINE FORM          "
6190 POSITION 5,21:? "                              ":FOR Q=4 TO 20:POSITION 5,Q:? " ":POSITION 34,Q:? " ":NEXT Q
6200 POSITION 6,22:? "Press ANY KEY for SETUP MENU":POKE 82,6:POSITION 6,4:? FIX1$:? FIX2$:? FIX3$
6210 POSITION 6,8:? FIXF1$:? FIXF2$:? FIXF3$:? FIXF4$:POSITION 6,13:? FRM1$:? FRM2$:? FRM3$
6220 POSITION 6,17:? FRM41$:? FRM42$:? FRM43$:? FRM44$:CLOSE #1:OPEN #1,4,0,"K":GET #1,K:CLOSE #1
6230 POKE 82,0:GOTO 6000
6240 REM CUSTOM PROMPTS
6250 GRAPHICS 0:POKE 82,13:POKE 709,8:POKE 710,32:POKE 712,32:POKE 752,1:POKE 756,GT:GOSUB 130
6260 ? "↰":POSITION 4,1:? "───────┤ CUSTOM PROMPTS ├───────":POSITION 6,4:? "Select Label-type by Number"
6270 POSITION 13,7:? "1 3-LINE BLANK":? "2 3-LINE FORM":? "3 4-LINE BLANK":? "4 4-LINE FORM":? "5 SETUP  MENU"
6280 POKE 82,14:CPR=PEEK(764):GET #1,CPR:TRAP 6280:IF CPR=255 THEN 6280
6290 IF CPR-48>5 OR CPR-48<1 THEN 6280
6300 ON CPR-48 GOTO 6310,6330,6350,6380,6410
6310 POSITION 15,7:? "3-LINE BLANK":GOSUB 2300:POSITION 14,17:INPUT PROMPT1$:GOSUB 2290:GOSUB 2400
6320 POSITION 14,17:INPUT PROMPT2$:GOSUB 2290:GOSUB 2410:POSITION 14,17:INPUT PROMPT3$:GOTO 6250
6330 POSITION 15,8:? "3-LINE FORM":GOSUB 2300:POSITION 14,17:INPUT FPMT1$:GOSUB 2290:GOSUB 2400
6340 POSITION 14,17:INPUT FPMT2$:GOSUB 2290:GOSUB 2410:POSITION 14,17:INPUT FPMT3$:GOTO 6250
6350 POSITION 15,9:? "4-LINE BLANK":GOSUB 2300:POSITION 14,17:INPUT FOUR1$:GOSUB 2290:GOSUB 2400:POSITION 14,17
6360 INPUT FOUR2$:GOSUB 2290:GOSUB 2410:POSITION 14,17:INPUT FOUR3$:GOSUB 2290:GOSUB 2420
6370 POSITION 14,17:INPUT FOUR4$:GOTO 6250
6380 POSITION 15,10:? "4-LINE FORM":GOSUB 2300:POSITION 14,17:INPUT F4PMT1$:GOSUB 2290:GOSUB 2400:POSITION 14,17
6390 INPUT F4PMT2$:GOSUB 2290:GOSUB 2410:POSITION 14,17:INPUT F4PMT3$:GOSUB 2290:GOSUB 2420
6400 POSITION 14,17:INPUT F4PMT4$:GOTO 6250
6410 ? "↰":POKE 82,2:POSITION 2,2:POKE 709,0
6420 ? 30;" PROMPT1$=";CHR$(34);PROMPT1$;CHR$(34);":";"PROMPT2$=";CHR$(34);PROMPT2$;CHR$(34)
6430 ? 31;" PROMPT3$=";CHR$(34);PROMPT3$;CHR$(34)
6440 ? 32;" FPMT1$=";CHR$(34);FPMT1$;CHR$(34);":";"FPMT2$=";CHR$(34);FPMT2$;CHR$(34)
6450 ? 33;" FPMT3$=";CHR$(34);FPMT3$;CHR$(34)
6460 ? 34;" FOUR1$=";CHR$(34);FOUR1$;CHR$(34);":";"FOUR2$=";CHR$(34);FOUR2$;CHR$(34)
6470 ? 35;" FOUR3$=";CHR$(34);FOUR3$;CHR$(34);":";"FOUR4$=";CHR$(34);FOUR4$;CHR$(34)
6480 ? 36;" F4PMT1$=";CHR$(34);F4PMT1$;CHR$(34);":";"F4PMT2$=";CHR$(34);F4PMT2$;CHR$(34)
6490 ? 37;" F4PMT3$=";CHR$(34);F4PMT3$;CHR$(34);":";"F4PMT4$=";CHR$(34);F4PMT4$;CHR$(34)
6500 ? "CONT":POSITION 0,0
6510 POKE 842,13:STOP
6520 POKE 842,12:POKE 82,0:GOTO 6000
6530 REM CUSTOM FIXED LABEL
6540 GRAPHICS 0:POKE 710,162:POKE 712,162:POKE 752,1:POKE 756,GT:POKE 82,13
6550 POSITION 13,1:? "┌────────────┐":? "|FIXED LABELS|":? "└────────────┘":POKE 82,2
6560 GOSUB 2330:GOSUB 130
6570 FL=PEEK(764):GET #1,FL:TRAP 6560:IF FL=255 THEN 6570
6580 IF FL-48<1 OR FL-48>3 THEN 6560
6590 ON FL-48 GOTO 6600,6630,6670
6600 POSITION 5,8:? "3-LINE":TRAP 6540:GOSUB 2340:POSITION 9,13:INPUT FIX1$
6610 GOSUB 2360:POSITION 9,14:INPUT FIX2$:GOSUB 2365:POSITION 9,15:INPUT FIX3$
6620 GOTO 6540
6630 POSITION 16,8:? "4-LINE":GOSUB 2340:POSITION 9,13:INPUT FIXF1$
6640 GOSUB 2360:POSITION 9,14:INPUT FIXF2$
6650 GOSUB 2365:POSITION 9,15:INPUT FIXF3$
6660 GOSUB 2370:POSITION 9,16:INPUT FIXF4$
6665 GOTO 6540
6670 ? "↰":POSITION 2,2:POKE 709,2
6680 ? 15;" FIX1$=";CHR$(34);FIX1$;CHR$(34)
6690 ? 16;" FIX2$=";CHR$(34);FIX2$;CHR$(34):? 17;" FIX3$=";CHR$(34);FIX3$;CHR$(34)
6700 ? 18;" FIXF1$=";CHR$(34);FIXF1$;CHR$(34):? 19;" FIXF2$=";CHR$(34);FIXF2$;CHR$(34)
6710 ? 20;" FIXF3$=";CHR$(34);FIXF3$;CHR$(34):? 21;" FIXF4$=";CHR$(34);FIXF4$;CHR$(34)
6720 ? "CONT":POSITION 0,0
6730 POKE 842,13:STOP
6740 POKE 842,12:POKE 82,0:GOTO 6000
6790 REM CUSTOM FORM LABEL
6800 GRAPHICS 0:POKE 710,112:POKE 712,112:POKE 752,1:POKE 756,GT:POKE 82,14
6810 POSITION 14,1:? "┌──────────┐":? "|FORM LABEL|":? "└──────────┘":POKE 82,2
6820 GOSUB 2330:GOSUB 130
6830 FL=PEEK(764):GET #1,FL:TRAP 6820:IF FL=255 THEN 6830
6840 IF FL-48<1 OR FL-48>3 THEN 6820
6850 ON FL-48 GOTO 6860,6900,6950
6860 POSITION 5,8:? "3-LINE":TRAP 6800:GOSUB 2340:POSITION 9,13:INPUT FRM1$
6870 GOSUB 2360:POSITION 9,14:INPUT FRM2$
6880 GOSUB 2365:POSITION 9,15:INPUT FRM3$
6890 GOTO 6800
6900 POSITION 16,8:? "4-LINE":GOSUB 2340:POSITION 9,13:INPUT FRM41$
6910 GOSUB 2360:POSITION 9,14:INPUT FRM42$
6920 GOSUB 2365:POSITION 9,15:INPUT FRM43$
6930 GOSUB 2370:POSITION 9,16:INPUT FRM44$
6940 GOTO 6800
6950 ? "↰":POSITION 2,2:POKE 709,0
6960 ? 22;" FRM1$=";CHR$(34);FRM1$;CHR$(34)
6970 ? 23;" FRM2$=";CHR$(34);FRM2$;CHR$(34):? 24;" FRM3$=";CHR$(34);FRM3$;CHR$(34)
6980 ? 25;" FRM41$=";CHR$(34);FRM41$;CHR$(34):? 26;" FRM42$=";CHR$(34);FRM42$;CHR$(34)
6990 ? 27;" FRM43$=";CHR$(34);FRM43$;CHR$(34):? 28;" FRM44$=";CHR$(34);FRM44$;CHR$(34)
7000 ? "CONT":POSITION 0,0
7010 POKE 842,13:STOP
7020 POKE 842,12:POKE 82,0:GOTO 6000
7099 REM PRINT LABEL
7100 TRAP 7100:POKE 82,2:GOSUB 2260:GOSUB 830
7110 POSITION 2,7:? "TURN ON PRINTER":POSITION 14,10:? "   "
7120 POSITION 2,9:? "How many LABELS":? "do you want":POSITION 13,10:INPUT LNUM$:LNUM=VAL(LNUM$)
7130 IF LNUM<1 THEN 7110
7140 POSITION 4,13:? " PRINTING "
7150 FOR TNUM=1 TO LNUM
7160 LPRINT CHR$(27);CHR$(15);CHR$(27);CHR$(83);CHR$(0);CHR$(27);CHR$(65);CHR$(6);ULBL1$
7170 LPRINT ULBL2$:LPRINT ULBL3$
7180 IF LABEL=4 THEN LPRINT ULBL4$:GOTO 7230
7190 IF LABEL=1 THEN GOTO 7220
7200 LPRINT :LPRINT :LPRINT
7210 LPRINT LLBL1$:LPRINT LLBL2$:LPRINT LLBL3$
7220 IF LABEL=1 OR LABEL=2 THEN LPRINT :LPRINT :LPRINT
7230 IF LABEL=4 THEN LPRINT :LPRINT
7240 NEXT TNUM:GOSUB 2260
7250 IF LABEL=1 OR LABEL=4 THEN 150
7260 IF LABEL=2 THEN 210
7500 REM TITLE PAGE
7510 MT=PEEK(106):GT=MT-8:GRAPHICS 0:POKE 106,GT
7520 DL=PEEK(560)+256*PEEK(561):POKE DL+6,7:POKE 710,0:POKE 709,200:POKE 752,1
7530 POSITION 4,1:? "PHOTOGRAPHIC":POKE DL+7,10
7540 FOR Q=12 TO 20 STEP 4
7550 POKE 82,Q:POSITION Q,Q-10:? "┌───────┐":? "|       |":? "|┌─────┐|":? "||     ||":? "||     ||"
7560 ? "|└─────┘|":? "|       |":? "└───────┘"
7570 GOSUB 800
7580 NEXT Q
7590 POSITION 13,3:? A$:GOSUB 820:GOSUB 800:POSITION 17,7:? A$:GOSUB 820:GOSUB 800:X=1
7600 POSITION 20+X,11:? A$(X,X);:GOSUB 820
7610 IF X>7 THEN X=1:GOTO 7630
7620 GOTO 7600
7630 POSITION 20+X,16:? B$(X,X);:GOSUB 820:IF X>7 THEN 7650
7640 GOTO 7630
7650 GOSUB 800:POSITION 9,14:? "by":POSITION 4,16:? "Gary Coppola"
7660 FOR Z=1536 TO 1554:READ H:POKE Z,H:NEXT Z
7670 POSITION 10,21:? "Press START To Begin"
7680 POSITION 4,1:? "photo":U=USR(1536)
7690 DATA 104,173,31,208,201,6,240,10,232,142,10,212,142,25,208,76,1,6,96
7700 IF PEEK(53279)=6 THEN 10020
7800 POSITION 25,18:? "  Verification:QUIT?(Y/N)     ":GOSUB 830:GOSUB 130
7810 TRAP 7800:GET #1,G:IF G=89 OR G=121 THEN POKE 82,2:GRAPHICS 0:END
7820 IF G=78 OR G=110 THEN 40
7830 GOTO 7810
7850 ? "↑  Verification:SAVE TO DISK?(Y/N)":GOSUB 830:GOSUB 130
7860 TRAP 8050:GET #1,G:IF G=89 OR G=121 THEN SAVE "D:PHOTOLBL.BAS":GOTO 6000
7870 IF G=78 OR G=110 THEN 6000
7880 GOTO 7860
8000 POKE 712,66:POKE 752,1:POKE 82,3:FOR J=1 TO 3
8005 FOR Q=14 TO 0 STEP -1:SOUND 0,150+Q,10,Q:NEXT Q:NEXT J:GOSUB 2260
8010 POSITION 3,8:? " ERROR #";PEEK(195):? "HAS OCCURRED":? :? "RETURNING TO":? " MAIN MENU"
8020 FOR Q=1 TO 130:NEXT Q:TRAP 40000
8030 GOTO 40
8050 TRAP 40000:? "↰↰         DISK SAVE - ABORTED":? "             ERROR # ";PEEK(195)
8060 FOR J=1 TO 140:NEXT J:GOTO 6000
10000 REM REDEFINE CHARACTERS
10020 CHSET=GT*256:POSITION 5,21:? "INITIALIZING, PLEASE WAIT..."
10030 POKE 204,GT:POKE 206,224:MOVE$="h"┤ ♥1M┌KHPyfNfLJPr◆":U=USR(ADR(MOVE$))
10040 POKE 756,GT:FOR J=1 TO 9:READ OC
10050 FOR B=0 TO 7:READ I:POKE CHSET+OC+B,I
10060 NEXT B:NEXT J:GOTO 15
10070 DATA 512,255,255,192,192,192,192,192,192
10080 DATA 576,0,0,0,0,170,170,170,170
10090 DATA 584,255,255,3,3,3,3,3,3
10100 DATA 592,85,85,85,85,85,85,85,85
10110 DATA 600,3,3,3,3,3,3,255,255
10120 DATA 608,192,192,192,192,192,192,255,255
10130 DATA 632,24,24,0,255,255,0,24,24
10140 DATA 640,170,170,170,170,170,170,170,170
10150 DATA 672,85,85,85,85,0,0,0,0