VCR Label v1.0 (VCRLABEL.BAS)

VCR Label v1.0 by Frank Walters, 57

Description

VCR Label v1.0 by Frank Walters, 57

From the Antic disk of May 1989 (Vol. 8 No. 1) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 7.0 KB

Dialect
Atari BASIC
Lines
158
Variables
TYPE, Z$, P$, X$, L, BL$, DLT$, I, C, K, WIDE$, LINE1$, WIDEOFF$, C$, U1$, LINE2$, T$, U2$, N1$, N2$, N3$, N4$, N5$, N6$, C1$, C2$, C3$, T1$, T2$, T3$, BOLD$, P66$, P88$, BOX$, TOP$, UON$, UOFF$, TOT, BRK, JNK
BASIC listing (158 lines)
1 REM VCR LABEL  1.0
2 REM BY FRANK WALTERS
3 REM (c)1989, ANTIC PUBLISHING INC.
4 BRK=(PEEK(53279)<>5):GOSUB 31000
5 TYPE=0
10 IF TYPE<1 OR TYPE>6 THEN 4000
20 GOTO 1000
100 ? :? "Title ";Z$;" - don't type over SPACE":?
110 POKE 752,0:? P$;:INPUT #16;X$
120 L=LEN(X$):IF L<33 THEN X$(L+1,33)=BL$(L+1,33)
130 IF X$(17,17)<>" " THEN ? "↑↑↑";DLT$;" Do not write in↓␛↓↑THIS SPACE↰":? :GOTO 110
140 FOR I=1 TO 33:IF X$(I,I)="_" THEN X$(I,I)=" "
150 NEXT I:POKE 752,1
160 RETURN
190 ? "↑→→→→→→→→→→→→→→→→→→→→→→0000◀◀◀◀":C=0:GOTO 220
200 POKE 752,0:TRAP 190:? :? "Tape counter (0-9999) ◀◀◀◀◀◀◀◀";:INPUT #16;C:C=INT(ABS(C)):X$=""
210 IF C>9999 THEN ? :? "Maximum 4 whole digits.↑↑↑↑":GOTO 200
220 TRAP 40000:IF C<1000 THEN X$="0":IF C<100 THEN X$="00":IF C<10 THEN X$="000"
230 X$(LEN(X$)+1)=STR$(C):POKE 752,1
240 TRAP 40000:RETURN
300 POKE 752,0:? :? "Program ";Z$;" time (h mm) ◀◀◀◀◀◀";:INPUT #16;X$
310 IF LEN(X$)<>4 THEN X$="0:00"
320 IF X$(2,2)=" " THEN X$(2,2)=":"
330 IF X$(2,2)<>":" OR LEN(X$)<>4 THEN ? "↑↑";:GOTO 300
340 TRAP 40000:POKE 752,1:RETURN
400 GOSUB 31000:CLOSE #4:OPEN #4,4,0,"K:":GET #4,K:IF (K<32 AND K<>27) OR K>124 THEN 400
410 CLOSE #4:? CHR$(K);:RETURN
500 ? #1;WIDE$;LINE1$;WIDEOFF$;C$
510 ? #1;U1$;WIDE$;LINE2$;WIDEOFF$;T$;U2$
520 RETURN
1000 DIM N1$(16),N2$(16),N3$(16),N4$(16),N5$(16),N6$(16)
1005 DIM X$(33),P$(66),C1$(4),C2$(4),C3$(4),C$(4),BL$(33),DLT$(19)
1010 DIM T1$(4),T2$(4),T3$(4),T$(4),LINE1$(16),LINE2$(16),WIDE$(6),WIDEOFF$(4),BOLD$(4),P66$(4),P88$(4),BOX$(21)
1020 DIM TOP$(36),Z$(1),UON$(4),UOFF$(4),U1$(4),U2$(4)
1030 P$="________________ ________________←←←←←←←←←←←←←←←←←←←←←←←←←←←←←←←←←←":BOX$="─────────────────────"
1040 TOP$=" VCR LABEL MAKER  by Frank Walters "
1050 BL$(1)=" ":BL$(33)=BL$:BL$(2)=BL$:DLT$(1)="↑":DLT$(19)=DLT$:DLT$(2)=DLT$
1060 ON TYPE GOSUB 4100,4200,4300,4400,4500,4600
1070 IF TYPE>4000 THEN 4060
2000 POKE 82,2:GRAPHICS 0:POKE 710,194:POKE 709,204:POKE 752,1:? TOP$:GOSUB 31000
2010 ? :? "Number of titles on label (1-3)> ";
2020 GOSUB 400:K=K-48
2030 IF K<1 OR K>3 THEN ? "←";:GOTO 2020
2040 TOT=K:?
2100 Z$="1":GOSUB 100
2110 N1$=X$(1,16):N2$=X$(18,33)
2120 GOSUB 200:C1$=X$
2130 GOSUB 300:T1$=X$:? "↰";TOP$:POSITION 8,2:? "┌";BOX$;"┐":POSITION 8,3
2140 ? "|";N1$;" ";C1$;"|":POSITION 8,4:? "|";N2$;" ";T1$;"|":POSITION 8,5:? "└";BOX$;"┘"
2150 POSITION 8,7:? "▌Is this correct (Y/N)▌";
2160 GOSUB 400:IF K<>110 AND K<>78 AND K<>121 AND K<>89 THEN ? "←";:GOTO 2160
2170 ? :IF K=78 OR K=110 THEN 2100
2180 ON TOT GOTO 3000,2200,2200
2200 Z$="2":GOSUB 100
2210 N3$=X$(1,16):N4$=X$(18,33)
2220 GOSUB 200:C2$=X$
2230 GOSUB 300:T2$=X$:POSITION 2,5:? DLT$:POSITION 8,5
2240 ? "|";N3$;" ";C2$;"|":POSITION 8,6:? "|";N4$;" ";T2$;"|":POSITION 8,7:? "└";BOX$;"┘"
2250 POSITION 8,9:? "▌Is this correct (Y/N)▌";
2260 GOSUB 400:IF K<>110 AND K<>78 AND K<>121 AND K<>89 THEN ? "←";:GOTO 2260
2270 ? :IF K=78 OR K=110 THEN 2200
2280 ON TOT-1 GOTO 3000,2300
2300 Z$="3":GOSUB 100
2310 N5$=X$(1,16):N6$=X$(18,33)
2320 GOSUB 200:C3$=X$
2330 GOSUB 300:T3$=X$:POSITION 2,7:? DLT$:POSITION 8,7
2340 ? "|";N5$;" ";C3$;"|":POSITION 8,8:? "|";N6$;" ";T3$;"|":POSITION 8,9:? "└";BOX$;"┘"
2350 POSITION 8,11:? "▌Is this correct (Y/N)▌";
2360 GOSUB 400:IF K<>110 AND K<>78 AND K<>121 AND K<>89 THEN ? "←";:GOTO 2360
2370 ? :IF K=78 OR K=110 THEN 2300
2800 GOTO 3000
2900 TRAP 40000:? :? "↑↑↑↑↑";DLT$,"  PRINTER ERROR - ";PEEK(195)
3000 ? :? "      ▌[SPACE BAR] to print ▌":? "      ▌   [ESC]    to abort ▌"
3010 GOSUB 400:IF K<>32 AND K<>27 THEN ? "←";:GOTO 3010
3020 IF K=27 THEN CLOSE #4:CLOSE #1:RUN
3030 POKE 710,66:TRAP 2900:CLOSE #1:OPEN #1,8,0,"P:":? #1;BOLD$;
3040 IF TOT=3 THEN ? #1;P88$;:GOTO 3060
3050 ? #1;P66$;
3060 FOR I=1 TO TOT
3070 IF I=1 THEN LINE1$=N1$:LINE2$=N2$:C$=C1$:T$=T1$
3080 IF I=2 THEN LINE1$=N3$:LINE2$=N4$:C$=C2$:T$=T2$
3090 IF I=3 THEN LINE1$=N5$:LINE2$=N6$:C$=C3$:T$=T3$
3095 U1$="♥":U2$="♥":IF TOT=3 AND I<3 THEN U1$=UON$:U2$=UOFF$
3100 IF TOT=1 THEN ? #1;""
3110 IF TOT=2 AND I=TOT THEN ? #1;""
3120 GOSUB 500:NEXT I:? #1;"":IF TOT=3 THEN ? #1;""
3130 IF TOT=1 THEN ? #1;"":? #1;""
3140 CLOSE #1:?
3150 ? "↑↑↑";DLT$;:? "      ▌<1>Reprint same label▌":? "      ▌<2>Make new label    ▌"
3160 ? "      ▌<3>Quit              ▌"
3170 POKE 752,1:POKE 710,194:? :? "      ▌Select > ";
3180 GOSUB 400:K=K-48:IF K<1 OR K>3 THEN ? "←";:GOTO 3180
3190 ON K GOTO 3200,2000,3210
3200 ? "↑↑";DLT$;:GOTO 3030
3210 CLOSE #4:CLOSE #1:POKE 82,2:POKE 752,0:GRAPHICS 0:END
4000 POKE 710,66:? "↰NO PRINTER SUBROUTINE FOR TYPE ↰";TYPE
4010 ? :? "Select your printer type.":? :? "The following types are available:"
4020 ?
4021 ? "TYPE=1 OKIDATA 92/192  "
4022 ? "TYPE=2 EPSON/STAR NX-10"
4023 ? "TYPE=3 GEMINI 10X/SG-10"
4024 ? "TYPE=4 PANASONIC 1080  "
4025 ? "TYPE=5 C.ITOH PROWRITER"
4026 ? "TYPE=6 Other Printer   "
4030 ? :? "What type of printer do you have";:INPUT TYPE:GOTO 10
4050 ? :END
4060 ? "↰TYPE ";(TYPE-4000)/100;" Printer has not been tested.↰"
4070 ? "You must delete line ";TYPE+5;" before":? "using this printer sub-routine:"
4080 IF TYPE>4000 THEN LIST TYPE,TYPE+80:? :? :? TYPE+5;"↑↑";:POKE 710,66
4090 END
4100 REM OKIDATA 92/192
4110 WIDE$="↑→":REM 6CPI
4120 WIDEOFF$="↑":REM 12CPI
4130 P66$="␛6":REM 6 LINES/INCH
4140 P88$="␛8":REM 8 LINES/INCH
4150 BOLD$="␛1":REM CQ
4160 UON$="␛C":REM UNDERLINE ON
4170 UOFF$="␛D":REM UNDERLINE OFF
4180 RETURN
4200 REM EPSON/STAR NX-10
4210 WIDE$="␛M▂":REM 6 CPI
4220 WIDEOFF$="␛M●":REM 12CPI
4230 P66$="␛2":REM 6 LINES/INCH
4240 P88$="␛0":REM 8 LINES/INCH
4250 BOLD$="␛G":REM DBL STRIKE
4260 UON$="␛-├":REM UNDERLINE ON
4270 UOFF$="␛-♥":REM UNDERLINE OFF
4280 RETURN
4300 REM GEMINI 10X/STAR SG-10
4310 WIDE$="␛B▕␛W├":REM 6CPI (12CPI-DOUBLE WIDTH
4320 WIDEOFF$="␛W♥":REM 12CPI (DOUBLE WIDTH OFF)
4330 GOTO 4230
4400 REM PANASONIC 1080
4405 TYPE=4400:REM DELETE THIS LINE IF USING THIS SUB-ROUTINE
4410 WIDE$="␛M␛W├":REM 6CPI(12CPI-DOUBLE WIDTH ON)
4420 WIDEOFF$="␛W♥":REM 12CPI(DOUBLE WIDTH OFF)
4430 GOTO 4230
4500 REM C.ITOH PROWRITER
4505 TYPE=4500:REM DELETE THIS LINE IF USING THIS SUB-ROUTINE
4510 WIDE$="␛E▂":REM 6CPI(12CPI-DOUBLE WIDTH ON)
4520 WIDEOFF$="▖":REM 12CPI(DOUBLE WIDTH OFF)
4530 P66$="␛A":REM 6 LINES/INCH
4540 P88$="␛B":REM 8 LINES/INCH
4550 BOLD$="␛!":REM DOUBLE STRIKE
4560 UON$="␛X":REM UNDERLINE ON
4570 UOFF$="␛Y":REM UNDERLINE OFF
4580 RETURN
4600 REM OTHER PRINTER:ENTER YOUR CODES
4605 TYPE=4600:REM DELETE THIS LINE IF USING THIS SUB-ROUTINE
4610 WIDE$="♥♥♥♥♥♥":REM 6CPI(12CPI-DOUBLE WIDTH ON)
4620 WIDEOFF$="♥♥♥♥":REM 12CPI(DOUBLE WIDTH OFF)
4630 P66$="♥♥♥♥":REM 6 LINES/INCH
4640 P88$="♥♥♥♥":REM 8 LINES/INCH
4650 BOLD$="♥♥♥♥":REM DOUBLE STRIKE
4660 UON$="♥♥♥♥":REM UNDERLINE ON
4670 UOFF$="♥♥♥♥":REM UNDERLINE OFF
4680 RETURN
31000 JNK=USR(ADR("h)♥┐MhhI♥p╲)p┐♣▔▂R◆"),BRK):RETURN