Chemistry Tutor v1.3 (CHEMTUTR.BAS)

Chemistry Tutor v1.3 by John Kennedy, 221

Description

Chemistry Tutor v1.3 by John Kennedy, 221

From the Antic disk of Antic: December 1989/January 1990 - Vol. 8 No. 7 — disk A.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 27.0 KB

Dialect
Atari BASIC
Lines
523
Variables
RAMA, P1$, P2$, N1$, N2$, C(, S(, MOVE$, ZERO$, SUB$, CURSOR$, DLI$, SP1$, SP2$, SN1$, SN2$, T$, FW(, TT$, CD1$, CD2$, CD3$, CD4$, W$, SUB(, CS(, CA1$, CA2$, CA3$, CA4$, T1$, T2$, T3$, T4$, B$, NP, NN, AA, XLOC, MM, Q, W, P, CP1, N, CN1, RA, R1, RB, R2, TR, I, P1, J, N1, CP2, CN2, R3, R4, P2, N2, L2, L4, BAL, X, XX, YY, XPOS, YPOS, K, D, Y, RIGHT, TRY, WRONG, REP, SUB1, SUB2, GIVEN, EX, ANS, LN, M1, M2, CPD, T, WS, WE, II, L, V, TL, F, R, A, TEMP1, TEMP2, MX1, MX2, MX3, MX4, CY, OY1, MY1, OY2, MY2, OY3, MY3, OY4, MY4, DY1, DY2, DY3, DY4, C, BREAK, Z, DNUM, B
BASIC listing (523 lines)
1 REM **** CHEMISTRY TUTOR ****
2 REM ****    >V. 1.3<     ****
3 REM **** BY JOHN KENNEDY ****
4 REM (C) 1989 ANTIC PUBLISHING, INC
5 RAMA=PEEK(106)-4:POKE 106,RAMA:GRAPHICS 0
10 DIM P1$(20),P2$(20),N1$(20),N2$(20),C(4),S(2,4),MOVE$(55),ZERO$(40),SUB$(80),CURSOR$(8),DLI$(190)
20 DIM SP1$(15),SP2$(15),SN1$(15),SN2$(15),T$(40),FW(4),TT$(20)
30 DIM CD1$(20),CD2$(15),CD3$(15),CD4$(15),W$(100),SUB(4),CS(4)
40 DIM CA1$(15),CA2$(15),CA3$(15),CA4$(15),T1$(20),T2$(20),T3$(20),T4$(20),B$(38):B$=" ":B$(38)=" ":B$(2)=B$
45 NP=39:NN=41:REM 39 POSITIVE, 41    NEGATIVE IONS.
50 MOVE$="hh┐Lh┐Kh┐Nh┐Mh┐Ph┐O ♥1K┌MfKP▕fLfMP▕fNFOp▕Pj)♥EPp┐FP┴♣_◆"
55 CURSOR$="→┌┌┌┌→♥♥"
60 ZERO$="hh┐Lh┐Kh┐Nh┐M ♥┴┌KfKP▕fLFMp▕PrENp┐FN┴♣i◆"
65 SUB$="♥♥♥<fff<♥♥♥┴8┴┴<♥♥♥↑6▘┴>♥♥♥↑6▘6↑♥♥♥▂←6>╱♥♥♥>0>╱>♥♥♥<◆|f<♥♥♥◀╱▘┴0♥♥♥<f<f<♥♥♥<f>╱<"
70 AA=PEEK(106)-8:XLOC=53248:POKE 54279,AA:MM=256*AA:GOSUB 6500
75 Q=USR(ADR(MOVE$),PEEK(756)*256,RAMA*256,1024)
80 Q=USR(ADR(MOVE$),RAMA*256+128,RAMA*256.0002+512,80):Q=USR(ADR(MOVE$),ADR(SUB$),RAMA*256+128,80)
95 GOSUB 2000:GOTO 2500
100 REM POSITIVE IONS
110 DATA AMMONIUM,NH4,1,1,18
120 DATA COPPER (I),Cu,1,0,63.5
130 DATA POTASSIUM,K,1,0,39.1
140 DATA SILVER,Ag,1,0,108
150 DATA SODIUM,Na,1,0,23
160 DATA BARIUM,Ba,2,0,137
170 DATA COPPER (II),Cu,2,0,63.5
180 DATA ZINC,Zn,2,0,65.4
190 DATA ALUMINUM,Al,3,0,27
200 DATA CALCIUM,Ca,2,0,40.1
210 DATA CHROMIUM (III),Cr,3,0,52
220 DATA COBALT (II),Co,2,0,58.9
230 DATA IRON (II),Fe,2,0,55.8
240 DATA IRON (III),Fe,3,0,55.8
250 DATA LEAD (II),Pb,2,0,207
260 DATA MAGNESIUM,Mg,2,0,24.3
270 DATA MERCURY (I),Hg,1,0,201
280 DATA MERCURY (II),Hg,2,0,201
290 DATA NICKEL (II),Ni,2,0,58.7
300 DATA TIN (II),Sn,2,0,119
310 DATA TIN (IV),Sn,4,0,119
320 DATA CHROMIUM (II),Cr,2,0,52
330 DATA LITHIUM,Li,1,0,6.94
340 DATA MANGANESE (II),Mn,2,0,54.9
350 DATA STRONTIUM,Sr,2,0,87.6
360 DATA ANTIMONY (III),Sb,3,0,122
370 DATA SILICON,Si,4,0,28.1
380 DATA HYDROGEN,H,1,0,1
390 DATA ANTIMONY (V),Sb,5,0,122
400 DATA CADMIUM,Cd,2,0,112
410 DATA GOLD (III),Au,3,0,197
420 DATA GOLD (I),Au,1,0,197
430 DATA LEAD (IV),Pb,4,0,207
440 DATA MANGANESE (IV),Mn,4,0,54.9
450 DATA NICKEL (III),Ni,3,0,58.7
460 DATA TITANIUM (II),Ti,2,0,47.9
470 DATA TITANIUM (III),Ti,3,0,47.9
480 DATA TITANIUM (IV),Ti,4,0,47.9
490 DATA CESIUM,Cs,1,0,133
500 REM NEGATIVE IONS
510 DATA BROMIDE,Br,1,0,79.9
520 DATA HYDROXIDE,OH,1,1,17
530 DATA NITRATE,NO3,1,1,62
540 DATA CARBONATE,CO3,2,1,60
550 DATA OXIDE,O,2,0,16
560 DATA SULFATE,SO4,2,1,96
570 DATA SULFIDE,S,2,0,32.1
580 DATA PHOSPHATE,PO4,3,1,79
590 DATA ACETATE,C2H3O2,1,1,59
600 DATA CHLORATE,ClO3,1,1,83.5
610 DATA CHLORIDE,Cl,1,0,35,5
620 DATA CHLORITE,ClO2,1,1,67.5
630 DATA CHROMATE,CrO4,2,1,116
640 DATA CYANIDE,CN,1,1,26
650 DATA DICHROMATE,Cr2O7,2,1,216
660 DATA FLUORIDE,F,1,0,19
670 DATA HYDRIDE,H,1,0,1
680 DATA HYDROGEN CARBONATE,HCO3,1,1,61
690 DATA HYDROGEN SULFATE,HSO4,1,1,97.1
700 DATA HYDROXIDE,OH,1,1,17
710 DATA IODIDE,I,1,0,127
720 DATA NITRITE,NO2,1,1,46
730 DATA PERCHLORATE,ClO4,1,1,99.5
740 DATA PERMANGANATE,MnO4,1,1,119
750 DATA SULFITE,SO3,2,1,80.1
760 DATA HYPOCHLORITE,ClO,1,1,51.5
770 DATA OXALATE,C2H4,2,1,88
780 DATA HYDROGEN SULFIDE,HS,1,1,33.1
790 DATA IODATE,IO3,1,1,175
800 DATA ARSENATE,AsO4,3,1,139
810 DATA BORATE,BO3,3,1,58.8
820 DATA THIOSULFATE,S2O3,2,1,112
830 DATA THIOCYANATE,SCN,1,1,58.1
840 DATA SELENATE,SeO4,2,1,143
850 DATA SELENIDE,Se,2,0,79
860 DATA FERRICYANIDE,Fe(CN)6,3,1,212
870 DATA FERROCYANIDE,Fe(CN)6,4,1,212
880 DATA CYANATE,OCN,1,1,42
890 DATA PHOSPHIDE,P,3,0,31
900 DATA NITRIDE,N,3,0,14
910 DATA TARTRATE,C4H4O6,2,1,148
1000 REM WRITE AND BALANCE EQUATIONS
1005 GOSUB 6200
1010 POSITION 12,1:? "BALANCE EQUATION";
1015 FOR W=1 TO 4:GOSUB 4200:NEXT W
1020 GOSUB 5200
1040 POSITION 0,4:? "React: ";P1$;" ";N1$;:POSITION 7,5:? P2$;" ";N2$;
1045 POSITION 0,6:? "Prod:  ";P1$;" ";N2$;:POSITION 7,7:? P2$;" ";N1$;
1050 P=CP1:N=CN1:T1$=SP1$:T2$=SN1$:RA=R1:RB=R2:GOSUB 4000
1060 CA1$=T4$:TR=0:FW(1)=I*P1+J*N1
1150 POKE 752,0:POSITION 0,19:? "FORMULA:":POSITION 2,20:? P1$;" ";N1$;" ";:POSITION 0,22:? "===>";:GOSUB 7500
1152 INPUT CD1$
1155 POKE 752,1:IF CD1$="" THEN 1150
1160 IF CD1$=CA1$ THEN POSITION 3,11:? "▔▔":POSITION 5,10:? CD1$;" + ";:GOTO 1185
1165 TR=TR+1:IF TR>2 THEN CD1$=CA1$:W=3:GOSUB 4200:POSITION 2,16:? "CORRECT FORMULA IS ";CA1$:GOSUB 4600:GOTO 1160
1170 T1$=SP1$:T2$=SN1$:T3$=CD1$:T4$=CA1$:GOSUB 5000:REM SEE WHAT IS WRONG WITH FORMULA
1180 W=3:GOSUB 4200:W=4:GOSUB 4200:POSITION 0,16:? W$;:GOTO 1150
1185 W=3:GOSUB 4200:W=4:GOSUB 4200
1187 P=CP2:N=CN2:T1$=SP2$:T2$=SN2$:RA=R3:RB=R4:GOSUB 4000:CA2$=T4$:TR=0:FW(2)=I*P2+J*N2
1190 POKE 752,0:POSITION 0,19:? "FORMULA:":POSITION 2,20:? P2$;" ";N2$;" ";:POSITION 0,22:? "===>";:GOSUB 7500
1192 INPUT CD2$
1195 POKE 752,1:IF CD2$="" THEN 1190
1200 IF CD2$=CA2$ THEN L2=5+LEN(CA1$):POSITION L2+3,11:? "▔▔":POSITION 5+L2,10:? CD2$;" ---> ";:GOTO 1230
1205 TR=TR+1:IF TR>2 THEN CD2$=CA2$:W=3:GOSUB 4200:POSITION 2,16:? "CORRECT FORMULA IS ";CA2$:GOSUB 4600:GOTO 1200
1210 T1$=SP2$:T2$=SN2$:T3$=CD2$:T4$=CA2$:GOSUB 5000:REM SEE WHAT IS WRONG WITH FORMULA
1220 W=3:GOSUB 4200:W=4:GOSUB 4200:POSITION 0,16:? W$;:GOTO 1190
1230 W=3:GOSUB 4200:W=4:GOSUB 4200
1240 P=CP1:N=CN2:T1$=SP1$:T2$=SN2$:RA=R1:RB=R4:GOSUB 4000:CA3$=T4$:TR=0:FW(3)=P1*I+N2*J
1250 POKE 752,0:POSITION 0,19:? "FORMULA:":POSITION 2,20:? P1$;" ";N2$;" ";:POSITION 0,22:? "===>";:GOSUB 7500
1252 INPUT CD3$
1255 POKE 752,1:IF CD3$="" THEN 1250
1260 IF CD3$=CA3$ THEN POSITION 10,13:? "▔▔";:POSITION 12,12:? CD3$;" + ";:GOTO 1290
1265 TR=TR+1:IF TR>2 THEN CD3$=CA3$:W=3:GOSUB 4200:POSITION 2,16:? "CORRECT FORMULA IS ";CA3$:GOSUB 4600:GOTO 1260
1270 T1$=SP1$:T2$=SN2$:T3$=CD3$:T4$=CA3$:GOSUB 5000:REM SEE WHAT IS WRONG WITH FORMULA
1280 W=3:GOSUB 4200:W=4:GOSUB 4200:POSITION 0,16:? W$;:GOTO 1250
1290 W=3:GOSUB 4200:W=4:GOSUB 4200
1300 P=CP2:N=CN1:T1$=SP2$:T2$=SN1$:RA=R3:RB=R2:GOSUB 4000:CA4$=T4$:TR=0:FW(4)=P2*I+N1*J
1310 POKE 752,0:POSITION 0,19:? "FORMULA:":POSITION 2,20:? P2$;" ";N1$;" ";:POSITION 0,22:? "===>";:GOSUB 7500
1312 INPUT CD4$
1315 POKE 752,1:IF CD4$="" THEN 1310
1320 IF CD4$=CA4$ THEN L4=5+LEN(CA3$):POSITION 10+L4,13:? "▔▔";:POSITION 12+L4,12:? CD4$;:GOTO 1350
1325 TR=TR+1:IF TR>2 THEN CD4$=CA4$:W=3:GOSUB 4200:POSITION 2,16:? "CORRECT FORMULA IS ";CA4$:GOSUB 4600:GOTO 1320
1330 T1$=SP2$:T2$=SN1$:T3$=CD4$:T4$=CA4$:GOSUB 5000:REM SEE WHAT IS WRONG WITH FORMULA
1340 W=3:GOSUB 4200:W=4:GOSUB 4200:POSITION 0,16:? W$;:GOTO 1310
1350 W=3:GOSUB 4200:W=4:GOSUB 4200:POKE 752,1
1360 POSITION 2,20:? "Arrow keys move between compounds":? "Backspace  erases entry."
1370 ? "  Return   when finished."
1380 GOSUB 6000:POKE 704,36:Q=USR(ADR(ZERO$),MM+512,128):POKE 559,46
1385 FOR I=1 TO 4:CS(I)=1:NEXT I
1390 BAL=0:I=0:POKE 752,1:X=0:T$="♥♥♥♥♥♥♥♥"
1400 XX=3+7*(I>1)+L2*(I=1)+L4*(I=3)+X:YY=10+2*(I>1):POSITION XX,YY:XPOS=4*XX+44:YPOS=54+8*(I>1)
1405 GOSUB 6600
1410 TRAP 1410:CLOSE #3:OPEN #3,4,0,"K:":GET #3,K:CLOSE #3:GOSUB 7500
1420 IF K=43 THEN GOSUB 6700:I=I-1+4*(I=0):X=0:GOTO 1400
1430 IF K=42 THEN GOSUB 6700:I=I+1-4*(I=3):X=0:GOTO 1400
1440 IF K=155 THEN 1480
1445 IF K=126 THEN GOSUB 6700:T$(2*I+X+1,2*I+X+1)=" ":X=X-1+(X=0):K=80:GOTO 1465
1450 IF K=32 THEN T$(2*I+X+1,2*I+X+1)=CHR$(K):GOSUB 6700:X=X-(X>0)+(X=0):K=80:GOTO 1465
1455 IF (K<48 OR K>57) THEN 1410
1460 T$(2*I+X+1,2*I+X+1)=CHR$(K):X=X+1:IF X>1 THEN X=1:GOSUB 6700
1465 TRAP 1472
1470 CS(I+1)=VAL(T$(2*I+1,2*I+2)):GOTO 1475
1472 CS(I+1)=1
1475 POSITION XX,YY:? CHR$(K-48+48*(K=32));:IF BAL=1 THEN GOSUB 4730
1477 GOTO 1400
1480 REM CHECK FOR BALANCE
1510 FOR I=1 TO 4
1515 IF CS(I)=C(I) THEN 1530
1520 BAL=1:POSITION 2,16:? "Not balanced. Try again!!";:FOR D=1 TO 50:NEXT D
1525 W=3:GOSUB 4200:W=1:GOSUB 4200:GOSUB 4700:GOSUB 6700:I=0:X=0:POP :GOTO 1400
1530 NEXT I
1540 GOSUB 6700:W=4:GOSUB 4200
1550 POKE 751,1:POSITION 2,20:? "Equation correctly balanced."
1555 IF Y=14 THEN RETURN
1560 POSITION 2,22:? "Try again? (Y/N) ";
1570 CLOSE #3:OPEN #3,4,0,"K:":GET #3,K:CLOSE #3:GOSUB 7500
1580 IF K=ASC("Y") OR K=ASC("y") THEN 1015
1590 IF K=ASC("N") OR K=ASC("n") THEN RETURN
1600 GOTO 1570
2000 REM TITLE SCREEN
2010 T1$="▶▶▶▶▶▶▶▶▶▶▶▶▶▶▶▶▶▶▶▶":Q=USR(ADR(MOVE$),ADR(T1$),MM+512+48,20):Q=USR(ADR(MOVE$),ADR(T1$),MM+640+48,20)
2012 T1$(1,12)="╱╱╱╱♥♥♥♥♥♥♥♥"
2015 Q=USR(ADR(MOVE$),ADR(T1$),MM+768+76,16):T1$="▶▶▶▶":Q=USR(ADR(MOVE$),ADR(T1$),MM+896+88,8)
2020 POKE 53256,3:POKE 53257,3:POKE 704,36:POKE 705,36:POKE 706,224:POKE 707,224:POKE 623,0
2030 POKE 53248,96:POKE 53249,128:SETCOLOR 2,7,2:SETCOLOR 1,7,12:POKE 752,1
2040 POSITION 11,7:? "                  "
2050 POSITION 11,8:? " /     THE      \ "
2060 POSITION 11,9:? "                  "
2070 POSITION 11,10:? "    CHEMISTRY     "
2080 POSITION 11,11:? "                  "
2090 POSITION 11,12:? " \    TUTOR     / "
2100 POSITION 11,13:? "                  "
2102 POSITION 5,17:? "▎▕";:POSITION 5,18:? "▎▕";:POSITION 4,19:? "╱  ╲";
2104 POSITION 3,20:? "◢    ◣";:POSITION 3,21:? "▔▔▔▔▔▔";
2110 POKE 53258,3:POKE 53259,1:POKE 53250,104:POKE 53251,136
2120 POSITION 19,15:? "by"
2130 POSITION 13,17:? "●▂▂▂▂▂▂▂▂▂▂▂▂●"
2140 POSITION 13,18:? " John Kennedy "
2150 POSITION 13,19:? "●▔▔▔▔▔▔▔▔▔▔▔▔●"
2160 GOSUB 6800
2170 Q=USR(ADR(ZERO$),53248,8):Q=USR(ADR(ZERO$),MM+384,639):? "↰"
2180 RETURN
2500 REM MENU
2510 POKE 53256,3:POKE 705,36:SETCOLOR 2,7,2:SETCOLOR 1,7,12:POKE 752,1
2520 Q=USR(ADR(MOVE$),ADR("▶▶▶▶▶▶"),MM+512+19,6):POKE 53248,108:POKE 704,196:POKE 53257,1
2530 POSITION 14,0:? "▔▔▔▔▔▔▔▔▔▔"
2540 POSITION 14,1:? "   MENU   "
2550 POSITION 14,2:? "          "
2552 POSITION 4,6:? "Name ions"
2556 POSITION 4,8:? "Write symbols and charges for ions"
2560 POSITION 4,10:? "Write chemical formulas"
2570 POSITION 4,12:? "Write chemical equations"
2580 POSITION 4,14:? "Stoichiometric calculations"
2585 POSITION 4,16:? "End program"
2588 POSITION 2,19:? "OPTION TO CHANGE":POSITION 2,21:? "SELECT TO CHOOSE";
2590 GOSUB 7500:Y=6:POKE 53247,0:POKE 53249,44:GOTO 2640
2600 P=PEEK(53279):GOSUB 7500
2620 IF P<>3 THEN 2650
2625 POSITION 0,Y:? "   ";:Q=USR(ADR(ZERO$),MM+640+40+8*((Y-6)/2),4)
2630 Y=Y+2:IF Y>16 THEN Y=6
2640 Q=USR(ADR(MOVE$),ADR("????"),MM+640+40+8*((Y-6)/2),4):POSITION 0,Y:? "==>";
2645 FOR D=1 TO 15:NEXT D
2650 IF P<>5 THEN 2600
2655 IF Y=16 THEN POKE 53248,0:POKE 53249,0:POKE 623,4:POKE 53277,0:POKE 559,34:GRAPHICS 0:POKE 702,64:END
2660 ON (Y-6)/2+1 GOSUB 7000,7300,2700,1000,2900
2670 POKE 559,0:POKE 53248,0:POKE 53249,0:POKE 53250,0:Q=USR(ADR(ZERO$),MM+512,511):GRAPHICS 0:POKE 559,46:P=7
2680 GOTO 2500
2700 REM CHEMICAL FORMULAS
2710 GOSUB 6200
2720 POSITION 13,1:? "WRITE FORMULAS";
2725 FOR W=1 TO 4:GOSUB 4200:NEXT W
2730 RIGHT=0:TRY=0:POSITION 2,10:? "RIGHT==>  ♥";:POSITION 19,10:? "WRONG==>  ♥";
2740 GOSUB 5200:TR=0:P=CP1:N=CN1:T1$=SP1$:T2$=SN1$:RA=R1:RB=R2:GOSUB 4000
2750 CA1$=T4$:POKE 752,0
2755 POSITION 0,19:? "FORMULA:":POSITION 2,20:? P1$;" ";N1$;" ":POSITION 0,22:? "===>";:INPUT CD1$:POKE 752,1
2757 IF CD1$="" THEN 2750
2760 IF CD1$=CA1$ THEN 2785
2765 TR=TR+1:IF TR>2 THEN POSITION 2,16:? "CORRECT FORMULA IS ";CA1$:GOSUB 4600:W=3:GOSUB 4200:GOTO 2785
2770 T1$=SP1$:T2$=SN1$:T3$=CD1$:T4$=CA1$:W=3:GOSUB 4200:GOSUB 5000:REM SEE WHAT IS WRONG WITH FORMULA
2775 WRONG=1
2780 POSITION 2,16:? W$;:GOSUB 4600:W=3:GOSUB 4200:W=4:GOSUB 4200:GOTO 2755
2785 W=4:GOSUB 4200
2790 IF  NOT WRONG THEN RIGHT=RIGHT+1
2792 IF RIGHT=10 THEN POSITION 12,10:? "├♥";:POSITION 29,10:? "♥";:GOTO 2810
2793 TRY=TRY+1:IF TRY-RIGHT=10 THEN POSITION 12,10:? "♥";:POSITION 29,10:? "├♥";:GOTO 2810
2795 WRONG=0:POSITION 12,10:? CHR$(RIGHT):POSITION 29,10:? CHR$(TRY-RIGHT)
2800 IF TRY<10 THEN 2740
2810 POSITION 2,16:? "TRY AGAIN? (Y/N) ";
2815 CLOSE #3:OPEN #3,4,0,"K:":GET #3,K:CLOSE #3:GOSUB 7500
2820 IF K<>ASC("y") AND K<>ASC("n") THEN 2815
2825 IF K=ASC("y") THEN 2725
2830 RETURN
2900 REM STOICHIOMETRY
2910 REP=0
2950 GOSUB 1000+10*REP:TRY=1:POSITION 12,1:? "  STOICHIOMETRY  "
2954 TRAP 40000
2955 W=1:GOSUB 4200
2960 FOR D=1 TO 50:NEXT D:W=4:GOSUB 4200
2970 SUB1=INT(RND(0)*4+1)
2980 SUB2=INT(RND(0)*4+1):IF SUB1=SUB2 THEN 2980
2990 T$=CA1$:SUB(1)=LEN(T$):T$(SUB(1)+1)=CA2$:SUB(2)=LEN(T$)
3000 T$(SUB(2)+1)=CA3$:SUB(3)=LEN(T$):T$(SUB(3)+1)=CA4$:SUB(4)=LEN(T$)
3010 GIVEN=FW(SUB1)*4*RND(0):EX=1*(GIVEN>=100)+10*(GIVEN<100 AND GIVEN>=10)+100*(GIVEN<10)
3015 GIVEN=INT(GIVEN*EX)/EX
3020 ANS=GIVEN/FW(SUB1)*C(SUB2)/C(SUB1)*FW(SUB2):EX=1*(ANS>=100)+10*(ANS<100 AND ANS>=10)+100*(ANS<10)
3025 ANS=INT(ANS*EX)/EX
3030 IF SUB1<3 THEN T1$="REACTED.":GOTO 3040
3035 T1$="PRODUCED."
3040 IF SUB2<3 THEN T2$="REACTED?":GOTO 3050
3045 T2$="PRODUCED?"
3050 T3$=STR$(GIVEN):TT$=T3$:GOSUB 4300:T3$=TT$
3055 POSITION 0,4:? T3$;" G. OF ";T$(SUB(SUB1-1)+1,SUB(SUB1));" WERE ";T1$
3060 POSITION 0,6:? "HOW MANY G. OF ";T$(SUB(SUB2-1)+1,SUB(SUB2));" WERE ";T2$
3065 W=4:GOSUB 4200:GOSUB 4600:W=3:GOSUB 4200
3070 POSITION 2,20:? "ENTER ANSWER AND PRESS RETURN ":POSITION 2,22:? "===>";
3080 GOSUB 4500:GOSUB 4400:T4$=TT$
3090 LN=3065:TRAP 5300
3180 IF ABS(ANS-VAL(T4$))>0.05*ANS AND TRY<2 THEN POSITION 2,16:? "NOT CORRECT: TRY AGAIN.";:TRY=TRY+1:GOTO 3065
3182 T3$=STR$(ANS):FOR I=1 TO LEN(T3$):T3$(I,I)=CHR$(ASC(T3$(I))-48*(T3$(I,I)<>".")):NEXT I
3185 IF TRY=2 THEN GOSUB 3500
3190 POSITION 2,16:? "CORRECT!!! TRY AGAIN? (Y/N)";
3200 CLOSE #3:OPEN #3,4,0,"K:":GET #3,K:CLOSE #3:GOSUB 7500
3210 IF K=ASC("n") THEN 2670
3220 IF K=ASC("y") THEN Y=14:REP=1:GOTO 2950
3230 GOTO 3200
3500 REM TUTORIAL
3505 POSITION 2,16:? "NOT CORRECT!!!"
3510 GOSUB 4600:W=3:GOSUB 4200:W=4:GOSUB 4200
3515 POSITION 2,19:? "ADD ALL ATOMIC WEIGHTS IN COMPOUND";
3520 POSITION 2,21:? "ENTER FORMULA WEIGHT FOR ";T$(SUB(SUB1-1)+1,SUB(SUB1)):POSITION 2,22:? "===>";
3530 GOSUB 4500:GOSUB 4400
3540 LN=3510:TRAP 5300:IF ABS(VAL(TT$)-FW(SUB1))<0.05*FW(SUB1) THEN 3560
3550 TT$=STR$(FW(SUB1)):GOSUB 4300:POSITION 2,16:? "CORRECT VALUE IS ";TT$;" TRY AGAIN":GOTO 3510
3560 W=3:GOSUB 4200:W=4:GOSUB 4200
3565 POSITION 2,19:? "MOLES = MASS / FORMULA WEIGHT";
3570 POSITION 2,21:? "ENTER MOLES OF ";T$(SUB(SUB1-1)+1,SUB(SUB1)):POSITION 2,22:? "===>";
3580 GOSUB 4500:GOSUB 4400:M1=INT(GIVEN/FW(SUB1)*1000)/1000
3590 LN=3560:TRAP 5300:IF ABS(VAL(TT$)-M1)<0.05*M1 THEN 3610
3600 TT$=STR$(M1):GOSUB 4300:POSITION 2,16:? "CORRECT VALUE IS ";TT$;" TRY AGAIN":GOSUB 4600:GOTO 3560
3610 M2=INT(C(SUB2)/C(SUB1)*M1*1000)/1000
3620 W=3:GOSUB 4200:W=4:GOSUB 4200
3625 POSITION 2,19:? "UNKNOWN COEFFICIENT/KNOWN COEFFICIENT";:POSITION 2,20:? "TIMES MOLES OF KNOWN SUBSTANCE";
3630 POSITION 2,21:? "ENTER MOLES OF ";T$(SUB(SUB2-1)+1,SUB(SUB2)):POSITION 2,22:? "===>";
3640 GOSUB 4500:GOSUB 4400
3650 LN=3620:TRAP 5300:IF ABS(VAL(TT$)-M2)<0.05*M2 THEN 3670
3660 TT$=STR$(M2):GOSUB 4300:POSITION 2,16:? "CORRECT VALUE IS ";TT$;" TRY AGAIN":GOSUB 4600:GOTO 3620
3670 W=3:GOSUB 4200:W=4:GOSUB 4200
3675 POSITION 2,19:? "ADD ALL ATOMIC WEIGHTS IN COMPOUND";
3680 POSITION 2,21:? "ENTER FORMULA WEIGHT FOR ";T$(SUB(SUB2-1)+1,SUB(SUB2)):POSITION 2,22:? "===>";
3690 GOSUB 4500:GOSUB 4400
3700 LN=3670:TRAP 5300:IF ABS(VAL(TT$)-FW(SUB2))<0.05*FW(SUB2) THEN 3720
3710 TT$=STR$(FW(SUB2)):GOSUB 4300:POSITION 2,16:? "CORRECT VALUE IS ";TT$;" TRY AGAIN":GOSUB 4600:GOTO 3670
3720 W=3:GOSUB 4200:W=4:GOSUB 4200
3725 POSITION 2,19:? "MASS = MOLES * FORMULA WEIGHT";
3730 POSITION 2,21:? "ENTER MASS OF ";T$(SUB(SUB2-1)+1,SUB(SUB2)):POSITION 2,22:? "===>";
3740 GOSUB 4500:GOSUB 4400
3750 LN=3720:TRAP 5300:IF ABS(VAL(TT$)-ANS)<0.05*ANS THEN W=3:GOSUB 4200:W=4:GOSUB 4200:TRAP 40000:RETURN
3760 TT$=STR$(ANS):GOSUB 4300:POSITION 2,16:? "CORRECT VALUE IS ";TT$;" TRY AGAIN":GOSUB 4600:GOTO 3720
4000 FOR I=1 TO 5:FOR J=1 TO 5
4010 IF I*P=J*N THEN POP :GOTO 4030
4020 NEXT J:NEXT I
4030 CPD=CPD+1:S(1,CPD)=I:S(2,CPD)=J:N=1:IF I>1 AND RA>0 THEN T4$(1,1)="(":N=N+1
4040 T4$(N,N+LEN(T1$)-1)=T1$:N=N+LEN(T1$)
4050 IF I>1 AND RA>0 THEN T4$(N,N)=")":N=N+1
4060 IF I>1 THEN T4$(N,N)=STR$(I):N=N+1
4070 IF J>1 AND RB>0 THEN T4$(N,N)="(":N=N+1
4080 T4$(N,N+LEN(T2$)-1)=T2$:N=N+LEN(T2$)
4090 IF J>1 AND RB>0 THEN T4$(N,N)=")":N=N+1
4100 IF J>1 THEN T4$(N,N)=STR$(J):N=N+1
4110 T1$=T4$(N-1,N-1):T4$(N-1)=T1$
4120 RETURN
4200 REM CLEAR WINDOW
4205 T=PEEK(752):POKE 752,1
4210 WS=3:WE=7:IF W=2 THEN WS=9:WE=13
4220 IF W=3 THEN WS=15:WE=16
4230 IF W=4 THEN WS=18:WE=22
4240 FOR II=WE TO WS STEP -1:POSITION 39,II:? "◀";:POSITION 0,II:? B$;" ";:NEXT II
4250 POKE 752,T:GOSUB 7500:RETURN
4300 REM CONVERT ATARI TO CHEMFONT
4310 TRAP 4340:FOR II=1 TO LEN(TT$)
4320 TT$(II,II)=CHR$(ASC(TT$(II))-48*(TT$(II,II)<>"." AND TT$(II,II)<>"-" AND TT$(II,II)<>"+"))
4330 NEXT II
4340 TRAP 40000:RETURN
4400 REM CONVERT CHEMFONT TO ATARI
4410 TRAP 4440:FOR II=1 TO LEN(TT$)
4420 TT$(II,II)=CHR$(ASC(TT$(II))+48*(TT$(II,II)<>"." AND TT$(II,II)<>"-" AND TT$(II,II)<>"+"))
4430 NEXT II
4440 TRAP 40000:RETURN
4500 REM ENTER VALUE FROM KEYBOARD
4505 I=1:TT$=""
4510 CLOSE #3:OPEN #3,4,0,"K:":GET #3,K:CLOSE #3:GOSUB 7500
4515 IF K=43 THEN TT$(I)="+":I=I+1:GOTO 4570
4520 IF K=46 THEN TT$(I)=".":I=I+1:GOTO 4570
4525 IF K=45 THEN TT$(I)="-":I=I+1:GOTO 4570
4530 IF K=155 THEN RETURN
4540 IF K=126 THEN I=I-1*(I>1):TT$(I,I)=" ":GOTO 4570
4550 IF K<48 OR K>57 THEN 4510
4560 TT$(I)=CHR$(K-48):I=I+1
4570 POSITION 6,22:? TT$;"    ";:GOSUB 7500:GOTO 4510
4600 REM DELAY
4610 FOR D=1 TO 100:NEXT D:RETURN
4700 REM HELP SCREEN FOR BALANCING             EQUATIONS
4710 POSITION 0,3:? "IONS";:POSITION 10,3:? "REACT";:POSITION 20,3:? "PROD";:POSITION 30,3:? "BALANCED";
4720 POSITION 1,4:? SP1$;:POSITION 1,5:? SN1$;:POSITION 1,6:? SP2$;:POSITION 1,7:? SN2$;
4730 TT$=STR$(CS(1)*S(1,1)):GOSUB 4300:POSITION 12,4:? TT$;" ";
4735 TT$=STR$(CS(1)*S(2,1)):GOSUB 4300:POSITION 12,5:? TT$;" ";
4740 TT$=STR$(CS(2)*S(1,2)):GOSUB 4300:POSITION 12,6:? TT$;" ";
4745 TT$=STR$(CS(2)*S(2,2)):GOSUB 4300:POSITION 12,7:? TT$;" ";
4750 TT$=STR$(CS(3)*S(1,3)):GOSUB 4300:POSITION 21,4:? TT$;" ";
4755 TT$=STR$(CS(4)*S(2,4)):GOSUB 4300:POSITION 21,5:? TT$;" ";
4760 TT$=STR$(CS(4)*S(1,4)):GOSUB 4300:POSITION 21,6:? TT$;" ";
4765 TT$=STR$(CS(3)*S(2,3)):GOSUB 4300:POSITION 21,7:? TT$;" ";
4770 REM CHECK BALANCE OF PROD AND             REACT
4780 IF CS(1)*S(1,1)=CS(3)*S(1,3) THEN POSITION 32,4:? "YES";:GOTO 4800
4790 POSITION 32,4:? "NO ";
4800 IF CS(1)*S(2,1)=CS(4)*S(2,4) THEN POSITION 32,5:? "YES";:GOTO 4820
4810 POSITION 32,5:? "NO ";
4820 IF CS(2)*S(1,2)=CS(4)*S(1,4) THEN POSITION 32,6:? "YES";:GOTO 4840
4830 POSITION 32,6:? "NO ";
4840 IF CS(2)*S(2,2)=CS(3)*S(2,3) THEN POSITION 32,7:? "YES";:GOTO 4860
4850 POSITION 32,7:? "NO ";
4860 GOSUB 7500:RETURN
5000 REM FORMULA ERRORS
5010 W$="":L=LEN(T1$)+2*(T4$(1,1)="(")+(I>1)
5020 TRAP 5080:IF T3$(1,L)=T4$(1,L) THEN 5100
5030 FOR V=1 TO L:IF T3$(V,V)<>T4$(V,V) THEN POP :GOTO 5050
5040 NEXT V
5050 IF T3$(V,V)="(" OR T4$(V,V)="(" OR T3$(V,V)=")" OR T4$(V,V)=")" THEN W$="CHECK PARENTHESIS: ":GOTO 5199
5060 IF T4$(V,V)>="A" AND T3$(V,V)>="A" THEN W$="CHECK POS. ION: ":GOTO 5199
5070 W$="CHECK SUB. POS. ION: ":GOTO 5199
5080 W$="CHECK POS. ION: ":GOTO 5199
5100 TRAP 5180:IF T3$(L+1,L+1)<="9" AND T3$(L+1,L+1)>="0" THEN W$="CHECK SUB. POS. ION: ":GOTO 5199
5105 TL=LEN(T3$):IF TL<LEN(T4$) THEN TL=LEN(T4$)
5110 TRAP 5180:FOR V=L+1 TO TL:IF T3$(V,V)<>T4$(V,V) THEN POP :GOTO 5130
5120 NEXT V
5130 IF T3$(V,V)="(" OR T4$(V,V)="(" OR T3$(V,V)=")" OR T4$(V,V)=")" THEN W$="CHECK PARENTHESIS: ":GOTO 5199
5140 IF T4$(V,V)>="A" AND T3$(V,V)>="A" THEN W$="CHECK NEG. ION: ":GOTO 5199
5150 W$="CHECK SUB. NEG. ION: ":GOTO 5199
5180 TRAP 5190:W$="CHECK NEG. ION: ":IF T3$(V,V)<="9" AND T3$(V,V)>="0" THEN W$="CHECK SUB. NEG. ION: ":GOTO 5199
5190 TRAP 5199:IF T4$(V,V)<="9" AND T4$(V,V)>="0" THEN W$="CHECK SUB. NEG. ION: "
5199 TRAP 40000:W$(LEN(W$)+1)=T3$:RETURN
5200 REM GET IONS
5210 CPD=0:LN=100+INT(RND(0)*NP+1)*10:RESTORE LN:READ P1$,SP1$,CP1,R1,P1
5220 RESTORE 500+INT(RND(0)*NN+1)*10:READ N1$,SN1$,CN1,R2,N1
5230 LN=100+INT(RND(0)*NP+1)*10:RESTORE LN:READ P2$,SP2$,CP2,R3,P2:IF P1$=P2$ THEN 5230
5240 RESTORE 500+INT(RND(0)*NN+1)*10:READ N2$,SN2$,CN2,R4,N2:IF N1$=N2$ THEN 5240
5250 RETURN
5300 REM ENTRY ERRORS
5310 W=3:GOSUB 4200:POSITION 2,16:? "ENTRY ERROR!! TRY AGAIN":GOSUB 7500:GOTO LN
6000 REM BALANCE EQUATION
6010 FOR I=1 TO 4:C(I)=1:NEXT I
6020 F=0
6030 FOR J=1 TO 2:REM COMPOUND
6040 FOR I=1 TO 2:REM ION
6050 T=3*(I=J)+4*(I<>J):IF C(J)*S(I,J)=C(T)*S(I,T) THEN 6130
6060 F=1
6070 R=C(J)*S(I,J)/S(I,T):IF R>1 THEN C(T)=R:GOTO 6090
6080 C(J)=C(T)*S(I,T)/S(I,J)
6090 A=1
6095 TEMP1=C(J):TEMP2=C(T)
6100 IF C(J)=INT(C(J)+0.01) AND C(T)=INT(C(T)+0.01) THEN 6130
6110 A=A+1
6120 C(J)=A*TEMP1:C(T)=A*TEMP2:GOTO 6100
6130 NEXT I:NEXT J
6140 IF F=1 THEN 6020
6150 FOR I=1 TO 4:C(I)=INT(C(I)+0.01):NEXT I:RETURN
6200 REM INITIAL WORK SCREEN
6210 POKE 53248,0:POKE 53249,0:GRAPHICS 0:SETCOLOR 2,0,6:GOSUB 10000:POKE 756,RAMA:POKE 702,0:POKE 559,46
6215 Q=USR(ADR(ZERO$),MM+512,511)
6220 Q=USR(ADR(MOVE$),ADR("▶▶▶▶▶▶▶▶▶"),MM+640+20,9):Q=USR(ADR(MOVE$),ADR("▶▶▶▶▶▶▶▶▶"),MM+768+20,9)
6225 POKE 623,1:POKE 705,136:POKE 706,136:POKE 53249,96:POKE 53250,128:POKE 53257,3:POKE 53258,3
6230 RETURN
6500 REM INITIALIZE PLAYER
6525 POKE 704,36
6530 POKE 559,46
6540 POKE 53277,3
6550 POKE XLOC,0
6560 Q=USR(ADR(ZERO$),MM+512,511)
6590 RETURN
6600 REM DRAW CURSOR
6605 POKE XLOC,0:POKE 53256,0
6610 Q=USR(ADR(MOVE$),ADR(CURSOR$),MM+512+YPOS,8):POKE XLOC,XPOS
6650 RETURN
6700 REM ERASE CURSOR
6705 POKE XLOC,0:Q=USR(ADR(ZERO$),MM+512+YPOS,8)
6730 RETURN
6800 REM BUBBLES
6810 GOSUB 6910:GOSUB 6920:GOSUB 6930:GOSUB 6940:POKE 53252,MX1:POKE 53253,MX2:POKE 53254,MX3:POKE 53255,MX4
6815 FOR CY=1 TO 50
6820 OY1=MY1:OY2=MY2:OY3=MY3:OY4=MY4
6825 MY1=MY1-DY1:IF MY1<40 THEN GOSUB 6910:POKE 53252,MX1
6830 MY2=MY2-DY2:IF MY2<40 THEN GOSUB 6920:POKE 53253,MX2
6835 MY3=MY3-DY3:IF MY3<40 THEN GOSUB 6930:POKE 53254,MX3
6840 MY4=MY4-DY4:IF MY4<40 THEN GOSUB 6940:POKE 53255,MX4
6845 POKE MM+384+OY1,0:POKE MM+384+MY1,1:MX1=MX1+(MY1<84)*(INT(RND(0)*6)-3):POKE 53252,MX1
6850 POKE MM+384+OY2,0:POKE MM+384+MY2,4:MX2=MX2+(MY2<84)*(INT(RND(0)*7)-3):POKE 53253,MX2
6855 POKE MM+384+OY3,0:POKE MM+384+MY3,16:MX3=MX3+(MY3<84)*(INT(RND(0)*6)-3):POKE 53254,MX3
6860 POKE MM+384+OY4,0:POKE MM+384+MY4,64:MX4=MX4+(MY4<84)*(INT(RND(0)*6)-3):POKE 53255,MX4
6870 NEXT CY:RETURN
6910 MX1=INT(RND(0)*6)+68:MY1=95:DY1=INT(RND(0)*8+1):RETURN
6920 MX2=INT(RND(0)*6)+68:MY2=95:DY2=INT(RND(0)*8+1):RETURN
6930 MX3=INT(RND(0)*6)+68:MY3=95:DY3=INT(RND(0)*8+1):RETURN
6940 MX4=INT(RND(0)*6)+68:MY4=95:DY4=INT(RND(0)*8+1):RETURN
7000 REM NAME IONS
7010 GOSUB 6200:POKE 702,64
7020 POSITION 15,1:? "NAME IONS";
7025 FOR W=1 TO 4:GOSUB 4200:NEXT W
7030 RIGHT=0:TRY=0:POSITION 2,10:? "RIGHT==>  ♥";:POSITION 19,10:? "WRONG==>  ♥";
7040 IF RND(0)>0.5 THEN LN=100+INT(RND(0)*NP+1)*10:RESTORE LN:READ P1$,T$,C,R1:T1$="+":GOTO 7060
7050 RESTORE 500+INT(RND(0)*NN+1)*10:READ P1$,T$,C,R1:T1$="-"
7060 TT$=STR$(C):GOSUB 4300
7065 POKE 752,0:POSITION 2,20:? "Name ";T$;"  Charge ";T1$;TT$:POSITION 2,22:GOSUB 7500
7068 INPUT CD1$:POKE 752,1:IF CD1$="" THEN 7060
7070 IF CD1$=P1$ THEN 7090
7080 POSITION 0,16:? "INCORRECT, ";T$;" IS ";P1$:GOSUB 4600:W=3:GOSUB 4200:W=4:GOSUB 4200:GOTO 7105
7090 RIGHT=RIGHT+1:W=4:GOSUB 4200
7100 IF RIGHT=10 THEN POSITION 12,10:? "├♥";:POSITION 29,10:? "♥";:GOTO 7130
7105 TRY=TRY+1:IF TRY-RIGHT=10 THEN POSITION 12,10:? "♥";:POSITION 29,10:? "├♥";:GOTO 7130
7110 POSITION 12,10:? CHR$(RIGHT):POSITION 29,10:? CHR$(TRY-RIGHT)
7120 IF TRY<10 THEN 7040
7130 POSITION 2,16:? "TRY AGAIN? (Y/N) ";
7140 CLOSE #3:OPEN #3,4,0,"K:":GET #3,K:CLOSE #3:GOSUB 7500
7150 IF K<>ASC("Y") AND K<>ASC("N") THEN 7140
7160 IF K=ASC("Y") THEN 7025
7170 RETURN
7300 REM SYMBOLS AND CHARGES FOR IONS
7310 GOSUB 6200
7320 POSITION 13,1:? "WRITE SYMBOLS"
7325 FOR W=1 TO 4:GOSUB 4200:NEXT W
7330 RIGHT=0:TRY=0:POSITION 2,10:? "RIGHT==>  ♥";:POSITION 19,10:? "WRONG==>  ♥";
7340 IF RND(0)>0.5 THEN LN=100+INT(RND(0)*NP+1)*10:RESTORE LN:READ P1$,T$,C,R1:T1$="+":GOTO 7360
7350 RESTORE 500+INT(RND(0)*NN+1)*10:READ P1$,T$,C,R1:T1$="-":C=-C
7360 POKE 752,0:POSITION 2,20:? "Symbol for ";P1$:POSITION 2,22:? "===>";:GOSUB 7500
7365 INPUT CD1$:POKE 752,1:IF CD1$="" THEN 7360
7370 IF CD1$=T$ THEN W=4:GOSUB 4200:GOTO 7390
7380 POSITION 0,16:? "INCORRECT, ";P1$;" IS ";T$:GOSUB 4600:W=3:GOSUB 4200:W=4:GOSUB 4200:GOTO 7420
7385 W=4:GOSUB 4200:GOSUB 4600:W=3:GOSUB 4200
7390 POSITION 2,20:? "Charge of ";P1$:POSITION 2,22:? "===>";:GOSUB 4500:GOSUB 4400
7400 LN=7385:TRAP 5300:IF C=VAL(TT$) THEN RIGHT=RIGHT+1:GOTO 7420
7405 TT$=STR$(C):GOSUB 4300
7410 POSITION 2,16:? "INCORRECT, THE CHARGE OF ";T$;" IS ";TT$:GOSUB 4600:W=3:GOSUB 4200:W=4:GOSUB 4200
7420 IF RIGHT=10 THEN POSITION 12,10:? "├♥";:POSITION 29,10:? "♥";:GOTO 7450
7425 TRY=TRY+1:IF TRY-RIGHT=10 THEN POSITION 12,10:? "♥";:POSITION 29,10:? "├♥";:GOTO 7450
7430 POSITION 12,10:? CHR$(RIGHT):POSITION 29,10:? CHR$(TRY-RIGHT)
7440 IF TRY<10 THEN W=4:GOSUB 4200:GOTO 7340
7450 W=3:GOSUB 4200:W=4:GOSUB 4200:POSITION 2,16:? "TRY AGAIN? (Y/N) ";
7460 CLOSE #3:OPEN #3,4,0,"K:":GET #3,K:CLOSE #3:GOSUB 7500
7470 IF K<>ASC("y") AND K<>ASC("n") THEN 7460
7480 IF K=ASC("y") THEN 7325
7490 TRAP 40000:RETURN
7500 REM DISABLE BREAK KEY
7510 BREAK=PEEK(16)-128*(PEEK(16)>=128):POKE 16,BREAK:POKE 53774,BREAK:RETURN
10000 T=PEEK(559):POKE 559,Z:RESTORE 11100:READ DNUM
10010 D=PEEK(560)+256*PEEK(561)
10020 FOR I=1 TO DNUM:READ B:POKE D+B,PEEK(D+B)+128:NEXT I
10030 B=INT(ADR(DLI$)/256):A=ADR(DLI$)-B*256:POKE 512,A:POKE 513,B
10040 POKE 256,Z:POKE 54286,192
11010 DLI$="H-♥├n♥├▔◣TI♥P◣▔◣T)╱▔┴Ph@I├P▖▔◣T)$▔┴P)♥▔┬"
11012 DLI$(41)="Ph@I▕P◣▔◣T)╱▔┴Ph@I┘P▖▔◣T)F▔┴P)♥▔┬Ph@I┤P◣"
11014 DLI$(81)="▔◣T)╱▔┴Ph@I┐P▖▔◣T)x▔┴P)♥▔┬Ph@I╱P◣▔◣T)╱▔┴"
11016 DLI$(121)="Ph@I╲P▖▔◣T)2▔┴P):▔┬Ph@I◢P◣▔◣T)╱▔┴Ph@I▗P▖"
11018 DLI$(161)="▔◣T)F▔┴P)♥▔┬Ph@)♥▔♥├▔◣T)╱▔┴Ph@"
11095 POKE 559,T:RETURN
11100 DATA 11,2,3,6,7,12,13,18,19,21,22,27