Two-Column Printing (TWOCOLMN.BAS)
Two-Column Printing by Earl Haley, 34
Description
Two-Column Printing by Earl Haley, 34
From the Antic disk of June 1989 (Vol. 8 No. 2) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 4.1 KB
- Dialect
- Atari BASIC
- Lines
- 93
- Variables
BUZ$,N,BLANK$,COL1$,COL2$,R$,TEST$,FILENAME$,PAGE,FILE,FINISHED,COLUMN,S,F,LINE,NL,PRINTLINE,CP,FS,BYTE,FLAG,TEST,PRYNTLYNE,KSIZE,A
BASIC listing (93 lines)
2 REM TWO-COLUMN PRINTING
4 REM BY EARL HALEY
6 REM (c)1989, ANTIC PUBLISHING INC.
10 GRAPHICS 0:POKE 710,14:POKE 712,14:POKE 709,2:DIM BUZ$(3):FOR N=1 TO 3:BUZ$(N)=CHR$(253):NEXT N
20 ? :? :? " TWO-COLUMN PRINTER PROGRAM":? :? " By Earl Haley"
25 KSIZE=40*80
30 DIM BLANK$(KSIZE),COL1$(KSIZE),COL2$(KSIZE),R$(41),TEST$(2),FILENAME$(15):PAGE=0:FILE=1:FINISHED=0
40 BLANK$(1)=" ":BLANK$(KSIZE)=" ":BLANK$(2)=BLANK$:COL1$=BLANK$:COL2$=BLANK$
50 GOSUB 700:GOSUB 800:GOTO 370
100 TRAP 230:CLOSE #1:OPEN #1,4,0,FILENAME$:PAGE=0
110 TRAP 230
120 FOR COLUMN=1 TO 2
130 S=1:F=40
140 FOR LINE=1 TO NL:REM (NL DEFINED IN LINES 740 AND 750)
150 INPUT #1,R$:IF LEN(R$)=3 THEN IF R$(1,3)="XXX" OR R$(1,3)=BUZ$ THEN 150
160 ON COLUMN GOTO 170,180
170 COL1$(S,F)=R$:GOTO 190
180 COL2$(S,F)=R$
190 S=F+1:F=S+39
200 NEXT LINE
210 NEXT COLUMN
220 GOTO 250
230 IF PEEK(195)=170 THEN ? CHR$(125):? :? "FILE NOT FOUND":CLOSE #1:GOTO 380
235 IF PEEK(195)=160 THEN ? "DRIVE# ERROR":CLOSE #2:GOTO 440
240 IF PEEK(195)=144 THEN ? CHR$(125):? :? "DISK DRIVE ERROR":CLOSE #1:GOTO 380
245 IF PEEK(195)=136 THEN FINISHED=1:GOTO 250
246 ? "DISK ERROR":CLOSE #1:GOTO 380
250 PAGE=PAGE+1
260 CLOSE #2:OPEN #2,8,0,"P:"
270 S=1:F=40
280 FOR PRYNTLYNE=1 TO NL
290 ? #2;COL1$(S,F);COL2$(S,F)
300 S=F+1:F=S+39
310 NEXT PRYNTLYNE
320 COL1$=BLANK$:COL2$=BLANK$
330 ? #2:? #2;BLANK$(1,36);"- ";PAGE;" -"
340 IF FILE<>FINISHED THEN 345
341 ? #2;BLANK$(1,35);"- END -":FINISHED=0:? "↰DONE !":? "Press a Key":GOSUB 660:RUN
345 IF CP<>1 THEN 350
346 ? "Pause for Paper Change - Check Your Pprinter- Press Any Key When Ready":GOSUB 660:GOTO 110
350 IF CP=2 THEN FOR N=1 TO FS-NL-2:? #2:NEXT N
360 GOTO 110
370 CLOSE #2:GRAPHICS 0:POKE 710,50:? CHR$(125)
375 IF FS=84 THEN ? :? "< LEGAL SIZE 8 1/2 x 14 INCHES >"
376 IF FS=66 THEN ? :? "< STANDARD SIZE 8 1/2 x 11 INCHES >"
380 ? :? "Be Sure ANTIC DISK Is In Drive"
382 ? :? "Be sure Printer and Paper are ready"
385 ? :? :? "What File do you wish to print"
390 ? :? :? "(1) ANTIC HELP FILE"
400 ? :? "(2) OTHER":POKE 752,1:? :? "?"
410 GOSUB 660
420 ON BYTE-48 GOTO 430,435
430 FILENAME$="D:DOC.TXT":FLAG=2:GOTO 100
435 ? CHR$(125)
440 ? :? :? :? "(Press RETURN for disk directory)":? "(Lists only files with .TXT extender)"
450 ? :? "ENTER NAME OF 40-COLUMN TEXT FILE"
460 ? "(D:XXXXXXXX.XXX)"
470 TRAP 230:INPUT FILENAME$:IF FILENAME$="" THEN GOSUB 590:GOTO 440
472 IF LEN(FILENAME$)<3 THEN ? "FILENAME TOO SHORT !":? :GOTO 450
475 TEST$=FILENAME$(1,2)
476 IF TEST$<>"D:" AND TEST$<>"D1" AND TEST$<>"D2" AND TEST$<>"D8" THEN ? "DRIVE #?":GOTO 450
480 IF LEN(FILENAME$)>15 THEN ? "FILENAME TOO LONG !":? :GOTO 450
490 CLOSE #1:OPEN #1,4,0,FILENAME$
500 TRAP 550:FOR N=1 TO 10
510 INPUT #1,R$:IF LEN(R$)>40 THEN ? "NOT A 40-COLUMN FILE":POP :CLOSE #1:GOTO 560
520 IF LEN(R$)>1 THEN CLOSE #1:FLAG=2:POP :? :GOTO 100
530 NEXT N
550 CLOSE #1:? :? :? "NOT A 40-COLUMN TEXT FILE !"
560 ? :? "PRESS ANY KEY TO CONTINUE"
570 GOSUB 660
580 GOTO 380
590 TRAP 630:CLOSE #1:OPEN #1,7,0,"D:*.*":TEST=0:FOR N=1 TO 99:INPUT #1,R$
600 IF R$(11,13)="TXT" THEN TEST=TEST+1:? R$;" ";
610 NEXT N
630 IF PEEK(195)=136 THEN 650
640 ? "DISK ERROR"
650 IF TEST<1 THEN ? :? "NO 40 COLUMN TEXT FILES FOUND":?
655 CLOSE #1:RETURN
660 CLOSE #4:OPEN #4,4,0,"K:":GET #4,BYTE:CLOSE #4:RETURN
700 ? :? "BE SURE SOURCE DISK IS IN DRIVE":? :? "BE SURE PRINTER IS READY":? :? :? "SELECT PAPER SIZE":?
710 ? " (1) Standard 8 1/2 x 11 inches."
720 ? :? " (2) Legal size 8 1/2 x 14 inches":POKE 752,1:? "?";
730 GOSUB 660
740 IF BYTE=49 THEN FS=66:NL=52:RETURN
750 IF BYTE=50 THEN FS=84:NL=68:RETURN
760 GOTO 730
800 ? CHR$(125):? :? "WHICH DO YOU WANT"
810 ? :? " (1) Change paper after each page"
820 ? :? " (2) Continuous feed paper":? :? "?"
830 GOSUB 660
840 IF BYTE=49 THEN CP=1:RETURN
850 IF BYTE=50 THEN CP=2:RETURN
860 GOTO 830
