disk utility (LOCATOR.BAS)

disk utility by Jeffrey A. Summers, 21

Description

disk utility by Jeffrey A. Summers, 21

From the Antic disk of June 1989 (Vol. 8 No. 2) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.5 KB

Dialect
Atari BASIC
Lines
49
Variables
FN$, FN1$, MASK$, SEARCH$, WINSTR$, CASE$, BUFR$, FOUND, DLIST, PTR, SLEN, WINSTR, BUFR, SEARCH, FPTR, I, FLEN, INP, D, MAKEUP, P, BEGIN, ENN, X
BASIC listing (49 lines)
10 REM LOCATOR
20 REM JEFFREY A. SUMMERS, MD
30 REM (c)1989, ANTIC PUBLISHING INC.
100 DIM FN$(20),FN1$(20),MASK$(20),SEARCH$(50),WINSTR$(143),CASE$(1),BUFR$(10000)
109 GOSUB 10000:FOUND=0
110 CLOSE #1:OPEN #1,12,0,"E:":POKE 710,18
120 DLIST=PEEK(560)+256*PEEK(561):POKE DLIST+3,71:POKE DLIST+6,6:? "    LOCATOR           by j summers"
130 POSITION 7,7:? "Files to search: ";:INPUT #1,MASK$
140 POSITION 7,9:? "String to search for: ";:INPUT #1,SEARCH$
150 POSITION 7,12:? "Case sensitive (Y/N): ";:INPUT #1,CASE$:IF CASE$<>"Y" AND CASE$<>"N" THEN 150
160 IF MASK$="" THEN MASK$="D:*.*"
165 PTR=USR(ADR(WINSTR$),ADR(MASK$),LEN(MASK$),ADR(":"),1,2)
170 SLEN=LEN(SEARCH$):WINSTR=ADR(WINSTR$):BUFR=ADR(BUFR$):BUFR$(10000)=" "
180 SEARCH=ADR(SEARCH$)
200 TRAP 1000:FPTR=1:GRAPHICS 0:POKE 710,18
210 CLOSE #2:OPEN #2,7,0,MASK$
220 TRAP 600:FOR I=1 TO FPTR:INPUT #2,FN$:NEXT I:FN1$=MASK$(1,PTR):FN1$(PTR+1)=FN$(3,10):FPTR=FPTR+1:CLOSE #2
230 FOR I=LEN(FN1$) TO 1 STEP -1:IF FN1$(I,I)<>" " THEN POP :GOTO 240
235 NEXT I
240 FN1$(I+1)=".":FN1$(I+2)=FN$(11,13)
250 CLOSE #3:OPEN #3,4,0,FN1$
260 ? "CHECKING ";FN1$
300 FLEN=USR(INP,3,BUFR,10000)
310 IF CASE$<>"Y" THEN D=USR(MAKEUP,BUFR,FLEN)
320 P=USR(WINSTR,BUFR,FLEN,SEARCH,SLEN,1)
330 IF P<>0 THEN 400
340 IF FLEN<>10000 THEN 500
350 BUFR$(1)=BUFR$(9900):BUFR$(10000)=" "
360 FLEN=USR(INP,3,BUFR+100,9900)+100
370 GOTO 310
400 BEGIN=P-18:IF BEGIN<1 THEN BEGIN=1
410 ENN=P+19:IF ENN>FLEN THEN ENN=FLEN
415 ? "Found in file ";FN1$;"       ":FOR I=BEGIN TO ENN:? CHR$(27);BUFR$(I,I);:NEXT I:FOUND=1
420 POKE 752,1:? :? "Next file Exit Continue":POKE 752,0
430 CLOSE #5:OPEN #5,4,0,"K:":GET #5,X:CLOSE #5:IF X=78 THEN 500
440 IF X=69 THEN 600
450 IF X<>67 THEN 430
460 P=USR(WINSTR,BUFR,FLEN,SEARCH,SLEN,P+1)
470 GOTO 330
500 CLOSE #3:GOTO 210
600 IF  NOT FOUND THEN ? :? "Not Found."
610 ? "Done.":END
1000 ? :? "Illegal directory name":GOTO 2000
2000 FOR I=1 TO 700:NEXT I:CLOSE #1:CLOSE #2:GOTO 110
10000 INP=ADR("hhh◣◣◣◣*)╲↓B┘h↓E┘h↓D┘h↓I┘h↓H┘ Vd=H┘┐T=I┘┐U◆")
10010 WINSTR$(1,71)="hh┐Wh┐Vh┐ah┐◆h┐Yh┐Xhh┐bh┐gh┐f8%fi├┐f%gi♥┐g┴%feV┐h%geW┐i┴%Ve◆┐d%Wea┐e ♥1"
10020 WINSTR$(72,143)="hQXP HDbPu%h8eV┐T%ieW┐U%T┴i├┐T%Ui♥┐U◆%hEdP▔%iEeP╲)♥┐T┐U◆%h┴i├┐h%ii♥┐i┴♣5"
10030 MAKEUP=ADR("hh┐Uh┐Th┐Wh┐V%T┴eV┐X%UeW┐Y ♥1TIa♣┴%T┴i├┐T%Ui♥┐UEYPi%TEXPc◆8i ┌T┴♣◆")
10040 RETURN