Egyptian Calendar (EGYPT.BAS)
Egyptian Calendar by Chris Carrier, 49
Description
Egyptian Calendar by Chris Carrier, 49
From the Antic disk of July 1989 (Vol. 8 No. 3).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 5.9 KB
- Dialect
- Atari BASIC
- Lines
- 173
- Variables
D$,M$,ERA$,CAL$,ENSEASON$,YEAR,MONTH,DATE,IYEAR,BC,JYEAR,JDAY,LDAYS,X,DOW,EBM,EY,JSC,ESEASON,EMO,ENYEAR,SENWORSET3,AMENTOHEP1,NABONASSAR,CBM,CY,CM,ENMONTH$,COPSEASON$,ORDINAL$,ALEXANDRIAN,AUGUSTAN,CD,Y,SR,SRMONTH$,YASDI,SR$,TSC,TEY,CJ
BASIC listing (173 lines)
5 REM EGYPTIAN CALENDAR
10 REM BY CHRIS CARRIER
15 REM (C)1989, ANTIC PUBLISHING INC.
20 DIM D$(9),M$(9),ERA$(5),CAL$(18),ENMONTH$(15),ENSEASON$(7),SRMONTH$(9)
25 POKE 710,14:POKE 712,14:POKE 709,14:? "↰":? :? :?
35 ? "This will give you the date in both Egyptian calendars, and the ";
37 ? "heliacal rising of Sirius."
38 ? :? :? "Type in a YEAR, MONTH, DATE"
39 ? "(If date is BC, type a '-' before the year.)":?
40 ? "YEAR ";:GOSUB 410:INPUT YEAR:? "MONTH ";:INPUT MONTH:? "DATE ";:INPUT DATE
41 IF YEAR<1582 THEN CAL$="J":GO TO 45
42 IF YEAR>1923 THEN CAL$="G":GO TO 45
43 ? :? " Gregorian or Julian Calendar? ";
44 INPUT CAL$
45 IYEAR=YEAR
48 IF IYEAR<0 THEN IYEAR=0-IYEAR:BC=1
49 IF BC=0 THEN ERA$="A.D."
50 IF BC=1 THEN ERA$="B.C."
60 IF YEAR<0 THEN YEAR=YEAR+1
70 JYEAR=YEAR+4712
80 JDAY=0
90 JDAY=JDAY+(JYEAR*365)
95 REM *** ADD LEAP YEARS
100 LDAYS=1178+INT(YEAR/4)
110 JDAY=JDAY+LDAYS
130 JDAY=JDAY+2
135 IF CAL$="J" THEN 160
140 JDAY=JDAY-INT(YEAR/100)
150 JDAY=JDAY+INT(YEAR/400)
160 IF MONTH=2 THEN JDAY=JDAY+31
161 REM LEAP YEAR
163 IF YEAR/4=INT(YEAR/4) THEN X=1:DATE=DATE+1
164 IF CAL$="J" THEN 168
165 IF YEAR/400=INT(YEAR/400) THEN X=1:DATE=DATE+1
168 IF X=1 THEN DATE=DATE-1
169 IF X=1 AND MONTH>2 THEN JDAY=JDAY+1
170 IF MONTH=3 THEN JDAY=JDAY+59
180 IF MONTH=4 THEN JDAY=JDAY+90
190 IF MONTH=5 THEN JDAY=JDAY+120
200 IF MONTH=6 THEN JDAY=JDAY+151
210 IF MONTH=7 THEN JDAY=JDAY+181
220 IF MONTH=8 THEN JDAY=JDAY+212
230 IF MONTH=9 THEN JDAY=JDAY+243
240 IF MONTH=10 THEN JDAY=JDAY+273
250 IF MONTH=11 THEN JDAY=JDAY+304
260 IF MONTH=12 THEN JDAY=JDAY+334
270 JDAY=JDAY+DATE
271 IF CAL$="J" THEN JDAY=JDAY-2
272 IF X=1 THEN JDAY=JDAY-1
275 IF CAL$="J" THEN 290
276 IF YEAR/400=INT(YEAR/400) THEN 280
277 IF YEAR/100=INT(YEAR/100) AND MONTH<3 THEN JDAY=JDAY+1
280 IF YEAR/400=INT(YEAR/400) THEN JDAY=JDAY-1:DATE=DATE-1
290 DOW=JDAY
300 IF DOW>700000 THEN DOW=DOW-700000
305 IF DOW<1 THEN DOW=DOW+700000
310 IF DOW>70000 THEN DOW=DOW-70000
320 IF DOW>7000 THEN DOW=DOW-7000
330 IF DOW>700 THEN DOW=DOW-700
340 IF DOW>70 THEN DOW=DOW-70
345 IF DOW>7 THEN DOW=DOW-7
346 IF DOW>7 THEN GOTO 300
348 IF DOW<1 THEN GOTO 305
350 RESTORE 1100:FOR CJ=1 TO DOW:READ D$:NEXT CJ:GOTO 500
400 FOR CJ=2 TO 14:POKE 709,CJ:NEXT CJ:RETURN
410 FOR CJ=14 TO 2 STEP -1:POKE 709,CJ:NEXT CJ:RETURN
500 RESTORE 1000:FOR CJ=1 TO MONTH:READ M$:NEXT CJ
1000 DATA JANUARY,FEBRUARY,MARCH,APRIL,MAY,JUNE,JULY,AUGUST,SEPTEMBER,OCTOBER,NOVEMBER,DECEMBER
1100 DATA TUESDAY,WEDNESDAY,THURSDAY,FRIDAY,SATURDAY,SUNDAY,MONDAY
1200 DATA THOUT,PAAPE,HATOR,KIAHK,TOBE,MSHIR,PARMHAT,PARMUTE,PASHONS,PAONE,EPEP,MESORE,EPAGOMENAL
2000 REM ORIG. EGYPTIAN CALENDAR
2001 EBM=JDAY-171867
2002 GOSUB 400:? "↰":POSITION 12,12:? " CALCULATING...";:GOSUB 410
2010 IF EBM<0 THEN EBM=EBM+533265:EY=EY-1461
2015 IF EY<0 THEN JSC=JSC-1:EY=EY+1461
2020 IF EBM>533265 THEN EBM=EBM-533265:EY=EY+1461
2030 IF EBM>36500 THEN EBM=EBM-36500:EY=EY+100
2040 IF EBM>3650 THEN EBM=EBM-3650:EY=EY+10
2050 IF EBM>365 THEN EBM=EBM-365:EY=EY+1
2060 IF EBM>365 THEN 2010
2061 TEY=EY-111
2065 IF EY>1461 THEN JSC=JSC+1:EY=EY-1461
2066 IF EY>1461 THEN 2065
2067 IF TEY>1424 THEN TSC=TSC+1:TEY=TEY-1424
2068 IF TEY>1424 THEN 2067
2070 IF EBM<1 THEN 2010
2100 REM
2105 ESEASON=1
2110 IF EBM>120 THEN EBM=EBM-120:ESEASON=ESEASON+1
2120 IF EBM>120 THEN 2110
2125 REM 5 EPAGOMENAL DAYS MADE
2126 REM A 5TH MONTH OF SUMMER
2127 IF ESEASON=4 THEN ESEASON=3:EBM=EBM+120
2130 IF ESEASON=1 THEN ENSEASON$=" AKHIT "
2131 IF ESEASON=2 THEN ENSEASON$=" PERIT "
2132 IF ESEASON=3 THEN ENSEASON$=" SHEMU "
2200 REM MONTH AND DAY
2205 EMO=1
2210 IF EBM>30 THEN EBM=EBM-30:EMO=EMO+1
2220 IF EBM>30 THEN 2210
2300 REM COMPUTE ERAS
2310 SENWORSET3=((JSC-1)*1461)-904+EY
2320 AMENTOHEP1=((JSC-1)*1461)-1238+EY
2330 NABONASSAR=((JSC-1)*1461)-2036+EY
3000 REM 365.25 DAY CALENDAR
3100 CBM=JDAY-1824664
3110 IF CBM<0 THEN CBM=CBM+146100:CY=CY-400
3120 IF CBM>146100 THEN CBM=CBM-146100:CY=CY+400
3130 IF CBM>14610 THEN CBM=CBM-14610:CY=CY+40
3140 IF CBM>1461 THEN CBM=CBM-1461:CY=CY+4
3150 IF CBM>1461 THEN 3120
3160 IF CBM<0 THEN 3110
3200 FOR CJ=1 TO 3:IF CBM>365 THEN CBM=CBM-365:CY=CY+1
3201 NEXT CJ
3210 IF CBM>30 THEN CM=CM+1:CBM=CBM-30:IF CBM>30 THEN 3210
3230 CM=CM+1
3300 REM NAMES OF MONTHS
3310 RESTORE 1200:FOR CJ=1 TO CM:READ ENMONTH$:NEXT CJ
3700 REM OTHER ERAS
3710 ALEXANDRIAN=CY+308
3720 AUGUSTAN=CY+312
4000 REM SOTHIC RISING
4010 SR=199.365967+(YEAR*(549.5/86400))
4015 IF CAL$="G" THEN SR=SR+INT(YEAR/100)-2
4016 IF CAL$="G" THEN SR=SR-INT(YEAR/400)
4100 IF SR>365.25 THEN SR=SR-365.25
4101 IF SR>365.25 THEN 4100
4102 IF SR<0 THEN SR=SR+365.25
4103 IF SR<0 THEN 4102
4110 SRMONTH$="JANUARY"
4120 IF SR>31 THEN SRMONTH$="FEBRUARY"
4130 IF SR>59.25 THEN SRMONTH$="MARCH"
4140 IF SR>90.25 THEN SRMONTH$="APRIL"
4150 IF SR>120.25 THEN SRMONTH$="MAY"
4160 IF SR>151.25 THEN SRMONTH$="JUNE"
4170 IF SR>181.25 THEN SRMONTH$="JULY"
4180 IF SR>212.25 THEN SRMONTH$="AUGUST"
4190 IF SR>243.25 THEN SRMONTH$="SEPTEMBER"
4200 IF SR>273.25 THEN SRMONTH$="OCTOBER"
4210 IF SR>304.25 THEN SRMONTH$="NOVEMBER"
4220 IF SR>334.25 THEN SRMONTH$="DECEMBER"
4320 IF SRMONTH$="FEBRUARY" THEN SR=SR-31
4330 IF SRMONTH$="MARCH" THEN SR=SR-59.25
4340 IF SRMONTH$="APRIL" THEN SR=SR-90.25
4350 IF SRMONTH$="MAY" THEN SR=SR-120.25
4360 IF SRMONTH$="JUNE" THEN SR=SR-151.25
4370 IF SRMONTH$="JULY" THEN SR=SR-181.25
4380 IF SRMONTH$="AUGUST" THEN SR=SR-212.25
4390 IF SRMONTH$="SEPTEMBER" THEN SR=SR-243.25
4400 IF SRMONTH$="OCTOBER" THEN SR=SR-273.25
4410 IF SRMONTH$="NOVEMBER" THEN SR=SR-304.25
4420 IF SRMONTH$="DECEMBER" THEN SR=SR-334.25
4900 SR=INT(SR*1)
4910 SR=SR+1
9000 IF CAL$="J" THEN CAL$="JULIAN CALENDAR"
9010 IF CAL$="G" THEN CAL$="GREGORIAN CALENDAR"
9800 REM
9810 GOSUB 400:? "↰":? D$;", ";M$;" ";DATE;", ";IYEAR;" ";ERA$;" "
9815 ? CAL$,"JD#";JDAY
9900 ? "Original Calendar Date: ";ENSEASON$;EMO;"-";EBM
9910 ? :? "Various Eras:"
9915 ? "Year #";EY;" of Julian Sothic Cycle #";JSC
9916 ? "Year #";TEY;" of True Sothic Cycle #";TSC
9920 ? "Year of Senworset III: ";SENWORSET3
9925 ? "Year of Amentohep I: ";AMENTOHEP1
9930 ? "Year of Nabonassar: ";NABONASSAR
9950 ? :? :? :? :?
9960 ? "Coptic Calendar: ";CY;" ";ENMONTH$;" ";CBM
9962 IF CM=13 THEN 9965
9965 ? "Alexandrian Year ";ALEXANDRIAN
9970 ? "Augustan Year ";AUGUSTAN
9990 ? :? "Sothic Rising this year: ";SRMONTH$;" ";SR:GOSUB 410
9999 END
