The Nerve Game (NERVE.BAS)
The Nerve Game by Jason Strautman, 53
Description
The Nerve Game by Jason Strautman, 53
From the Antic disk of Antic: December 1989/January 1990 - Vol. 8 No. 7 — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 6.5 KB
- Dialect
- Atari BASIC
- Lines
- 206
- Variables
C0,C1,C2,C8,C9,C10,C12,C13,C15,C16,C17,C19,C20,C250,C255,PLAYER,CARDNUM,TURN(,NAME$,ONCARD(,LOOP,KEY,PLAY,TIME,OLDT,LEFT,TIME(,HI,LO,SCRMEM,ENA,DLIST,PAUSE,X,Y,CHAR,MISC$,LETTER,DICE$,RETURN,ROLL,NUM,POSS$,CURR,CARDP(,DRAW,SORT,CHECK,I,J,ALLOT,TOP,PLAY0,BASE,DLST
BASIC listing (206 lines)
1 REM THE NERVE GAME
2 REM BY JASON STRAUTMAN
3 REM (C)1989, ANTIC PUBLISHING, INC.
10 C0=0:C1=1:C2=2:C8=8:C9=9:C10=10:C12=12:C13=13:C15=15:C16=16:C17=17:C19=19:C20=20:C250=250:C255=255
20 REM The Nerve Game
30 REM By Jason Strautman
40 REM For Antic Publishing
50 GOSUB 1320:PLAYER=C1:GOSUB 1500
60 REM Main Loop
70 CARDNUM=C1
80 GOSUB 1020:GOSUB 1290
90 REM Re-Draw The Screen
100 TURN(PLAYER)=TURN(PLAYER)+C1
110 ? "↰":POSITION C13,C0:? "The Nerve Game":? "Player up:";NAME$(PLAYER*C10-C9,PLAYER*C10)
120 POSITION 23,C1:? "Finished ";ONCARD(PLAYER)-C1;" cards"
130 POSITION C2,C17:? "SPACE - Re-Roll Dice":? "ESC - Stop & End the Round"
140 ? "CLEAR - Draw Next Card":? "DELETE - Put Back Letter"
150 ? "ARROWS - Move":? "A-Z - Place a Letter"
160 GOSUB 670
170 CARDNUM=ONCARD(PLAYER):GOSUB 940:POKE C20,C0:POKE C19,C0
180 FOR LOOP=C1 TO C2 STEP C0
190 KEY=C0:GOSUB 320
200 IF PEEK(764)<>C255 THEN GET #C1,KEY:KEY=KEY-128*(KEY>128):IF KEY>96 AND KEY<123 THEN KEY=KEY-32
210 POKE 764,C255
220 IF KEY>64 AND KEY<91 THEN GOSUB 390
230 IF (KEY>41 AND KEY<46) OR KEY=61 THEN GOSUB 490
240 IF KEY=27 THEN 750
250 IF KEY=32 THEN GOSUB 670
260 IF KEY=125 THEN GOSUB 820
270 IF KEY=126 THEN GOSUB 560
280 NEXT LOOP
290 PLAYER=PLAYER+C1:IF PLAYER>PLAY THEN 1190
300 GOTO 70
310 REM Timer Routine
320 TIME=INT((PEEK(C19)*C255+PEEK(C20))/60):IF TIME<>OLDT THEN OLDT=TIME:SOUND C0,100,C10,C15:SOUND C0,C0,C0,C0
330 LEFT=TIME(PLAYER)-TIME:HI=INT(LEFT/10):LO=LEFT-HI*10:POKE SCRMEM,16+HI:POKE SCRMEM+1,16+LO
340 IF TIME<TIME(PLAYER) THEN RETURN
350 ? "↰":POKE ENA,C0:POSITION C13,11:? "↰TIME IS UP!!!":POSITION C8,C12:? "Starting back at card #";
360 ? ONCARD(PLAYER):POKE 561,INT(DLIST/256):POKE 560,DLIST-PEEK(561)*256:FOR PAUSE=C1 TO C250:NEXT PAUSE
370 GOSUB 1290:POKE 560,0:POKE 561,6:GOTO 100
380 REM Place A Letter
390 LOCATE X,Y,CHAR:IF CHAR<>148 THEN RETURN
400 MISC$=CHR$(KEY)
410 FOR LETTER=C1 TO C12
420 IF MISC$=DICE$(LETTER,LETTER) THEN 450
430 NEXT LETTER
440 RETURN
450 POSITION C2*LETTER,C2:? " "
460 DICE$(LETTER,LETTER)=" ":POSITION X,Y:? MISC$;"←";
470 RETURN
480 REM Move The Cursor
490 IF KEY=45 AND Y>C9 THEN Y=Y-C1
500 IF KEY=61 AND Y<C12 THEN Y=Y+C1
510 IF KEY=43 AND X>C17 THEN X=X-C2
520 IF KEY=42 AND X<21 THEN X=X+C2
530 POSITION X,Y:? "→←";
540 RETURN
550 REM Remove A Letter
560 LOCATE X,Y,CHAR:CHAR=CHAR-128
570 IF CHAR<65 THEN RETURN
580 FOR RETURN=C1 TO C12
590 IF DICE$(RETURN,RETURN)=" " THEN 620
600 NEXT RETURN
610 RETURN
620 DICE$(RETURN,RETURN)=CHR$(CHAR)
630 POSITION C2*RETURN,C2:? CHR$(CHAR)
640 POSITION X,Y:? "●←";
650 RETURN
660 REM Roll The Dice
670 FOR ROLL=C1 TO C12
680 NUM=INT(RND(C0)*98+C1)
690 DICE$(ROLL)=POSS$(NUM,NUM)
700 POSITION C2*ROLL,C2:? DICE$(ROLL)
710 NEXT ROLL
720 GOTO 940
730 RETURN
740 REM End Of The Round
750 GOSUB 810:POKE ENA,C0:POKE 561,INT(DLIST/256):POKE 560,DLIST-PEEK(561)*256
760 ? "↰":POSITION C12,C9:? "Any challenges?";:GET #1,KEY:ON KEY=89 OR KEY-32=89 GOTO 100:? "N"
770 POSITION C10,C13:? "These cards are okay."
780 FOR PAUSE=C1 TO C250:NEXT PAUSE
790 LET ONCARD(PLAYER)=CARDNUM:POKE 560,0:POKE 561,6
800 GOTO 100
810 REM Draw A New Card
820 POSITION C2,C15:? "Checking card..."
830 FOR X=C17 TO 21 STEP C2
840 FOR Y=C8 TO C12
850 LOCATE X,Y,CHAR
860 IF CHAR=ASC("●") THEN POSITION C2,C15:? " ":POSITION X,Y:? "●←";:GOTO 180
870 NEXT Y
880 NEXT X
890 POSITION C2,C15:? " ":CARDNUM=CARDNUM+C1
900 IF CARDNUM=C9 THEN 1120
910 GOTO 670:GOTO 940
920 RETURN
930 REM Place a Card On The Screen
940 CURR=CARDP(PLAYER,CARDNUM):RESTORE 19950+CURR*50
950 POSITION C16,6:? "┌─────┐":POKE 85,C16:? "| ";CURR;" |":POKE 85,C16:? "├─────┤":POSITION C16,C13:? "└─────┘"
960 FOR DRAW=C1 TO 4
970 READ MISC$:POSITION C16,C8+DRAW:? MISC$
980 NEXT DRAW
990 X=C17:Y=C9:POKE ENA,3:POSITION X,Y:? "→←";
1000 RETURN
1010 REM Shuffle The Cards
1020 FOR SORT=C1 TO C8
1030 NUM=INT(RND(C0)*C8+C1)
1040 IF SORT=C1 THEN 1080
1050 FOR CHECK=C1 TO SORT
1060 IF NUM=CARDP(PLAYER,CHECK) THEN 1030
1070 NEXT CHECK
1080 CARDP(PLAYER,SORT)=NUM
1090 NEXT SORT
1100 RETURN
1110 REM Out of Cards
1120 POKE ENA,C0:? "↰":POKE 561,INT(DLIST/256):POKE 560,DLIST-PEEK(561)*256
1130 POSITION C12,C9:? "Any challenges?";:GET #1,KEY:IF KEY=89 OR KEY=122 THEN CARDNUM=ONCARD(PLAYER):GOTO 100
1140 ? "N":POSITION 6,C13:? "All your cards are gone!!!"
1150 FOR PAUSE=C1 TO C250:NEXT PAUSE
1160 GOSUB 1290
1170 POKE 560,0:POKE 561,6:GOTO 290
1180 REM Must Be End Of Game
1190 GRAPHICS 0:POKE 710,2:? "Here are the scores:":FOR I=C1 TO PLAY:LET ONCARD(I)=C1:FOR J=C1 TO PLAY
1200 IF TURN(I)>TURN(J) THEN LET ONCARD(I)=ONCARD(I)+C1
1210 NEXT J:NEXT I
1220 FOR I=C1 TO C8
1230 FOR J=C1 TO PLAY
1240 IF ONCARD(J)=I THEN ? NAME$(J*C10-C9,J*C10);" (";ONCARD(J);") ";TURN(J);" turns"
1250 NEXT J
1260 NEXT I
1270 END
1280 REM Reset The Timer
1290 POKE C20,C0:POKE C19,C0
1300 RETURN
1310 REM Initialize
1320 DIM DICE$(C12),POSS$(98),NAME$(80),MISC$(C10),CARDP(C8,C8),ONCARD(C8),TURN(C8),TIME(C8)
1330 OPEN #C1,4,C0,"K:":GRAPHICS C0:SCRMEM=PEEK(88)+PEEK(89)*256+117
1340 FOR I=C1 TO C8:LET ONCARD(I)=C1:TURN(I)=C0:NEXT I
1350 POSS$="AAAAAAAAABBCCDDDDEEEEEEEEEEEEFFGGGHHIIIIIIIIIJKLLLLMMNNNNNNOOOOOOOOPPQRRRRRRSSSSTTTTTTUUUUVVWWXYYZ"
1360 POKE 710,146:POKE 709,C12:POKE 82,C2
1370 ? "↰":POSITION C13,C0:? "The Nerve Game":POSITION 11,C1:? "By Jason Strautman"
1380 REM Get # Of Players And Names
1390 TRAP 1390:POSITION C2,4:? "How many players for this game";:INPUT PLAY:PLAY=INT(PLAY)
1400 IF PLAY<C0 OR PLAY>C8 THEN 1390
1410 FOR I=C1 TO PLAY
1420 POSITION C2,5+C2*I:? "Player #";I;"'s name -->";:INPUT #C16,MISC$
1430 TRAP 1430:POSITION C2,6+C2*I:? " How many seconds per round";:INPUT ALLOT
1440 ON ALLOT<15 OR ALLOT>99 GOTO 1430:TIME(I)=ALLOT
1450 IF LEN(MISC$)<C10 THEN FOR J=LEN(MISC$)+C1 TO C10:MISC$(J)=" ":NEXT J
1460 NAME$(I*C10-C9)=MISC$
1470 NEXT I
1480 RETURN
1490 REM Player/Missle for Card
1500 TOP=PEEK(106)-C8:POKE 54279,TOP
1510 ENA=53277:POKE 559,46:POKE ENA,C0
1520 POKE 53248,114:PLAY0=512
1530 BASE=256*TOP:POKE 53256,C1
1540 POKE 53249,130:POKE 705,80
1550 FOR I=BASE+PLAY0 TO BASE+PLAY0+128:POKE I,C0:NEXT I
1560 POKE 704,80:RESTORE 1600
1570 FOR J=BASE+PLAY0+41 TO BASE+PLAY0+70
1580 POKE J,C255:POKE J+128,C255:NEXT J
1590 REM Set up the Display List
1600 DLIST=PEEK(560)+PEEK(561)*256:FOR I=0 TO 30:POKE 1536+I,PEEK(DLIST+I):NEXT I:POKE 560,0:POKE 561,6:DLST=1536
1610 POKE DLST,80:POKE DLST+7,C0:POKE DLST+9,C0:POKE DLST+24,C0:POKE DLST+30,C2:POKE DLST+31,C2:POKE DLST+32,65
1620 POKE DLST+33,PEEK(560):POKE DLST+34,PEEK(561):POKE DLST+29,2:RETURN
19998 REM Data for the Cards
19999 REM CARD #1
20000 DATA | ● |
20010 DATA |●─●─●|
20020 DATA | ● |
20030 DATA | ● |
20049 REM CARD #2
20050 DATA |●─●─●|
20060 DATA | |
20070 DATA |●─●─●|
20080 DATA | |
20099 REM CARD #3
20100 DATA |● ●|
20110 DATA |● ●|
20120 DATA |● ●|
20130 DATA |●─●─●|
20149 REM CARD #4
20150 DATA |●─●─●|
20160 DATA |● ●|
20170 DATA |●─●─●|
20180 DATA | |
20199 REM CARD #5
20200 DATA |●─● |
20210 DATA | |
20220 DATA |●─● |
20230 DATA |●─● |
20249 REM CARD #6
20250 DATA |● |
20260 DATA |● |
20270 DATA |● ●|
20280 DATA |●─●─●|
20299 REM CARD #7
20300 DATA |● ●|
20310 DATA |● ●|
20320 DATA |● ●|
20330 DATA |● ●|
20349 REM CARD #8
20350 DATA | ● |
20360 DATA |●─●─●|
20370 DATA | ● |
20380 DATA | |
