The Joystick Tester (JOYTEST.BAS)
The Joystick Tester by Kevin C. Gevatosky, 69
Description
The Joystick Tester by Kevin C. Gevatosky, 69
From the Antic disk of September 1989 (Vol. 8 No. 5) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 8.3 KB
- Dialect
- Atari BASIC
- Lines
- 248
- Variables
GRID(,RESPONSE(,RTIME(,DBTIME,INIT,RAMSET,ROMSET,Y,X,CHAR,K,TEST,CYCLES,CNT,MISS,DMISS,TTIME,SPNEW,SPOLD,STK,XP,TEMP
BASIC listing (248 lines)
100 REM *************************
110 REM * THE JOYSTICK TESTER *
120 REM * BY KEVIN C. GEVATOSKY *
130 REM * COPYRIGHT 1989 *
140 REM * ANTIC PUBLISHING *
150 REM *************************
160 POKE 106,PEEK(106)-2
170 DIM GRID(101),RESPONSE(101),RTIME(101)
180 DBTIME=10
190 GRAPHICS 2+16:SETCOLOR 4,5,0
200 ? #6;" *****************"
210 ? #6;" *JOysTIck TEstER*"
220 ? #6;" *****************"
230 ? #6:? #6;" jOYSTICK TESTER"
240 ? #6:? #6;" pADDLE TESTER"
250 ? #6:? #6;" eVALUATOR"
260 IF INIT THEN 470
270 REM
280 REM *** SETUP A RAM CHAR. SET ***
290 REM
300 INIT=1:POSITION 2,11:? #6;"(initializing)"
310 RAMSET=PEEK(106)*256
320 ROMSET=226*256
330 FOR Y=1 TO 64
340 FOR X=0 TO 7
350 CHAR=PEEK(ROMSET+X)
360 POKE RAMSET+X,CHAR
370 NEXT X
380 ROMSET=ROMSET+8:RAMSET=RAMSET+8
390 NEXT Y
400 RAMSET=PEEK(106)*256
410 FOR X=0 TO 7:POKE RAMSET+X,0:NEXT X
420 FOR X=0 TO 7:POKE RAMSET+(16*8)+X,255:NEXT X
430 POSITION 2,11:? #6;" "
440 REM
450 REM *** GET KEYBOARD RESPONSE ***
460 REM
470 OPEN #1,4,0,"K:":GET #1,K:CLOSE #1
480 IF K>96 THEN K=K-32
490 IF K=ASC("J") THEN TEST=1:GOTO 590
500 IF K<>ASC("E") THEN 570
510 GRAPHICS 0:POKE 752,1:? :? :? "Enter a number from 10 to 100 for the"
520 ? "number of response cycles.":?
530 TRAP 530:INPUT CYCLES:IF CYCLES<10 OR CYCLES>100 THEN ? :? "A number from 10 to 100 please!":GOTO 530
540 TRAP 32000
550 ? :GOSUB 2550
560 CNT=0:MISS=0:DMISS=0:TTIME=0:TEST=0:GOTO 590
570 IF K=ASC("P") THEN GOTO 2160
580 GOTO 470
590 GRAPHICS 16+2
600 POKE 756,PEEK(106)
610 IF NOT TEST THEN 650
620 SETCOLOR 4,7,4
630 POSITION 1,0:? #6;"joystick test grid"
640 GOTO 670
650 SETCOLOR 4,10,2
660 POSITION 3,0:? #6;"evaluator grid"
670 POSITION 5,1:? #6;"┌──┬──┬──┐"
680 POSITION 5,2:? #6;"| | | |"
690 POSITION 5,3:? #6;"| | | |"
700 POSITION 5,4:? #6;"├──┼──┼──┤"
710 POSITION 5,5:? #6;"| | | |"
720 POSITION 5,6:? #6;"| | | |"
730 POSITION 5,7:? #6;"├──┼──┼──┤"
740 POSITION 5,8:? #6;"| | | |"
750 POSITION 5,9:? #6;"| | | |"
760 POSITION 5,10:? #6;"└──┴──┴──┘"
770 POSITION 0,11:? #6;"press start for menu";
780 REM
790 REM *** GRID POSITION SELECTOR ***
800 REM
810 IF TEST THEN SPNEW=STICK(0):GOTO 840
820 SPNEW=INT(RND(0)*14+1)
830 IF SPNEW=SPOLD THEN GOTO 820
840 ON SPNEW GOTO 820,820,820,820,860,980,1100,820,1220,1340,1460,820,1580,1700,1820
850 REM
860 REM *** LOWER-RIGHT ***
870 POSITION 12,8:? #6;"♣♣";
880 POSITION 12,9:? #6;"♣♣";
890 GOSUB 1950
900 SETCOLOR 3,4,6+6*(1-STRIG(0))
910 IF NOT TEST THEN 940
920 IF STICK(0)=5 THEN 900
930 GOTO 950
940 GOSUB 2010
950 POSITION 12,8:? #6;" ";
960 POSITION 12,9:? #6;" ";
970 GOTO 810
980 REM *** UPPER-RIGHT ***
990 POSITION 12,2:? #6;"♣♣";
1000 POSITION 12,3:? #6;"♣♣";
1010 GOSUB 1950
1020 SETCOLOR 3,4,6+6*(1-STRIG(0))
1030 IF NOT TEST THEN 1060
1040 IF STICK(0)=6 THEN 1020
1050 GOTO 1070
1060 GOSUB 2010
1070 POSITION 12,2:? #6;" ";
1080 POSITION 12,3:? #6;" ";
1090 GOTO 810
1100 REM *** RIGHT ***
1110 POSITION 12,5:? #6;"♣♣";
1120 POSITION 12,6:? #6;"♣♣";
1130 GOSUB 1950
1140 SETCOLOR 3,4,6+6*(1-STRIG(0))
1150 IF NOT TEST THEN 1180
1160 IF STICK(0)=7 THEN 1140
1170 GOTO 1190
1180 GOSUB 2010
1190 POSITION 12,5:? #6;" ";
1200 POSITION 12,6:? #6;" ";
1210 GOTO 810
1220 REM *** LOWER-LEFT ***
1230 POSITION 6,8:? #6;"♣♣";
1240 POSITION 6,9:? #6;"♣♣";
1250 GOSUB 1950
1260 SETCOLOR 3,4,6+6*(1-STRIG(0))
1270 IF NOT TEST THEN 1300
1280 IF STICK(0)=9 THEN 1260
1290 GOTO 1310
1300 GOSUB 2010
1310 POSITION 6,8:? #6;" ";
1320 POSITION 6,9:? #6;" ";
1330 GOTO 810
1340 REM *** UPPER-LEFT ***
1350 POSITION 6,2:? #6;"♣♣";
1360 POSITION 6,3:? #6;"♣♣";
1370 GOSUB 1950
1380 SETCOLOR 3,4,6+6*(1-STRIG(0))
1390 IF NOT TEST THEN 1420
1400 IF STICK(0)=10 THEN 1380
1410 GOTO 1430
1420 GOSUB 2010
1430 POSITION 6,2:? #6;" ";
1440 POSITION 6,3:? #6;" ";
1450 GOTO 810
1460 REM *** LEFT ***
1470 POSITION 6,5:? #6;"♣♣";
1480 POSITION 6,6:? #6;"♣♣";
1490 GOSUB 1950
1500 SETCOLOR 3,4,6+6*(1-STRIG(0))
1510 IF NOT TEST THEN 1540
1520 IF STICK(0)=11 THEN 1500
1530 GOTO 1550
1540 GOSUB 2010
1550 POSITION 6,5:? #6;" ";
1560 POSITION 6,6:? #6;" ";
1570 GOTO 810
1580 REM *** DOWN ***
1590 POSITION 9,8:? #6;"♣♣";
1600 POSITION 9,9:? #6;"♣♣";
1610 GOSUB 1950
1620 SETCOLOR 3,4,6+6*(1-STRIG(0))
1630 IF NOT TEST THEN 1660
1640 IF STICK(0)=13 THEN 1620
1650 GOTO 1670
1660 GOSUB 2010
1670 POSITION 9,8:? #6;" ";
1680 POSITION 9,9:? #6;" ";
1690 GOTO 810
1700 REM *** UP ***
1710 POSITION 9,2:? #6;"♣♣";
1720 POSITION 9,3:? #6;"♣♣";
1730 GOSUB 1950
1740 SETCOLOR 3,4,6+6*(1-STRIG(0))
1750 IF NOT TEST THEN 1780
1760 IF STICK(0)=14 THEN 1740
1770 GOTO 1790
1780 GOSUB 2010
1790 POSITION 9,2:? #6;" ";
1800 POSITION 9,3:? #6;" ";
1810 GOTO 810
1820 REM *** NEUTRAL ***
1830 POSITION 9,5:? #6;"♣♣";
1840 POSITION 9,6:? #6;"♣♣";
1850 SETCOLOR 3,4,6+6*(1-STRIG(0))
1860 IF PEEK(53279)=6 THEN 190
1870 IF STICK(0)=15 THEN 1850
1880 POSITION 9,5:? #6;" ";
1890 POSITION 9,6:? #6;" ";
1900 SETCOLOR 3,4,6
1910 GOTO 810
1920 REM
1930 REM *** BEEP & START TIMER ***
1940 REM
1950 IF NOT TEST THEN CNT=CNT+1:GRID(CNT)=SPNEW:IF CNT>CYCLES THEN 2340
1960 SOUND 0,28,10,15:FOR X=0 TO 3:NEXT X:SOUND 0,0,0,0:POKE 19,0:POKE 20,0:RETURN
1970 REM
1980 REM *** GET STICK RESPONSE ***
1990 REM
2000 IF PEEK(53279)=6 THEN 190
2010 IF STICK(0)=15 THEN 2000
2020 STK=STICK(0):REM READ & DEBOUNCE
2030 FOR X=1 TO DBTIME
2040 IF STICK(0)<>STK THEN 2020
2050 NEXT X
2060 RTIME(CNT)=PEEK(19)*256+PEEK(20)
2070 IF STK<>SPNEW THEN SOUND 0,40,6,15:FOR X=1 TO 5:NEXT X:GOTO 2090
2080 SOUND 0,30,10,15:FOR X=1 TO 3:NEXT X
2090 SPOLD=SPNEW:RESPONSE(CNT)=STK
2100 IF STICK(0)<>15 THEN 2100
2110 SOUND 0,0,0,0
2120 FOR X=1 TO 20:NEXT X:RETURN
2130 REM
2140 REM *** PADDLE TESTER ***
2150 REM
2160 GRAPHICS 5:POKE 752,1:SETCOLOR 4,5,2:SETCOLOR 2,5,2
2170 POKE 656,0:POKE 657,0:? " PADDLE TESTER ";
2180 POKE 656,1:POKE 657,13:? "Yellow line ="
2190 POKE 657,13:? "Green line =";
2200 POKE 656,3:POKE 657,10:? "Press START for menu";
2210 COLOR 0:PLOT 0,13:XP=76-INT(PADDLE(0)/3):COLOR 1:DRAWTO XP,13:COLOR 0:PLOT XP,13:DRAWTO 76,13
2220 COLOR 0:PLOT 0,26:XP=76-INT(PADDLE(1)/3):COLOR 2:DRAWTO XP,26:COLOR 0:PLOT XP,26:DRAWTO 76,26
2230 POKE 656,1:POKE 657,27:? 228-PADDLE(0);" ":POKE 657,27:? 228-PADDLE(1);" ";
2240 SOUND 0,228-PADDLE(0),10,15
2250 SOUND 1,228-PADDLE(1),10,15
2260 IF NOT PTRIG(0) THEN SETCOLOR 4,2,8:GOTO 2290
2270 IF NOT PTRIG(1) THEN SETCOLOR 4,12,10:GOTO 2290
2280 SETCOLOR 4,5,2
2290 IF PEEK(53279)=6 THEN SOUND 0,0,0,0:SOUND 1,0,0,0:GOTO 190
2300 GOTO 2210
2310 REM
2320 REM *** DISPLAY RESULTS ***
2330 REM
2340 GRAPHICS 2+16
2350 ? :? "The evaluation is over. Here are the"
2360 ? "results for ";CYCLES;" iterations:"
2370 FOR X=1 TO CYCLES
2380 TEMP=GRID(X)
2390 IF RESPONSE(X)=TEMP THEN 2420
2400 MISS=MISS+1
2410 IF TEMP=5 OR TEMP=6 OR TEMP=9 OR TEMP=10 THEN DMISS=DMISS+1
2420 TTIME=TTIME+RTIME(X)
2430 NEXT X
2440 ? :? "Overall accuracy = ";INT((CYCLES-MISS)/CYCLES*100);"%"
2450 ? "Total error = ";INT(MISS/CYCLES*100);"%"
2460 ? "Horiz. & vert. error = ";INT((MISS-DMISS)/CYCLES*100);"%"
2470 ? "Diagonal error = ";INT(DMISS/CYCLES*100);"%"
2480 ? "Average response time = ";INT((TTIME/CYCLES)/60*100)/100;" seconds"
2490 GOSUB 2550
2500 GRAPHICS 0
2510 POSITION 0,0:? " INDIVIDUAL RESPONSES "
2520 ? "Cycle","Grid","Response","Time":?
2530 FOR X=1 TO CYCLES:? X,GRID(X),RESPONSE(X),INT(RTIME(X)/60*100)/100:NEXT X
2540 GOSUB 2550:GOTO 190
2550 ? :? "Press joystick TRIGGER to continue."
2560 IF STRIG(0) THEN 2560
2570 RETURN
