The Atari Numerologist (NUMBERS.BAS)

The Atari Numerologist by Clifton Oyamot, 193

Description

The Atari Numerologist by Clifton Oyamot, 193

From the Antic disk of Antic: December 1989/January 1990 - Vol. 8 No. 7 — disk A.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 23.6 KB

Dialect
Atari BASIC
Lines
465
Variables
NAME$, FIRST$, MIDDLE$, LAST$, ASSIGN$, VOWEL$, ALPHA(, NAME(, X, Y, ALPAH(, MONTH, DAY, YEAR, COUNT, ROW1, ROW2, V, Q, E, T$, SOULURGE, QUIESCENT, EXPRESSION, REDUCED, LIFEPATH, ID, TEXT, ID$, TEXT$, SOUL$, QUIESCENT$, EXPRESSION$, LIFE$, LINENUBER, LINENUMBER, LIFE, K, PYEAR, PMONTH, PDAY, YEARP, MONTH2, DAY2, YEAR2, REDUCE, PERSONAL, O
BASIC listing (465 lines)
1 REM The Atari Numerologist
2 REM by Clifton Oyamot
3 REM (C) 1989 ANTIC PUBLISHNG, INC.
5 CLOSE #1:CLOSE #2
6 POKE 82,1
10 DIM NAME$(20),FIRST$(20),MIDDLE$(20),LAST$(20),ASSIGN$(9),VOWEL$(5),T$(4),ID$(3),TEXT$(40)
15 DIM SOUL$(3),QUIESCENT$(3),EXPRESSION$(3),LIFE$(3)
20 DIM ALPHA(3,9),NAME(6,20)
25 V=0:Q=0:E=0
27 CLOSE #1:CLOSE #2
30 GOSUB 1000
40 GOSUB 1100
50 GOSUB 1200
60 NAME$=FIRST$:ROW1=1:ROW2=2
70 IF LEN(NAME$)<>0 THEN GOSUB 1400
80 GOSUB 1600
90 NAME$=MIDDLE$:ROW1=3:ROW2=4
100 IF LEN(NAME$)<>0 THEN GOSUB 1400
110 GOSUB 1600
120 NAME$=LAST$:ROW1=5:ROW2=6
130 IF LEN(NAME$)<>0 THEN GOSUB 1400
140 GOSUB 1600
150 GOSUB 1700
160 GOSUB 1900
170 GOSUB 2100
180 CLOSE #1:CLOSE #2
190 GOTO 25
999 END
1000 REM CHOICES
1010 ? "↰";:POKE 709,4:POKE 710,0
1020 ? "         The Atari Numerologist        ";
1030 ? "           by Clifton Oyamot           ";
1040 ? "Check (N)ame or (D)ates?";
1050 OPEN #2,4,0,"K:":GET #2,K:CLOSE #2
1060 IF CHR$(K)="N" THEN RETURN
1070 IF CHR$(K)="D" THEN 3000
1080 POSITION 1,2
1090 GOTO 1040
1100 REM INITIALIZATION
1110 REM PART 1
1120 ? CHR$(K):? "Initializing";
1130 FOR X=1 TO 6
1140 FOR Y=1 TO 20
1150 NAME(X,Y)=0
1160 NEXT Y
1170 NEXT X
1180 RETURN
1200 REM DATA COLLECTOR
1210 TRAP 1200:POSITION 1,2
1220 FOR X=1 TO 30:? CHR$(254);:NEXT X
1225 POSITION 1,2
1230 FOR X=1 TO 12:? CHR$(254);:NEXT X
1235 POSITION 1,2
1240 ? "First Name :";:INPUT #16,FIRST$
1250 ? "Middle Name:";:INPUT #16,MIDDLE$
1260 ? "Last Name  :";:INPUT #16,LAST$
1270 TRAP 1270:? :? "Birthdate"
1280 ? "Month:";:INPUT #16,MONTH
1290 ? "Day  :";:INPUT #16,DAY
1295 ? "(Enter the year as 4 digits, ex. 1955)"
1300 ? "Year :";:INPUT #16,YEAR
1305 IF YEAR<1000 THEN 1300
1306 TRAP 40000
1310 ? "CALCULATING"
1320 RETURN
1400 REM NAME CALCULATIONS
1410 REM PART 1
1420 FOR X=1 TO LEN(NAME$)
1430 IF ASC(NAME$(X,X))>90 THEN NAME$(X,X)=CHR$(ASC(NAME$(X,X))-32)
1440 Y=64
1450 IF ASC(NAME$(X,X))>73 THEN Y=73
1460 IF ASC(NAME$(X,X))>82 THEN Y=82
1470 NAME(ROW1,X)=ASC(NAME$(X,X))-Y
1480 VOWEL$="AEIOU"
1490 FOR Y=1 TO 5
1500 IF NAME$(X,X)=VOWEL$(Y,Y) THEN NAME(ROW2,X)=1
1510 NEXT Y
1520 NEXT X
1530 RETURN
1540 RETURN
1600 REM PART 2
1610 FOR X=1 TO LEN(NAME$)
1620 IF NAME(ROW2,X)=1 THEN V=V+NAME(ROW1,X)
1630 IF NAME(ROW2,X)=0 THEN Q=Q+NAME(ROW1,X)
1640 NEXT X
1650 E=V+Q
1660 RETURN
1700 REM PART 3
1710 T$=STR$(V)
1720 IF V>9 THEN V=VAL(T$(1,1))+VAL(T$(2,2))
1730 T$=STR$(Q)
1740 IF Q>9 THEN Q=VAL(T$(1,1))+VAL(T$(2,2))
1750 T$=STR$(E)
1755 IF E>99 THEN E=VAL(T$(1,1))+VAL(T$(2,2))+VAL(T$(3,3))
1760 IF E>9 THEN E=VAL(T$(1,1))+VAL(T$(2,2))
1770 IF V>9 THEN 1710
1780 IF Q>9 THEN 1730
1790 IF E>9 THEN 1750
1800 SOULURGE=V:QUIESCENT=Q:EXPRESSION=E
1810 RETURN
1900 REM BIRTHDATE CALCULATIONS
1910 T$=STR$(MONTH)
1920 IF MONTH>9 THEN MONTH=VAL(T$(1,1))+VAL(T$(2,2))
1930 IF MONTH>9 THEN 1920
1940 LIFEPATH=MONTH+DAY+YEAR
1950 T$=STR$(LIFEPATH)
1960 LIFEPATH=VAL(T$(1,1))+VAL(T$(2,2))+VAL(T$(3,3))+VAL(T$(4,4))
1970 T$=STR$(LIFEPATH)
1980 IF LIFEPATH>9 THEN LIFEPATH=VAL(T$(1,1))+VAL(T$(2,2))
1990 IF LIFEPATH>9 THEN 1970
2000 RETURN
2100 REM INTERPRETATION
2110 ? "INTERPRETING"
2113 FOR X=1 TO 150:NEXT X
2115 OPEN #1,8,0,"E:"
2117 POKE 709,4:POKE 710,0
2120 FOR X=1 TO 100:NEXT X
2130 ? "Soul Urge"
2135 TEXT$="Soul Urge"
2140 LINENUMBER=SOULURGE*10+5000
2150 GOSUB LINENUMBER
2160 GOSUB 2300
2180 ? "↰":? "Quiescent Self"
2185 TEXT$="Quiescent Self"
2190 LINENUMBER=QUIESCENT*10+5100
2200 GOSUB LINENUMBER
2210 GOSUB 2300
2220 ? "↰":? "Expression"
2225 TEXT$="Expression"
2230 LINENUMBER=EXPRESSION*10+5200
2240 GOSUB LINENUMBER
2250 GOSUB 2300
2260 ? "↰":? "Life Path"
2265 TEXT$="Life Path"
2270 LINENUMBER=LIFEPATH*10+5300
2280 GOSUB LINENUMBER
2290 GOSUB 2300
2295 RETURN
2300 POSITION 3,20:? "Hit 'P' to output screen to printer"
2305 POKE 752,1
2310 POSITION 8,21:? "Hit <space> to continue"
2320 OPEN #2,4,0,"K:"
2330 GET #2,K
2340 CLOSE #2
2345 POKE 752,0
2350 IF CHR$(K)<>"P" THEN RETURN
2360 CLOSE #1
2370 OPEN #1,8,0,"P:"
2373 ? #1
2374 ? #1;"Analysis by the Atari Numerologist":? #1;TEXT$
2375 ? "Subject:";FIRST$;" ";MIDDLE$;" ";LAST$:? #1
2380 GOSUB LINENUMBER
2390 CLOSE #1
2400 OPEN #1,8,0,"E:"
2410 POKE 709,4:POKE 710,0
2420 RETURN
3000 REM DATES-
3010 POSITION 1,2
3020 FOR X=1 TO 30:? CHR$(254);:NEXT X
3030 ? "Check your personal":? "(M)onth, (D)ay, or (Y)ear?";
3040 OPEN #2,4,0,"K:":GET #2,K:CLOSE #2
3050 REM DATA COLLECTOR
3060 TRAP 3050:POSITION 1,2
3070 FOR X=1 TO 20:? CHR$(254);:NEXT X
3075 POSITION 1,3:FOR X=1 TO 30:? CHR$(254);:NEXT X:POSITION 1,2
3080 ? "Birthdate"
3090 ? "Month:";:INPUT #16,MONTH
3100 ? "Day  :";:INPUT #16,DAY
3105 ? "(Enter year as 4 digits ex. 1955)"
3110 ? "Year :";:INPUT #16,YEAR
3115 IF YEAR<1000 THEN 3110
3120 ? :? "The Present"
3130 ? "Month:";:INPUT #16,MONTH2
3140 ? "Day  :";:INPUT #16,DAY2
3145 ? "Enter year as 4 digits, ex. 1955)"
3150 ? "Year :";:INPUT #16,YEAR2
3155 IF YEAR2<1000 THEN 3150
3160 TRAP 40000:GOSUB 3500
3165 TEXT$="Yearly Forecast"
3170 IF CHR$(K)="M" THEN GOSUB 3550
3180 IF CHR$(K)="D" THEN GOSUB 3600
3190 ? "INTERPRETING":FOR X=1 TO 150:NEXT X
3195 ? "↰":? "Outlook"
3200 REM INTERPRETATION
3204 CLOSE #1
3205 OPEN #1,8,0,"E:"
3207 POKE 709,4:POKE 710,0
3210 LINENUMBER=PERSONAL*10+5400
3215 GOSUB LINENUMBER
3220 POSITION 3,20:? "Hit 'P' to output screen to printer"
3230 POKE 752,1
3240 POSITION 8,21:? "Hit <space> to continue"
3250 OPEN #2,4,0,"K:"
3260 GET #2,K
3270 CLOSE #2
3275 POKE 752,0
3280 IF CHR$(K)<>"P" THEN 25
3290 CLOSE #2:CLOSE #1
3300 OPEN #1,8,0,"P:"
3304 ? #1
3305 ? #1;"Analysis by the Atari Numerologist":? #1;TEXT$
3306 ? "Subject:";FIRST$;" ";MIDDLE$;" ";LAST$:? #1
3310 GOSUB LINENUMBER
3315 CLOSE #1:CLOSE #2
3320 GOTO 25
3500 REM PERSONAL YEAR
3510 YEAR=YEAR2
3520 GOSUB 1900
3530 PERSONAL=LIFEPATH
3540 RETURN
3550 REM PERSONAL MONTH
3555 TEXT$="Monthly Forecast"
3560 REDUCE=MONTH2+YEAR2
3570 GOSUB 3700
3580 PERSONAL=REDUCE
3590 RETURN
3600 REM PERSONAL DAY
3605 TEXT$="Daily Forecast"
3610 REDUCE=REDUCE+DAY2
3620 GOSUB 3700
3630 PERSONAL=REDUCE
3640 RETURN
3700 REM REDUCTIONS
3710 T$=STR$(REDUCE)
3720 IF REDUCE>9 THEN REDUCE=VAL(T$(1,1))+VAL(T$(2,2))
3730 IF REDUCE>9 THEN 3710
3740 RETURN
5000 REM SOUL URGES-
5009 RETURN
5010 ? #1;"You have an innate need to lead and":? #1;"direct.  Until this urge is satisfied"
5011 ? #1;"you will never be completely happy.":? #1;"Alone you are courageous, strong-"
5012 ? #1;"willed and determined.  However, when":? #1;"you are with others these traits can"
5013 ? #1;"make you a bit overbearing and":? #1;"domineering."
5019 RETURN
5020 ? #1;"You are naturally friendly and":? #1;"sociable.  You also have a need to "
5021 ? #1;"fix things when they are not quite":? #1;"perfect.  Peace and quiet are what"
5022 ? #1;"you yearn for.  You are easily":? #1;"persuaded.  Diplomacy and tact are "
5023 ? #1;"the trademark of your character."
5029 RETURN
5030 ? #1;"A natural optimist, you look at the":? #1;"bright and cheerful side of life."
5031 ? #1;"You possess a vivid imagination and":? #1;"you love to talk.  Coupled with your"
5032 ? #1;"colorful language, you make a":? #1;"wonderful entertainer.  However, you"
5033 ? #1;"also tend to exagerrate things.":? #1;"When situations warrant it, you can"
5034 ? #1;"be very generous."
5039 RETURN
5040 ? #1;"You have the urge to see a job well-":? #1;"done.  You cannot tolerate a job"
5041 ? #1;"left incomplete or incorrect.":? #1;"You feel organization is the key."
5042 ? #1;"You have an established routine.":? #1;"You cannot stand to see things wasted"
5043 ? #1;"You are against the strict inter-":? #1;"pretation of the law.  Your word is"
5044 ? #1;"your bond.  You also have a high set":? #1;"of morals which you feel everyone":? #1;"should adhere to."
5049 RETURN
5050 ? #1;"You dream of distant and romantic":? #1;"lands of adventure. You seek freedom"
5051 ? #1;"and you can't be bothered with details":? #1;"and routine. You are clever."
5052 ? #1;"'Curiosity is your lifework, and":? #1;"versatility the byline'."
5059 RETURN
5060 ? #1;"You have strong humanitarian":? #1;"tendencies.You wish to be of service"
5061 ? #1;"to others.  You long for harmony,":? #1;"beauty and rythmn in your life."
5062 ? #1;"There is an artist lying within you":? #1;"that longs to be recognized."
5069 RETURN
5070 ? #1;"You possess a highly developed ":? #1;"intuition.The psychic world holds a"
5071 ? #1;"fascination for you.  One of your":? #1;"greatest pleasures is observing or"
5072 ? #1;"researching the paranormal and ":? #1;"coming to your own conclusions."
5073 ? #1;"You are just a bit self-indulgent."
5079 RETURN
5080 ? #1;"You admire success and wish to attain":? #1;"it in your chosen field.  With your"
5081 ? #1;"hardwork and determination, you may":? #1;"achieve it.  Quality is important."
5082 ? #1;"You are persuasive, a natural sales":? #1;"person."
5089 RETURN
5090 ? #1;"You are a dreamer, a visionary.":? #1;"You're ideal concept of the world can"
5091 ? #1;"clash with harsh reality.  You would":? #1;"like everyone to enjoy the pleasures"
5092 ? #1;"of life, and you would like to enjoy":? #1;"those luxuries yourself."
5099 RETURN
5100 REM QUIESCENT SELF-
5110 ? #1;"Everything you do is for a purpose.":? #1;"Until you have a definite goal or"
5111 ? #1;"plan you remain uninspired.  You have":? #1;"a strong will and you are ambitious."
5112 ? #1;"However, you can also be too self-":? #1;"indulgent and you cultivate an"
5113 ? #1;"attitude of superiority."
5119 RETURN
5120 ? #1;"You have a charm which makes people":? #1;"want to please you.  However, when"
5121 ? #1;"denied your wishes, you may scheme":? #1;"to get your ways.  Despite this, your"
5122 ? #1;"natural inclination is to help people."
5129 RETURN
5130 ? #1;"You see great things to come in the":? #1;"future and that is where you put"
5131 ? #1;"your faith.  However, there is a":? #1;"tendency to drift because you may"
5132 ? #1;"feel life has given you enough bumps."
5139 RETURN
5140 ? #1;"Your inherent stability makes you":? #1;"generally self-reliant. However, you"
5141 ? #1;"can find hardships where they do":? #1;"not exist and you can be quite a"
5142 ? #1;"slave driver."
5149 RETURN
5150 ? #1;"You seek adventure with a carefree":? #1;"attitude. You don't worry about the"
5151 ? #1;"future or the past but of today.":? #1;"You are imaginative and make a good"
5152 ? #1;"dreamer and/or magician."
5159 RETURN
5160 ? #1;"You long for peace and quiet.  You":? #1;"also possess an inner confidence"
5161 ? #1;"of attaining your goals.  This leads":? #1;"to harmony with yourself.  Luxury is"
5162 ? #1;"not necessary for you but comfort is."
5169 RETURN
5170 ? #1;"When alone, peace and quiet":? #1;"contemplation is the rule.  There is"
5171 ? #1;"little in the world that suprises you.":? #1;"You enjoy the quiet solitude of being":? #1;"alone."
5179 RETURN
5180 ? #1;"A strong barrier protects you.  You":? #1;"can overcome most obstacles.  You"
5181 ? #1;"find happiness in solitude.  You":? #1;"manage your time wisely.  You also"
5182 ? #1;"enjoy solving problems."
5189 RETURN
5190 ? #1;"You seek justice and will settle for":? #1;"nothing less.  You have a strong"
5191 ? #1;"conscience.  You can be, when at your":? #1;"best, the epitome of the noble spirit.";
5199 RETURN
5200 REM EXPRESSIONS-
5210 ? #1;"You seek to express perfect indivi-":? #1;"tuality.  You must learn to make your"
5211 ? #1;"own decisions and to play the leader.":? #1;"You must use your great courage to"
5212 ? #1;"be an example to the world.  However,":? #1;"you must be careful of pride, hubris."
5213 ? #1;"When negative, you can become a":? #1;"dictator.  You must work in a way to"
5214 ? #1;"implement your great originality.":? #1;"Do not be hindered by tradition, set"
5215 ? #1;"your own standards, and take nothing":? #1;"at face value.  You have the ability"
5216 ? #1;"to change the world if you follow your":? #1;"natural inclinations."
5217 RETURN
5220 ? #1;"You possess a cooperative spirit.":? #1;"You are highly sympathetic and have"
5221 ? #1;"a goodwill.  You prefer to 'go with":? #1;"the flow'.  It is easy for you to "
5222 ? #1;"be in unfamiliar surroundings and ":? #1;"meet new people.  Your role is that"
5223 ? #1;"of the peace maker.  On the negative":? #1;"side, you can be conceited and"
5224 ? #1;"ignorant.  You often give the":? #1;"impression that you are hypocritical."
5225 ? #1;"You should strive to be agreeable and":? #1;"sincere to be the diplomat that you":? #1;"are."
5226 RETURN
5230 ? #1;"As the natural optimist, your goal is":? #1;"to spread cheer and goodwill to"
5231 ? #1;"those around you.  People often seek":? #1;"you out to console them.  However,"
5232 ? #1;"you do not feel burdened by this":? #1;"responsibility.  You find happiness"
5233 ? #1;"in service.  You enjoy expressing":? #1;"yourself in both words and action."
5234 ? #1;"However, you are prone to scatter":? #1;"your energies and you tend to talk":? #1;"too much."
5235 ? #1;"Your's is an important mission:":? #1;"to reveal the beauty of life in all"
5236 ? #1;"its aspects to the unenlightened."
5237 RETURN
5240 ? #1;"You are the builder, of your life,":? #1;"your happiness, and of your community."
5241 ? #1;"More the realist than the romanitic,":? #1;"you are a sturdy, productive"
5242 ? #1;"member of society."
5243 ? #1;"When less developed,you can be petty,":? #1;"narrow-minded, and jealous."
5244 ? #1;"When at your height, your efforts are":? #1;"benefiting you, your neighbors, and"
5245 ? #1;"the world."
5246 RETURN
5250 ? #1;"You have a dynamic personality. You":? #1;"best express yourself using your"
5251 ? #1;"oratical or written skills.  You are":? #1;"the person that spreads ideas, news,"
5252 ? #1;"and such, but first you must learn":? #1;"that change brings progress."
5253 ? #1;"You must learn to let go of things,":? #1;"such as the past.  Your temper can"
5254 ? #1;"manifest itself in passionate":? #1;"displays.  You may also be impulsive."
5255 ? #1;"Nevertheless, you will find happiness":? #1;"spreading the words, the words of"
5256 ? #1;"change and progress."
5257 RETURN
5260 ? #1;"You are the signpost, the guardian.":? #1;"You are trying to show the way that"
5261 ? #1;"those around you, and the world in":? #1;"general, should be going.  The"
5262 ? #1;"Golden Rule is the only code you need":? #1;"follow.  You need beauty and harmony"
5263 ? #1;"for your well-being.  At your worst,":? #1;"you are egocentric, selfish, and"
5264 ? #1;"worrisome.":? #1;"By seeking, creating, and protecting":? #1;"beauty will you find happiness."
5265 RETURN
5270 ? #1;"You best express yourself through":? #1;"silence.  You have many lessons to"
5271 ? #1;"learn, much to understand.  Things":? #1;"are not always what they seem, and"
5272 ? #1;"you must learn to discern the hidden":? #1;"message.  You have a high regard for"
5273 ? #1;"the mystical and/or the spiritual.":? #1;"Coupled with a keen mind, you have"
5274 ? #1;"the potential to see and understand":? #1;"the complexities of life in a far"
5275 ? #1;"greater depth than most."
5276 RETURN
5280 ? #1;"You are one to which power,":? #1;"organization, and success is very"
5281 ? #1;"important.  However, success should":? #1;"not come only to you.  You believe"
5282 ? #1;"that all should share what the world":? #1;"has to offer.  By applying yourself"
5283 ? #1;"you can obtain those goods, which":? #1;"you share with those around you."
5284 ? #1;"On the negative side, you are prone":? #1;"to violent displays of anger.  When"
5285 ? #1;"not following the correct path, you":? #1;"can be the cause of unhappiness, for"
5286 ? #1;"you and those who know you.  You":? #1;"cannot handle failure well."
5287 ? #1;"If you find your niche in life, you":? #1;"can become a great person."
5288 RETURN
5290 ? #1;"Compassion is your goal and trademark.":? #1;"You are seldom touched by envy, "
5291 ? #1;"jealousy, and derision and rarely do":? #1;"you condemn things."
5292 ? #1;"If not careful however, you can lead":? #1;"a life of disappointments and"
5293 ? #1;"depression.  You must pour forth love":? #1;"into the world.  You have the"
5294 ? #1;"potential to attain life's highest":? #1;"ideals."
5295 RETURN
5300 REM LIFE CYCLES-
5310 ? #1;"You are the pioneer, the leader, the":? #1;"captain. You are highly original and"
5311 ? #1;"creative and you possess the drive to":? #1;"put your ideas into practice.  You"
5312 ? #1;"are highly ambitious. Sometimes, your":? #1;"ambition can get the most of you, and"
5313 ? #1;"you become hasty and domineering. You":? #1;"also tend to be critical but unable"
5314 ? #1;"to take criticism yourself."
5315 RETURN
5320 ? #1;"More the follower than the leader,":? #1;"you provide steady, quiet help. You"
5321 ? #1;"are best suited to executing plans":? #1;"rather than creating them.  You try"
5322 ? #1;"to maintain harmony. Without being":? #1;"agressive, you are still able to"
5323 ? #1;"gather all that you need, including":? #1;"many friends.  You are possessed of"
5324 ? #1;"charm and courtesy. You are also":? #1;"highly independent, self-sufficient."
5325 RETURN
5330 ? #1;"You are the pinnacle of self-":? #1;"expression. You see life with an"
5331 ? #1;"unclouded vision. You are amazingly":? #1;"versatile, so versatile that you"
5332 ? #1;"may have trouble choosing just one":? #1;"talent to highlight. You can acquire"
5333 ? #1;"knowledge quite easily without serious":? #1;"study. You are highly sociable,"
5334 ? #1;"making it easy for people to like you,":? #1;"except those who do not understand"
5335 ? #1;"you. You have a way with words that":? #1;"may serve you well as writer,"
5336 ? #1;"teacher, or entertainer. You are not":? #1;"truly happy unless you are with"
5337 ? #1;"someone who takes you seriously and":? #1;"understands you."
5338 RETURN
5340 ? #1;"Growth is the only thing possible for":? #1;"you. You are a practical, organized"
5341 ? #1;"worker.  Method and logic are your":? #1;"tools. You may restrict yourself by"
5342 ? #1;"your strict conservatism. You are able":? #1;"to visualize the concepts of artists"
5343 ? #1;"and architects well, then execute them":? #1;"in your own way. You are highly":? "dependable."
5344 RETURN
5350 ? #1;"You feel life is one great adventure.":? #1;"Because of this, you value your"
5351 ? #1;"freedom to explore it. You are also":? #1;"highly intellectual and a master of"
5352 ? #1;"words, both written and spoken.You":? #1;"would do well as a teacher, lecturer,"
5353 ? #1;"or a brilliant entertainer. Coupled":? #1;"with your sharp wit,you can be highly"
5354 ? #1;"sarcastic and humorous. Express":? #1;"yourself in the best way possible and"
5355 ? #1;"you should be content."
5356 RETURN
5360 ? #1;"You have the distinction of being a":? #1;"teacher. Not neccesarily in school,"
5361 ? #1;"but a teacher of life. Philosophy,":? #1;"harmony, and beauty are all part of"
5362 ? #1;"your lesson plan and a neccesary part":? #1;"of you and your suroundings."
5364 ? #1;"You have a deep appreciation for the":? #1;"arts and music.In these fields you are"
5365 ? #1;"either creator or connoiseur.Yours is":? #1;"a great burden, but you are a great"
5366 ? #1;"humanitarian."
5367 RETURN
5370 ? #1;"You have a keen,analytical mind which":? #1;"seeks the answers, the underlying"
5371 ? #1;"meaning to everything around you.Your":? #1;"probings may center about those things"
5372 ? #1;"occult.You have a reserved manner but":? #1;"you are still respected. You"
5373 ? #1;"appreciate, indeed need, the finer":? #1;"things in life, such as good art."
5374 ? #1;"You have many obstacles to encounter":? #1;"and many lessons to learn."
5375 RETURN
5380 ? #1;"Efficient and capable, you can obtain":? #1;"a life of prosperity. You are able to"
5381 ? #1;"understand and sympathize with human":? #1;"nature. You possess a lot of authority"
5382 ? #1;"and are happy when in control of some":? #1;"large endeavor. You may overwork"
5383 ? #1;"yourself and be a bit dictatorial.":? #1;"You must learn to curb or control the"
5384 ? #1;"destructive forces which lie within":? #1;"you. You can contribute the most when"
5385 ? #1;"putting an effort into the practical":? #1;"advancement of man."
5386 RETURN
5390 ? #1;"You may spend your life seeking":? #1;"answers to the intangible questions."
5391 ? #1;"You understand the value of service to":? #1;"others. You strive for perfection."
5392 ? #1;"You understand the need for silence.":? #1;"You are also extremely sensitive to"
5393 ? #1;"everything around you. This allows you":? #1;"to be highly perceptive. You have a"
5394 ? #1;"tendency to fly to the heights then":? #1;"plunge into the depths. You cannot be"
5395 ? #1;"limited. You will live a full life."
5396 RETURN
5400 REM PERSONAL FORECASTS-
5410 ? #1;"Now is the time for you start new":? #1;"things. Go after the things you want."
5411 ? #1;"Take the initiative."
5412 RETURN
5420 ? #1;"This is the time to follow rather":? #1;"than lead.  Cooperation is the key"
5421 ? #1;"here.  Things started continue to":? #1;"slowly grow.  Cultivate them."
5422 RETURN
5430 ? #1;"Lots of social activities ahead.":? #1;"Try not to scatter your energies to"
5431 ? #1;"widely.  This is a time to be happy,":? #1;"express the joy of life."
5432 RETURN
5440 ? "Time to face reality. You must work":? "hard and extra responsibilities may"
5441 ? "come your way."
5442 RETURN
5450 ? #1;"This is a time to go places, have":? #1;"new experiences.  Be ready for the"
5451 ? #1;"unexpected and open yourself to new":? #1;"perspectives."
5452 RETURN
5460 ? #1;"Things are settling down.  Accent on":? #1;"steady friendships.  You may find"
5461 ? #1;"yourself working in a group project.":? #1;"You may be inclined to go along with":? #1;"the crowd."
5462 RETURN
5470 ? #1;"This is time best spent by yourself.":? #1;"Examine yourself, meditate.  Rely on"
5471 ? #1;"your inner strength and faith.":? #1;"Tomorrow brings new and better things."
5472 RETURN
5480 ? #1;"If you've earned it, recognition will":? #1;"come to you.  Think big and aim high."
5481 ? #1;"Now is the time to better your status":? #1;"both financially and materially."
5482 RETURN
5490 ? #1;"Now is the time to wrap up loose ends,":? #1;"end old projects and get ready for new"
5491 ? #1;"ones.  You can afford to give.  Pay":? #1;"attention to what is going on around"
5492 ? #1;"you and you will realize the common":? #1;"humanity we all share."
5493 RETURN