Icon Animation System with samples (ANIMATOR.BAS)
Icon Animation System with samples by Jim Johnson, 239
Description
Icon Animation System with samples by Jim Johnson, 239
From the Antic disk of June 1989 (Vol. 8 No. 2) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 6.6 KB
- Dialect
- Atari BASIC
- Lines
- 160
- Variables
C0,C1,C2,C3,C4,C5,C6,C7,C8,C9,C20,MAX,MODE,OFF,WAIT,FILENAME$,KEY$,B$,G$,G2$,SEQ$,SCRIPT$,SRADR,PICT,BADR,IOCB,ADRHI,ADRLO,OLDX,OLDY,CURX,CURY,KEY,FRAMES,I,X,L,SCRMEM,ICON,SECTR1,SECTR,I2,DELAY,PAUSE,FRAME,NM,NMHI,NMLO,K,BRK,C100
BASIC listing (160 lines)
100 REM ICON ANIMATION SYSTEM, LISTING 1, THE ANIMATOR
103 REM BY JIM JOHNSON
106 REM (c)1989 ANTIC PUBLISHING INC.
110 C0=0:C1=1:C2=2:C3=3:C4=4:C5=5:C6=6:C7=7:C8=8:C9=9:C20=20:MAX=C20+C5
120 MODE=C6:OFF=40000:WAIT=10
130 DIM FILENAME$(20),KEY$(C3)
140 DIM B$(128),G$(616),G2$(616*MAX)
150 DIM SEQ$(101),SCRIPT$(10*10)
160 SRADR=ADR("hh▔┐┘h▔┤┘h▔▝┘h▔◣┘hh▔├┘hh*)R▔▕┘ SdJ-┘┘I├p┤◆♥Pq)♥┐U-┘┘┐T◆")
170 PICT=ADR("hh┐Lh┐Kh┐Nh┐Mhh┐Ohh*hh┐P$O◢1M┌K◢@▶Pw┴%KeP┐K♣▕fL┴%MeO┐M♣▕fNJP[◆")
180 B$="♥":B$(128)=B$:B$(C2)=B$:BADR=ADR(B$)
190 G$="♥":G$(616)=G$:G$(C2)=G$
200 IOCB=832+16:ADRHI=INT(ADR(G2$)/256):ADRLO=ADR(G2$)-ADRHI*256
260 GOSUB 31000:TRAP OFF:GOSUB 1630:POSITION C2,C3
270 ? " ┌─┐":? " | | CREATE ANIMATION FILE":? " └─┘"
280 ? " ┌─┐":? " | | LOAD ANIMATION FILE":? " └─┘"
290 ? " ┌─┐":? " | | SAVE ANIMATION FILE":? " └─┘"
300 ? " ┌─┐":? " | | SEQUENCER":? " └─┘"
310 ? " ┌─┐":? " | | VIEW ANIMATION":? " └─┘"
320 ? " ┌─┐":? " | | SCRIPTER":? " └─┘"
330 GOSUB 1680
340 OLDX=C5:OLDY=C4:CURX=OLDX:CURY=OLDY
350 CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY
360 IF KEY=45 AND CURY>C4 THEN CURY=CURY-C3:GOTO 450
370 IF KEY=61 AND CURY<19 THEN CURY=CURY+C3:GOTO 450
380 IF KEY=155 AND CURY=C4 THEN 470
390 IF KEY=155 AND CURY=C7 THEN 1460
400 IF SEQ$="" THEN 440
410 IF KEY=155 AND CURY=10 THEN 1330
420 IF KEY=155 AND CURY=13 THEN 1170
430 IF KEY=155 AND CURY=16 THEN 960
440 IF KEY=155 AND CURY=19 THEN TRAP 260:RUN "D:SCRIPTER.BAS"
450 POSITION OLDX,OLDY:? " ";:POSITION CURX,CURY:? " ";:OLDX=CURX:OLDY=CURY
460 GOTO 350
470 GOSUB 1630:GOSUB 1680:POKE 752,C0
480 ? :? " How many pictures do you wish to":? " load (maximum=";MAX;")";:INPUT KEY$:IF KEY$="" THEN 260
490 FRAMES=VAL(KEY$):SEQ$="":FOR I=C1 TO FRAMES:SEQ$(I,I)=CHR$(I):NEXT I:IF FRAMES>MAX THEN FRAMES=MAX
500 POKE 752,C1:POSITION C4,22:? "INSERT GRAPHICS DISK, PRESS RETURN":CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY
510 X=USR(SRADR,BADR,361,C1,C3):IF B$(C1,15)="PRINT SHOP:CLK!" THEN 530
520 POSITION C7,C8:? "* NOT PRINT SHOP FORMAT *↰";:FOR I=C1 TO 300:NEXT I:GOTO 470
530 GOSUB 1690
540 L=ADR(G$):SCRMEM=PEEK(88)+PEEK(89)*256+C4+C4*20
560 REM LOAD ICONS
570 ICON=C0
580 FOR SECTR1=362 TO 393:X=USR(SRADR,BADR,SECTR1,C1,C3)
590 FOR I=C0 TO 96 STEP 32:REM If B$(X+19,X+19)<>"X" And B$(X+20,X+20)<>"x" Then Pop :Pop :Goto 570
600 ICON=ICON+C1
610 SECTR=ASC(B$(I+17,I+17))+256*ASC(B$(I+18,I+18))
620 FOR I2=C0 TO 378 STEP 126:X=USR(SRADR,BADR,SECTR,C1,C3)
630 G$(I2+C1,I2+126)=B$(C1,126):SECTR=ASC(B$(127,127))+256*ASC(B$(128,128)):NEXT I2
640 X=USR(SRADR,BADR,SECTR,C1,C3):G$(505,572)=B$(C1,68)
650 X=USR(SRADR,BADR,SECTR1,C1,C3)
660 X=USR(PICT,SCRMEM,L,11,52,C20)
670 G2$(C1+616*(ICON-C1))=G$
680 IF ICON=FRAMES THEN 970
690 NEXT I:NEXT SECTR1
950 REM DISPLAY IMAGES
960 GOSUB 1690
970 L=ADR(G$):SCRMEM=PEEK(88)+PEEK(89)*256+C4+C4*20
980 FOR I=C1 TO LEN(SEQ$)
990 IF ASC(SEQ$(I,I))=C0 THEN GOSUB 1590:GOTO 1020
1000 L=ADR(G2$)+616*(ASC(SEQ$(I,I))-C1)
1010 X=USR(PICT,SCRMEM,L,11,52,C20)
1020 FOR DELAY=C1 TO WAIT:IF PEEK(764)<>255 THEN GOSUB 1060
1025 NEXT DELAY:POKE 77,C0
1030 IF PEEK(764)<>255 THEN GOSUB 1060
1040 NEXT I
1050 POKE 764,255:GOTO 980
1060 CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY
1070 IF KEY=155 AND CURX=C4 THEN WAIT=WAIT+C1+C4*(WAIT>29)+C5*(WAIT>45)+10*(WAIT>90)
1080 IF KEY=155 AND CURX=11 THEN WAIT=WAIT-C1-C4*(WAIT>30)-C5*(WAIT>50)-10*(WAIT>100):IF WAIT<C0 THEN WAIT=C0
1090 IF KEY=155 AND CURX=18 THEN PAUSE= NOT PAUSE
1100 IF KEY=155 AND CURX=25 AND PAUSE THEN 1270
1110 IF KEY=155 AND CURX=32 THEN POP :POP :GOTO 260
1120 IF KEY=42 AND CURX<32 THEN CURX=CURX+C7:POKE 657,OLDX:? " ";:POKE 657,CURX:? " ";:OLDX=CURX
1130 IF KEY=43 AND CURX>C4 THEN CURX=CURX-C7:POKE 657,OLDX:? " ";:POKE 657,CURX:? " ";:OLDX=CURX
1140 IF PAUSE THEN 1060
1150 RETURN
1160 GOSUB 1060
1170 REM SEQUENCER
1180 GOSUB 1630:GOSUB 1680
1190 ? :? "ENTER '0' TO PAUSE SEQUENCE."
1200 FRAME=C1:SEQ$="":?
1210 ? "FRAME #";FRAME;":◀◀◀◀";
1220 INPUT KEY$:IF KEY$="" AND SEQ$="" THEN SEQ$=CHR$(C1):GOTO 960
1230 IF KEY$="" THEN FRAME=FRAME-C1:GOTO 960
1240 KEY=VAL(KEY$):IF KEY<C0 OR KEY>FRAMES THEN ? "↰↑";:GOTO 1210
1250 SEQ$(FRAME,FRAME)=CHR$(KEY)
1260 FRAME=FRAME+C1:IF FRAME<101 THEN 1210
1265 FRAME=FRAME-C1:GOTO 960
1270 REM ADVANCE
1280 I=I+C1:IF I>LEN(SEQ$) THEN I=C1
1290 IF ASC(SEQ$(I,I))=C0 THEN 1280
1300 L=ADR(G2$)+616*(ASC(SEQ$(I,I))-C1)
1310 X=USR(PICT,SCRMEM,L,11,52,C20)
1320 GOTO 1060
1325 REM SAVE SEQUENCE FILE
1330 GOSUB 1630:GOSUB 1680:TRAP 3000
1340 POSITION C2,C3:? "USE FORMAT: 'DEV:FILENAME.EXT'"
1350 POKE 752,C0:POSITION C2,C5:? "FILENAME TO SAVE?";:POKE 764,255
1360 ON PEEK(764)=255 GOTO 1360:IF PEEK(764)=28 THEN CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY:GOTO 260
1370 ? "←";:INPUT FILENAME$:IF FILENAME$="" THEN GOSUB 2320:GOTO 1350
1380 CLOSE #C1:OPEN #C1,C8,C0,FILENAME$
1390 SEQ$(LEN(SEQ$)+C1)=CHR$(FRAMES):? #C1;SEQ$
1400 POKE IOCB+C2,11
1410 POKE IOCB+C4,ADRLO:POKE IOCB+C5,ADRHI
1420 NM=616*FRAMES:NMHI=INT(NM/256):NMLO=NM-NMHI*256
1430 POKE IOCB+C8,NMLO:POKE IOCB+C9,NMHI
1440 X=USR(ADR("hhh*LVd"),16)
1450 CLOSE #C1:SEQ$=SEQ$(C1,LEN(SEQ$)-C1):GOTO 260
1455 REM LOAD SEQUENCE FILE
1460 GOSUB 1630:GOSUB 1680:TRAP 3000
1470 POSITION C2,C3:? "USE FORMAT: 'DEV:FILENAME.EXT'":SEQ$=""
1480 POKE 752,C0:POSITION C2,C5:? "FILENAME TO LOAD?";:POKE 764,255
1490 ON PEEK(764)=255 GOTO 1490:IF PEEK(764)=28 THEN CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY:GOTO 260
1500 ? "←";:INPUT FILENAME$:IF FILENAME$="" THEN GOSUB 2320:GOTO 1480
1510 CLOSE #C1:OPEN #C1,C4,C0,FILENAME$
1520 INPUT #C1;SEQ$:FRAMES=ASC(SEQ$(LEN(SEQ$),LEN(SEQ$))):SEQ$=SEQ$(C1,LEN(SEQ$)-C1)
1530 POKE IOCB+C2,C7
1540 POKE IOCB+C4,ADRLO:POKE IOCB+C5,ADRHI
1550 NM=616*FRAMES:NMHI=INT(NM/256):NMLO=NM-NMHI*256
1560 POKE IOCB+C8,NMLO:POKE IOCB+C9,NMHI
1570 X=USR(ADR("hhh*LVd"),16)
1580 CLOSE #C1:GOTO 960
1590 REM PAUSE
1600 FOR DELAY=C1 TO 100
1610 IF PEEK(764)<>255 THEN GOSUB 1060
1620 NEXT DELAY:RETURN
1630 REM TITLE SCREEN
1640 GRAPHICS C0:POKE 709,C0:POKE 710,C0:GOSUB 31000:POKE 752,C1
1650 POSITION C0,C0:? " Icon Animation System * SEQUENCER * "
1660 POSITION C0,C1:? "________________________________________"
1670 RETURN
1680 FOR I=C1 TO 10:POKE 710,I:NEXT I:RETURN
1690 GRAPHICS MODE:GOSUB 31000:POKE 752,C1:PAUSE=C0
1700 POKE 708,C0:POKE 709,C0:POKE 710,C0:POKE 712,C0
1710 COLOR C1:PLOT 30,C2:DRAWTO 121,C2:DRAWTO 121,57:DRAWTO 30,57:DRAWTO 30,C2
1720 ? " ┌─┐ ┌─┐ ┌─┐ ┌─┐ ┌─┐"
1730 ? " | |SLOW| |FAST| |PAUS| |ADV.| |EXIT"
1740 ? " └─┘ └─┘ └─┘ └─┘ └─┘"
1750 OLDX=C4:OLDY=C1:CURX=OLDX:CURY=OLDY
1760 POKE 656,CURY:POKE 657,CURX:? " ";
1770 FOR I=C1 TO 10:POKE 710,I:POKE 712,I:NEXT I:RETURN
1780 RETURN
2320 REM DIRECTORY
2340 G$(C1)=" ":G$(616)=" ":G$(C2)=G$:K=C0:L=C0:POKE 752,C1
2350 CLOSE #C1:OPEN #C1,C6,C0,"D1:*.*"
2360 INPUT #C1,FILENAME$
2370 IF FILENAME$(C4,11)="SHOP:CLK" THEN GOSUB 2440:RETURN
2380 IF FILENAME$(C5,C8)="FREE" THEN CLOSE #C1:GOTO 2410
2390 G$(17*K+C1,17*K+LEN(FILENAME$))=FILENAME$:K=K+C1
2400 GOTO 2360
2410 FOR I=C0 TO 13:POSITION C1,C7+I:? G$(17*(L+I)+C1,17*(L+I)+17);" ";G$(17*(L+I+14)+C1,17*(L+I+14)+17)
2420 NEXT I:? :? FILENAME$;" ";
2430 RETURN
2440 POSITION 2,22:? " * PRINT SHOP FORMAT *↰";:RETURN
3000 REM ERROR MSG
3010 CLOSE #C1:POKE 703,C4:POKE 752,C1:? "↰":? " * FILE ACCESS ERROR * ↰";
3020 FOR I=C1 TO 100:NEXT I:POKE 703,24:GOTO 260
31000 BRK=USR(ADR("h)♥┐MhhI♥p╲)p┐♣▔▂R◆"),C1):RETURN :REM DISABLES BREAK WHEN ARG=1
