Machine Language Stringer (STRDAT.BAS)
Machine Language Stringer by Andy Barton, 23
Description
Machine Language Stringer by Andy Barton, 23
From the Antic disk of July 1989 (Vol. 8 No. 3).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.8 KB
- Dialect
- Atari BASIC
- Lines
- 49
- Variables
A$,B$,C$,ML$,S$,N$,Q,ED,N,SLN,X,A,B,ST,EDST,Z,QQ$,NUM,SVST,SVT,T1$,T2$,TT1$,TT2$,BST,MV1$,M1$,ML1$,ML2$,A1$,DSLN,SNL,S1$,S1(,S2$,S2(,ML1(,ML2(
BASIC listing (49 lines)
10 REM MACHINE LANGUAGE STRINGER
20 REM by Andy Barton
30 REM for Antic Mag.
50 REM
60 DIM A$(120),B$(15),C$(120),ML$(10000),S$(5),N$(2):Q=1:ED=0:N=1
70 C$(1)=" ":C$(120)=" ":C$(2)=C$
80 ? "↰":? :? :? "CONVERT OBJ FILE TO STRING DATA":? :?
90 ? "INPUT OBJ FILE (Dn:xxx)"
100 INPUT B$:TRAP 90:IF B$(1,1)<>"D" THEN 90
110 CLOSE #1:OPEN #1,4,0,B$
120 ? "STARTING LINE NO."
130 TRAP 120:INPUT SLN:DSLN=SLN:SLN=SLN+1:TRAP 40000
135 IF SLN<482 THEN ? :? "STARTING LINE NO. MUST BE GREATER THEN 480 ":? :GOTO 120
140 ? "NAME ML STRING (2 CHARACTERS ONLY)":INPUT N$:IF LEN(N$)=0 THEN 140
150 S$=N$:S$(LEN(N$)+1)=STR$(N)
160 ? "↰":TRAP 410
170 GET #1,X:GET #1,X:REM DISCARD FILE IDENTIFICATION CODE (255,255)
180 TRAP 420:REM NOMAL EOF
190 GET #1,A:GET #1,B:ST=B*256+A
200 IF ED=0 THEN BST=ST:GOTO 220
210 IF ST<>EDST THEN GOSUB 450:BST=ST:N=N+1:S$(LEN(N$)+1)=STR$(N):Q=1:SLN=SLN+2:DSLN=SLN:SLN=SLN+1
220 GET #1,A:GET #1,B:ED=B*256+A
230 POKE 766,1:POSITION 2,4:? C$:POSITION 2,4:? SLN;" ";S$;"$(";Q;",";:POSITION 22,4:? ")=";CHR$(34);
240 TRAP 390:REM EARLY EOF
250 FOR Z=1 TO 90:GET #1,X
260 IF X=155 OR X=34 THEN 350
270 ? CHR$(X);
280 ST=ST+1:IF ST>ED THEN 330
290 NEXT Z
300 POSITION 18,4:? Q+Z-2:Q=Q+90:SLN=SLN+1:GOSUB 310:GOTO 230
310 POKE 766,0:POSITION 2,10:? "CONT":POSITION 1,2:? " ";:POKE 842,13:STOP
320 POKE 842,12:RETURN
330 REM ST -> ED REACHED
340 POSITION 18,4:? Q+Z-1:GOSUB 310:EDST=ST:Q=Q+Z:SLN=SLN+1:GOTO 180
350 IF Z=1 THEN 360
355 POSITION 18,4:? Q+Z-2:GOSUB 310:SLN=SLN+1
360 POSITION 2,4:? C$:POSITION 2,4:? SLN;" ";S$;"$(";Q+Z-1;",";Q+Z-1;")=";"CHR$(";X;")"
370 GOSUB 310:SLN=SLN+1:Q=Q+Z:ST=ST+1:IF ST>ED THEN EDST=ST:GOTO 180
380 GOTO 230
390 REM ERROR -- EARLY EOF
400 GOSUB 310
410 ? " ERROR -- EARLY EOF !!!":STOP
420 GOSUB 310:GOSUB 450:? :? "DONE":POKE 766,0:REM NORMAL EOF
430 ? " LIST these lines into a disk file then ENTER them into your basic program"
440 END
450 NUM=ED-BST+1:POSITION 2,4:? C$:POSITION 2,4:? DSLN;"DIM ";S$;"$(";NUM;")":GOSUB 310:POSITION 2,4:? C$
460 POSITION 2,4:? SLN;" X=USR(ADR(";CHR$(34);"hh┐qh┐ph┐Uh┐Th┐oh┐np▕fo ♥1p┌TfTP▕fUfpP▕fqFnPlFoPh◆";CHR$(34);
470 ? "),ADR(";S$;"$),";BST;",";NUM;")"
480 GOSUB 310:RETURN
