Finance Program (old, refer to 90-04) (FINANCE.BAS)

Finance Program (old, refer to 90-04) by Philip W. Bate, 63

Description

Finance Program (old, refer to 90-04) by Philip W. Bate, 63

From the Antic disk of Antic: October/November 1989 - Vol. 8 No. 6 — disk A.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 7.8 KB

Dialect
Atari BASIC
Lines
156
Variables
SPC$, MSG$, YEAR$, HEAD$, HEAD2$, HEAD3$, FINANCE$, D$, MONEY$, MON$, AMT$, MNY$, I$, PRIN$, BAL$, LINE$, PMT$, CHRG$, A, PMT, MONEY, IN, NUM, B, C, Q, X, MON, AMT, PRIN, P, Z, O, M, L, I, CHRG, BAL, CP, R, N, APR, D, DOL, U
BASIC listing (156 lines)
10 REM *** FINANCE PROGRAM***
20 REM *** by Philip W. Bate PhD
25 REM (c) 1989, ANTIC PUBLISHING INC.
30 CLOSE #1:OPEN #1,4,0,"K":SETCOLOR 2,13,0:SETCOLOR 0,0,0:POKE 82,1
40 DIM SPC$(39),MSG$(28),YEAR$(4),HEAD$(39),HEAD2$(39),HEAD3$(39),FINANCE$(1100),D$(2)
50 DIM MONEY$(10),MON$(2),AMT$(10),MNY$(10),I$(7),PRIN$(7),BAL$(10),LINE$(39),PMT$(7),CHRG$(7)
60 SPC$=" ":SPC$(39)=" ":SPC$(2)=SPC$:MSG$="PRESS 'RETURN' FOR MAIN MENU"
70 HEAD3$="MON  PYMNT   IN+CHGS PRIN"
80 REM *** MAIN MENU***
90 A=0:N=0:P=0:MNY$="":NUM=0:PMT=0:I$="":PRIN$="":BAL$="":LINE$="":PMT$=""
100 ? "↰":? :? "    FINANCE PROGRAM "
110 ? :? "1 - AMOUNT OF PAYMENT"
120 ? :? "2 - NUMBER OF PAYMENTS"
130 ? :? "3 - AMORTIZATION SCHEDULE"
140 ? :? "4 - AMORTIZATION W/ VARYING PAYMENTS"
150 ? :? "5 - APPRECIATION SCHEDULE"
160 ? :? "6 - SAVINGS SCHEDULE"
170 ? :? :? "    CHOOSE ONE ":GOSUB 1040
175 IF A<49 OR A>54 THEN 80
180 TRAP 1380:ON A-48 GOTO 190,240,290,510,830,890
190 REM ***PAYMENT AMOUNT***
200 ? "↰":GOSUB 1150:GOSUB 1170
210 AMT=INT(MONEY*IN*(1/(1-(1+IN)^(-NUM)))*100+0.5)/100:PMT=AMT:GOSUB 1410
220 ? :? :? "PAYMENTS ARE $";MNY$:? :? "INTEREST IS $";:AMT=PMT*NUM-MONEY:GOSUB 1410:? MNY$
230 POSITION 4,15:? MSG$:GOSUB 1040
240 REM *** NUMBER OF PAYMENTS ***
250 ? "↰":GOSUB 1150:GOSUB 1180
260 NUM=INT(-(LOG(1-MONEY/PMT*IN))/LOG(IN+1)+0.9999)
270 ? :? :? "NUMBER OF PAYMENTS IS ";NUM:? :? "INTEREST IS $";:AMT=PMT*NUM-MONEY:GOSUB 1410:? MNY$
280 POSITION 4,15:? MSG$:GOSUB 1040
290 REM *** AMORTIZATION SCHEDULE ***
300 GOSUB 1120:GOSUB 1170:GOSUB 1180:GOSUB 1220:GOSUB 1250:GOSUB 470
310 B=0:C=0:Q=0
320 FOR X=MON TO NUM+MON-1
330 AMT=INT((MONEY*IN)*100+0.5)/100:GOSUB 1410:I$=MNY$:AMT=PMT-VAL(I$):GOSUB 1410
340 PRIN$=MNY$:PRIN=VAL(PRIN$):AMT=MONEY-PRIN:GOSUB 1480:BAL$=MNY$
350 B=B+PMT:C=C+VAL(I$):Q=Q+PRIN
360 LINE$=SPC$:LINE$(1,2)=MON$:LINE$(4,10)=PMT$:LINE$(12,18)=I$:LINE$(20,26)=PRIN$:LINE$(30,39)=BAL$
370 ? LINE$;:IF P=80 THEN GOSUB 1350
380 MONEY=INT(VAL(BAL$)*100+0.5)/100:MON=MON+1:GOSUB 1230
390 Z=INT(MONEY*(1+IN)*100+0.5)/100:IF PMT>=Z THEN AMT=Z:GOSUB 1410:PMT$=MNY$:PMT=Z
400 IF INT(MON/13)=MON/13 THEN 420
410 TRAP 80:NEXT X
420 ? :? YEAR$;" INTEREST=";C;"    PRIN=";Q:C=0:Q=0
430 IF P=80 THEN GOSUB 1360
440 MON=1:GOSUB 1230:YEAR$=STR$(VAL(YEAR$)+1):X=X+1
450 GOSUB 1090:GOSUB 470
460 GOTO 330
470 HEAD$(1,4)=YEAR$:HEAD$(5,29)=" AMORTIZATION - BALANCE= "
480 HEAD2$="MON  PYMNT   INTRST  PRIN       BALANCE"
490 IF P=80 THEN GOSUB 1320
500 ? "↰":? :? HEAD$;MONEY:? :? HEAD2$:RETURN
510 REM *** AMORTIZATION VARYING PMTS***
520 GOSUB 1120:GOSUB 1220:GOSUB 1250:GOSUB 730
530 GOSUB 770:B=O:C=0:M=0:L=6
540 IF PMT>=MONEY THEN CHRG$="***":PRIN$="***":AMT=MONEY-PMT:GOSUB 1410:BAL$=MNY$
550 I=(INT((MONEY*IN)*100+0.5)/100):AMT=I+CHRG:GOSUB 1410:CHRG$=MNY$:AMT=PMT-VAL(CHRG$):GOSUB 1410
560 PRIN$=MNY$:PRIN=VAL(PRIN$):IF PMT=0 THEN PRIN=-VAL(CHRG$):PRIN$=PMT$
570 AMT=MONEY-PRIN:GOSUB 1480:BAL$=MNY$
580 B=B+PRIN:C=C+I:M=M+CHRG
590 LINE$(1,38)=SPC$:LINE$(1,2)=MON$:LINE$(4,10)=PMT$:LINE$(12,18)=CHRG$:LINE$(20,26)=PRIN$:LINE$(29,38)=BAL$
600 POSITION 1,L:? LINE$;:IF P=80 THEN GOSUB 1350
610 IF VAL(BAL$)<0 THEN 820
620 IF VAL(BAL$)=0 THEN 670
630 MONEY=INT(VAL(BAL$)*100+0.5)/100:MON=MON+1:GOSUB 1230
640 Z=INT((MONEY*(1+IN)+CHRG)*100+0.5)/100:IF PMT>=Z THEN AMT=Z:GOSUB 1410:PMT$=MNY$:PMT=Z
650 IF INT(MON/13)=MON/13 THEN 670
660 GOSUB 770:L=L+1:PRIN=0:GOTO 540
670 ? :? :? YEAR$;" INTEREST=";C;"    CHARGES=";M:? "PRINCIPAL PAID= ";B
680 IF P=80 THEN GOSUB 1360
690 IF VAL(BAL$)<=O THEN GOSUB 1090:GOTO 80
700 MON=1:GOSUB 1230:YEAR$=STR$(VAL(YEAR$)+1)
710 GOSUB 1090:GOSUB 730
720 GOTO 530
730 HEAD$(1,4)=YEAR$:HEAD$(5,29)=" AMORTIZATION - BALANCE="
740 HEAD2$="MON  PYMNT   IN/CHRG PRIN       BALANCE"
750 IF P=80 THEN GOSUB 1310
760 ? "↰":? :? HEAD$;MONEY:? :? HEAD2$:RETURN
770 POSITION 1,22:? "ENTER PAYMENT";:INPUT PMT$:IF LEN(PMT$)=0 THEN PMT=0:PMT$="   -   ":GOTO 790
780 AMT=VAL(PMT$):GOSUB 1410:PMT$=MNY$:PMT=VAL(PMT$)
790 POSITION 22,22:? "CHARGES";:INPUT CHRG$:IF LEN(CHRG$)=0 THEN CHRG=0:GOTO 810
800 CHRG=VAL(CHRG$)
810 POSITION 1,22:? SPC$;:RETURN
820 ? :? " LOAN OVERPAID BY: ";ABS(VAL(BAL$)):GOTO 670
830 REM *** APPRECIATION ***
840 ? "↰":GOSUB 1150:GOSUB 1200
850 BAL=INT(MONEY*(1+IN)^(CP)*100+0.5)/100
860 ? :? :? "YOUR INVESTMENT WILL BE WORTH ";BAL
870 GOSUB 1090:GOSUB 730
880 GOTO 80
890 REM *** SAVINGS SCHEDULE ***
900 ? "↰":GOSUB 1150:GOSUB 1180:GOSUB 1210:GOSUB 1220:GOSUB 1250
910 B=0:C=0
920 GOSUB 1030
930 FOR X=1 TO NUM
940 AMT=INT((MONEY*IN)*100+0.5)/100:GOSUB 1410:I$=MNY$:R=AMT:IF AMT=0 THEN I$="   0.00"
950 AMT=MONEY+R+PMT:GOSUB 1410:BAL$=MNY$:MONEY=VAL(BAL$)
960 ? MON,PMT$,I$,BAL$:IF P=80 THEN GOSUB 1340
970 MON=MON+1:B=B+VAL(I$):C=C+PMT:IF MON=13 THEN MON=1
980 IF INT(X/12)=X/12 OR X=NUM THEN 1000
990 NEXT X
1000 ? :? "INTEREST=";B;"  PAYMENTS=";C:IF P=80 THEN ? #4;CHR$(13);"INTEREST=";B;"  PAYMENTS=";C:REM PRINTS TOTALS
1010 IF X=NUM THEN GOSUB 1050:GOTO 80
1020 GOSUB 1030:GOTO 990
1030 ? "↰":? :? "MONTH","PAYMENT","INTEREST","AMOUNT":? :IF P=80 THEN GOSUB 1330
1035 RETURN
1040 REM *** PAUSE ROUTINES ***
1050 GET #1,A:IF A=255 THEN 1050
1060 IF A=155 THEN 80
1070 IF A<48 OR A>89 THEN 1370
1080 RETURN
1090 POSITION 2,22:? MSG$:? "  PRESS ANY KEY TO CONTINUE ":GET #1,N:IF N=255 THEN 1090
1100 IF N=155 THEN 80
1110 RETURN
1120 REM ***INPUTS***
1130 ? "↰":? :? "INPUT STARTING YEAR (PRESS 'RETURN' FOR 1989)";:INPUT YEAR$:IF LEN(YEAR$)=0 THEN YEAR$="1989"
1140 IF VAL(YEAR$)>2050 OR VAL(YEAR$)<1970 THEN 1370
1150 ? :? "ENTER STARTING MONEY AMOUNT";:GOSUB 1460:MONEY$=MNY$:MONEY=VAL(MONEY$)
1160 ? :? "ENTER INTEREST RATE";:INPUT APR:IN=APR/1200:RETURN
1170 ? :? "ENTER NUMBER OF PAYMENTS";:INPUT NUM:RETURN
1180 ? :? "ENTER MONTHLY PAYMENT";
1190 GOSUB 1390:PMT$=MNY$:PMT=VAL(PMT$):RETURN
1200 ? :? "ENTER # OF COMPOUNDING PERIODS/YEAR";:INPUT CP:IN=APR/(100*CP)
1210 ? :? "HOW MANY YEARS TO COMPOUND";:INPUT NUM:RETURN
1220 ? :? "ENTER STARTING MONTH (1-12)";:INPUT MON
1230 D$=STR$(MON):IF MON<1 OR MON>13 THEN 1370
1240 MON$="  ":MON$(3-LEN(D$),2)=D$:RETURN
1250 ? :? " HARDCOPY Y/N ":GOSUB 1040:IF A<>89 THEN 1300
1260 REM *** PRINTER SUBROUTINE***
1270 ? "↰":? :? "IF PRINTER IS READY PRESS 'P'":GET #1,P
1280 IF P<>80 THEN 1370
1290 CLOSE #4:OPEN #4,8,0,"P":? #4;CHR$(27);"@";CHR$(27);"l";CHR$(15);CHR$(27);"Q";CHR$(55)
1300 RETURN :REM ABOVE SETS PRINTER TO DEFAULT, SETS LEFT MARGIN AT 15 AND RIGHT MARGIN AT 55
1310 ? #4;CHR$(13);CHR$(13):REM THIS LINE JUST ADDS TWO 'RETURNS'
1320 ? #4;HEAD$;MONEY;CHR$(13);CHR$(13);HEAD2$;CHR$(13):RETURN :REM THIS ADDS THE HEADINGS WITH RETURNS
1330 ? #4;CHR$(13);"MONTH","PAYMENT","INTEREST","AMOUNT";CHR$(13):RETURN
1340 ? #4;MON,PMT$,I$,BAL$:RETURN :REM THESE TWO LINES PRINT THE HEADING,'RETURNS',& EACH LINE OF THE SAVINGS PROGRAM
1350 ? #4;LINE$:RETURN
1360 ? #4;CHR$(13);YEAR$;" INTEREST=";C;"    PRIN=";B:? #4;"CHARGES= ";M:RETURN :REM PRINTS TOTALS AT BOTTOM OF PAGE
1370 REM *** ERROR ROUTINE ***
1380 ? "↰":? :? "INPUT MISTAKE - START OVER":FOR I=1 TO 100:NEXT I:GOTO 80
1390 REM ***CONVERT ROUTINE ***
1400 INPUT AMT
1410 AMT$=STR$(INT(AMT*100)):IF LEN(AMT$)>7 THEN 1480
1420 IF AMT=0 THEN MNY$="    0.00":GOTO 1530
1430 D=LEN(AMT$):DOL=INT(AMT)
1440 MNY$="   0.00":MNY$(6,7)=AMT$(D-1,D):IF INT(AMT)=0 THEN 1530
1450 MNY$(7-D,4)=STR$(DOL):GOTO 1530
1460 REM *** CONVERT LARGE ***
1470 INPUT AMT
1480 AMT$=STR$(INT(AMT*100))
1490 IF AMT=0 THEN MNY$="      0.00":GOTO 1530
1500 D=LEN(AMT$):DOL=INT(AMT)
1510 MNY$="      0.00":MNY$(9,10)=AMT$(D-1,D):IF INT(AMT)=0 THEN MNY$(7,8)="0.":GOTO 1530
1520 MNY$(10-D,7)=STR$(DOL)
1530 RETURN