Yak-Spell quiz maker (SPLBLD.BAS)

Yak-Spell quiz maker, 25

Description

Yak-Spell quiz maker, 25

From the Antic disk of May 1989 (Vol. 8 No. 1) — disk B.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.1 KB

Dialect
Atari BASIC
Lines
104
Variables
Z, L, DRV, SPL$, FL$, IO$, W$, TLK$, CLEAR, I, Y, WORD, LEARN, J, SPEAK, W, A
BASIC listing (104 lines)
5 REM YAK-SPELL BUILD
10 REM BY MATTHEW RATCLIFF
15 REM (c)1989, ANTIC PUBLISHING INC.
20 Z=0:L=1:DRV=L
30 DIM SPL$(440),FL$(20),IO$(15),W$(20),TLK$(15)
40 GRAPHICS Z
50 ? "Stick-port 1, VM JR-port 2, VM800 run":? "Press RTN"
60 INPUT W$
70 ? "↰Yak-Spell Build"
80 GOSUB 460
90 ? "<NEW> output file ?":GOSUB 720
100 TRAP 110:CLOSE #L:OPEN #L,8,Z,IO$:GOTO 120
110 ? "CAN'T OPEN FILE ";IO$:GOTO 90
120 CLOSE #L:CLEAR=USR(1682)
130 FOR I=L TO 20
140 ? "↰*Yak-Spell Builder*":? :? "(RTN=done)":? "Word ";I;" of 20 MAX"
150 ? "TYPE word: ";:INPUT FL$
160 IF LEN(FL$) THEN 200
170 ? "Finished ";:GOSUB 950
180 IF Y THEN POP :GOTO 250
190 GOTO 150
200 ? "You typed ";FL$:? "OK ";:GOSUB 950
210 IF  NOT (Y) THEN 140
220 WORD=I:GOSUB 590
230 NEXT I
240 ? "Space exhausted."
250 I=WORD
260 ? "Putting it away-"
270 ? "Say 'correct'"
280 ? "or other word/phrase"
290 ? "for spelling OK "
300 FL$="CORRECT":WORD=21:GOSUB 590
310 ? "Say 'try again' or some other"
320 ? "word/phrase for"
330 ? "an incorrect spelling":FL$="TRY AGAIN":WORD=22:GOSUB 590
340 WORD=I:GOSUB 830:GOSUB 930
350 ? "Print words ";:GOSUB 950
360 IF  NOT Y THEN 430
370 TRAP 380:CLOSE #L:OPEN #L,8,Z,"P:":GOTO 390
380 ? "Print error ";PEEK(195):CLOSE #L:GOTO 350
390 ? #L;"Spell  file: ";IO$
400 ? #L;"Total words: ";WORD
410 GOSUB 850:CLOSE #L:OPEN #L,8,0,"P:"
420 ? #L;CHR$(12);:CLOSE #L:? "↰List done.":? :?
430 ? :? "End ";:GOSUB 950
440 IF Y THEN GRAPHICS Z:END
450 GOTO 40
460 ? "Current disk drive #";DRV
470 ? "Enter drive for a list"
480 ? "of spell files, or press [RTN]"
490 ? "to use curr drive ";:INPUT FL$
500 TRAP 460:IF LEN(FL$) THEN DRV=VAL(FL$)
510 IF DRV<L OR DRV>8 THEN 460
520 FL$="D1:*.SPL":FL$(2,2)=CHR$(DRV+48)
530 TRAP 540:CLOSE #L:OPEN #L,7,Z,FL$:GOTO 550
540 ? "I/O ERR ON ";FL$:? "PRESS RTN":INPUT FL$:GOTO 460
550 TRAP 570:? "↰Spell Data Files"
560 INPUT #L,FL$:? FL$:GOTO 560
570 CLOSE #L
580 RETURN
590 ? :? "Say word #";WORD;"->";FL$
600 LEARN=USR(1670,(WORD))
610 FOR J=L TO 50:NEXT J
620 SPEAK=USR(1676,(WORD)):GOSUB 1000
630 ? "fire to continue,"
640 ? "pull back on stick to RELEARN ?";
650 IF STRIG(Z)=Z THEN 680
660 IF STICK(Z)=15 THEN 650
670 GOTO 590
680 IF LEN(FL$)=20 THEN 700
690 FOR W=LEN(FL$)+L TO 20:FL$(W,W)=CHR$(155):NEXT W
700 W=20*(WORD-L)+L:SPL$(W,W+19)=FL$
710 RETURN
720 ? "Enter NAME ?":? "(Press RTN only for DIR)"
730 ? "<Name only,not drv or ext>?"
740 INPUT FL$:IF LEN(FL$) THEN 760
750 GOSUB 460:GOTO 740
760 IO$="D1:":IO$(2,2)=CHR$(DRV+48)
770 IO$(4)=FL$:IO$(LEN(IO$)+L)=".SPL"
780 TLK$(L,3)=IO$(L,3):TLK$(4)=FL$:TLK$(LEN(TLK$)+L)=".SPK"
790 ? "File is ";IO$
800 ? "Right ";:GOSUB 950
810 IF Y THEN RETURN
820 GOTO 790
830 ? "↰Writing file ";IO$
840 CLOSE #L:OPEN #L,8,Z,IO$:? #L,WORD:I=WORD
850 FOR W=L TO I
860 WORD=20*(W-L)+L
870 FOR J=WORD TO WORD+19
880 IF SPL$(J,J)=CHR$(155) THEN POP :GOTO 900
890 ? #L;SPL$(J,J);:NEXT J
900 ? #L
910 NEXT W
920 CLOSE #L:RETURN
930 W=USR(1766,ADR(TLK$))
940 RETURN
950 ? "(Y/N) ";:INPUT W$
960 IF LEN(W$)=Z THEN ? :GOTO 950
970 IF W$(L,L)="Y" OR W$(L,L)="y" THEN Y=L:RETURN
980 IF W$(L,L)="N" OR W$(L,L)="n" THEN Y=Z:RETURN
990 ? :GOTO 950
1000 A=PEEK(16640)+256*PEEK(16641)-16384+256
1010 ? "Total Size = ";A
1020 RETURN