Customer List Manager (MANAGER.BAS)

Customer List Manager by Thomas Andrews, 88

Description

Customer List Manager by Thomas Andrews, 88

From the Antic disk of August 1989 (Vol. 8 No. 4).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 10.7 KB

Dialect
Atari BASIC
Lines
235
Variables
WON, ZERO, TEN, SIX, SIXTY, HUN, TWO, FIVE, MAX, FIND, SRCH, CHNGR, ANS$, LI(, WI$, W$, FLD$, TITLE$, FNAME$, HDG$, L$, SHIFT$, PFLG, DEV, NR, ANS, LL, OVER, LNE, J, X, YEAR, MODE, I2, I, A, DELAY, RX1, LAD1, BEGIN1, LAST1, ITEMS, B, LAD, LIADR, I1, RX2, LAD2, BEGIN2, LAST2, STRT1, FIN1, STRT2, FIN2, J1, I3, RX3, LAD3, BEGIN3, LAST3, STRT3, FIN3, K, NP, FP, LP, WP, PG, JJ
BASIC listing (235 lines)
10 REM CUSTOMER LIST MANAGER
20 REM BY THOMAS ANDREWS
30 REM (C)1989, ANTIC PUBLISHING INC.
40 WON=1:ZERO=0:TEN=10:SIX=6:SIXTY=TEN*SIX:HUN=TEN*TEN:TWO=WON+WON:FIVE=5:MAX=19000
45 REM THE FOLLOWING ML ROUTINE WAS   WRITTEN BY SCOTT SHECK IN THE DEC 1984 ANTIC
50 FIND=ADR("hh┐├h┐♥h┐┘h┐▕)├┐T ♥┤U1♥♣─F▕P▂%┘P◢H1♥♣♠┤├◆F┘fTP▕fUf♥P◆f├P\")
55 REM
60 SRCH=ADR("hh┐Lh┐Khh┐Mh┐Oh┐Nh┐Qh┐P)♥┐T┐U%Mp?%QP╱%PEM♣5 ♥1KI?p&)▶QNp IA♣▝I[0╲┴i QNp┌%PP▕FQFPfNP▕fO┴♣HHDMPOfT◆")
65 CHNGR=ADR("hh┐Lh┐Kh┐Nh┐M ♥1K▗♥┌K%MP▕FNFMP┐%NP├◆fKP▕fL)▶1K80d")
70 DIM ANS$(TEN),LI(HUN),WI$(HUN),W$(SIXTY*TEN),FLD$(SIXTY),TITLE$(14),FNAME$(SIXTY),HDG$(40)
80 DIM L$(MAX),SHIFT$(135)
85 SHIFT$(WON)="hh┐Lh┐Kh┐Ph┐Oh┐U┐Nh┐T┐MP▕FNFM ♥"├8%KeO┐Q%LeP┐QpU0␛h┴%KeM┐K%LeN┐L┴%OeM┐O%PeN"
86 SHIFT$(76)="┐P1K┌O%TP▕FUFTP┤%Up&◆▕p▂fKP▕fLfOP◆fPP\%KP▕FLFK%OP▕FPFOPJpH◆"
90 FNAME$="NAME :PHONE:ADDR.:TYPE :NOTES:":OPEN #TWO,4,ZERO,"K:":OPEN #3,13,ZERO,"E:"
100 PRINT "↰":POKE 710,198:POKE 709,ZERO:POSITION SIX,ZERO:PRINT "  CUSTOMER LIST MANAGER ↓":TRAP 25000
110 PRINT "A. START NEW LIST↓":PRINT "B. ADD TO LIST↓":PFLG=ZERO:DEV=ZERO:CLOSE #WON
120 PRINT "C. LOAD LIST FROM DISK↓":PRINT "D. EDIT/UPDATE LIST↓"
130 PRINT "E. SAVE LIST TO DISK↓":PRINT "F. SORT LIST↓":PRINT "G. PRINT/DISPLAY LIST↓"
140 PRINT "H. CHANGE LIST TITLE↓":PRINT "I. LOAD EDIT OR WORD PROCESSOR FILE"
180 GOSUB 20000:IF NR=ZERO THEN IF  NOT ((ANS=WON) OR (ANS=3) OR (ANS=9)) THEN 100
185 ON ANS GOSUB 200,1000,2000,3000,4000,5000,6000,8000,9000
190 GOTO 100
200 HDG$="↰CREATE NEW LIST":GOSUB 14000:POSITION TWO,SIX:GOSUB 20020
210 L$="":NR=ZERO:LL=WON:HDG$(17)=" ITEM #":GOTO 1005
1000 HDG$="↰ADD TO PRESENT LIST ":GOSUB 14000:HDG$(21)=" ITEM #"
1005 IF NR=HUN THEN PRINT HDG$:POSITION TWO,TEN:PRINT "THIS LIST IS FULL!!":GOSUB 23000:RETURN
1006 OVER=MAX-LL:IF OVER<SIX*HUN THEN PRINT HDG$:POSITION TWO,TEN:PRINT "MEMORY SPACE RUNNING LOW":GOSUB 23000
1007 ? HDG$;NR+WON:POKE 82,SIX:? :W$="":LNE=PEEK(84):POKE 702,ZERO
1010 FOR J=WON TO TEN:POKE 85,ZERO:GOSUB 16000:POKE 764,255:INPUT #16,FLD$
1015 IF FLD$="" THEN FLD$=" "
1020 POKE 84,LNE:PRINT "↑";FLD$:X=USR(CHNGR,ADR(FLD$),LEN(FLD$))
1030 W$(LEN(W$)+WON)=FLD$:LNE=LNE+TWO:POKE 84,LNE:NEXT J:POKE 82,TWO:POKE 702,64
1033 IF LEN(W$)>OVER THEN PRINT HDG$:POSITION TWO,TEN:PRINT "THIS ITEM DOES NOT FIT!":GOSUB 23000:RETURN
1035 L$(LL)=W$:NR=NR+WON:LI(NR)=LL:POSITION TWO,22
1040 LL=LEN(L$)+WON:? "PRESS OPTION FOR NEXT ITEM; START FOR MAIN MENU";
1050 ANS=PEEK(53279):IF ANS=3 THEN 1005
1060 IF ANS<>6 THEN 1050
1070 L$(LL)=" ":RETURN
2000 HDG$="↰LOAD LIST FROM DISK":PRINT HDG$:GOSUB 21000
2010 OPEN #WON,4,ZERO,W$:INPUT #WON;TITLE$:? :? TITLE$;"   ";
2012 INPUT #WON,FLD$:YEAR=VAL(FLD$):POKE 752,WON:PRINT YEAR
2015 L$="":LL=WON:NR=ZERO:TRAP 2040:GOSUB 20040
2020 W$="":FOR J=WON TO TEN:INPUT #WON,FLD$:W$(LEN(W$)+WON)=FLD$:NEXT J
2025 IF LL+LEN(W$)>MAX THEN 2040
2030 L$(LL)=W$:NR=NR+WON:LI(NR)=LL:LL=LEN(L$)+WON:IF NR<HUN THEN 2020
2040 POKE 752,ZERO:TRAP 25000:L$(LL)=" ":CLOSE #WON:PRINT "↓↓THERE ARE ";NR;" ITEMS ON THIS LIST"
2050 GOSUB 23000:RETURN
3000 HDG$="↰EDIT/UPDATE LIST":PRINT HDG$:POSITION TWO,SIX:PRINT "WHICH FUNCTION?↓↓"
3010 PRINT "A. EDIT AND UPDATE 1 YEAR↓":PRINT "B. EDIT ONLY↓"
3015 PRINT "C. UPDATE ONLY↓":PRINT "D. RETURN TO MAIN MENU"
3020 GOSUB 20000:MODE=ANS:IF MODE=WON THEN GOSUB 15040:YEAR=YEAR+WON:GOSUB 20040
3025 IF MODE=3 THEN GOSUB 21200:YEAR=YEAR+WON:GOSUB 20040
3030 ON MODE GOTO 3050,3040,3050,20180:GOTO 3000
3040 PRINT HDG$:GOSUB 15000:TRAP 25000
3050 OPEN #WON,8,ZERO,"D:EDITLIST.DAT":? #WON;TITLE$:? #WON;YEAR
3051 I2=ZERO:FOR I=WON TO NR:IF WI$(I,I)="♥" THEN 3240
3053 I2=I2+WON:POKE 82,SIX:GOSUB 20100
3055 POKE 764,255:POSITION ZERO,22:POKE 82,ZERO:? "CTRL-A=NEXT ITEM   CTRL-D=DELETE ITEM"
3060 PRINT "CTRL-M=MAIN MENU   ESC=REDO THIS ITEM";:POSITION SIX,TWO:PRINT "→←";:POKE 82,SIX:POKE 702,ZERO
3070 GET #TWO,A:IF A=125 OR A=156 OR A=157 OR A=254 OR A=255 THEN 3070
3075 IF A=155 THEN POKE 85,SIX:PUT #3,29:GOTO 3070
3080 IF A=WON OR A=13 OR A=4 THEN 3100
3085 IF A=27 THEN I=I-WON:I2=I2-WON:NEXT I:RETURN
3090 PUT #3,A:GOTO 3070
3100 IF A<>4 THEN 3200
3105 SOUND ZERO,SIXTY,TEN,TEN:FOR DELAY=WON TO SIXTY:NEXT DELAY:SOUND ZERO,ZERO,ZERO,ZERO
3110 POKE 82,ZERO:POKE 712,52:POSITION 2,22:PRINT "↑↑ARE YOU SURE? (Y/N)";:INPUT ANS$
3120 POKE 712,ZERO:IF ANS$="" THEN 3126
3125 IF ANS$(WON,WON)="Y" OR ANS$(WON,WON)="y" THEN 3230
3126 I=I-WON:I2=I2-WON:NEXT I:RETURN
3200 LNE=TWO:POKE 82,SIX:POKE 85,SIX:FOR J=WON TO TEN:POKE 84,LNE:INPUT #3,FLD$:IF FLD$="" THEN FLD$=" "
3210 X=USR(CHNGR,ADR(FLD$),LEN(FLD$)):PRINT #WON;FLD$:LNE=LNE+TWO:NEXT J
3230 POKE 702,64:POKE 82,TWO:GOTO 3255
3240 POKE 752,WON:PRINT HDG$:POSITION TEN,TEN:PRINT "PROCESSING ITEM ";I
3245 RX1=LI(I)-WON:LAD1=RX1+ADR(L$):FOR J=WON TO TEN:BEGIN1=USR(FIND,LAD1,J)+RX1:LAST1=PEEK(WON)+BEGIN1-WON
3246 IF J=SIX THEN IF MODE=3 THEN NEXT J
3250 PRINT #WON;L$(BEGIN1,LAST1):NEXT J:IF MODE=3 THEN PRINT #WON;" "
3253 GOTO 3260
3255 IF MODE=WON AND A=13 AND I2<ITEMS THEN 3380
3256 IF A=13 AND I<>NR THEN GOSUB 21200
3260 NEXT I:POKE 752,ZERO:CLOSE #WON
3270 TRAP 25000:W$="D:EDITLIST.DAT":PRINT HDG$:GOTO 2010
3380 PRINT "↰":POSITION TWO,TEN:PRINT "THE ENTIRE LIST MUST BE REVIEWED WHEN UPDATING"
3390 GOSUB 23000:GOTO 3260
4000 HDG$="↰SAVE LIST TO DISK":PRINT HDG$:GOSUB 15000:PRINT HDG$:GOSUB 21000:TRAP 25000
4010 OPEN #WON,8,ZERO,W$:? #WON;TITLE$:? #WON;STR$(YEAR)
4020 FOR I=WON TO NR:IF WI$(I,I)="♥" THEN 4050
4030 RX1=LI(I)-WON:LAD1=RX1+ADR(L$):FOR J=WON TO TEN:BEGIN1=USR(FIND,LAD1,J)+RX1:LAST1=PEEK(WON)+BEGIN1-WON
4040 PRINT #WON;L$(BEGIN1,LAST1):NEXT J
4050 NEXT I:CLOSE #WON:RETURN
5000 HDG$="↰SORT LIST":PRINT HDG$:PRINT TITLE$;"   ";YEAR
5010 I=WON:GOSUB 20150:A=ANS:IF A=TEN+WON THEN RETURN
5020 I=TWO:GOSUB 20150:B=ANS:IF B=TEN+WON THEN RETURN
5025 PRINT HDG$:POSITION TWO,TEN:PRINT "CHECKING ITEM # ":POKE 752,WON
5030 LAD=ADR(L$):LIADR=ADR(ANS$)+TEN+SIX:FOR I=NR TO TWO STEP -WON:I1=I:I2=I-WON
5035 POSITION 19,TEN:PRINT I;"  "
5060 RX1=LI(I1)-WON:LAD1=LAD+RX1
5065 BEGIN1=USR(FIND,LAD1,A)+RX1:LAST1=PEEK(WON)+BEGIN1-WON
5090 RX2=LI(I2)-WON:LAD2=LAD+RX2
5100 BEGIN2=USR(FIND,LAD2,A)+RX2:LAST2=PEEK(WON)+BEGIN2-WON
5130 IF L$(BEGIN1,LAST1)>L$(BEGIN2,LAST2) THEN 5500
5135 IF L$(BEGIN1,LAST1)<L$(BEGIN2,LAST2) THEN 5160
5140 STRT1=USR(FIND,LAD1,B)+RX1:FIN1=PEEK(WON)+STRT1-WON
5145 STRT2=USR(FIND,LAD2,B)+RX2:FIN2=PEEK(WON)+STRT2-WON
5150 IF L$(STRT1,FIN1)>=L$(STRT2,FIN2) THEN 5500
5160 FOR J=I TO NR:J1=J:IF J=NR THEN 5260
5190 I3=J+WON:RX3=LI(I3)-WON
5200 LAD3=LAD+RX3:BEGIN3=USR(FIND,LAD3,A)+RX3:LAST3=PEEK(WON)+BEGIN3-WON
5230 IF L$(BEGIN2,LAST2)<L$(BEGIN3,LAST3) THEN J=NR
5235 IF L$(BEGIN2,LAST2)<>L$(BEGIN3,LAST3) THEN 5260
5240 STRT3=USR(FIND,LAD3,B)+RX3:FIN3=PEEK(WON)+STRT3-WON
5245 STRT2=USR(FIND,LAD2,B)+RX2:FIN2=PEEK(WON)+STRT2-WON
5250 IF L$(STRT2,FIN2)<=L$(STRT3,FIN3) THEN J=NR
5260 NEXT J
5290 K=(J1-I2)*SIX:X=USR(ADR(SHIFT$),LIADR+(I1-WON)*SIX,LIADR+(I2-WON)*SIX,K):LI(J1)=RX2+WON
5500 NEXT I:POKE 752,ZERO:RETURN
6000 HDG$="↰PRINT/DISPLAY LIST"
6005 PRINT HDG$:POSITION TWO,SIX:PRINT "DISPLAY DEVICE?↓↓"
6010 PRINT "A. SCREEN↓":PRINT "B. PRINTER↓":? "C. WORD PROCESSOR FILE↓":PRINT "D. RETURN TO MAIN MENU"
6020 GOSUB 20000:ON ANS GOTO 6030,6100,6400,21020:GOTO 6005
6030 MODE=TWO:HDG$="↰DISPLAY LIST":GOSUB 15000:I2=ZERO
6035 FOR I=WON TO NR:IF WI$(I,I)="♥" THEN 6090
6037 POKE 82,SIX:LNE=TWO:I2=I2+WON:GOSUB 20100
6040 POKE 82,TWO:POSITION TWO,22:PRINT "OPTION=FORWARD SELECT=BACK START=MENU";
6050 A=PEEK(53279):IF (A=3)+(A=5)+(A=SIX)=ZERO THEN 6050
6060 IF A=3 THEN IF I2=ITEMS THEN I=I-WON:I2=I2-WON
6065 IF A=3 THEN 6090
6070 IF A=SIX THEN I=NR:GOTO 6090
6080 I2=I2-TWO:IF I2<ZERO THEN I=ZERO:I2=ZERO:GOTO 6090
6082 FOR I1=I-WON TO WON STEP -WON:IF WI$(I1,I1)<>"♥" THEN I=I1-WON:I1=WON:GOTO 6084
6083 IF I1=WON THEN I=ZERO:I2=ZERO
6084 NEXT I1
6090 NEXT I:RETURN
6100 HDG$="↰PRINT LIST":GOSUB 15000:NP=INT((ITEMS+4)/FIVE):PRINT HDG$;"↓↓↓↓":DEV=WON
6110 PRINT "THERE ARE ";NP;" PAGES TO THIS LIST↓"
6115 PRINT "WHICH PAGES ARE TO BE PRINTED?↓↓"
6117 PRINT "(A '0' ANSWER INDICATES ALL PAGES)↓↓↓"
6120 TRAP 6120:PRINT "FIRST PAGE? ";:INPUT #16,FP:FP=INT(FP):IF FP=ZERO THEN FP=WON:LP=NP:GOTO 6140
6125 IF FP<WON OR FP>NP THEN 6120
6130 TRAP 6130:PRINT "LAST PAGE? ";:INPUT #16,LP:LP=INT(LP):IF LP=ZERO THEN FP=WON:LP=NP
6135 IF LP<FP OR LP>NP THEN 6130
6140 PRINT "↰↓↓↓↓↓ADJUST PAPER, THEN PRESS ANY KEY":GET #TWO,ANS
6150 TRAP 25000:OPEN #WON,8,ZERO,"P:":PFLG=WON:WP=WON:ANS$="     "
6200 K=-WON:PG=ZERO:FOR I=WON TO NR:IF WI$(I,I)="♥" THEN 6350
6210 K=K+WON:X=K/FIVE:IF INT(X)=X THEN 6220
6215 IF PG>=FP AND PG<=LP THEN 6325
6217 GOTO 6350
6220 PG=PG+WON:IF PG>LP THEN I=NR:GOTO 6350
6230 IF PG<FP THEN 6350
6310 PRINT "↰PRINTING...↓↓↓":? "PRESS ANY KEY TO STOP"
6315 JJ=40-(LEN(TITLE$)+14)/TWO:W$=" ":W$(JJ)=W$:W$(TWO)=W$
6320 PRINT #WON;W$;TITLE$;"   ";YEAR;"  pg.";PG
6325 RX1=LI(I)-WON
6330 PRINT #WON:FOR J=WON TO TEN:IF PEEK(764)<255 THEN I=NR:J=TEN:POKE 764,255:GOTO 6345
6340 GOSUB 20400:PRINT #WON;ANS$;:GOSUB 16000:PRINT #WON;" ";FLD$
6345 NEXT J:IF WP THEN IF INT((K+WON)/FIVE)=(K+WON)/FIVE THEN FOR J=WON TO TEN:PRINT #WON:NEXT J
6350 NEXT I:CLOSE #WON:RETURN
6400 HDG$="↰PRINT WORD PROCESSOR FILE":GOSUB 15000
6410 PRINT HDG$:GOSUB 21000:OPEN #WON,8,ZERO,W$:WP=ZERO:PFLG=WON:ANS$="":DEV=WON
6420 PRINT #WON;TITLE$;"   ";YEAR
6430 FOR I=WON TO NR:IF WI$(I,I)="♥" THEN 6350
6440 GOTO 6325
8000 HDG$="↰CHANGE LIST TITLE":GOSUB 14000:POSITION TWO,5:PRINT "PRESENT LIST TITLE: ";TITLE$
8010 PRINT :PRINT "YEAR: ";YEAR;"↓↓↓":GOSUB 20020:RETURN
9000 HDG$="↰RECOVER LIST":PRINT HDG$:POSITION TWO,SIX
9010 PRINT "WHICH FILE TYPE?↓↓":PRINT "A. EDIT FILE↓":PRINT "B. WORD PROCESSOR FILE↓"
9020 PRINT "C. RETURN TO MAIN MENU":GOSUB 20000:ON ANS GOTO 9040,9050,20015:GOTO 9000
9040 W$="D:EDITLIST.DAT":PRINT HDG$:GOTO 2010
9050 PRINT HDG$:GOSUB 21000:OPEN #WON,4,ZERO,W$:NR=ZERO:L$="":LL=WON:TRAP 9100
9060 INPUT #1,FLD$:X=LEN(FLD$):YEAR=VAL(FLD$(X-3,X)):TITLE$=FLD$(WON,X-7):PRINT FLD$
9070 INPUT #WON,FLD$:FOR J=WON TO TEN:INPUT #1,W$:FLD$=W$(8):X=USR(CHNGR,ADR(FLD$),LEN(FLD$))
9075 IF LEN(L$)+LEN(FLD$)+WON>MAX THEN 9100
9080 L$(LEN(L$)+WON)=FLD$:NEXT J:NR=NR+WON:LI(NR)=LL:LL=LEN(L$)+WON:IF NR<HUN THEN 9070
9100 L$(LL)=" ":CLOSE #WON:RETURN
14000 POKE 709,TEN:POKE 710,ZERO:PRINT HDG$:POSITION TEN,TEN
14010 PRINT "BAILOUT OPTION!!!↓":? "IF YOU BELONG HERE,PRESS RETURN"
14020 PRINT "FOR THE MAIN MENU, PRESS THE SPACE BAR"
14030 GET #2,ANS:IF ANS=32 THEN POP :RETURN
14040 IF ANS<>155 THEN PRINT CHR$(ANS);:GOTO 14030
14050 POKE 709,ZERO:POKE 710,198:PRINT HDG$:RETURN
15000 PRINT HDG$:POSITION TWO,SIX:PRINT "HOW MANY ITEMS ARE TO BE SELECTED?↓↓"
15010 PRINT "A. ALL ITEMS↓":PRINT "B. SOME ITEMS↓":PRINT "C. RETURN TO MAIN MENU":GOSUB 20000
15020 ON ANS GOTO 15040,15050,15030:GOTO 15000
15030 POP :RETURN
15040 ITEMS=NR:WI$="├":WI$(NR)=WI$:WI$(TWO)=WI$:RETURN
15050 PRINT HDG$:I=WON:GOSUB 20150:A=ANS:IF A=TEN+WON THEN RETURN
15055 LAD=ADR(L$):PRINT HDG$:POKE 702,64
15060 POSITION TWO,SIX:PRINT "SEARCH SEQUENCE?":? "(USE '?' FOR A WILDCARD CHARACTER)"
15065 PRINT "(USE ALL CAPITAL LETTERS)↓":INPUT FLD$:IF FLD$="" THEN FLD$=" "
15070 PRINT HDG$:POSITION 12,8:PRINT "SEARCHING...":POSITION TEN,TEN:PRINT "ITEMS FOUND:"
15100 GOSUB 21200:ITEMS=ZERO
15110 POKE 752,WON:FOR I=WON TO NR:RX1=LI(I)-WON:POSITION 23,8:PRINT I
15120 LAD1=LAD+RX1:BEGIN1=USR(FIND,LAD1,A)+RX1:LAST1=PEEK(WON)+BEGIN1-WON:W$=L$(BEGIN1,LAST1)
15125 W$(WON,WON)=CHR$(ASC(W$(WON,WON))-128)
15130 X=USR(SRCH,ADR(FLD$),LEN(FLD$),ADR(W$),LEN(W$))
15140 IF X THEN WI$(I,I)="├":ITEMS=ITEMS+WON
15150 POSITION 23,TEN:PRINT ITEMS:NEXT I:POKE 752,ZERO:IF ITEMS<>ZERO THEN RETURN
15160 PRINT HDG$:PRINT "↓↓↓↓NO ITEMS FOUND!!!↓↓":PRINT "FIELD #";A;"↓↓"
15170 PRINT "SEARCH SEQUENCE:":PRINT FLD$:POSITION TWO,20:PRINT "PRESS RETURN"
15180 INPUT ANS$:POP :RETURN
16000 PRINT #DEV;FNAME$(J*SIX-FIVE,J*SIX);:RETURN
20000 SOUND ZERO,125,TEN,TEN:FOR DELAY=WON TO TEN:NEXT DELAY:SOUND ZERO,ZERO,ZERO,ZERO:POKE 764,255
20005 POSITION TWO,21:PRINT "ENTER LETTER: ";:INPUT #16,ANS$:IF ANS$="" THEN 20000
20010 ANS=ASC(ANS$(WON,WON))-64:IF ANS<ZERO THEN ANS=ZERO
20015 RETURN
20020 PRINT "LIST TITLE? (14 CHAR. MAX) ":INPUT TITLE$:PRINT
20030 TRAP 20030:PRINT "YEAR ":INPUT YEAR:TRAP 25000
20035 IF YEAR<1000 OR YEAR>2100 THEN 20030
20040 FNAME$=FNAME$(WON,30)
20045 FOR I=YEAR-FIVE TO YEAR-WON:FNAME$(LEN(FNAME$)+WON)=STR$(I):FNAME$(LEN(FNAME$)+WON)=" :":NEXT I:RETURN
20100 POKE 752,WON:PRINT "↰":POSITION TWO,ZERO:? TITLE$;" ";YEAR;"  ITEM ";I2;" OF ";ITEMS:? :RX1=LI(I)-WON
20110 FOR J=WON TO TEN:POKE 85,ZERO:GOSUB 16000
20115 JJ=J:IF MODE=WON AND J=TEN THEN 20130
20116 IF MODE=WON AND J>=SIX THEN JJ=J+WON
20120 GOSUB 20400:PRINT FLD$
20130 NEXT J:POKE 752,ZERO:RETURN
20150 POSITION TWO,SIX:PRINT "WHICH FIELD IS TO BE USED FOR LEVEL ";I;"?↓"
20160 FOR J=WON TO TEN:PRINT CHR$(64+J);". ";FNAME$(J*SIX-FIVE,J*SIX-WON):NEXT J
20165 PRINT "K. RETURN TO MAIN MENU"
20170 GOSUB 20000:POSITION TWO,21:PRINT "↑":IF ANS<WON OR ANS>TEN+WON THEN 20170
20175 IF ANS=TEN+WON THEN POP :RETURN
20180 RETURN
20400 LAD1=ADR(L$)+RX1:BEGIN1=USR(FIND,LAD1,J)+RX1:LAST1=PEEK(WON)+BEGIN1-WON
20410 FLD$=L$(BEGIN1,LAST1):FLD$(WON,WON)=CHR$(ASC(FLD$(WON,WON))-128):IF PFLG THEN RETURN
20420 B=LEN(FLD$)+WON:IF B>40 THEN RETURN
20430 FLD$(B)=" ":FLD$(SIXTY)=" ":FLD$(B+WON)=FLD$(B):RETURN
21000 POSITION 2,6:PRINT "FILENAME?":PRINT "BLANK ENTRY RETURNS TO MAIN MENU↓":INPUT W$
21005 IF W$="" THEN POP :RETURN
21007 FLD$="D:":IF LEN(W$)>WON THEN IF W$(WON,TWO)="D:" THEN RETURN
21010 FLD$(3)=W$:W$=FLD$
21020 RETURN
21200 WI$="♥":WI$(HUN)=WI$:WI$(TWO)=WI$:RETURN
23000 FOR DELAY=WON TO SIXTY*FIVE:NEXT DELAY:RETURN
25000 PRINT HDG$;"↓↓↓↓↓":X=PEEK(195):PRINT " ERROR #";X:POSITION TWO,TEN+TEN:PRINT "PRESS RETURN":CLOSE #WON
25010 POKE 752,ZERO:POKE 82,TWO:TRAP 25000:INPUT #16;W$:POP :GOTO 100