The Ultimate Chaos Game! (CHAOS.BAS)
The Ultimate Chaos Game! by Roger A. Pruitt, 30
Description
The Ultimate Chaos Game! by Roger A. Pruitt, 30
From the Antic disk of Antic: December 1989/January 1990 - Vol. 8 No. 7 — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.6 KB
- Dialect
- Atari BASIC
- Lines
- 69
- Variables
CX,CY,I,SIZE,P,TH,X,Y,X(,S,Y(,X0,Y0,X1,Y1,DM,XX,A$,W,RSD$,B$,NAME$,SCREEN,IO,DUMMY$,K,LDR$,SVR$
BASIC listing (69 lines)
1000 REM THE ULTIMATE CHAOS GAME!
1001 REM BY ROGER A. PRUITT
1002 REM (C) ANTIC PUBLISHING, INC
1010 GOSUB 28350:GOTO 10000
1030 GRAPHICS 24:SETCOLOR 2,0,0:SETCOLOR 1,0,10:COLOR 1
1040 CX=318/2:CY=190/2:DEG :I=1:SIZE=360/P
1050 FOR TH=0 TO 360 STEP SIZE:X=CX+CY*SIN(TH):Y=CY-CY*COS(TH)
1060 X(I)=-X+X/S:Y(I)=-Y+Y/S
1070 I=I+1:NEXT TH
1080 X0=INT(320*RND(0)):Y0=INT(192*RND(0))
1090 I=INT(P*RND(0)+1)
1100 X1=(X(I)+X0)*S:Y1=(Y(I)+Y0)*S
1110 PLOT X1,Y1:X0=X1:Y0=Y1
1120 IF PEEK(53279)=2 THEN 10000
1130 IF PEEK(53279)=3 THEN GOSUB 3000
1140 IF PEEK(53279)=5 THEN GOSUB 5000
1160 GOTO 1090
3000 TRAP 4000:CLOSE #1:OPEN #1,8,0,"P:":? #1;CHR$(27);"C";CHR$(0);CHR$(11);
3010 ? #1;CHR$(27);"D";CHR$(8);CHR$(16);CHR$(24);CHR$(32);CHR$(40);CHR$(48);CHR$(56);CHR$(64);CHR$(72);CHR$(0)
3020 DM=PEEK(88)+PEEK(89)*256
3030 PRINT #1;CHR$(27);"A";CHR$(8)
3100 FOR I=0 TO 23:XX=DM+320*I
3110 A$=CHR$(0):A$(320)=CHR$(0):A$(2)=A$
3120 W=USR(ADR(RSD$),XX,ADR(A$)):PRINT #1;"▗▗";CHR$(27);"K";CHR$(64);CHR$(1);A$:NEXT I:? #1;CHR$(27);"@"
3130 POKE 764,255
3140 RETURN
4000 IF PEEK(53279)=3 THEN TRAP 40000:GOTO 3000
4010 GOTO 4000
5000 B$(1)="D:":B$(LEN(B$)+1)=NAME$:B$(LEN(B$)+1)=".PIC"
5010 SCREEN=PEEK(88)+256*PEEK(89)
5020 TRAP 5040:CLOSE #2:OPEN #2,IO,0,B$
5030 W=USR(ADR(DUMMY$),2,SCREEN,7680):CLOSE #2:RETURN
5040 CLOSE #2:TRAP 40000:POP
5050 ? :POSITION 14,12:? "DISK ERROR.":FOR X=1 TO 400:NEXT X:GOTO 10000
6000 GRAPHICS 24:SETCOLOR 2,0,0:SETCOLOR 1,0,10
6010 GOSUB 5000
6020 IF PEEK(53279)=2 THEN 10000
6030 IF PEEK(53279)=3 THEN GOSUB 3000
6040 GOTO 6020
10000 GRAPHICS 0:POKE 752,1
10010 POSITION 7,2:? "┌────────────────────────┐"
10020 POSITION 7,3:? "|THE ULTIMATE CHAOS GAME!|":POSITION 7,4:? "| by Roger A. Pruitt |"
10030 POSITION 7,5:? "└────────────────────────┘"
10040 POSITION 12,8:? "1. Create Chaos."
10050 POSITION 12,10:? "2. Load Picture."
10060 POSITION 3,13:? "Select option by pressing 1 or 2.";
10070 POKE 764,255:POKE 694,0:POKE 702,64:GET #3,K:IF K<49 OR K>50 THEN 10070
10080 FOR I=0 TO 15:POSITION 2,8:? "↑":NEXT I
10090 POSITION 2,8:? "Input picture name";:INPUT NAME$
10100 IF K=50 THEN IO=4:DUMMY$=LDR$:GOTO 6000
10110 IO=8:DUMMY$=SVR$
10140 TRAP 10140:POSITION 2,10:? "Give number of sides of polygon":INPUT P:IF P<1 THEN P=1
10145 IF P>10 THEN POSITION 3,11:? " ":GOTO 10140
10150 TRAP 10150:POSITION 2,13:? "Give scale factor ( >0 TO 1 )":INPUT S
10155 IF (S<=0) OR (S>1) THEN POSITION 3,14:? " ":GOTO 10150
10156 TRAP 40000
10160 POKE 752,1:POSITION 6,18:? "To print press▕OPTION▎key."
10170 POSITION 3,19:? "To save to disk press▕SELECT▎key."
10180 POSITION 2,20:? "To quit hold▕START▎and press▕OPTION."
10190 POSITION 4,23:? "To create CHAOS press▕START▎key.";
10200 IF PEEK(53279)=6 THEN GOTO 1030
10210 GOTO 10200
28350 DIM RSD$(103),A$(640),NAME$(8),B$(14),SVR$(39),LDR$(39),DUMMY$(39),X(11),Y(11)
28360 RSD$(1)="hh┐Q┐Uh┐P┐Th┐Oh┐N)♥┐M"♥ ♥1T▄V┴%Ti(┐T♣▕fUh◆◢Pj ♥"♥▎V1N*┌Nh◆◢PtH@◢Pm┴%Ni◢┐N♣▕fO┴%Pi├┐P┐T♣▕fQ"
28370 RSD$(91)="%Q┐UfM%MI(P/◆"
28380 CLOSE #3:OPEN #3,4,0,"K:"
28400 LDR$="hhh◣◣◣◣*)╲↓B┘h↓E┘h↓D┘h↓I┘h↓H┘ Vd┤T ♥┤U◆"
28410 SVR$="hhh◣◣◣◣*)▝↓B┘h↓E┘h↓D┘h↓I┘h↓H┘ Vd┤T ♥┤U◆"
28430 RETURN
