game (DOOMED.BAS)

game by Tony Barnes, 75

Description

game by Tony Barnes, 75

From the Antic disk of June 1989 (Vol. 8 No. 2) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 9.1 KB

Dialect
Atari BASIC
Lines
153
Variables
BRK, T, SC, LVL, MN, X2, Z1, D2, P2$, PM$, I, Y2, BR$, BL$, X3, Z2, D3, P3$, Y3, Z, ST, X, X1, Y, Y1, P0$, R1$, WLK, R2$, L2$, L1$, P1$, Q, PWR, H$, TMR, F$, F2$, M$, DNUM, D, B, DLI$, A, CHR, C$, MOV, OFFSET
BASIC listing (153 lines)
2 REM DOOMED
4 REM BY TONY BARNES
6 REM (c)1989, ANTIC PUBLISHING INC.
10 GRAPHICS 18:GOSUB 50:GOSUB 20000:GOSUB 11000:GOSUB 10000:GOSUB 5500:GOSUB 40
20 POSITION 3,7:? #6;"&'":POSITION 3,8:? #6;"()**+,-"
25 POSITION 0,9:? #6;"tony barnes    antic";
30 GOTO 8000
40 POKE 708,6:POKE 710,22:POKE 709,10:RETURN
50 BRK=USR(ADR("h)♥┐MhhI♥p╲)p┐♣▔▂R◆"),1):RETURN
60 FOR T=15 TO 0 STEP -1:SOUND 0,193,10,T:SOUND 1,47,12,T:NEXT T
65 SC=SC+5:POKE 53278,1:POSITION 0,11:? #6;SC:RETURN
100 IF PEEK(19)>=4 THEN POKE 19,0:LVL=LVL+1:IF LVL>8 THEN 1300
105 MN= NOT MN:IF MN THEN 200
110 IF X2<57 OR X2>190 OR Z1=1 THEN 130
115 X2=X2+D2:POKE 53250,X2:SOUND 3,PEEK(53770),2,1:RETURN
130 FOR T=200 TO 192 STEP -1:SOUND 0,T,12,2:POKE 706,T:NEXT T
135 POKE 53250,0:POKE 706,200:Z1=0:P2$=PM$:I=INT(RND(0)*2)
140 D2=LVL*(I=0)-LVL*(I>0):X2=57*(I=0)+190*(I>0):I=INT(RND(0)*3)+1
145 Y2=31*(I=1)+39*(I=2)+47*(I=3):IF D2<0 THEN P2$(Y2)=BR$:RETURN
150 IF D2>0 THEN P2$(Y2)=BL$:RETURN
200 IF X3<57 OR X3>190 OR Z2=1 THEN 220
205 X3=X3+D3:POKE 53251,X3:SOUND 2,PEEK(53770),2,1:RETURN
210 FOR T=200 TO 192 STEP -1:SOUND 0,T,12,2:POKE 707,T:NEXT T
220 POKE 53251,0:POKE 707,200:Z2=0:P3$=PM$:I=INT(RND(0)*2)
225 D3=LVL*(I=0)-LVL*(I>0):X3=57*(I=0)+190*(I>0):I=INT(RND(0)*3)+1
230 Y3=31*(I=1)+39*(I=2)+47*(I=3):IF D3<0 THEN P3$(Y3)=BR$:RETURN
235 IF D3>0 THEN P3$(Y3)=BL$:RETURN
250 I=INT(RND(0)*18)+1:LOCATE I,5,Z:T=132*(Z=132 OR Z=162)+162*(Z=161)+35*(Z=35)
255 COLOR T:PLOT I,5:RETURN
1000 ST=PEEK(632):GOSUB 100:POKE 53278,1:IF PEEK(53260)>0 THEN GOSUB 1200
1001 IF LVL>5 THEN GOSUB 250
1002 IF PEEK(644)=0 AND ST<12 THEN 1100
1005 X=INT((X1-44)/8):Y=INT((Y1-16)/8):LOCATE X,Y+2,Z:IF Z=132 THEN 1250
1010 IF Z=32 THEN Y1=Y1+1:IF ST>12 THEN P0$(Y1)=R1$
1015 IF (ST=10 OR ST=6 OR ST=14) AND Z<>32 THEN 1150
1030 X=X-(ST>8 AND ST<12)+(ST<8):IF X<1 OR X>18 THEN 1035
1032 X1=X1-2*(ST>8 AND ST<12)+2*(ST<8):WLK= NOT WLK
1035 IF ST<8 THEN 1060
1037 IF ST>12 THEN 1000
1040 IF WLK=0 THEN P0$(Y1)=R1$
1045 IF WLK=1 THEN P0$(Y1)=R2$
1055 POKE 53248,X1:GOTO 1000
1060 IF WLK=0 THEN P0$(Y1)=L2$
1065 IF WLK=1 THEN P0$(Y1)=L1$
1075 POKE 53248,X1:GOTO 1000
1100 SOUND 0,143,10,3:SOUND 1,147,10,3:POKE 53249,X1-17*(ST>8)+9*(ST<8)
1105 GOSUB 100:IF ST>8 THEN P0$(Y1)=R1$:P1$(Y1+3)="U*"
1110 IF ST<8 THEN P0$(Y1)=L1$:P1$(Y1+3)="*U"
1115 POKE 705,PEEK(20):IF PEEK(53261)=4 THEN Z1=1:GOSUB 60
1120 IF PEEK(53261)=8 THEN Z2=1:GOSUB 60
1125 POKE 53278,1:IF PEEK(53260)>=4 THEN GOSUB 1200
1130 SOUND 0,0,0,0:SOUND 1,0,0,0:P1$=PM$:POKE 53249,255:POKE 53278,1:GOTO 1005
1150 FOR Q=0 TO 10:SOUND 0,100,8,10-Q:IF X1<57 OR X1>191 THEN 1165
1160 X1=X1-(ST=10)+(ST=6)
1165 Y1=Y1-1:IF ST=14 THEN P0$(Y1)=L2$
1170 IF ST>8 AND ST<12 THEN P0$(Y1)=R1$
1175 IF ST<8 THEN P0$(Y1)=L1$
1180 POKE 53278,1:GOSUB 100:IF PEEK(53260)>=4 THEN GOSUB 1200
1185 POKE 53248,X1:NEXT Q:GOTO 1000
1200 FOR T=15 TO 0 STEP -1:SOUND 1,PEEK(53770),10,T:NEXT T
1205 PWR=PWR-1:IF PWR<-1 THEN 1250
1210 COLOR 32:PLOT 11+PWR,11:RETURN
1250 POP :FOR I=0 TO 3:SOUND I,0,0,0:NEXT I
1255 FOR T=0 TO 15:SOUND 0,PEEK(53770),8,T:SOUND 1,PEEK(53770),12,T:NEXT T
1260 FOR T=15 TO 0 STEP -1:SOUND 0,PEEK(53770),8,T
1270 SOUND 1,PEEK(53770),12,T:FOR I=704 TO 711:POKE I,T:NEXT I:NEXT T
1275 FOR T=0 TO 300:NEXT T:P0$=PM$:P1$=P0$:P2$=PM$:P3$=PM$:GOTO 8000
1300 FOR T=140 TO 126 STEP -0.3:SOUND 0,T,8,2:SOUND 1,T,12,2:POKE 704,T
1305 NEXT T:P0$=PM$:P1$=PM$:P2$=PM$:P3$=PM$:FOR T=0 TO 3:SOUND T,0,0,0
1310 POKE 53248+T,0:NEXT T:POKE 559,0:POKE 711,146:POSITION 0,0
1315 ? #6;"!!!!############!!!!";
1320 ? #6;"#  !!!!!!!!!!!#!!  !";
1325 ? #6;"#            !!!   ┐";
1330 ? #6;"##                 ┐";
1335 ? #6;"###                ┐";
1340 ? #6;"!!!!!!!!!!!!!!!!!!!!";
1345 P3$(36)=H$:P0$(39)=R1$:POKE 53251,80:POKE 53248,120:POKE 559,46
1350 POKE 707,255:FOR T=0 TO 400:NEXT T:TMR=0
1355 IF TMR<60 THEN POSITION 0,11:? #6;"YOU HAVE EARNED "
1360 IF TMR>60 AND TMR<120 THEN POSITION 0,11:? #6;"YOUR FREEDOM    "
1365 IF TMR>120 AND TMR<200 THEN POSITION 0,11:? #6;"FREEDOM???      "
1370 IF TMR>200 AND TMR<250 THEN POSITION 0,11:? #6;"I WAS INNOCENT  "
1375 IF TMR>250 AND TMR<280 THEN POSITION 0,11:? #6;"TO BEGIN WITH   "
1380 IF TMR>280 THEN POSITION 0,11:? #6;"HA HA HA HA HA"
1385 TMR=TMR+1:POKE 707,248+4*(RND(0)*1):IF TMR<310 THEN 1355
1390 GOTO 1260
5500 POKE 559,0:DIM F$(1),F2$((INT(ADR(F$)/1024)+1)*1024-ADR(F$)-1),PM$(384),M$(128)
5505 DIM P0$(128),P1$(128),P2$(128),P3$(128)
5510 PM$="♥":PM$(384)="♥":PM$(2)=PM$:M$=PM$:P0$=M$:P1$=P0$:P2$=P1$:P3$=P2$
5515 POKE 54279,ADR(PM$)/256:POKE 53277,3:POKE 623,24:POKE 53257,1
5520 DIM L1$(18),L2$(18),R1$(18),R2$(18),BL$(12),BR$(12),H$(10)
5530 L1$="♥▂↑←▂0lr<Lp<▂vf▘▘♥"
5540 L2$="♥▂↑←▂0|n^^\>7ccCC♥"
5545 R1$="♥p8xp▘6N<2▂<pog00♥"
5550 R2$="♥p8xp▘>v♠♠;|lFFCC♥"
5555 BL$="♥♥<◀]I▶▶◀<♥♥"
5560 BR$="♥♥<◀;┼▶▶◀<♥♥"
5565 H$="♥<◀♠|▶▶?→♥":RETURN
8000 POKE 559,46:GOSUB 40:POSITION 0,0:POKE 711,146:POKE 53248,120
8005 ? #6;"!!!!############!!!!";
8010 ? #6;"#  !!!!!!!!!!!!!!  !";
8015 ? #6;"#                  ┐";
8020 ? #6;"##                 ┐";
8025 ? #6;"###                ┐";
8030 ? #6;"!!!!!!!!!!!!!!!!!!!!";
8035 POKE 53251,80:P3$(36)=H$:P0$(39)=R1$:SOUND 0,121,10,4:SOUND 1,162,10,4
8040 SOUND 2,64,12,3:FOR T=0 TO 50:NEXT T:POKE 559,46:FOR T=0 TO 50:NEXT T
8045 FOR T=128 TO 140 STEP 0.5:POKE 704,T:SOUND 3,T,8,T-128:NEXT T
8050 FOR T=252 TO 255 STEP 0.5:POKE 707,T:SOUND 3,T,6,T-252:NEXT T
8055 FOR T=4 TO 0 STEP -0.3:SOUND 0,182,10,T:SOUND 1,144,10,T:SOUND 2,64,12,T
8060 NEXT T:SOUND 3,0,0,0:TMR=0
8065 POKE 707,248+6*((RND(0)*2)>1):TMR=TMR+1
8070 IF TMR>210 THEN POSITION 0,11:? #6;"press FIRE to start";:GOTO 8100
8075 IF TMR>60 AND TMR<90 THEN POSITION 0,11:? #6;"GUILTY AS CHARGED"
8080 IF TMR>90 AND TMR<120 THEN POSITION 0,11:? #6;"but i am innocent"
8085 IF TMR>120 AND TMR<160 THEN POSITION 0,11:? #6;"     GUILTY      "
8090 IF TMR>160 THEN POSITION 0,11:? #6;"TO THE DOOM CHAMBER"
8092 IF PEEK(644)=0 THEN TMR=210
8095 GOTO 8065
8100 FOR T=140 TO 128 STEP -0.3:POKE 704,T:SOUND 3,T,6,T-128:NEXT T:POKE 704,0
8110 POKE 707,248+6*((RND(0)*2)>1):IF PEEK(644) THEN 8110
8115 SC=0:PWR=9:TMR=0:Y1=39:X2=0:X3=0:LVL=1:P0$(Y1)=L2$
8120 POKE 704,170:POKE 559,0:POKE 53251,0:POKE 53248,0:POSITION 0,0
8125 ? #6;"!!!!##!!!!!!!!##!!!!";
8130 ? #6;"┐  !!!!      !!!!  !";
8135 ? #6;"┐                  #";
8140 ? #6;"┐                  !";
8145 ? #6;"┐                  #";
8150 ? #6;"!!##!#!!###!!!##!!#!":POSITION 0,11:? #6;"0        ":POKE 559,46
8155 COLOR 192:PLOT 9,11:DRAWTO 19,11:FOR T=4 TO 1 STEP -1:COLOR 32
8160 PLOT 0,T:FOR I=15 TO 6 STEP -0.5:SOUND 0,237,10,I:SOUND 1,192,12,I
8165 NEXT I:NEXT T:FOR X1=48 TO 64 STEP 0.5:SOUND 2,X1,10,2:POKE 53248,X1
8170 NEXT X1:FOR T=1 TO 4:COLOR 5:PLOT 0,T:FOR I=6 TO 0 STEP -0.3
8175 SOUND 0,237,10,I:SOUND 1,192,12,I:NEXT I:NEXT T:SOUND 2,0,0,0
8180 POKE 711,32:GOTO 1000
10000 RESTORE 11100:READ DNUM
10010 D=PEEK(560)+256*PEEK(561)
10020 FOR I=1 TO DNUM:READ B:POKE D+B,PEEK(D+B)+128:NEXT I
10030 B=INT(ADR(DLI$)/256):A=ADR(DLI$)-B*256:POKE 512,A:POKE 513,B
10040 POKE 54286,192:POKE 256,Z:RETURN
11000 DIM DLI$(55):DLI$="H-♥├n♥├▔◣TI♥P╲))▔▎Ph@I├P╲)'▔▎Ph@)♥▔♥├)>▔"
11010 DLI$(41)="▎P-●♥▔┴P) ▔└Ph@":RETURN
11100 DATA 3,10,11,12
20000 POKE 559,0:CHR=38912:I=256*224:POKE 756,152
20005 DIM C$(126)
20006 C$(1,63)="├♠▶?▶♠▶_◀▕├A▶▶o▶◀w┘___♥♠♠♠♥┤♥♥♥as▶▶▶┐zrbC╱▂←?╱▶?<←▂→?▶╲px<<←←▖▖"
20007 C$(64,126)="◢N▂←<<>▶▶▗╲╲▖▖←◀|x◣♥0dfscw>▝♥Z▶kCffC▘♥>crh◆♠6▔♥xnCg3♠^ ♥ 08<80 "
20010 MOV=ADR("hh┐qh┐ph┐Uh┐Th┐oh┐n ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆")
20015 I=USR(MOV,57344,38912,1024)
20020 FOR X=1 TO LEN(C$) STEP 9
20030 OFFSET=ASC(C$(X,X))
20035 Z=USR(MOV,ADR(C$(X+1)),CHR+OFFSET*8,8):NEXT X
20040 Z=7:RETURN