Beam Me Up (BEAM.BAS)
Beam Me Up, game by Steven Ginzburg, 168
Description
Beam Me Up, game by Steven Ginzburg, 168
From the Antic disk of Antic: October/November 1989 - Vol. 8 No. 6 — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 5.5 KB
- Dialect
- Atari BASIC
- Lines
- 139
- Variables
A$,PM,DL,I,X,Y,A,VVTP,O,J,MAIN$,B,Z,NX,S,L,N,FN$,Q,R,MX,MY,M,SC,ANS,NOT
BASIC listing (139 lines)
0 REM BEAM ME UP
1 REM BY STEVEN GINZBURG
2 REM (C)1989 ANTIC PUBLISHING INC.
4 DIM A$(128),FN$(15)
5 N=1:GOTO 100
7 A$(Y,Y+9)="♥♥♥♥♥♥♥♥":RETURN
10 GRAPHICS 2:POKE 559,46:POKE 710,0:POKE 53256,0:REM TITLE SCREEN
12 ? :? :? :? :? "↑ ────────────────────────────────────";
15 POKE 752,1:POKE 709,15:POKE 708,207
17 FOR I=0 TO 10
20 ? #6;" ↑BEAM← ↑ME UP←"
22 NEXT I
23 POKE 53256,0
25 POKE 53248,120
30 A$(99,106)="$<┴◀┴<$$"
40 Y=100:GOSUB 900
50 ? :? "by Steve Ginzburg":? :? " PRESS START"
60 POKE 16,64:POKE 53774,64:REM DISBLE BREAK KEY
70 IF PEEK(53279)=7 THEN 70:REM WAIT FOR START
80 RETURN
100 PM=PEEK(106)-36
105 GOSUB 750
110 GOSUB 600
120 L=0:REM INITIALIZE PM GRAPHICS
170 POKE 623,2
180 POKE 704,10
190 POKE 53277,3
200 POKE 54279,PM
205 GOSUB 10
210 A$(1)="♥":A$(128)="♥"
220 A$(2)=A$
230 POKE 19,0:POKE 20,0
250 GOSUB 500:REM DRAW SCREEN
260 POKE 559,46
300 POKE 53278,X:POKE 53248,X:REM MOVE ROUTINE
302 POKE 77,0:REM STOP ATTRACT MODE
305 POKE 710,RND(0)*255
310 A$(Y,Y+7)="$<┴◀┴<$$":REM PUT CHARACTER ON SCREEN
320 IF X<46 THEN 210
330 TRAP 700:MX=X-44:MY=Y*2-23
332 M=(MY*160+MX)/4:R=(M-INT(M))*4:M=INT(M)+SC:B=PEEK(M)
334 POKE 203,R:POKE 205,B
336 Z=USR(ADR(")@┐L%KI♥p◣FLFL8i├┴♣r%L%M┐L)┘8eKI♥p▗FLFLfK┴♣nh◆")):REM ML ROUTINE - BIT DECODER
338 Z=PEEK(204):TRAP 40000
340 IF PEEK(53279)=3 OR PEEK(19)=19 THEN GOSUB 900:GOTO 300:REM IF TIME OUT OR OPTION HIT
350 IF Z=1 AND A=0 THEN 370
360 IF Z=1 THEN GOSUB 7:Y=Y-2:GOTO 300
370 POKE 53278,X
380 FOR I=0 TO 5:NEXT I:A=PEEK(53252)
400 IF A=0 AND (J>=7 OR J=0) THEN GOSUB 7:B=B+1:Y=Y+1+(B>15):SOUND 1,0,0,0:SOUND 0,Y,10,4:J=0:GOTO 300
402 B=0:IF J>=7 THEN J=0
405 IF A>3 AND A<7 THEN 700
410 IF STRIG(0)=0 THEN GOSUB 7:J=J+1:IF J<4 THEN Y=Y-2:SOUND 1,200-J*4,10,4
415 IF STRIG(0)=1 THEN J=0:SOUND 1,0,0,0
420 S=STICK(0):IF S=15 THEN 445:REM READ JOYSTICK AND ADJUST X AND Y
425 GOSUB 7
430 X=X+2*(S<8)-2*(S>8 AND S<13):IF NOT J THEN SOUND 0,100,16,8
435 IF A<>2 AND A<>3 AND A<>5 THEN 445
440 Y=Y+3*(INT(S/4)*4=S-1)-2*(INT(S/2)=S/2):IF NOT J THEN SOUND 0,175-Y,10,8
445 SOUND 0,0,0,0
450 GOTO 300
500 GRAPHICS 8+16:DL=PEEK(560)+256*PEEK(561):POKE 559,0:POKE 53248,0:REM LOAD SCREEN
502 FOR I=0 TO 199
503 IF PEEK(DL+I)=15 OR PEEK(DL+I)=15+64 THEN POKE DL+I,PEEK(DL+I)-1
504 NEXT I:SC=PEEK(88)+256*PEEK(89)
505 POKE 559,0
510 L=L+1
515 TRAP 1000:IF L=10 THEN 1000
520 FN$="D:LEVEL .PIC"
530 FN$(8,8)=STR$(L)
540 OPEN #1,4,0,FN$
545 TRAP 40000
550 A=USR(ADR(MAIN$))
560 X=195:Y=104
565 CLOSE #1
570 POKE 559,46
580 RETURN
600 REM START STRING USEAGE A$
610 VVTP=PEEK(134)+256*PEEK(135)
620 O=(PM*256+512)-PEEK(140)-PEEK(141)*256
630 POKE VVTP+3,INT(O/256)
640 POKE VVTP+2,O-INT(O/256)*256
645 A$(1)="♥":A$(128)="♥":REM CLEAR A$
647 A$(2)=A$
650 RETURN
700 SOUND 1,0,0,0:Y=1:REM DEATH ROUTINE
705 FOR I=1 TO 35
710 R=RND(0):POKE 704,R*255
720 SOUND 0,R*255,16,8
722 ON Y GOSUB 725,726,727
723 GOTO 730
725 POKE 53248,X:POKE 53256,0:Y=2:RETURN
726 POKE 53248,X-4:POKE 53256,1:Y=3:RETURN
727 POKE 53248,X-12:POKE 53256,3:Y=1:RETURN
730 NEXT I
735 SOUND 0,0,0,0
745 GOTO 110
750 DIM MAIN$(342):REM ML ROUTINE TO LOAD SCREEN
760 RESTORE 800
770 FOR A=1536 TO 1556
780 READ B:POKE A,B
790 NEXT A
800 DATA 162,16,169,1,157,72,3,169,0,157,73,3,32,86,228,48,1,96,104,104,96
810 MAIN$="h"♣)╲↓B┘)h↓D┘)♥↓E┘)├↓H┘)♥↓I┘)♥┐◆ ♥╱%◆I╲p▔I▔p♣I└p<f◆┴♣j"
820 MAIN$(55)="%h┐j┴♣t%h▔D▕f◆ ♥╱%h▔E▕f◆ ♥╱%h▔F▕f◆ ♥╱%h▔G▕f◆ ♥╱%h▔H▕┴♣D)♥┐l┐"
830 MAIN$(115)="f%X┐◆┐d%Y┐a┐e ♥╱@◢p^)♥┐c%h)♥┐k%h)▶┐bP▂ ♥╱%h┐c ♥╱%h┐bFb%kP↑ ♥"
840 MAIN$(175)="╱%h┐i┴♣/Fb)▶EbPuFc)▶EcPmp7 ♥╱%h┐i┴♣┼Fb)▶EbPnFc)▶EcPfp"
850 MAIN$(228)=CHR$(155)
860 MAIN$(229)="◆)▕EjpRpI%i ♥┌◆┴)Pe◆┐◆)♥ea┐aff)◆EfP/)├ElP┴┴)├ed┐d┐◆)♥┐l┐fee┐e┐"
870 MAIN$(291)="a┴♣┌fl┴)(ed┐◆)♥┐fee┐a%kp0P▄%i ♥┌◆┴)├e◆┐◆)♥ea┐a%kp┬Pe"
880 RETURN
900 FOR I=1+20*( NOT N) TO Y+7:REM BEAM ROUTINE
905 SOUND 1,0,0,0
910 A=USR(ADR("h-◣R▔@▕◆")):REM GET RANDOM NUMBER AND PUT IN 704
920 A$(I,I)=CHR$(PEEK(704))
925 SOUND 0,I,12,10
930 NEXT I
940 SOUND 0,0,0,0:POKE 704,10
950 FOR I=Y+7 TO 1 STEP -1
960 A$(I,I)="♥"
970 NEXT I
980 POKE 704,10
990 X=195:Y=105:N=1:POKE 19,0:RETURN
1000 GRAPHICS 0:REM WIN GAME ROUTINE
1010 POKE 559,0:POKE 712,PEEK(710)
1015 POKE 752,1
1020 ? " ╱▔▔▔▔▔▔▔▔ ▔▔ ▔▔▔▔▔▔▔▔▔╲ "
1030 ? " ◢◣▂ ▂▂▂▂▂▂▂▂ ▂▂▂▂▂▂▂▂▂ ▂◢◣"
1035 ? " ◢◣▔ ────────┐ ┌───────── ▔◢◣ "
1040 POKE 559,46:Y=100:A$(100)="$<┴◀┴<$$"
1045 POSITION 2,22:? " ─────────────────YOU─ESCAPED──"
1050 POKE 53248,120:N=1:GOSUB 900
1055 POSITION 2,22:? "↑"
1060 POSITION 2,0:X=100
1065 FOR N=0 TO 3
1070 SOUND 0,X,8,8
1080 ? "↑";
1090 FOR Y=0 TO 100:NEXT Y:X=X-20:NEXT N
1100 N=0:GOTO 110
