The Discovery Incident, text adventure (ADVENT.BAS)
The Discovery Incident, text adventure by David Woolley, 258
Description
The Discovery Incident, text adventure by David Woolley, 258
From the Antic disk of Antic: October/November 1989 - Vol. 8 No. 6 — disk B.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 26.8 KB
- Dialect
- Atari BASIC
- Lines
- 553
- Variables
O2$,OBJECTS(,OB$,A$,ACT$,OBJ$,D$,O$,V$,N$,C$,I$,F(,X,Y,Z,SET,MM,XX,YY,ZZ,M,FIR,SHO,WEA,REM,ACT,REA,PUS,PUL,REP,SHOW,PRE,USE,DRO,NN,VB,QQ,N,LL,DV,M$,CHAR,ML,A,I,D,K,SAVE,LOAD,A3,B$,SUX$,Z1$,Z2$,Z3$,Z4$,E(,ZZ$,CANNISTER,LOG,FRESHAIR,BADAIR,NAVACOMP,ENGSTATUS,O,A1,A2,A4,A5,A6,A7,A8,A9,A0,LI,MENU,CLE,OPEN,GAS,DEATH,CLEARGAS,END,RGG,RFRFR,DI,HOME,DFKFM,HHFG,AA4,HHFG2,I2$,I3$,BFFV,VFWEF,RFRF
BASIC listing (553 lines)
0 REM THE DISCOVERY INCIDENT
1 REM BY DAVID WOOLLEY
2 REM (C)1989, ANTIC PUBLISHING, INC.
3 CLR :O=0:A1=1:A2=2:A3=3:A4=4:A5=5:A6=6:A7=7:A8=8:A9=9:A0=10:LI=52:X=O:Y=A4:Z=A1
4 POKE 559,O
5 OPEN #A1,A4,O,"K:"
9 DIM OBJ$(159),ACT$(102),D$(105),A$(56),O$(A6*A2),V$(A3),N$(A3),C$(A6),I$(33),F(A8*A2)
10 DIM O2$(A3),OBJECTS(A0+A1,A3),E(A6),I2$(33),I3$(33)
11 ACT$="GO GETTAKEXAINVN S E W U D FIRSHOWEAREMACTREAPUSPULREPFIXSHOMENNORSOUEASWESUP DOWPREUSECLIDESDRO"
12 OBJ$="TRARIFMANMASCOMPISWATC CS CW CE CCOMCOMCOMCOMCOMCANLEVTOOPARWINLADLADLADSIGCABPODENGDOODOODOODOO"
13 OBJ$(97)="LOGLOGLOGLOGCAMWRIWRIBUTH F N O S OPENORSOUEASWESUP DOW "
14 GOSUB A9*(A0^A3)+A9*(A0^A2)
15 GOTO A9*(A0^A3)
20 GRAPHICS O:POKE 756,SET:SETCOLOR A2,O,O
25 IF Z=A1 THEN FOR QQ=10000 TO 10025
26 IF Z=A2 THEN FOR QQ=10026 TO 10057
27 IF Z=A3 THEN FOR QQ=10058 TO 10083
29 RESTORE QQ:READ XX,YY,ZZ,D$,C$
30 IF XX=X AND YY=Y THEN GOTO (A3*A0)+A9
35 NEXT QQ
39 ? "↰":? :? D$
40 GOSUB A0^A3*A8+A9*A0
41 IF LEN(O$)=1 THEN O$="NONE"
42 ? :? "OBJECTS:";O$;".":? :? "EXITS:";
44 IF C$(A1,A1)="N" THEN ? "NORTH ";
45 IF C$(A2,A2)="S" THEN ? "SOUTH ";
46 IF C$(A3,A3)="E" THEN ? "EAST ";
47 IF C$(A4,A4)="W" THEN ? "WEST ";
48 IF C$(A5,A5)="U" THEN ? "UP ";
49 IF C$(A6,A6)="D" THEN ? "DOWN ";
50 POKE 82,O:? :? "────────────────────────────────────────"
51 IF PEEK(82)=O THEN ? " ";:POKE 82,A2
52 GOSUB A0^A3*A8+A0*A0+A0*A4:GOSUB A0^A3*A8+A0*A0+A0
53 ? "WHAT NOW";:INPUT A$:IF LEN(A$)=O THEN 55
54 GOSUB A0^A3*A8:GOSUB A0^A3*A8+A3*A0
55 GOSUB A0^A3*A8+(A0+A3)*A5
56 ON M GOTO 60,75,75,110,185,205,205,205,205,205,205,220,220,240,255,270,290,384,390,398,398,406,9077
57 ON M-23 GOTO 205,205,205,205,205,205,434,462,205,205,464
58 ? "I DON'T UNDERSTAND YOUR USE OF VERBS.":GOTO LI
60 IF NN=139 AND C$(A1,A1)="N" THEN Y=Y+A1:GOTO 8155
62 IF NN=142 AND C$(A2,A2)="S" THEN Y=Y-A1:GOTO 8155
64 IF NN=145 AND C$(A3,A3)="E" THEN X=X+A1:GOTO 8155
66 IF NN=148 AND C$(A4,A4)="W" THEN X=X-A1:GOTO 8155
68 IF NN=151 AND C$(A5,A5)="U" THEN Z=Z-A1:GOTO 8155
70 IF NN=154 AND C$(A6,A6)="D" THEN Z=Z+A1:GOTO 8155
72 ? "YOU CANNOT TRAVEL IN THAT DIRECTION.":GOTO LI
75 IF NN>31 THEN GOTO 86
76 IF NN=13 AND OBJECTS(A5,A3)<>O THEN 86
77 VB=NN:GOSUB 8065
79 IF OBJECTS(M,A3)=O THEN ? "YOU'VE ALREADY GOT IT.":GOTO LI
81 FOR QQ=A1 TO A3:OBJECTS(M,QQ)=O:NEXT QQ
83 I$(LEN(I$)+A1)=N$:? "TAKEN.":O2$="":GOTO LI
86 IF NN=55 OR NN=58 THEN ? "THEY'RE LOCKED AWAY.":GOTO LI
88 IF NN=13 THEN ? "IT'S MOUNTED TO THE WALL.":GOTO LI
90 IF NN=49 THEN ? "IT'S TOO HEAVY.":GOTO LI
92 ? "YOU CAN'T GET THAT.":GOTO LI
103 ? "YOU CAN'T GET THAT.":GOTO LI
105 ? "TAKEN.":O2$="":GOTO LI
110 IF NN=13 AND (O2$="COM" OR OBJECTS(A5,A3)=O) THEN GOTO 134
111 IF NN=13 THEN GOTO 135
112 IF NN=1 THEN GOTO 141
114 IF NN=64 THEN GOTO 147
116 IF NN=85 THEN GOTO 155
118 IF NN=97 THEN GOTO 165
120 IF NN=112 THEN GOTO 175
122 IF NN=157 THEN GOTO 39
123 IF NN<=31 THEN VB=NN:GOSUB 8065
124 IF N$=O2$ OR OBJECTS(M,A3)=O THEN 134
125 IF (NN=55 OR NN=58 OR NN=78) AND (Y=A1 AND Z=A2) THEN GOTO 134
126 IF (NN=52 OR NN=79 OR NN=82) AND (Y=O AND Z=A2) THEN GOTO 134
127 IF (NN>=118 AND NN<=136 OR NN=61) AND (X=A7 AND Y=A4 AND Z=A1) THEN GOTO 134
128 IF NN=73 AND (Y=A2 AND Z=A1) OR (X=A1 AND Y=A4 AND Z=A1) OR (Y=A6 AND Z=A1) OR (Y=A2 AND Z=A2) THEN 134
129 IF NN=73 AND (X=A1 AND Y=A4 AND Z=A2) OR (X=A7 AND Y=A4 AND Z=A2) OR (Y=A6 AND Z=A2) OR (Y=2 AND Z=3) THEN 134
130 IF NN=73 AND (X=A1 AND Y=A4 AND Z=A3) OR (X=A7 AND Y=A4 AND Z=A3) OR (Y=A6 AND Z=A3) THEN GOTO 134
131 IF NN=49 AND X=O AND Y=A4 AND Z=A2 THEN GOTO 134
132 IF NN=109 AND (Y=A6 AND Z=A1) OR (Y=A2 AND Z=A1) OR (Y=A6 AND Z=A2) OR (Y=A2 AND Z=A2) THEN GOTO 134
133 ? "YOU CAN'T SEE IT HERE.":GOTO LI
134 RESTORE (11000+NN):READ A$,D$:? D$:GOTO LI
135 IF X=A2 AND Y=A7 AND Z=A1 THEN NN=40:GOTO 134
136 IF X=A3 AND Y=A8 AND Z=A1 THEN NN=34:GOTO 134
137 IF X=A4 AND Y=A8 AND Z=A1 THEN NN=37:GOTO 134
138 IF X=A5 AND Y=A7 AND Z=A1 THEN NN=43:GOTO 134
139 IF X=A7 AND Y=A4 AND Z=A1 THEN NN=46:GOTO 134
140 IF Y=A1 AND Z=A1 THEN ? "YOU HAVE NEVER FULLY UNDERSTOOD THIS COMPUTER.NOW IS NOT THE TIME!":GOTO LI
141 RESTORE (11000+NN):READ A$,D$:? D$:IF F(A7)=O THEN ? "IT IS BROKEN."
142 GOTO LI
147 IF (X=A3 OR X=A4) AND Y=A4 AND Z=A1 THEN NN=64:GOTO 134
149 IF (X=A3 OR X=A4) AND Y=A4 AND Z=A2 THEN NN=70:GOTO 134
151 IF (X=A3 OR X=A4) AND Y=A4 AND Z=A3 THEN NN=67:GOTO 134
153 GOTO 133
155 IF Y=A6 AND Z=A1 THEN NN=85:GOTO 134
157 IF Y=A2 AND Z=A1 THEN NN=88:GOTO 134
159 IF Y=A6 AND Z=A2 THEN NN=91:GOTO 134
160 IF Y=A2 AND Z=A2 THEN NN=94:GOTO 134
162 GOTO 133
165 IF (Y=A6 AND Z=A1) OR OBJECTS(A8,A3)=O THEN NN=97:GOTO 134
167 IF (Y=A2 AND Z=A1) OR OBJECTS(A9,A3)=O THEN NN=100:GOTO 134
169 IF (Y=A6 AND Z=A2) OR OBJECTS(A0,A3)=O THEN NN=103:GOTO 134
171 IF (Y=A2 AND Z=A2) OR OBJECTS(A0+A1,A3)=O THEN NN=106:GOTO 134
173 GOTO 133
175 IF X=O AND Y=A4 AND Z=A2 THEN 179
177 GOTO 133
179 IF F(A1)=A1 AND F(A7)=A1 THEN NN=115:GOTO 134
181 GOTO 134
185 ? "YOU ARE CARRYING:"
187 IF LEN(I$)=O THEN ? "NOTHING.":GOTO LI
190 QQ=A1:ZZ=A1
192 IF OBJ$(QQ,QQ+A2)=I$(ZZ,ZZ+A2) THEN 196
194 QQ=QQ+A3:GOTO 192
196 RESTORE (11000+QQ):READ D$,A$:? D$;
197 IF QQ=A1 AND F(A1)=A1 THEN ? "(WORN)":GOTO 200
198 IF QQ=A0 AND F(A0+A1)=A1 THEN ? "(WORN)":GOTO 200
199 ?
200 QQ=A1:ZZ=ZZ+A3
201 IF ZZ>LEN(I$) THEN GOTO LI
202 GOTO 192
205 IF VB=16 OR VB=70 THEN NN=139:GOTO 60
207 IF VB=19 OR VB=73 THEN NN=142:GOTO 60
209 IF VB=22 OR VB=76 THEN NN=145:GOTO 60
211 IF VB=25 OR VB=79 THEN NN=148:GOTO 60
213 IF VB=28 OR VB=82 OR VB=94 THEN NN=151:GOTO 60
215 IF VB=31 OR VB=85 OR VB=97 THEN NN=154:GOTO 60
217 ? "YOU CAN'T GO THAT WAY.":GOTO LI
220 IF VB=37 AND (NN>=22 AND NN<=31) THEN GOTO 406
221 IF VB=34 AND (NN=A4 AND OBJECTS(A2,A3)<>O) THEN ? "YOU HAVEN'T GOT ONE.":GOTO LI
222 IF VB=34 AND (NN=16 AND OBJECTS(A6,A3)<>O) THEN ? "YOU HAVEN'T GOT ONE.":GOTO LI
223 IF VB=34 AND (NN=A4 AND F(A9)=A1) OR (NN=16 AND F(A0)=A1) THEN ? "IT DOESN'T WORK.":GOTO LI
225 IF VB=37 THEN ? "TRY FIRING A WEAPON.":GOTO LI
228 ? "AS YOU READY THE WEAPON, A BEAM OF LIGHT STREAKS DOWN FROM THE CEILING AND STRIKES IT."
229 IF VB=34 AND NN=A4 THEN F(A9)=A1:GOTO LI
230 IF VB=34 AND NN=16 THEN F(A0)=A1:GOTO LI
233 IF F(A9)=A1 THEN F(A0)=A1:GOTO LI
235 IF F(A0)=A1 THEN F(A9)=A1:GOTO LI
240 IF NN=A1 AND OBJECTS(A1,A3)=O AND F(A1)=O THEN F(A1)=A1:? "OK.":GOTO LI
242 IF NN=A1 AND F(A1)=A1 THEN ? "YOU ALREADY ARE.":GOTO LI
244 IF NN=A1 AND OBJECTS(A1,A3)<>O THEN ? "YOU HAVEN'T GOT ONE.":GOTO LI
246 IF NN=A0 AND OBJECTS(A4,A3)=O AND F(A0+A1)=O THEN F(A0+A1)=A1:? "OK.":GOTO LI
248 IF NN=A0 AND F(A0+A1)=A1 THEN ? "YOU ALREADY ARE.":GOTO LI
250 IF NN=A0 AND OBJECTS(A4,A3)<>O THEN ? "YOU HAVEN'T GOT ONE.":GOTO LI
251 IF NN=19 THEN ? "THE STRAP IS BROKEN.":GOTO LI
252 ? "YOU CAN'T DO THAT.":GOTO LI
255 IF NN=A1 AND F(A1)=A1 THEN F(A1)=O:? "OK.":GOTO LI
258 IF NN=A1 AND OBJECTS(A1,A3)<>O THEN ? "YOU HAVEN'T GOT ONE.":GOTO LI
260 IF NN=A1 AND F(A1)=O AND OBJECTS(A1,A3)=O THEN ? "YOU AREN'T WEARING IT.":GOTO LI
262 IF NN=A0 AND F(A0+A1)=A1 THEN F(A0+A1)=O:? "OK.":GOTO LI
264 IF NN=A0 AND OBJECTS(A4,A3)<>O THEN ? "YOU HAVEN'T GOT ONE.":GOTO LI
266 IF NN=A0 AND F(A0+A1)=O AND OBJECTS(A4,A1)=O THEN ? "YOU AREN'T WEARING IT.":GOTO LI
267 IF NN=19 AND OBJECTS(A7,A3)<>O THEN ? "YOU HAVEN'T GOT ONE.":GOTO LI
268 IF NN=19 AND OBJECTS(A7,A3)=O THEN ? "THE STRAP IS BROKEN.":GOTO LI
269 ? "YOU CAN'T DO THAT.":GOTO LI
270 IF NN=13 AND X=A2 AND Y=A7 AND Z=A1 AND F(A0+A4)=O THEN ? "OK.":F(A0+A4)=A1:GOTO LI
272 IF NN=13 AND X=A2 AND Y=A7 AND Z=A1 AND F(A0+A4)=A1 THEN ? "IT ALREADY IS.":GOTO LI
274 IF NN=13 AND X=A3 AND Y=A8 AND Z=A1 AND F(A0+A2)=O THEN ? "OK.":F(A0+A2)=A1:GOTO LI
276 IF NN=13 AND X=A3 AND Y=A8 AND Z=A1 AND F(A0+A2)=A1 THEN ? "IT ALREADY IS.":GOTO LI
278 IF NN=13 AND X=A4 AND Y=A8 AND Z=A1 AND F(A0+A3)=O THEN ? "OK.":F(A0+A3)=A1:GOTO LI
280 IF NN=13 AND X=A4 AND Y=A8 AND Z=A1 AND F(A0+A3)=A1 THEN ? "IT ALREADY IS.":GOTO LI
282 IF NN=13 AND X=A5 AND Y=A7 AND Z=A1 AND F(A0+A5)=O THEN ? "OK.":F(A0+A5)=A1:GOTO LI
284 IF NN=13 AND X=A5 AND Y=A7 AND Z=A1 AND F(A0+A5)=A1 THEN ? "IT ALREADY IS.":GOTO LI
286 ? "YOU CAN'T DO THAT.":GOTO LI
290 IF NN=A7 AND OBJECTS(A3,A3)=O THEN 322
292 IF NN=A7 AND OBJECTS(A3,A3)<>O THEN ? "YOU CAN'T SEE IT FROM HERE.":GOTO LI
294 IF NN=13 AND X=A4 AND Y=A8 AND Z=A1 AND F(A0+A3)=A1 THEN GOTO 328
296 IF NN=13 AND X=A4 AND Y=A8 AND Z=A1 AND F(A0+A3)=O THEN ? "IT'S NOT ACTIVATED.":GOTO LI
300 IF (NN=49 OR NN=112) AND X=O AND Y=A4 AND Z=A2 AND F(A1)=A1 AND F(A7)=A1 THEN GOTO 338
302 IF (NN=49 OR NN=112) AND X=O AND Y=A4 AND Z=A2 THEN 346
304 IF NN=49 AND NOT (X=O AND Y=A4 AND Z=A2) THEN ? "IT ISN'T HERE.":GOTO LI
306 IF NN=13 AND X=A2 AND Y=A7 AND Z=A1 AND F(A6)=A1 THEN GOTO 352
308 IF NN=13 AND X=A2 AND Y=A7 AND Z=A1 AND F(A6)=O AND F(A0+A4)=A1 THEN GOTO 358
309 IF NN=13 AND X=A2 AND Y=A7 AND Z=A1 AND F(A0+A4)=O THEN ? "IT'S NOT ACTIVATED.":GOTO LI
310 IF NN=13 AND X=A3 AND Y=A8 AND Z=A1 AND F(A0+A2)=A1 THEN GOTO 364
311 IF NN=13 AND X=A3 AND Y=A8 AND Z=A1 AND F(A0+A2)=O THEN ? "IT'S NOT ACTIVATED.":GOTO LI
312 IF NN=13 AND X=A5 AND Y=A7 AND Z=A1 AND F(A0+A5)=A1 THEN GOTO 368
313 IF NN=13 AND X=A5 AND Y=A7 AND Z=A1 AND F(A0+A5)=O THEN ? "IT'S NOT ACTIVATED.":GOTO LI
314 IF NN=13 AND Y=A4 AND Z=A1 THEN ? "THAT COMPUTER DOESN'T HAVE A VDU.":GOTO LI
316 IF NN=13 THEN ? "THERE ISN'T ONE HERE.":GOTO LI
318 IF NN=73 THEN ? "I'VE ALREADY TOLD YOU.":GOTO LI
320 ? "YOU CAN'T READ THAT.":GOTO LI
322 ? "IT READS:"
324 ? "GENERAL ORDER 6:IN THE EVENT OF ALL THE CREW DYING ALL SECURITY AREAS WILLBE SEALED OFF AND WILL BE";
326 ? "→OPENED IF THE CORRECT SECURITY CARDS ARE SHOWN TO THE SECURITY CAMERAS.":GOTO LI
328 ? "IT READS:"
330 ? "STARDATE 890317:ORDERS CONFIRMED. STARSHIP DISCOVERY TO LEAVE STAR SYSTEM NU DRACONIS";
332 ? "→SIXTY-TWO LY FROM EARTH.▶▶▶▶▶STARDATE 890318:ENSIGN HELMAN TO BE REPRIMANDED FOR FAILURE TO REPAIR";
334 ? "→WARPDRIVE'S EMERGENCY SPEED.▶▶▶STARDATE 890319:ENCOUNTERED ALIEN CANNISTER IN SPACE.WE HAVE";
336 ? "→DECIDED TO OPEN IT UP FOR FURTHUR INVESTIGATION.":GOTO LI
338 ? "IT READS:"
340 ? "WARNING:THIS CANNISTER CONTAINS A VIRUS DEADLY TO MOST CARBON BASED LIFEFORMS.SHOULD IT BE OPENED IT";
342 ? "→CAN BE ELIMINATED BY MIXING WITH IT THE (ON OUR WORLD) HIGHLY RARE GASES FLUORINE AND SULPHUR."
344 GOTO LI
346 ? "IT READS:"
348 ? "MDMMEKE:EEOSKWI WJWJSII KJEEUUUSSIW SJSJZUZJW MDK.JWM AKA DIDWW WWMS (TJF MKFKQ) NSNSNS WUWLK."
350 GOTO LI
352 ? "IT READS:"
354 ? "LIFE SUPPORT COMPUTER: CONFIRMED: SHIP'S AIR SYSTEM FREE OF ALIEN VIRUS."
356 GOTO LI
358 ? "IT READS:"
360 ? "LIFE SUPPORT COMPUTER: ALIEN VIRUS SPREAD THRU SHIP VIA AIR CONDITIONING SYSTEM."
362 GOTO LI
364 ? "IT READS:"
365 ? "NAVAGATION COMPUTER:COURSE DATA"
366 ? "STARSHIP DISCOVERY'S COURSE LAID IN. DESTINATION:PLANET EARTH. DISTANCE:";62-DI;" LYS."
367 GOTO LI
368 ? "IT READS:"
370 ? "ENGINE STATUS DISPLAY"
372 FOR QQ=A1 TO A6
374 ? "ENGINE ID NUMBER:";QQ
376 ? "ENGINE STATUS:";
378 IF E(QQ)=O THEN ? "ALL STOP"
380 IF E(QQ)=A1 THEN ? "FULL SPEED"
382 NEXT QQ:GOTO LI
384 IF NN<>52 OR NOT (Y=O AND Z=A2) THEN ? "YOU CAN'T DO THAT.":GOTO LI
386 E(X)=E(X)+A1:IF E(X)>A2 THEN ? "IT WON'T GO THAT FAR.":E(X)=A2:GOTO LI
388 ? "OK.":IF E(X)=A2 THEN F(A8)=A1:? "THE ENGINE BEGINS TO GRIND."
389 GOTO LI
390 IF NN<>52 OR NOT (Y=O AND Z=A2) THEN ? "YOU CAN'T DO THAT.":GOTO LI
392 E(X)=E(X)-A1:IF E(X)<O THEN ? "IT WON'T GO THAT FAR.":E(X)=O:GOTO LI
394 ? "OK.":IF E(X)=A1 THEN F(A8)=O:? "THE ENGINE STOPS GRINDING."
396 GOTO LI
398 IF NOT (X=A3 AND Y=A2 AND Z=A1) THEN ? "YOU CAN'T DO THAT.":GOTO LI
400 IF NN=19 THEN ? "A VOICE OVER THE PA SAYS:'THIS EQUIPMENT IS NOT FOR PERSONAL USE.'":GOTO LI
402 IF NN<>1 THEN ? "YOU CAN'T DO THAT.":GOTO LI
403 IF F(A7)=A1 THEN ? "IT ALREADY IS.":GOTO LI
404 ? "OK.":? "IT IS NOW FIXED.":F(A7)=A1:GOTO LI
406 IF NOT (NN>=22 AND NN<=31) THEN ? "NOTHING HAPPENS.":GOTO LI
408 IF NN=22 AND OBJECTS(A8,A3)<>O THEN ? "YOU HAVEN'T GOT IT.":GOTO LI
410 IF NN=25 AND OBJECTS(A9,A3)<>O THEN ? "YOU HAVEN'T GOT IT.":GOTO LI
412 IF NN=28 AND OBJECTS(A0,A3)<>O THEN ? "YOU HAVEN'T GOT IT.":GOTO LI
414 IF NN=31 AND OBJECTS(A0+A1,A3)<>O THEN ? "YOU HAVEN'T GOT ONE.":GOTO LI
416 IF NN=22 AND NOT (Y=A6 AND Z=A1) THEN ? "NOTHING HAPPENS.":GOTO LI
418 IF NN=25 AND NOT (Y=A2 AND Z=A1) THEN ? "NOTHING HAPPENS.":GOTO LI
420 IF NN=28 AND NOT (Y=A6 AND Z=A2) THEN ? "NOTHING HAPPENS.":GOTO LI
422 IF NN=31 AND NOT (Y=A2 AND Z=A2) THEN ? "NOTHING HAPPENS.":GOTO LI
424 IF NN=22 THEN F(A2)=A1
426 IF NN=25 THEN F(A3)=A1
428 IF NN=28 THEN F(A4)=A1
430 IF NN=31 THEN F(A5)=A1
432 ? "THE DOOR SILENTLY SLIDES OPEN.":GOTO LI
434 IF NOT (NN>=118 AND NN<=136) THEN ? "YOU CAN'T DO THAT.":GOTO LI
435 IF F(A0+A6)=A1 THEN ? "YOU CAN'T.THE WINDOW IS OPEN.":GOTO LI
436 IF NN=118 THEN ? "PLEASE SPECIFY A BUTTON.":GOTO LI
438 IF NN=121 THEN M$(LEN(M$)+A1)="◢"
440 IF NN=124 THEN M$(LEN(M$)+A1)="╱"
442 IF NN=127 THEN M$(LEN(M$)+A1)="▂"
444 IF NN=130 THEN M$(LEN(M$)+A1)="▖"
446 IF NN=133 THEN M$(LEN(M$)+A1)="┼"
448 IF NN=136 THEN GOTO 452
450 ? "CLICK!":GOTO LI
452 IF M$(A1,A1)="╱" AND M$(A2,A2)="┼" AND F(A0+A1)=A1 THEN GOTO 458
453 IF M$(A1,A1)="┼" AND M$(A2,A2)="╱" AND F(A0+A1)=A1 THEN GOTO 458
454 IF F(A0+A1)=A1 THEN GOTO 458
455 ? "THE HIGHLY DANGEROUS CONCENTRATED GASES INSIDE THE TANK ARE LET OUT AS THE WINDOW OPENS, KILLING YOU."
456 GOTO 8225
458 ? "THE WINDOW OPENS, AND YOU CAN FEEL STRANGE GASES FLOWING PAST YOU INTO THE AIR CONDITIONING."
460 F(A6)=A1:F(A0+A6)=A1:GOTO LI
462 ? "TELL ME EXACTLY WHAT YOU WANT TO DO.":GOTO LI
464 IF NN>31 THEN ? "YOU HAVEN'T GOT ONE.":GOTO LI
465 IF O2$<>"NON" THEN ? "YOU CAN'T DROP THAT HERE.":GOTO LI
466 VB=NN:GOSUB 8065
468 IF OBJECTS(M,A3)<>O THEN ? "YOU HAVEN'T GOT ONE.":GOTO LI
469 RESTORE 11000+NN:READ O2$
470 QQ=A1
472 IF I$(QQ,QQ+A2)=O2$ THEN GOTO 475
474 QQ=QQ+A3:GOTO 472
475 IF LEN(I$)=A3 THEN I$="":GOTO 480
476 IF QQ=LEN(I$)-A2 THEN GOTO 484
478 I2$=I$(A1,QQ-A1):I3$=I$(QQ+A3,LEN(I$)):I$="":I$=I2$:I$(LEN(I$)+A1)=I3$
480 I2$="":I3$="":OBJECTS(M,A1)=X:OBJECTS(M,A2)=Y:OBJECTS(M,A3)=Z
481 IF M=A1 THEN F(A1)=O
482 IF M=A4 THEN F(A0+A1)=O
483 ? "DROPPED.":GOTO LI
484 I2$=I$(A1,QQ-A1):I$="":I$=I2$:GOTO 480
8000 TRAP 8047
8001 A$(LEN(A$)+A1)=" ":O2$=O$
8002 FOR QQ=A1 TO LEN(A$)
8005 IF A$(QQ,QQ)=" " THEN 8015
8010 NEXT QQ
8015 V$=A$(A1,QQ-A1)
8020 N$=A$(QQ+A1,LEN(A$))
8025 RETURN
8030 IF LEN(V$)<A3 THEN V$(LEN(V$)+A1)=" "
8035 VB=A1
8040 IF ACT$(VB,VB+A2)=V$ THEN 8050
8042 TRAP 8063
8045 VB=VB+A3:GOTO 8040
8047 ? "I DON'T UNDERSTAND YOUR USE OF VERBS.":GOTO LI
8050 IF LEN(N$)<A3 THEN N$(LEN(N$)+A1)=" "
8055 NN=A1
8060 IF OBJ$(NN,NN+A2)=N$ THEN RETURN
8061 TRAP 8063
8062 NN=NN+A3:GOTO 8060
8063 ? "I DON'T UNDERSTAND YOU.":GOTO LI
8065 IF NOT INT(VB/A2) THEN DV=2.6
8070 IF INT(VB/A2) THEN DV=2.85714285
8075 IF VB<40 THEN M=INT(VB/DV)+A1
8080 IF VB>=40 THEN M=INT(VB/DV)
8082 IF VB>=100 THEN M=INT(VB/DV)-A1
8085 RETURN
8090 FOR M=A1 TO A0+A1
8095 IF OBJECTS(M,A1)=X AND OBJECTS(M,A2)=Y AND OBJECTS(M,A3)=Z THEN RESTORE 11000+((M*A3)-A2):READ O$:RETURN
8100 NEXT M
8105 O$="♥":RETURN
8110 FOR QQ=A1 TO A6
8115 IF E(QQ)=A1 THEN GOTO 8130
8120 NEXT QQ
8125 RETURN
8130 DI=DI+A1:IF DI=62 THEN GOTO 8190
8135 RETURN
8140 IF F(A8)=O THEN RETURN
8145 ? "THE ENGINE'S GRINDING INCREASES!"
8150 ? "SUDDENLY IT EXPLODES!EVERYTHING GOES DARK....":GOTO 8225
8155 IF Y=A7 AND Z=A1 AND F(A2)=O THEN GOTO 8180
8160 IF Y=A7 AND Z=A2 AND F(A4)=O THEN GOTO 8180
8165 IF Y=A1 AND Z=A1 AND F(A3)=O THEN GOTO 8185
8170 IF Y=A1 AND Z=A2 AND F(A5)=O THEN GOTO 8185
8175 GOTO 25
8180 ? "A LARGE METAL DOOR BLOCKS YOUR WAY.":Y=Y-A1:GOTO LI
8185 ? "A LARGE METAL DOOR BLOCKS YOUR WAY.":Y=Y+A1:GOTO LI
8190 ? "SUDDENLY, THE SHIP BEGINS TO SLOW DOWNAND FINALLY STOPS.A SMALL SHIP ENTERS THE LAUNCH BAY, AND..."
8195 FOR QQ=A1 TO A2*(A0*A0):NEXT QQ
8200 IF F(A6)=O THEN GOTO 8215
8205 ? "TWO MONTHS LATER, YOU RECEIVE FULL HONOURS FOR AVERTING DISASTER AND DESTROYING THE ALIEN VIRUS."
8210 GOTO 8230
8215 ? "THE ALIEN VIRUS IS SPREAD FROM THE SHIP TO EARTH, AND TWO THIRDS OF THE HUMAN RACE DIES OUT."
8220 GOTO 8230
8225 ? :? "▶▶YOU HAVE DIED."
8230 ? :? "▶PRESS ANY KEY TO TRY AGAIN."
8235 GET #A1,K:RUN
9000 GRAPHICS A0+A8:DIM M$(56)
9005 M$="hh┐▕h┐├h┐┤h┐┘h┐╱h┐┐ ♥p♣1├┌┘f├P▕f▕f┘P▕f┤F┐%┐I▶PhF╱%╱I▶P◆◆"
9010 CHAR=PEEK(106)-8:ML=USR(ADR(M$),57344,CHAR*256,1023):M$=""
9015 RESTORE 9036
9020 FOR A=16 TO 25:FOR I=O TO A7:READ D:POKE CHAR*256+A*A8+I,D:NEXT I:NEXT A
9025 FOR A=33 TO 58:FOR I=O TO A7:READ D:POKE CHAR*256+A*A8+I,D:NEXT I:NEXT A
9030 READ A:IF A=-A1 THEN GOTO 9077
9035 FOR I=O TO A7:READ D:POKE CHAR*256+A*A8+I,D:NEXT I:SET=CHAR:GOTO 9030
9036 DATA 127,99,99,99,99,99,127,0
9037 DATA 56,24,24,24,62,62,62,0
9038 DATA 127,3,3,127,96,96,127,0
9039 DATA 126,6,6,127,7,7,127,0
9040 DATA 112,112,112,119,119,127,7,0
9041 DATA 127,96,96,127,7,7,127,0
9042 DATA 124,108,96,127,99,99,127,0
9043 DATA 127,3,3,31,24,24,24,0
9044 DATA 62,54,54,127,119,119,127,0
9045 DATA 127,99,99,127,7,7,7,0
9046 DATA 63,51,51,127,115,115,115,0
9047 DATA 126,102,102,127,103,103,127,0
9048 DATA 127,103,103,96,99,99,127,0
9049 DATA 126,102,102,119,119,119,127,0
9050 DATA 127,96,96,127,112,112,127,0
9051 DATA 127,96,96,127,112,112,112,0
9052 DATA 127,99,96,111,103,103,127,0
9053 DATA 115,115,115,127,115,115,115,0
9054 DATA 12,12,12,12,60,60,60,0
9055 DATA 12,12,12,14,14,110,126,0
9056 DATA 102,102,108,127,103,103,103,0
9057 DATA 48,48,48,112,112,112,126,0
9058 DATA 103,127,127,119,103,103,103,0
9059 DATA 103,119,127,111,103,103,103,0
9060 DATA 127,99,99,103,103,103,127,0
9061 DATA 127,99,99,127,112,112,112,0
9062 DATA 127,99,99,103,103,103,127,7
9063 DATA 126,102,102,127,119,119,119,0
9064 DATA 127,96,127,3,115,115,127,0
9065 DATA 127,28,28,28,28,28,28,0
9066 DATA 103,103,103,103,103,103,127,0
9067 DATA 103,103,103,103,111,62,28,0
9068 DATA 103,103,103,111,127,127,103,0
9069 DATA 115,115,115,62,103,103,103,0
9070 DATA 103,103,103,127,28,28,28,0
9071 DATA 127,102,108,24,55,103,127,0
9072 DATA 31,127,99,3,31,28,0,28,0
9073 DATA 8,30,24,24,56,56,56,62,0
9074 DATA 9,120,24,24,28,28,28,124,0
9075 DATA -1
9077 GRAPHICS A0+A8
9080 POKE 756,SET:POSITION A1,O:? #A6;"the":POSITION A3,A1:? #A6;"discovery":POSITION A0+A1,A2:? #A6;"incident"
9085 POSITION A4,A3:? #A6;"0- PLAY GAME"
9090 POSITION A4,A5:? #A6;"1- SAVE GAME"
9095 POSITION A4,A7:? #A6;"2- LOAD GAME"
9100 POSITION A4,A9:? #A6;"3- SWAP SETS"
9105 POSITION A6,A0+A1:? #A6;"4- LEAVE"
9110 GET #A1,K:K=K-(A0*A4+A8)
9115 IF K=O THEN GOTO A0*A2
9120 IF K=A1 THEN GOTO 9155
9125 IF K=A2 THEN GOTO 9185
9130 IF K=A3 THEN GOTO 9145
9135 IF K=A4 THEN CLR :END
9140 GOTO 9110
9145 IF SET=CHAR THEN SET=224:GOTO 9080
9150 IF SET=224 THEN SET=CHAR:GOTO 9080
9155 OPEN #A2,A8,O,"D:AD.DAT"
9160 V$=CHR$(155):? #A2;X;V$;Y;V$;Z;V$;DI;V$;I$;V$;M$
9165 FOR QQ=A1 TO A0+A6:? #A2;F(QQ):NEXT QQ
9170 FOR QQ=A1 TO A6:? #A2;E(QQ):NEXT QQ
9175 FOR QQ=A1 TO A0+A1:FOR ZZ=A1 TO A3:? #A2;OBJECTS(QQ,ZZ):NEXT ZZ:NEXT QQ
9180 V$="":CLOSE #A2:GOTO 9110
9185 OPEN #A2,A4,O,"D:AD.DAT"
9190 INPUT #A2;X,Y,Z,DI,I$,M$
9195 FOR QQ=A1 TO A0+A6:INPUT #A2;K:F(QQ)=K:NEXT QQ
9200 FOR QQ=A1 TO A6:INPUT #A2;K:E(QQ)=K:NEXT QQ
9205 FOR QQ=A1 TO A0+A1:FOR ZZ=A1 TO A3:INPUT #2;K:OBJECTS(QQ,ZZ)=K:NEXT ZZ:NEXT QQ
9210 CLOSE #A2:GOTO 9110
9900 RESTORE 9935:FOR QQ=A1 TO A0+A1
9905 READ XX,YY,ZZ
9910 OBJECTS(QQ,A1)=XX
9915 OBJECTS(QQ,A2)=YY
9920 OBJECTS(QQ,A3)=ZZ
9925 NEXT QQ
9926 FOR QQ=A1 TO A6:E(QQ)=A1:NEXT QQ
9927 FOR QQ=A1 TO A0+A6:F(QQ)=O:NEXT QQ
9930 RETURN
9935 DATA 2,1,3
9936 DATA 7,4,2
9937 DATA 7,4,3
9938 DATA 0,4,1
9939 DATA 2,1,2
9940 DATA 0,4,2
9941 DATA 3,8,3
9942 DATA 3,4,1
9943 DATA 7,4,1
9944 DATA 0,4,3
9945 DATA 5,1,3
10000 DATA 2,1,1,SHIP'S COMPUTER:YOU ARE IN THE SHIP'S COMPUTER'S DATA PROCESSING UNIT.,OOEOOO
10001 DATA 3,1,1,SHIP'S COMPUTER:YOU ARE IN THE SHIP'S COMPUTER'S PRIMARY CONTROL UNIT.,NOEWOO
10002 DATA 4,1,1,SHIP'S COMPUTER:YOU ARE IN THE SHIP'S COMPUTER'S I/O CONTROL UNIT.,NOEWOO
10003 DATA 5,1,1,SHIP'S COMPUTER:YOU ARE IN THE SHIP'S COMPUTER'S DATA STORAGE UNIT.,OOOWOO
10004 DATA 3,2,1,METAL PASSAGE:YOU ARE IN A METAL PASSAGE.A SIGN READS 'SHIP'S COMPUTER'.,NSOOOO
10005 DATA 4,2,1,METAL PASSAGE:YOU ARE IN A METAL PASSAGE.A SIGN READS 'SHIP'S COMPUTER'.,NSOOOO
10006 DATA 3,3,1,METAL PASSAGE:YOU ARE IN A METAL PASSAGE.,NSOOOO
10007 DATA 4,3,1,METAL PASSAGE:YOU ARE IN A METAL PASSAGE.,NSOOOO
10008 DATA 0,4,1,INFIRMARY:YOU ARE IN THE SHIP'S INFIRMARY.,OOEOOO
10009 DATA 1,4,1,METAL PASSAGE:YOU ARE IN A METAL PASSAGE.A SIGN READS 'INFIRMARY'.,OOEWOO
10010 DATA 2,4,1,METAL PASSAGE:YOU ARE IN A METAL PASSAGE.,OOEWOO
10011 DATA 3,4,1,CONNECTING ROOM:YOU ARE STANDING NEXT TO A LADDER.,NSEWOD
10012 DATA 4,4,1,CONNECTING ROOM:YOU ARE STANDING NEXT TO A LADDER.,NSEWOD
10013 DATA 5,4,1,METAL PASSAGE:YOU ARE IN A METAL PASSAGE.,OOEWOO
10014 DATA 6,4,1,METAL PASSAGE:YOU ARE IN A METAL PASSAGE.A SIGN READS 'SCIENCE LAB'.,OOEWOO
10015 DATA 7,4,1,SCIENCE LAB:YOU ARE IN THE SCIENCE LAB.YOU CAN SEE A SCIENCE COMPUTER.,OOOWOO
10016 DATA 3,5,1,METAL PASSAGE:YOU ARE IN A METAL PASSAGE.,NSOOOO
10017 DATA 4,5,1,METAL PASSAGE:YOU ARE IN A METAL PASSAGE.,NSOOOO
10018 DATA 3,6,1,METAL PASSAGE:YOU ARE IN A METAL PASSAGE.A SIGN READS 'BRIDGE'.,NSOOOO
10019 DATA 4,6,1,METAL PASSAGE:YOU ARE IN A METAL PASSAGE.A SIGN READS 'BRIDGE'.,NSOOOO
10020 DATA 2,7,1,BRIDGE:YOU ARE IN THE SCIENCE STATION.YOU CAN SEE A COMPUTER.,OOEOOO
10021 DATA 3,7,1,BRIDGE:YOU ARE ON THE BRIDGE.,NSEWOO
10022 DATA 4,7,1,BRIDGE:YOU ARE ON THE BRIDGE.,NSEWOO
10023 DATA 5,7,1,BRIDGE:YOU ARE AT THE DUTY STATION.YOUCAN SEE A STATUS COMPUTER.,OOOWOO
10024 DATA 3,8,1,BRIDGE:YOU ARE IN THE NAVIGATOR'S STATION.YOU CAN SEE A COMPUTER.,OSEOOO
10025 DATA 4,8,1,BRIDGE:YOU ARE IN THE CAPTAIN'S CHAIR.YOU CAN SEE A COMPUTER.,OSOWOO
10026 DATA 1,0,2,ENGINE ROOM:YOU ARE IN ENGINE POD 1/A.YOU CAN SEE A LEVER WITH 3 POSITIONS.,OOEOOO
10027 DATA 2,0,2,ENGINE ROOM:YOU ARE IN ENGINE POD 1/B.YOU CAN SEE A LEVER WITH 3 POSITIONS.,NOOWOO
10028 DATA 3,0,2,ENGINE ROOM:YOU ARE IN ENGINE POD 2/A.YOU CAN SEE A LEVER WITH 3 POSITIONS.,NOOOOO
10029 DATA 4,0,2,ENGINE ROOM:YOU ARE IN ENGINE POD 2/B.YOU CAN SEE A LEVER WITH 3 POSITIONS.,NOOOOO
10030 DATA 5,0,2,ENGINE ROOM:YOU ARE IN ENGINE POD 3/A.YOU CAN SEE A LEVER WITH 3 POSITIONS.,NOEOOO
10031 DATA 6,0,2,ENGINE ROOM:YOU ARE IN ENGINE POD 3/B.YOU CAN SEE A LEVER WITH 3 POSITIONS.,OOOWOO
10032 DATA 2,1,2,WORKSHOP:YOU ARE IN THE WORKSHOP TOOL STORAGE ROOM.,OSEOOO
10033 DATA 3,1,2,WORKSHOP:YOU ARE IN THE WORKSHOP MAINTENANCE ROOM.,NSEWOO
10034 DATA 4,1,2,WORKSHOP:YOU ARE IN THE WORKSHOP SPAREPARTS ROOM.,NSEWOO
10035 DATA 5,1,2,WORKSHOP:YOU ARE IN THE WORKSHOP DATA STORAGE ROOM.,OSOWOO
10036 DATA 3,2,2,METAL CORRIDOR:YOU ARE IN A METAL CORRIDOR.A SIGN READS 'WORKSHOP/ENGINE ROOM'.,NSOOOO
10037 DATA 4,2,2,METAL CORRIDOR:YOU ARE IN A METAL CORRIDOR.A SIGN READS 'WORKSHOP/ENGINE ROOM'.,NSOOOO
10038 DATA 3,3,2,METAL CORRIDOR:YOU ARE IN A METAL CORRIDOR.,NSOOOO
10039 DATA 4,3,2,METAL CORRIDOR:YOU ARE IN A METAL CORRIDOR.,NSOOOO
10040 DATA 0,4,2,LAUNCH BAY 1:YOU ARE IN A LONG LAUNCH BAY.YOU CAN SEE AN ALIEN CANNISTER.,OOEOOO
10041 DATA 1,4,2,METAL CORRIDOR:YOU ARE IN A METAL CORRIDOR.A SIGN READS 'LAUNCH BAY 1'.,OOEWOO
10042 DATA 2,4,2,METAL CORRIDOR:YOU ARE IN A METAL CORRIDOR.,OOEWOO
10043 DATA 3,4,2,CONNECTING ROOM:YOU ARE STANDING NEXT TO A LADDER.,NSEWUD
10044 DATA 4,4,2,CONNECTING ROOM:YOU ARE STANDING NEXT TO A LADDER.,NSEWUD
10045 DATA 5,4,2,METAL CORRIDOR:YOU ARE IN A METAL CORRIDOR.,OOEWOO
10046 DATA 6,4,2,METAL CORRIDOR:YOU ARE IN A METAL CORRIDOR.A SIGN READS 'LAUNCH BAY 2'.,OOEWOO
10047 DATA 7,4,2,LAUNCH BAY 2:YOU ARE IN A LONG LAUNCH BAY.,OOOWOO
10048 DATA 3,5,2,METAL CORRIDOR:YOU ARE IN A METAL CORRIDOR.,NSOOOO
10049 DATA 4,5,2,METAL CORRIDOR:YOU ARE IN A METAL CORRIDOR.,NSOOOO
10050 DATA 3,6,2,METAL CORRIDOR:YOU ARE IN A METAL CORRIDOR.A SIGN READS 'SHIP'S LASERS'.,NSOOOO
10051 DATA 4,6,2,METAL CORRIDOR:YOU ARE IN A METAL CORRIDOR.A SIGN READS 'SHIP'S LASERS'.,NSOOOO
10052 DATA 2,7,2,SHIP'S LASERS:YOU ARE IN THE SHIP'S PORT LASER'S POWER SOURCE.,OOEOOO
10053 DATA 3,7,2,SHIP'S LASERS:YOU ARE IN THE SHIP'S PORT LASER'S TARGETING SYSTEM.,NSEWOO
10054 DATA 4,7,2,SHIP'S LASERS:YOU ARE IN THE SHIP'S STARBOARD LASER'S TARGETING SYSTEM.,NSEWOO
10055 DATA 5,7,2,SHIP'S LASERS:YOU ARE IN THE SHIP'S STARBOARD LASER'S POWER SOURCE.,OOOWOO
10056 DATA 3,8,2,SHIP'S LASERS:YOU ARE IN THE SHIP'S PORT LASER BANK.,OSEOOO
10057 DATA 4,8,2,SHIP'S LASERS:YOU ARE IN THE SHIP'S STARBOARD LASER BANK.,OSOWOO
10058 DATA 2,1,3,CARGO STORAGE:YOU ARE IN A CARGO STORAGE ROOM.,OOEOOO
10059 DATA 3,1,3,CARGO STORAGE:YOU ARE IN A CARGO STORAGE ROOM.,NOEWOO
10060 DATA 4,1,3,CARGO STORAGE:YOU ARE IN A CARGO STORAGE ROOM.,NOEWOO
10061 DATA 5,1,3,CARGO STORAGE:YOU ARE IN A CARGO STORAGE ROOM.,OOOWOO
10062 DATA 3,2,3,METAL TUBE:YOU ARE IN A METAL TUBE.A SIGN READS 'CARGO STORAGE'.,NSOOOO
10063 DATA 4,2,3,METAL TUBE:YOU ARE IN A METAL TUBE.A SIGN READS 'CARGO STORAGE'.,NSOOOO
10064 DATA 3,3,3,METAL TUBE:YOU ARE IN A METAL TUBE.,NSOOOO
10065 DATA 4,3,3,METAL TUBE:YOU ARE IN A METAL TUBE.,NSOOOO
10066 DATA 0,4,3,CAFETERIA:YOU ARE IN THE SHIP'S CAFETERIA.,OOEOOO
10067 DATA 1,4,3,METAL TUBE:YOU ARE IN A METAL TUBE.A SIGN READS 'CAFETERIA'.,OOEWOO
10068 DATA 2,4,3,METAL TUBE:YOU ARE IN A METAL TUBE.,OOEWOO
10069 DATA 3,4,3,CONNECTING ROOM:YOU ARE STANDING NEXT TO A LADDER.,NSEWUO
10070 DATA 4,4,3,CONNECTING ROOM:YOU ARE STANDING NEXT TO A LADDER.,NSEWUO
10071 DATA 5,4,3,METAL TUBE:YOU ARE IN A METAL TUBE.,OOEWOO
10072 DATA 6,4,3,METAL TUBE:YOU ARE IN A METAL TUBE.A SIGN READS 'OFFICER'S LOUNGE'.,OOEWOO
10073 DATA 7,4,3,OFFICER'S LOUNGE:YOU ARE IN THE OFFICER'S LOUNGE.,OOOWOO
10074 DATA 3,5,3,METAL TUBE:YOU ARE IN A METAL TUBE.,NSOOOO
10075 DATA 4,5,3,METAL TUBE:YOU ARE IN A METAL TUBE.,NSOOOO
10076 DATA 3,6,3,METAL TUBE:YOU ARE IN A METAL TUBE.A SIGN READS 'CREW'S QUARTERS'.,NSOOOO
10077 DATA 4,6,3,METAL TUBE:YOU ARE IN A METAL TUBE.A SIGN READS 'OFFICER'S QUARTERS'.,NSOOOO
10078 DATA 2,7,3,CREW'S QUARTERS:YOU ARE IN THE CREW'S QUARTERS.,OOEOOO
10079 DATA 3,7,3,CREW'S QUARTERS:YOU ARE IN THE CREW'S QUARTERS.,NSOWOO
10080 DATA 4,7,3,OFFICER'S QUARTERS:YOU ARE IN THE JUNIOR OFFICER'S QUARTERS.,NSEOOO
10081 DATA 5,7,3,OFFICER'S QUARTERS:YOU ARE IN THE OFFICER'S QUARTERS.,OOOWOO
10082 DATA 3,8,3,CREW'S QUARTERS:YOU ARE IN THE CREW'S QUARTERS.,OSOOOO
10083 DATA 4,8,3,OFFICER'S QUARTERS:YOU ARE IN THE CAPTAIN'S QUARTERS.,OSOOOO
11001 DATA TRANSLATOR,THE TRANSLATOR IS DESIGNED LIKE A MASKFITTING OVER THE EYES AND EARS.
11004 DATA RIFLE,THE LASER RIFLE IS A POWERFUL WEAPON. IT IS A SMALLER VERSION OF THE SHIP'S LASERS.
11007 DATA MANUAL,THE ELECTRONIC MANUAL IS THE THIRD EDITION DESIGNED FOR USE BY CADETS ANDOFFICERS.
11010 DATA MASK,THE OXYGEN MASK FITS NEATLY OVER THE WEARER'S MOUTH.
11013 DATA COMMUNICATOR,THE COMMUNICATOR IS A SMALL BUT POWERFUL DEVICE.THIS ONE IS CAN ONLY RECEIVE.
11016 DATA PISTOL,THE LASER PISTOL IS A HIGHLY PORTABLE HAND-LASER.
11019 DATA WATCH,THE WATCH IS A SMALL DIGITAL ONE. IT IS BROKEN.
11022 DATA C CARD,THE CARD IS OBVIOUSLY A FORM OF IDENTIFICATION.IT HAS THE COMMAND LOGOPRINTED ON IT.
11025 DATA S CARD,THE CARD IS OBVIOUSLY A FORM OF IDENTIFICATION.IT HAS THE SCIENCE LOGOPRINTED ON IT.
11028 DATA W CARD,THE CARD IS OBVIOUSLY A FORM OF IDENTIFICATION.IT HAS THE WEAPONS LOGOPRINTED ON IT.
11031 DATA E CARD,THE CARD IS OBVIOUSLY A FORM OF IDENTIFICATION.IT HAS THE ENGINEERING LOGO PRINTED ON IT.
11034 DATA COMPUTER,THE COMPUTER IS A STANDARD MK II NAVAGATION COMPUTER AND IS USED ON MOST STAR SHIPS.
11037 DATA COMPUTER,THE COMPUTER IS A SIMPLE SHIP'S LOG WITH A DISPLAY SCREEN AND A KEY BOARD.
11040 DATA COMPUTER,THE COMPUTER IS A STANDARD MK IV LIFE SUPPORT COMPUTER USED TO MONITOR THE AIR INSIDE A SHIP.
11043 DATA COMPUTER,THE COMPUTER IS A STATUS COMPUTER USEDTO MONITOR THE SHIP'S ENGINES.
11046 DATA COMPUTER,THE COMPUTER HAS BUTTONS MARKED 1-6. UNDER THEM IS PRINTED H F N O S AND OPEN.
11049 DATA CANNISTER,THE ALIEN CANNISTER IS ABOUT 2 METRES LONG AND HAS STRANGE WRITING ON IT.
11052 DATA LEVER,THE LEVER HAS 3 POSITIONS-EMERGENCY SPEED;FULL SPEED;AND ALL STOP.
11055 DATA TOOLS,THE TOOLS ARE LOCKED AWAY IN CABINETS.
11058 DATA SPARE PARTS,THE SPARE PARTS ARE LOCK AWAY INSIDE CABINETS.
11061 DATA WINDOW,THE WINDOW IS LOCATED BEHIND THE COMPUTER.IT IS AIR TIGHT.BEHIND IT IS A SMALL TANK.
11064 DATA LADDER,THE LADDER IS MADE OF STRONG METAL.IT GOES STRAIGHT UP INTO THE CEILING.
11067 DATA LADDER,THE LADDER IS MADE OF STRONG METAL.IT GOES STRAIGHT DOWN INTO THE FLOOR.
11070 DATA LADDER,THE LADDER IS MADE OF STRONG METAL.IT GOES STRAIGHT UP INTO THE CEILING AND DOWN INTO THE FLOOR.
11073 DATA SIGN,SIGNS ARE FOR YOUR CONVENIENCE ONLY. THEY DON'T PLAY A MAJOR PART IN THIS ADVENTURE.
11076 DATA CABINETS,THE CABINETS ARE LOCKED TIGHT AND YOU CANNOT GET INTO THEM.
11079 DATA ENGINE POD,THE ENGINE POD IS A SMALL GLASS TUBE JUST IN FRONT OF THE ENGINE.
11082 DATA ENGINE,THE ENGINE IS HIDDEN BEHIND A HUGE METAL SCREEN.
11085 DATA DOOR,THE DOOR IS MADE OF THICK METAL.ON IT IS THE COMMAND LOGO AND ABOVE IT IS A CAMERA.
11088 DATA DOOR,THE DOOR IS MADE OF THICK METAL.ON IT IS THE SCIENCE LOGO AND ABOVE IT IS A CAMERA.
11091 DATA DOOR,THE DOOR IS MADE OF THICH METAL.ON IT IS THE WEAPONS LOGO AND ABOVE IT IS A CAMERA.
11094 DATA DOOR,THE DOOR IS MADE OF THICK METAL.ON IT IS THE ENGINEERING LOGO AND ABOVE IT IS A CAMERA.
11097 DATA LOGO,THE COMMAND LOGO IS A FIVE POINTED STAR INSIDE A RING.
11100 DATA LOGO,THE SCIENCE LOGO IS A SPIRAL GALAXY INSIDE A RING.
11103 DATA LOGO,THE WEAPONS LOGO IS A DOUBLE EDGED SWORD INSIDE A RING.
11106 DATA LOGO,THE ENGINEERING LOGO IS A SPANNER INSIDE A RING.
11109 DATA CAMERA,THE CAMERA IS MOUNTED ON AN ARM SO THAT IT CAN CONSTANTLY WATCH YOU.
11112 DATA WRITING,NOT SURPRISINGLY THE ALIEN WRITING IS UNREADABLE.
11115 DATA WRITING,THE ALIEN WRITING SEEMS QUITE LEGIBLE.
11118 DATA BUTTONS,THERE ARE 6 BUTTONS MARKED H F N O S AND OPEN.
11121 DATA BUTTON H,THE BUTTON IS SMALL AND WHITE.IT IS MARKED 'H'.PRESUMABLY IT STANDS FOR HYDROGEN.
11124 DATA BUTTON F,THE BUTTON IS SMALL AND WHITE.IT IS MARKED 'F'.PRESUMABLY IT STANDS FOR FLUORINE.
11127 DATA BUTTON N,THE BUTTON IS SMALL AND WHITE.IT IS MARKED 'N'.PRESUMABLY IT STANDS FOR NITROGEN.
11130 DATA BUTTON O,THE BUTTON IS SMALL AND WHITE.IT IS MARKED 'O'.PRESUMABLY IT STANDS FOR OXYGEN.
11133 DATA BUTTON S,THE BUTTON IS SMALL AND WHITE.IT IS MARKED 'S'.PRESUMABLY IT STANDS FOR SULPHUR.
11136 DATA BUTTON OPEN,THE BUTTON IS SMALL AND RED.IT IS MARKED 'OPEN'.
