Tape Time Labelmaker (VCRLABEL.BAS)

Tape Time Labelmaker by Gary Coppola, 112

Description

Tape Time Labelmaker by Gary Coppola, 112

From the Antic disk of July 1989 (Vol. 8 No. 3).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 13.6 KB

Dialect
Atari BASIC
Lines
310
Variables
ERR$, HOLD$, J, L, Z, WAIT, LINE, A, TAPETYPE, MINBII, TOTMINBII, MINBIII, TOTMINBIII, PAUSE, TAPE$, TBII, TBIII, MET, BIIMETER, BIIIMETER, TOTALMETER, TIMELEFTBII, RO, TIMELEFTBIII, ROIII, VHSTYPE, MINSP, TOTMINSP, MINLP, TOTMINLP, MINEP, TOTMINEP, VHSTAPE$, TSP, TLP, TEP, SPMETER, LPMETER, EPMETER, TOTALMETERS, TIMELEFTSP, ROSP, TIMELEFTLP, ROLP, TIMELEFTEP, ROEP, X, I, C, CS, ERROR, X0, P0, TITLE1$, TITLE2$, TITLE3$, TITLE4$, TITLE5$, TITLE6$, TITLE7$, SPEED1$, SPEED2$, SPEED3$, SPEED4$, SPEED5$, SPEED6$, SPEED7$, MIN1$, MIN2$, MIN3$, MIN4$, MIN5$, MIN6$, MIN7$, CH, MODE, K, TNUM, LS, MAR, Y
BASIC listing (310 lines)
10 REM VCR TAPE TIME
20 REM BY PAUL SHANNON
30 REM (c)1988, ANTIC PUBLISHING
32 REM TAPE TIME LABELMAKER
34 REM BY GARY COPPOLA
36 REM (c)1989, ANTIC PUBLISHING
40 GRAPHICS 0:POKE 752,1:POKE 710,0:DIM ERR$(6),HOLD$(6)
50 ? " ┌────────────┐ ┌──────────────────┐ "
60 ? " |┌──┐  ┌──┐  | |┌────────────────┐| "
70 ? " |└┐┌┘  └┐┌┘  | ||                || "
80 ? " | ||APE ||IME| ||                || "
90 ? " | └┘    └┘   | ||                || "
100 ? " |   A  VCR   | ||                || "
110 ? " | UTILITY BY | ||                || "
120 ? " |PAUL SHANNON| ||                || "
130 ? " |c.1988 Antic| ||                || "
140 ? " └────────────┘ ||                || "
150 ? "┌───────────────┤|                || "
160 ? "|▎▎▎▎▎▎▎▎┌─────┐||                || "
170 ? "|        |     ||└────────────────┘| "
180 ? "| ▖▖▖▖▖  └─────┘| ●●●●●       ▎▎▎  | "
190 ? "└▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄┴▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄┘ "
200 ? "─┴┴───────────┴┴──┴┴────────────┴┴──"
210 POSITION 2,19:? "▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂"
220 POSITION 2,20:? " |                                | "
230 POSITION 2,21:? " |                                | "
240 POSITION 2,22:? " └────────────────────────────────┘ "
250 FOR J=1 TO 10:FOR L=2 TO 11
260 POSITION 20,L:? "▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄":POSITION 20,L:? "                "
280 NEXT L
300 NEXT J
320 REM
330 FOR Z=1 TO 5:POSITION 12,12:? "12:OO":FOR WAIT=1 TO 100:NEXT WAIT
340 POSITION 12,12:? "     ":FOR WAIT=1 TO 100:NEXT WAIT
360 NEXT Z
370 POSITION 12,12:? "12:OO"
380 CLR :DIM ERR$(6),HOLD$(6)
381 DIM TITLE1$(40),TITLE2$(40),TITLE3$(40),TITLE4$(40),TITLE5$(40),TITLE6$(40),TITLE7$(40)
382 DIM SPEED1$(4),SPEED2$(4),SPEED3$(4),SPEED4$(4),SPEED5$(4),SPEED6$(4),SPEED7$(4)
383 DIM MIN1$(3),MIN2$(3),MIN3$(3),MIN4$(3),MIN5$(3),MIN6$(3),MIN7$(3)
385 LINE=13:POSITION 2,16:? "Do You Want To:  1)Do Calculation":POSITION 19,17:? "2)Make a Label"
386 TRAP 1920:POSITION 2,18:? "Your Choice";:INPUT CH:GOSUB 1750
387 IF CH<1 OR CH>2 THEN 381
388 IF CH=1 THEN GOSUB 1750:GOSUB 1830:GOTO 390
389 IF CH=2 THEN POSITION 12,12:? "LABEL":GOSUB 1710:GOSUB 1750:GOTO 2170
390 POSITION 2,16:? "Do You Want: 1)BETA 2)VHS"
400 LINE=1:TRAP 1920
410 POSITION 27,16:INPUT A:GOSUB 1750:GOSUB 1830
420 IF A<1 OR A>2 THEN 390
430 IF A=1 THEN POSITION 12,12:? "BETA "
440 IF A=2 THEN POSITION 12,12:? " VHS "
450 IF A=1 THEN GOSUB 1830
460 IF A=2 THEN 880
470 REM BETA
480 LINE=2:TRAP 1920
490 POSITION 2,16:? "Is Your BETA Tape: 1)L-750 2)L-830":POSITION 36,16:INPUT TAPETYPE:GOSUB 1750
500 IF TAPETYPE<1 OR TAPETYPE>2 THEN 480
510 POSITION 2,16:? "Enter The Minutes BETA II"
520 LINE=3:TRAP 1920
530 POSITION 27,16:INPUT MINBII:GOSUB 1750
540 IF MINBII=0 THEN GOSUB 1710:GOTO 580
550 IF MINBII>900 THEN GOSUB 2080:GOTO 510
560 TOTMINBII=TOTMINBII+MINBII
570 GOTO 510
580 IF TAPETYPE=1 THEN POSITION 23,2:? "BETA L-750":POSITION 22,3:? "-------------"
590 IF TAPETYPE=2 THEN POSITION 23,2:? "BETA L-830":POSITION 22,3:? "-------------"
600 POSITION 22,5:? "Total Minutes":POSITION 21,6:? "BETA II  ";TOTMINBII
610 LINE=4:TRAP 1920
620 POSITION 2,16:? "Enter The Minutes BETA III"
630 POSITION 28,16:INPUT MINBIII:GOSUB 1750
640 IF MINBIII=0 THEN 670
645 IF MINBIII>900 THEN GOSUB 2080:GOTO 620
650 TOTMINBIII=TOTMINBIII+MINBIII
660 GOTO 620
670 POSITION 22,8:? "Total Minutes":POSITION 21,9:? "BETA III  ";TOTMINBIII
680 FOR PAUSE=1 TO 200:NEXT PAUSE
690 DIM TAPE$(11)
700 IF TAPETYPE=1 THEN TBII=180:TBIII=270:MET=222:TAPE$=" BETA L-750"
710 IF TAPETYPE=2 THEN TBII=200:TBIII=300:MET=246:TAPE$=" BETA L-830"
740 BIIMETER=(TOTMINBII/TBII)*MET
750 BIIIMETER=(TOTMINBIII/TBIII)*MET
760 TOTALMETER=BIIMETER+BIIIMETER
770 TIMELEFTBII=((MET-TOTALMETER)/MET)*TBII:GOSUB 1710
780 RO=INT(100*TIMELEFTBII+0.5)/100
790 POSITION 22,2:? TAPE$:POSITION 21,3:? "--------------"
800 POSITION 21,5:? RO;" Minutes":GOSUB 1790
810 POSITION 21,6:? "BETA II Left"
820 TIMELEFTBIII=((MET-TOTALMETER)/MET)*TBIII
830 ROIII=INT(100*TIMELEFTBIII+0.5)/100
840 POSITION 21,8:? ROIII;" Minutes":GOSUB 1790
850 POSITION 21,9:? "BETA III Left":GOSUB 1750
860 GOTO 1380
870 REM VHS
880 LINE=7:TRAP 1920
890 POSITION 2,16:? "Is Your VHS Tape: 1)T-120 2)T-160":POSITION 35,16:INPUT VHSTYPE:GOSUB 1750
900 IF VHSTYPE<1 OR VHSTYPE>2 THEN 880
910 POSITION 2,16:? "Enter The Minutes SP"
920 LINE=8:TRAP 1920
930 POSITION 22,16:INPUT MINSP:GOSUB 1750
940 IF MINSP=0 THEN GOSUB 1710:GOTO 980
950 IF MINSP>900 THEN GOSUB 2080:GOTO 910
960 TOTMINSP=TOTMINSP+MINSP
970 GOTO 910
980 IF VHSTYPE=1 THEN POSITION 23,2:? "VHS T-120":POSITION 21,3:? "--------------"
990 IF VHSTYPE=2 THEN POSITION 23,2:? "VHS T-160":POSITION 21,3:? "--------------"
1000 POSITION 21,4:? "Total Minutes":POSITION 21,5:? "SP Speed  ";TOTMINSP
1010 LINE=9:TRAP 1920
1020 POSITION 2,16:? "Enter The Minutes LP"
1030 POSITION 22,16:INPUT MINLP:GOSUB 1750
1040 IF MINLP=0 THEN 1070
1045 IF MINLP>900 THEN GOSUB 2080:GOTO 1020
1050 TOTMINLP=TOTMINLP+MINLP
1060 GOTO 1020
1070 POSITION 21,7:? "Total Minutes":POSITION 21,8:? "LP Speed  ";TOTMINLP
1080 LINE=10:TRAP 1920
1090 POSITION 2,16:? "Enter The Minutes EP(ELP)"
1100 POSITION 27,16:INPUT MINEP:GOSUB 1750
1110 IF MINEP=0 THEN 1140
1115 IF MINEP>900 THEN GOSUB 2080:GOTO 1090
1120 TOTMINEP=TOTMINEP+MINEP
1130 GOTO 1090
1140 POSITION 21,10:? "Total Minutes":POSITION 21,11:? "EP Speed  ";TOTMINEP
1150 FOR PAUSE=1 TO 200:NEXT PAUSE
1160 DIM VHSTAPE$(11)
1170 IF VHSTYPE=1 THEN TSP=120:TLP=240:TEP=360:MET=246:VHSTAPE$=" VHS T-120"
1190 IF VHSTYPE=2 THEN TSP=160:TLP=320:TEP=480:MET=327:VHSTAPE$=" VHS T-160"
1210 SPMETER=(TOTMINSP/TSP)*MET
1220 LPMETER=(TOTMINLP/TLP)*MET
1230 EPMETER=(TOTMINEP/TEP)*MET
1240 TOTALMETERS=SPMETER+LPMETER+EPMETER
1250 TIMELEFTSP=((MET-TOTALMETERS)/MET)*TSP:GOSUB 1710
1260 ROSP=INT(100*TIMELEFTSP+0.5)/100
1270 POSITION 22,2:? VHSTAPE$:POSITION 21,3:? "-------------"
1280 POSITION 21,4:? ROSP;" Minutes"
1290 POSITION 21,5:? "SP Speed Left"
1300 TIMELEFTLP=((MET-TOTALMETERS)/MET)*TLP
1310 ROLP=INT(100*TIMELEFTLP+0.5)/100
1320 POSITION 21,7:? ROLP;" Minutes"
1330 POSITION 21,8:? "LP Speed Left"
1340 TIMELEFTEP=((MET-TOTALMETERS)/MET)*TEP
1350 ROEP=INT(100*TIMELEFTEP+0.5)/100
1360 POSITION 21,10:? ROEP;" Minutes":GOSUB 1810
1370 POSITION 21,11:? "EP Speed Left":GOSUB 1750
1380 LINE=11:TRAP 1920
1390 POSITION 2,16:? "Want To 1)CONTINUE 2)PRINT"
1400 POSITION 28,16:INPUT X
1410 IF X<1 OR X>2 THEN GOSUB 1750:GOTO 1380
1430 IF X=1 THEN GOSUB 1710:GOSUB 1750:GOTO 380
1460 GOSUB 2060
1470 LINE=12:TRAP 1920
1480 REM PRINT
1490 POSITION 2,17:? "Input Tape Number"
1500 INPUT I
1510 LPRINT "# ";I
1520 IF A=1 THEN 1610
1530 IF VHSTYPE=1 THEN LPRINT "VHS T-120"
1540 IF VHSTYPE=2 THEN LPRINT "VHS T-160"
1550 LPRINT "---------"
1560 IF X<>2 THEN 1590
1570 LPRINT ROSP;"  Minutes SP Speed Remaining":LPRINT ROLP;"  Minutes LP Speed Remaining"
1580 LPRINT ROEP;"  Minutes EP Speed Remaining"
1590 GOSUB 2060
1600 LPRINT :GOTO 1660
1610 IF TAPETYPE=1 THEN LPRINT "BETA L-750"
1620 IF TAPETYPE=2 THEN LPRINT "BETA L-830"
1630 LPRINT "----------"
1640 LPRINT RO;"  Minutes BETA II Remaining"
1650 LPRINT ROIII;"  Minutes BETA III Remaining":GOSUB 2060
1660 LPRINT :GOSUB 1830
1670 GOSUB 1750
1680 GOTO 380
1690 END
1700 REM CLEAR SCREEN
1710 FOR C=2 TO 11
1720 POSITION 20,C:? "                "
1730 NEXT C
1740 RETURN
1750 FOR CS=16 TO 18:POSITION 0,CS:? "                                       ":NEXT CS:RETURN
1780 RETURN
1790 TOTMINBII=0:TOTMINBIII=0
1800 RETURN
1810 TOTMINSP=0:TOTMINLP=0:TOTMINEP=0
1820 RETURN
1830 POSITION 20,2:? "               "
1840 POSITION 20,3:? " Press RETURN  ":POSITION 20,4:? "  After Each   "
1850 POSITION 20,5:? "     Entry      || "
1860 POSITION 20,6:? "                || "
1870 POSITION 20,7:? "  Enter 0 When  || ":POSITION 20,8:? " Done Entering  || "
1875 POSITION 20,9:? " For Each Speed || "
1880 POSITION 20,10:? "               "
1890 POSITION 20,11:? "               "
1900 RETURN
1910 REM ERROR TRAP
1920 ERROR=PEEK(195)
1930 GOSUB 1750
1940 IF ERROR=8 THEN POSITION 10,16:? "ENTER NUMBERS ONLY!":FOR WAIT=1 TO 150:NEXT WAIT
1950 GOSUB 1750
1960 IF ERROR=8 THEN ON LINE GOTO 390,480,510,610,2060,2060,880,910,1010,1080,1380,1470,381,2170,2850
2060 LPRINT "---------------------------------"
2070 RETURN
2080 POKE 709,0:POKE 710,12:POKE 712,66
2090 ERR$="ERROR ":TRAP 40000
2100 FOR X0=1 TO 25:P0=INT(1.5+6*((X0/6)-INT(X0/6))):HOLD$=ERR$(P0,6)
2110 IF P0<>1 THEN HOLD$(6-P0+2)=ERR$(1,P0-1)
2120 POSITION 12^1,12:? HOLD$(1,5):NEXT X0
2130 POKE 712,0:POKE 709,202:POKE 710,0
2140 IF A=1 THEN POSITION 12,12:? "BETA "
2150 IF A=2 THEN POSITION 12,12:? " VHS "
2160 RETURN
2170 LINE=14:POSITION 2,16:? "Tape Format:  1)BETA   2)VHS"
2180 TRAP 1920:POSITION 2,17:? "Your Choice";:INPUT MODE:GOSUB 1750
2190 IF MODE<1 OR MODE>2 THEN 2170
2200 IF MODE=1 THEN POSITION 12,12:? "BETA ":GOSUB 1750:GOSUB 3000
2210 IF MODE=2 THEN POSITION 12,12:? " VHS ":GOSUB 1750:GOSUB 3000:GOTO 2310
2220 REM BETA
2260 GOSUB 3015:GOSUB 3020
2270 FOR WAIT=1 TO 500:NEXT WAIT:GOSUB 1750:POSITION 2,16:? "You can enter a maximum of 6 titles"
2280 ? "    Press ANY KEY to continue"
2290 CLOSE #2:OPEN #2,4,0,"K:":GET #2,K:CLOSE #2:GOTO 2400
2300 REM VHS
2310 GOSUB 3025:GOSUB 3030
2330 FOR WAIT=1 TO 500:NEXT WAIT:GOSUB 1750:POSITION 2,16:? "You can enter a maximum of 7 titles"
2340 GOTO 2280
2400 GOSUB 1750:POSITION 2,17:? "Enter Your FIRST Title":FOR WAIT=1 TO 90:NEXT WAIT
2410 TRAP 2400:GOSUB 3080:POSITION 1,18:INPUT TITLE1$:IF TITLE1$="" THEN GOTO 2790
2420 TNUM=1:GOSUB 1750:GOSUB 3120
2440 INPUT SPEED1$
2460 GOSUB 3150:INPUT MIN1$
2470 GOSUB 1750:POSITION 2,17:? "Enter Your SECOND Title":FOR WAIT=1 TO 90:NEXT WAIT
2480 TRAP 2470:GOSUB 3080:POSITION 1,18:INPUT TITLE2$:IF TITLE2$="" THEN GOTO 2790
2490 TNUM=2:GOSUB 1750:GOSUB 3120
2500 INPUT SPEED2$
2510 GOSUB 3150:INPUT MIN2$
2520 GOSUB 1750:POSITION 2,17:? "Enter Your THIRD Title":FOR WAIT=1 TO 90:NEXT WAIT
2530 TRAP 2520:GOSUB 3080:POSITION 1,18:INPUT TITLE3$:IF TITLE3$="" THEN GOTO 2790
2540 TNUM=3:GOSUB 1750:GOSUB 3120
2550 INPUT SPEED3$
2560 GOSUB 3150:INPUT MIN3$
2570 GOSUB 1750:POSITION 2,17:? "Enter Your FOURTH Title":FOR WAIT=1 TO 90:NEXT WAIT
2580 TRAP 2570:GOSUB 3080:POSITION 1,18:INPUT TITLE4$:IF TITLE4$="" THEN GOTO 2790
2590 TNUM=4:GOSUB 1750:GOSUB 3120
2600 INPUT SPEED4$
2610 GOSUB 3150:INPUT MIN4$
2620 GOSUB 1750:POSITION 2,17:? "Enter Your FIFTH Title":FOR WAIT=1 TO 90:NEXT WAIT
2630 TRAP 2620:GOSUB 3080:POSITION 1,18:INPUT TITLE5$:IF TITLE5$="" THEN GOTO 2790
2640 TNUM=5:GOSUB 1750:GOSUB 3120
2650 INPUT SPEED5$
2660 GOSUB 3150:INPUT MIN5$
2670 GOSUB 1750:POSITION 2,17:? "Enter Your SIXTH Title":FOR WAIT=1 TO 90:NEXT WAIT
2680 TRAP 2670:GOSUB 3080:POSITION 1,18:INPUT TITLE6$:IF TITLE6$="" THEN GOTO 2790
2690 TNUM=6:GOSUB 1750:GOSUB 3120
2700 INPUT SPEED6$
2710 GOSUB 3150:INPUT MIN6$
2720 IF MODE=2 THEN GOSUB 1750:POSITION 2,17:? "Enter Your SEVENTH Title":FOR WAIT=1 TO 90:NEXT WAIT
2730 IF MODE=2 THEN TRAP 2720:GOSUB 3080:POSITION 1,18:INPUT TITLE7$:IF TITLE7$="" THEN GOTO 2790
2740 IF MODE=2 THEN TNUM=7:GOSUB 1750:GOSUB 3120:INPUT SPEED7$
2750 IF MODE=2 THEN GOSUB 3150:INPUT MIN7$
2790 GOSUB 1750
2795 POSITION 2,16:? "Position LABEL in the printer,then"
2800 POSITION 10,17:? " TURN ON PRINTER ":FOR J=15 TO 0 STEP -1:SOUND 0,120,10,J:NEXT J
2810 FOR WAIT=1 TO 300:NEXT WAIT
2830 IF MODE=1 AND TNUM<=3 THEN LS=12
2835 IF MODE=1 AND TNUM>3 THEN LS=6
2840 IF MODE=2 AND TNUM<=4 THEN LS=12
2845 IF MODE=2 AND TNUM>4 THEN LS=6
2850 LINE=15:GOSUB 1750
2854 IF MODE=1 THEN GOSUB 3050
2856 IF MODE=2 THEN GOSUB 3060
2860 TRAP 1920:POSITION 9,16:? " SET THE LEFT MARGIN ":? "Refer to list for suggested setting"
2870 ? "MARGIN=";:INPUT MAR
2880 IF MAR<1 OR MAR>40 THEN 2850
2890 GOTO 3200
3000 POSITION 4,16:? "Refer to list for the suggested":? "  maximum number of characters"
3010 ? "  (CMAX) allowable for your title":RETURN
3015 POKE 82,20:POSITION 20,2:? " Brand":? " ──────────────":? " SONY":? :? " SCOTCH"
3017 ? :? " FUJI":? :? " MAXELL":POKE 82,2:RETURN
3020 POKE 82,32:POSITION 31,2:? "CMAX":? :? "31":? :? "20":? :? "31":? :? "30":POKE 82,2:RETURN
3025 POKE 82,20:POSITION 20,2:? " Brand":? " ──────────────":? " SCOTCH":? " SCOTCH EG":? " MAXELL EX"
3027 ? " MAXELL HGX":? " FUJI":? " MEMOREX":? " POLAROID":? " PANASONIC":POKE 82,2:RETURN
3030 POKE 82,32:POSITION 31,2:? "CMAX":? :? "35":? "27":? "30":? "27":? "35":? "31"
3040 ? "28":? "30":POKE 82,2:RETURN
3050 POKE 82,31:POSITION 29,2:? "MARGIN":? :? " 8 ":? :? "10 ":? :? " 9 ":? :? " 8 ":POKE 82,2:RETURN
3060 POKE 82,32:POSITION 30,2:? "MARGIN":? :? " 3 ":? " 3 ":? "11 ":? "14 ":? "10 "
3070 ? " 8 ":? "18 ":? "17 ":POKE 82,2:RETURN
3080 POSITION 2,17:? "┌───┬────┬────┬────┬────┬────┬────┐"
3090 POSITION 2,16:? "    5    10   15   20   25   30   35":RETURN
3100 POSITION 2,16:? "Enter Speed (BII or BIII):";:RETURN
3110 POSITION 2,16:? "Enter Speed (SP,LP or EP):";:RETURN
3120 IF MODE=1 THEN GOSUB 3100
3130 IF MODE=2 THEN GOSUB 3110
3140 RETURN
3150 POSITION 2,17:? "Program Length (in minutes)";:RETURN
3199 REM PRINTER CONTROL CODES
3200 LPRINT CHR$(27);CHR$(64):REM INITIALIZE PRINTER
3210 LPRINT CHR$(27);CHR$(110):REM NLQ PICA
3220 LPRINT CHR$(27);CHR$(65);CHR$(LS):REM LS/72 LINE SPACING
3230 LPRINT CHR$(27);CHR$(77);CHR$(MAR):REM LEFT MARGIN
3240 IF MODE=1 AND TNUM>3 THEN LPRINT CHR$(27);CHR$(83);CHR$(1):REM SUBSCRIPT FONT
3245 IF MODE=2 AND TNUM>4 THEN LPRINT CHR$(27);CHR$(83);CHR$(1):REM SUBSCRIPT FONT
3250 GOSUB 1750:POSITION 6,17:? "Press ANY KEY to print LABEL"
3260 CLOSE #2:OPEN #2,4,0,"K:":GET #2,K:CLOSE #2
3270 REM PRINT LABEL
3280 LPRINT TITLE1$;"  ";SPEED1$;" ";MIN1$;" "
3290 LPRINT TITLE2$;"  ";SPEED2$;" ";MIN2$;" "
3300 LPRINT TITLE3$;"  ";SPEED3$;" ";MIN3$;" "
3310 IF TNUM>3 THEN LPRINT TITLE4$;"  ";SPEED4$;" ";MIN4$;" "
3320 IF TNUM>3 THEN LPRINT TITLE5$;"  ";SPEED5$;" ";MIN5$;" "
3330 IF TNUM>3 THEN LPRINT TITLE6$;"  ";SPEED6$;" ";MIN6$;" "
3340 IF TNUM>3 AND MODE=2 THEN LPRINT TITLE7$;"  ";SPEED7$;" ";MIN7$;" "
3350 GOSUB 1710:GOSUB 1750:GOTO 380