Icon Animation System with samples (SCRIPTER.BAS)
Icon Animation System with samples by Jim Johnson, 239
Description
Icon Animation System with samples by Jim Johnson, 239
From the Antic disk of June 1989 (Vol. 8 No. 2) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 8.1 KB
- Dialect
- Atari BASIC
- Lines
- 205
- Variables
C0,C1,C2,C3,C4,C5,C6,C7,C8,C9,C20,MAX,MODE,OFF,WAIT,FILENAME$,TEMP$,DEVICE$,DPATH$,G$,G2$,SEQ$,FILE$,SCRIPT(,CYCLE(,FNL(,PICT,RAMDISK,OLDX,OLDY,CURX,CURY,KEY,FILE,I,SEQ,J,K,L,SCRMEM,X,DELAY,PAUSE,FRAMES,IOCB,ADRHI,ADRLO,NM,NMHI,NMLO,NRED,BRK
BASIC listing (205 lines)
100 REM ICON ANIMATION SYSTEM, LISTING 2, THE SCRIPTER
103 REM BY JIM JOHNSON
106 REM (c)1989 ANTIC PUBLISHING INC.
110 C0=0:C1=1:C2=2:C3=3:C4=4:C5=5:C6=6:C7=7:C8=8:C9=9:C20=20:MAX=C20+C5
120 MODE=C6:OFF=40000:WAIT=10:GOSUB 31000:GOSUB 30000
130 DIM FILENAME$(20),TEMP$(20),DEVICE$(3),DPATH$(6)
140 DIM G$(616),G2$(616*MAX)
150 DIM SEQ$(101),FILE$(20*10),SCRIPT(101),CYCLE(10),FNL(10)
170 PICT=ADR("hh┐Lh┐Kh┐Nh┐Mhh┐Ohh*hh┐P$O◢1M┌K◢@▶Pw┴%KeP┐K♣▕fL┴%MeO┐M♣▕fNJP[◆")
190 G$="♥":G$(616)=G$:G$(2)=G$
260 TRAP OFF:GOSUB 1500:POSITION C2,C3
270 ? " ┌─┐":? " | | CREATE SCRIPT":? " └─┘"
280 ? " ┌─┐":? " | | LOAD SCRIPT":? " └─┘"
290 ? " ┌─┐":? " | | SAVE SCRIPT":? " └─┘"
300 ? " ┌─┐":? " | | RUN SCRIPT":? " └─┘"
310 ? " ┌─┐":? " | | SEQUENCER":? " └─┘"
320 ? " ┌─┐":? " | | LOAD SEQUENCES TO RAMDISK":? " └─┘"
330 IF RAMDISK=1 THEN POSITION 5,19:? "X":?
340 GOSUB 1550
350 OLDX=C5:OLDY=C4:CURX=OLDX:CURY=OLDY
360 CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY
370 IF KEY=45 AND CURY>C4 THEN CURY=CURY-C3:GOTO 460
380 IF KEY=61 AND CURY<19-(3*(RAMDISK=1)) THEN CURY=CURY+C3:GOTO 460
390 IF KEY=155 AND CURY=C4 THEN 480
400 IF KEY=155 AND CURY=C7 THEN 670
410 IF KEY=155 AND CURY=10 AND FILE$<>"" THEN 740
420 IF KEY=155 AND CURY=13 AND FILE$<>"" THEN 800
430 IF KEY=155 AND CURY=16 THEN TRAP 260:RUN "D:ANIMATOR.BAS"
440 IF KEY=155 AND CURY=19 THEN 850
460 POSITION OLDX,OLDY:? " ";:POSITION CURX,CURY:? " ";:OLDX=CURX:OLDY=CURY
470 GOTO 360
480 REM CREATE SCRIPT
490 GOSUB 1500:GOSUB 1550
500 DEVICE$="D?:":DEVICE$(2,2)=STR$(RAMDISK):GOSUB 1700:GOSUB 1820
510 IF NOT FILE THEN CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY:GOTO 260
520 POSITION 17,C3:? "SEQUENCE CYCLES";:POSITION 17,C4:? "▔▔▔▔▔▔▔▔ ▔▔▔▔▔▔";
530 OLDX=C3:OLDY=C4+FILE*C2:CURX=OLDX:CURY=OLDY:I=C1
540 CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY
550 IF KEY=45 AND CURY>C4 THEN CURY=CURY-C2:GOTO 590
560 IF KEY=61 AND CURY<C4+FILE*C2 THEN CURY=CURY+C2:GOTO 590
570 IF KEY=155 AND CURY=C4+FILE*C2 THEN 260
580 IF KEY=155 AND CURY>C3 AND CURY<C5+FILE*C2 THEN 610
590 POSITION OLDX,OLDY:? " ";:POSITION CURX,CURY:? " ";:OLDX=CURX:OLDY=CURY
600 GOTO 540
610 FILE$=G$:FILENAME$=FILE$(C8*((CURY/C2)-C2)+C1,C8*((CURY/C2)-C2)+FNL(CURY/C2-C1))
620 SCRIPT(I)=CURY/C2-C1:POSITION OLDX,OLDY:? " ";
630 POSITION 17,C4+I:? FILENAME$:POSITION 28,C4+I:? " ←←←←";:POKE 752,C0
640 TRAP 630:INPUT KEY:POKE 752,C1:? :IF KEY<C0 OR KEY>100 THEN 630
650 CYCLE(I)=KEY:SEQ=I:I=I+C1:IF I=11 THEN 260
660 POSITION OLDX,OLDY:? " ";:GOTO 540
670 REM LOAD SCRIPT
680 TRAP 3000:DEVICE$="D?:":DEVICE$(2,2)=STR$(RAMDISK):GOSUB 1700:GOSUB 1500:GOSUB 1550
690 POSITION C2,C3:? "USE FORMAT: 'DEV:FILENAME.EXT'"
695 POKE 752,C0:POSITION C2,C5:? "FILENAME TO LOAD?";:POKE 764,255
696 ON PEEK(764)=255 GOTO 696:IF PEEK(764)=28 THEN CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY:GOTO 260
700 ? "←";:INPUT FILENAME$:IF FILENAME$="" THEN GOSUB 2320:GOTO 695
710 CLOSE #C1:OPEN #C1,C4,C0,FILENAME$
720 GET #1,SEQ:FOR I=C1 TO SEQ:GET #C1,J:SCRIPT(I)=J:GET #C1,J:CYCLE(I)=J:NEXT I:INPUT #C1;FILE$:CLOSE #C1
725 FOR J=C1 TO SEQ:FILENAME$=FILE$(C8*(J-C1)+C1,C8*(J-C1)+C8):I=C8
727 IF FILENAME$(I,I)=" " THEN I=I-C1:GOTO 727
728 FNL(J)=I:NEXT J
730 GOTO 260
740 REM SAVE SCRIPT
750 TRAP 3000:GOSUB 1500:GOSUB 1550:POSITION 2,3:? "USE FORMAT: 'DEV:FILENAME.EXT'"
755 POKE 752,C0:POSITION C2,C5:? "FILENAME TO SAVE?";:POKE 764,255
756 ON PEEK(764)=255 GOTO 756:IF PEEK(764)=28 THEN CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY:GOTO 260
760 ? "←";:INPUT FILENAME$:IF FILENAME$="" THEN GOSUB 2320:GOTO 755
770 CLOSE #C1:OPEN #C1,C8,C0,FILENAME$
780 PUT #C1,SEQ:FOR I=C1 TO SEQ:J=SCRIPT(I):PUT #C1,J:J=CYCLE(I):PUT #C1,J:NEXT I:? #C1;FILE$:CLOSE #C1
790 GOTO 260
800 REM RUN SCRIPT
810 FILENAME$="D?:":FILENAME$(2,2)=STR$(RAMDISK):GOSUB 1560:G$=FILE$
820 FOR J=C1 TO SEQ:I=SCRIPT(J):GOSUB 1360
830 FOR K=C1 TO CYCLE(J):GOSUB 970:NEXT K
840 NEXT J:POKE 77,C0:GOTO 820
850 REM LOAD RAMDISK
860 GOSUB 1500:GOSUB 1550
870 DEVICE$="D1:":GOSUB 1700:GOSUB 1820
880 IF NOT FILE THEN CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY:GOTO 260
890 IF PEEK(53279)=3 THEN 910
892 POKE 5439,ASC("1"):REM LOAD DUP.SYS FROM DRIVE #1
895 DPATH$="D?:*.*":DPATH$(2,2)=STR$(RAMDISK):TRAP 910:CLOSE #C1:OPEN #C1,C4,C0,DPATH$
900 XIO 33,#C1,C0,C0,DPATH$:CLOSE #C1:GOTO 895
910 POSITION 21,11:? "*LOADING*":POSITION C3,C4+FILE*C2:? " ";
920 FILENAME$=DEVICE$:FOR I=C1 TO FILE:POSITION C3,C2+I*C2:? " ";
930 FILENAME$="D1:":GOSUB 1360:GOSUB 1240
940 POSITION C3,C2+I*C2:? " ";:NEXT I:GOTO 260
950 REM DISPLAY IMAGES
960 GOSUB 1560
970 L=ADR(G$):SCRMEM=PEEK(88)+PEEK(89)*256+C4+C4*20
980 FOR I=C1 TO LEN(SEQ$)
990 IF ASC(SEQ$(I,I))=C0 THEN GOSUB 1470:GOTO 1040
1000 L=ADR(G2$)+616*(ASC(SEQ$(I,I))-C1)
1010 X=USR(PICT,SCRMEM,L,11,52,C20)
1020 FOR DELAY=C1 TO WAIT:IF PEEK(764)<>255 THEN GOSUB 1060
1025 NEXT DELAY:POKE 77,C0
1030 IF PEEK(764)<>255 THEN GOSUB 1060
1040 NEXT I
1050 RETURN
1060 CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY:POKE 764,255
1070 IF KEY=155 AND CURX=C4 THEN WAIT=WAIT+C1+C4*(WAIT>29)+C5*(WAIT>45)+10*(WAIT>90)
1080 IF KEY=155 AND CURX=11 THEN WAIT=WAIT-C1-C4*(WAIT>30)-C5*(WAIT>50)-10*(WAIT>100):IF WAIT<C0 THEN WAIT=C0
1090 IF KEY=155 AND CURX=18 THEN PAUSE= NOT PAUSE
1100 IF KEY=155 AND CURX=25 AND PAUSE THEN 1170
1110 IF KEY=155 AND CURX=32 THEN POP :POP :GOTO 260
1120 IF KEY=42 AND CURX<32 THEN CURX=CURX+C7:POKE 657,OLDX:? " ";:POKE 657,CURX:? " ";:OLDX=CURX
1130 IF KEY=43 AND CURX>4 THEN CURX=CURX-C7:POKE 657,OLDX:? " ";:POKE 657,CURX:? " ";:OLDX=CURX
1140 IF PAUSE THEN 1060
1150 RETURN
1160 GOSUB 1060
1170 REM ADVANCE
1175 IF SEQ$="" THEN 1060
1180 I=I+C1:IF I>LEN(SEQ$) THEN I=C1
1190 IF ASC(SEQ$(I,I))=C0 THEN 1180
1200 L=ADR(G2$)+616*(ASC(SEQ$(I,I))-C1)
1210 X=USR(PICT,SCRMEM,L,11,52,C20)
1220 GOTO 1060
1230 GOSUB 1500
1240 REM SAVE SEQUENCE FILE
1250 FILENAME$(C2,C2)="8"
1260 CLOSE #C1:TRAP 1345:OPEN #C1,C8,C0,FILENAME$
1270 SEQ$(LEN(SEQ$)+C1)=CHR$(FRAMES):? #C1;SEQ$
1280 IOCB=832+16:POKE IOCB+2,11
1290 ADRHI=INT(ADR(G2$)/256):ADRLO=ADR(G2$)-ADRHI*256
1300 POKE IOCB+C4,ADRLO:POKE IOCB+C5,ADRHI
1310 NM=616*FRAMES:NMHI=INT(NM/256):NMLO=NM-NMHI*256
1320 POKE IOCB+C8,NMLO:POKE IOCB+C9,NMHI
1330 X=USR(ADR("hhh*LVd"),16):IF (PEEK(IOCB+C9)*256+PEEK(IOCB+C8))<>NRED THEN 1345
1340 CLOSE #C1:SEQ$=SEQ$(C1,LEN(SEQ$)-C1):RETURN
1345 TRAP 260:CLOSE #C1:OPEN #C1,C4,C0,FILENAME$:XIO 33,#C1,C0,C0,FILENAME$:CLOSE #C1:GOTO 260
1350 GOSUB 1500
1360 REM LOAD SEQUENCE FILE
1370 FILENAME$(C4)=G$(C8*(I-C1)+C1,C8*(I-C1)+FNL(I)):FILENAME$(C4+FNL(I))=".SEQ"
1380 TRAP 1465:CLOSE #C1:OPEN #C1,C4,C0,FILENAME$
1390 INPUT #C1;SEQ$:FRAMES=ASC(SEQ$(LEN(SEQ$),LEN(SEQ$))):SEQ$=SEQ$(C1,LEN(SEQ$)-C1)
1400 IOCB=832+16:POKE IOCB+C2,C7
1410 ADRHI=INT(ADR(G2$)/256):ADRLO=ADR(G2$)-ADRHI*256
1420 POKE IOCB+C4,ADRLO:POKE IOCB+C5,ADRHI
1430 NM=616*FRAMES:NMHI=INT(NM/256):NMLO=NM-NMHI*256
1440 POKE IOCB+C8,NMLO:POKE IOCB+C9,NMHI
1450 X=USR(ADR("hhh*LVd"),16):NRED=PEEK(IOCB+C9)*256+PEEK(IOCB+C8)
1460 CLOSE #C1:RETURN
1465 POKE 656,C3:POKE 657,C2:? "* MISSING FILE * (";FILENAME$;") ";:POKE 656,CURY
1466 FOR DELAY=C1 TO WAIT:IF PEEK(764)<>255 THEN GOSUB 1060
1467 NEXT DELAY:POKE 77,C0
1468 POP :GOTO 840
1470 REM PAUSE
1480 FOR DELAY=C1 TO 100:IF PEEK(764)<>255 THEN GOSUB 1060
1490 NEXT DELAY:RETURN
1500 REM TITLE SCREEN
1510 GRAPHICS C0:POKE 709,C0:POKE 710,C0:GOSUB 31000:POKE 752,C1
1520 POSITION C0,C0:? " Icon Animation System * Scripter * "
1530 POSITION C0,C1:? "________________________________________"
1540 RETURN
1550 FOR I=C1 TO 10:POKE 710,I:NEXT I:RETURN
1560 GRAPHICS MODE:GOSUB 31000:POKE 752,C1:PAUSE=C0
1570 POKE 708,C0:POKE 709,C0:POKE 710,C0:POKE 712,C0
1580 COLOR C1:PLOT 30,C2:DRAWTO 121,C2:DRAWTO 121,57:DRAWTO 30,57:DRAWTO 30,C2
1590 ? " ┌─┐ ┌─┐ ┌─┐ ┌─┐ ┌─┐"
1600 ? " | |SLOW| |FAST| |PAUS| |ADV.| |EXIT"
1610 ? " └─┘ └─┘ └─┘ └─┘ └─┘"
1620 OLDX=C4:OLDY=C1:CURX=OLDX:CURY=OLDY
1630 POKE 656,CURY:POKE 657,CURX:? " ";
1640 FOR I=C1 TO 10:POKE 710,I:POKE 712,I:NEXT I:RETURN
1650 RETURN
1660 FOR DELAY=C1 TO 100
1670 IF PEEK(764)<>255 THEN GOSUB 1060
1680 NEXT DELAY:RETURN
1690 RETURN
1700 REM DIRECTORY OF SEQUENCES
1710 G$(C1)=" ":G$(20*10)=" ":G$(C2)=G$:FILE=C0
1720 FILENAME$=DEVICE$:FILENAME$(4)="*.SEQ":CLOSE #C1:OPEN #C1,C7,C0,FILENAME$
1730 INPUT #C1,FILENAME$
1740 IF FILENAME$(C5,C8)="FREE" OR FILE>8 THEN CLOSE #C1:GOTO 1800
1750 FILE=FILE+C1
1760 FILENAME$=FILENAME$(C3,LEN(FILENAME$)-C7):G$(C8*(FILE-C1)+C1,C8*(FILE-C1)+C8)=FILENAME$
1770 FOR I=C8 TO C1 STEP -C1:IF FILENAME$(I,I)<>" " THEN FNL(FILE)=I:POP :GOTO 1790
1780 NEXT I
1790 GOTO 1730
1800 RETURN
1820 ? "┌─┬────────┐":IF NOT FILE THEN 1840
1830 FOR I=C1 TO FILE:? "| |";:? G$(C8*(I-C1)+C1,C8*(I-C1)+C8);:? "|":? "├─┤ |":NEXT I
1840 ? "| | EXIT |";:IF FILE THEN ? :GOTO 1860
1850 ? " * NO SEQUENCE FILES *"
1860 ? "└─┴────────┘";
1870 RETURN
2320 REM DIRECTORY
2340 G$(C1)=" ":G$(616)=" ":G$(C2)=G$:K=C0:L=C0:POKE 752,C1
2350 CLOSE #C1:OPEN #C1,C7,C0,"D1:*.*"
2360 INPUT #C1,FILENAME$
2370 IF FILENAME$(C4,11)="SHOP:CLK" THEN GOSUB 2440:RETURN
2380 IF FILENAME$(C5,C8)="FREE" THEN CLOSE #C1:GOTO 2410
2390 G$(17*K+C1,17*K+LEN(FILENAME$))=FILENAME$:K=K+C1
2400 GOTO 2360
2410 FOR I=C0 TO 13:POSITION C1,C7+I:? G$(17*(L+I)+C1,17*(L+I)+17);" ";G$(17*(L+I+14)+C1,17*(L+I+14)+17)
2420 NEXT I:? :? FILENAME$;" ";
2430 RETURN
2440 POSITION 2,22:? " * PRINT SHOP FORMAT *↰";:RETURN
3000 REM ERROR MSG
3010 POKE 703,C4:POKE 752,C1:? "↰":? " * FILE ACCESS ERROR * ↰";
3020 FOR I=C1 TO 100:NEXT I:POKE 703,24:GOTO 260
30000 RAMDISK=1:TRAP 30010:CLOSE #4:OPEN #4,6,0,"D8:*.*":RAMDISK=8
30010 TRAP 30020:CLOSE #4
30020 TRAP OFF:RETURN
31000 BRK=USR(ADR("h)♥┐MhhI♥p╲)p┐♣▔▂R◆"),C1):RETURN
