Basic Enhancements creator (ENHANCE.BAS)

Basic Enhancements creator, 125

Description

Basic Enhancements creator, 125

From the Antic disk of May 1989 (Vol. 8 No. 1) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 15.2 KB

Dialect
Atari BASIC
Lines
222
Variables
Q$, CHOICE, Y
BASIC listing (222 lines)
10 REM BASIC ENHANCEMENTS
20 REM BY PAUL ALHART
25 REM (TYPE-IN VERSION BY C. JACKSON)
30 REM (c)1989, ANTIC PUBLISHING INC.
40 DIM Q$(1):Q$=CHR$(34):POKE 710,30:POKE 709,0:POKE 712,66
50 POKE 16,112:POKE 53774,112:? "↰↓        BASIC Enhancements":? :? "          by Paul Alhart":?
55 ? :? "  ( 1) BINLOAD","( 7) ERROR.164"
60 ? :? "  ( 2) DEC/HEX","( 8) LOCK":? :? "  ( 3) DELETE","( 9) OPENFILE"
70 ? :? "  ( 4) DIR","(10) RENAME":? :? "  ( 5) DRIVES","(11) UNLOCK"
80 ? :? "  ( 6) ERROR","(12) WRITEDOS":? :? :? ,"Your Choice";:INPUT CHOICE
85 TRAP 50:ON CHOICE GOSUB 100,200,400,500,1500,600,1900,1700,2000,1800,1750,2100
86 POKE 764,255:? :? "  (Press any key to continue...)"
88 IF PEEK(764)=255 THEN 88
90 POKE 764,255:GOTO 50
99 END
100 TRAP 40000:? "Creating BINLOAD":CLOSE #1:OPEN #1,8,0,"D:BINLOAD"
110 ? #1;"IF PEEK(5576)<>162 THEN ? ";Q$;"↰NOT COMPATIBLE with this DOS.";Q$;":STOP"
120 ? #1;"CLOSE #1:CLR :DIM Z$(18):? ";Q$;"↰Enter the Binary File to RUN.";Q$;":? ";Q$;"   Ex. D2:GAME";Q$
130 ? #1;"? ";Q$;"↑↑";Q$;":INPUT #16,Z$:OPEN #1,4,0,Z$:Z=USR(5576)"
140 CLOSE #1:? "BINLOAD Completed.":? :RETURN
200 TRAP 40000:? "Creating DEC":CLOSE #1:OPEN #1,8,0,"D:DEC"
210 ? #1;"CLOSE #1:CLR :DN=PEEK(769)"
220 ? #1;"DIM DN$(6),ZZ$(16),Z$(5),Z(4):OPEN #1,4,0,";Q$;"K:";Q$;":? ";Q$;
225 ? #1;"↰Enter Decimal Number up to 65535";Q$
230 ? #1;"? ";Q$;"↑↑";Q$;":DN$=";Q$;"D1:DEC";Q$;":DN$(2,2)=STR$(DN)"
240 ? #1;"? ";Q$;"↑↑";Q$;":FOR I=1 TO 4:Z(I)=0:NEXT I:ZZ$=";Q$;"0123456789ABCDEF";Q$
250 ? #1;"? ";Q$;"↑↑";Q$;":FOR I=1 TO 5:GET #1,Z";
255 ? #1;":IF Z>47 AND Z<59 THEN ? CHR$(Z);:Z$(I,I)=CHR$(Z):NEXT I:CLOSE #1"
260 ? #1;"? ";Q$;"↰";Q$;":Z=VAL(Z$):FOR I=1 TO 4:Z(I)=0:NEXT I"
270 ? #1;"? ";Q$;"↰";Q$;":ZZ=INT(Z/4096):IF ZZ>0 THEN Z(1)=ZZ:Z=Z-4096*ZZ"
280 ? #1;"? ";Q$;"↰";Q$;":ZZ=INT(Z/256):IF ZZ>0 THEN Z(2)=ZZ:Z=Z-256*ZZ"
290 ? #1;"? ";Q$;"↰";Q$;":ZZ=INT(Z/16):IF ZZ>0 THEN Z(3)=ZZ:Z=Z-16*ZZ"
300 ? #1;"? ";Q$;"↰";Q$;":Z(4)=Z"
310 ? #1;"? ";Q$;"↑↑DECIMAL ";Q$;";Z$;";Q$;" = ";Q$;";:FOR I=1 TO 4:? ZZ$(Z(I)+1,Z(I)+1);:NEXT I:? ";Q$;
311 ? #1;" HEX";Q$
320 ? #1;"? ";Q$;"↑↑↓Press SPACE BAR to Continue,";Q$;":? ";Q$;"H to Convert HEX Numbers,";Q$;
325 ? #1;":? ";Q$;"Any other Key to Quit.";Q$;":CLOSE #1"
330 ? #1;"? ";Q$;"↑↑";Q$;":OPEN #1,4,0,";Q$;"K:";Q$;":GET #1,Z:CLOSE #1:";
335 ? #1;"IF Z=72 THEN DN$(4)=";Q$;"HEX";Q$;":ENTER DN$"
340 ? #1;"IF Z=32 THEN ENTER DN$"
350 CLOSE #1:? "DEC Completed.":? :GOTO 1300
400 TRAP 40000:? "Creating DELETE":CLOSE #1:OPEN #1,8,0,"D:DELETE"
410 ? #1;"CLOSE #1:CLR :POKE 710,66:DIM Z$(18):? ";Q$;"↰Which File to DELETE?";Q$
420 ? #1;"? ";Q$;"↑   Ex. D2:DATA.EXE";Q$;":INPUT #16,Z$:? ";Q$;"↰Deleting ";Q$;";Z$:";
425 ? #1;"POKE 710,148:XIO 33,#1,0,0,Z$"
430 CLOSE #1:? "DELETE Completed.":? :RETURN
500 TRAP 40000:? "Creating DIR":CLOSE #1:OPEN #1,8,0,"D:DIR"
510 ? #1;"CLOSE #1:CLR :DIM Z$(18):Z$=";Q$;"D1:*.*";Q$;":? ";Q$;"↰Which Drive?";Q$;":OPEN #1,4,0,";Q$;
511 ? #1;"K:";Q$;":GET #1,Z:CLOSE #1:IF Z<49 OR Z>56 THEN STOP "
520 ? #1;"? ";Q$;"↰";Q$;":Z$(2,2)=CHR$(Z):OPEN #1,7,0,Z$:FOR I=1 TO 66:INPUT #1,Z$:? Z$:NEXT I"
530 CLOSE #1:? "DIR Completed.":? :RETURN
600 TRAP 40000:? "Creating ERROR":CLOSE #1:OPEN #1,8,0,"D:ERROR"
610 ? #1;"CLR:CLOSE #1 :DN=PEEK(769):DIM DN$(8),Z$(42):DN$=";Q$;"D1:ERROR";Q$;":DN$(2,2)=STR$(DN)"
620 ? #1;"? ";Q$;"↰Enter ERROR # ";Q$;";:FOR I=1 TO 5:GET #16,Z:IF Z<155 THEN Z$(I,I)=CHR$(Z):NEXT I"
630 ? #1;"? ";Q$;"↰";Q$;":Z=VAL(Z$)"
640 ? #1;"? ";Q$;"↰";Q$;":IF Z=1 THEN Z$=";Q$;"No Error";Q$
650 ? #1;"? ";Q$;"↰";Q$;":IF Z=2 THEN Z$=";Q$;"Insufficient Memory";Q$
660 ? #1;"? ";Q$;"↰";Q$;":IF Z=3 THEN Z$=";Q$;"Value Error";Q$
670 ? #1;"? ";Q$;"↰";Q$;":IF Z=4 THEN Z$=";Q$;"Too Many Variables";Q$
680 ? #1;"? ";Q$;"↰";Q$;":IF Z=5 THEN Z$=";Q$;"String Length Error";Q$
690 ? #1;"? ";Q$;"↰";Q$;":IF Z=6 THEN Z$=";Q$;"Out of Data Error";Q$
700 ? #1;"? ";Q$;"↰";Q$;":IF Z=7 THEN Z$=";Q$;"Number Greater than 32767";Q$
710 ? #1;"? ";Q$;"↰";Q$;":IF Z=8 THEN Z$=";Q$;"Input Statement Error";Q$
720 ? #1;"? ";Q$;"↰";Q$;":IF Z=9 THEN Z$=";Q$;"Array or String DIM Error";Q$
730 ? #1;"? ";Q$;"↰";Q$;":IF Z=10 THEN Z$=";Q$;"Argument Stack Overflow";Q$
740 ? #1;"? ";Q$;"↰";Q$;":IF Z=11 THEN Z$=";Q$;"Floating Point Overflow or Underflow Error";Q$
750 ? #1;"? ";Q$;"↰";Q$;":IF Z=12 THEN Z$=";Q$;"Line Not Found";Q$
760 ? #1;"? ";Q$;"↰";Q$;":IF Z=13 THEN Z$=";Q$;"No Matching FOR Statement";Q$
770 ? #1;"? ";Q$;"↰";Q$;":IF Z=14 THEN Z$=";Q$;"Line Too Long";Q$
780 ? #1;"? ";Q$;"↰";Q$;":IF Z=15 THEN Z$=";Q$;"GOSUB or FOR Line Deleted";Q$
790 ? #1;"? ";Q$;"↰";Q$;":IF Z=16 THEN Z$=";Q$;"RETURN Error";Q$
800 ? #1;"? ";Q$;"↰";Q$;":IF Z=17 THEN Z$=";Q$;"Garbage Error";Q$
810 ? #1;"? ";Q$;"↰";Q$;":IF Z=18 THEN Z$=";Q$;"Invalid String Character";Q$
820 ? #1;"? ";Q$;"↰";Q$;":IF Z=19 THEN Z$=";Q$;"LOAD Program Too Long";Q$
830 ? #1;"? ";Q$;"↰";Q$;":IF Z=20 THEN Z$=";Q$;"Bad Channel Number";Q$
840 ? #1;"? ";Q$;"↰";Q$;":IF Z=21 THEN Z$=";Q$;"LOAD File Error";Q$
850 ? #1;"? ";Q$;"↰";Q$;":IF Z=128 THEN Z$=";Q$;"BREAK Abort";Q$
860 ? #1;"? ";Q$;"↰";Q$;":IF Z=129 THEN Z$=";Q$;"IOCB Already Opened";Q$
870 ? #1;"? ";Q$;"↰";Q$;":IF Z=130 THEN Z$=";Q$;"Nonexistent Device";Q$
880 ? #1;"? ";Q$;"↰";Q$;":IF Z=131 THEN Z$=";Q$;"IOCB Opened for WRITE Only";Q$
890 ? #1;"? ";Q$;"↰";Q$;":IF Z=132 THEN Z$=";Q$;"Invalid Command";Q$
900 ? #1;"? ";Q$;"↰";Q$;":IF Z=133 THEN Z$=";Q$;"Device or File Not Open";Q$
910 ? #1;"? ";Q$;"↰";Q$;":IF Z=134 THEN Z$=";Q$;"Bad IOCB Number";Q$
920 ? #1;"? ";Q$;"↰";Q$;":IF Z=135 THEN Z$=";Q$;"IOCB Opened for READ Only";Q$
930 ? #1;"? ";Q$;"↰";Q$;":IF Z=136 THEN Z$=";Q$;"EOF (End of File)";Q$
940 ? #1;"? ";Q$;"↰";Q$;":IF Z=137 THEN Z$=";Q$;"Truncated Record";Q$
950 ? #1;"? ";Q$;"↰";Q$;":IF Z=138 THEN Z$=";Q$;"Device Timeout";Q$
960 ? #1;"? ";Q$;"↰";Q$;":IF Z=139 THEN Z$=";Q$;"Device NAK";Q$
970 ? #1;"? ";Q$;"↰";Q$;":IF Z=140 THEN Z$=";Q$;"Serial Bus Framing Error";Q$
980 ? #1;"? ";Q$;"↰";Q$;":IF Z=141 THEN Z$=";Q$;"Cursor Out of Range";Q$
990 ? #1;"? ";Q$;"↰";Q$;":IF Z=142 THEN Z$=";Q$;"Serial Bus Overrun";Q$
1000 ? #1;"? ";Q$;"↰";Q$;":IF Z=143 THEN Z$=";Q$;"Serial Bus Checksum Error";Q$
1010 ? #1;"? ";Q$;"↰";Q$;":IF Z=144 THEN Z$=";Q$;"Device Done Error";Q$
1020 ? #1;"? ";Q$;"↰";Q$;":IF Z=145 THEN Z$=";Q$;"Read After Write Compare  Error";Q$
1030 ? #1;"? ";Q$;"↰";Q$;":IF Z=146 THEN Z$=";Q$;"Function Not Implemented";Q$
1040 ? #1;"? ";Q$;"↰";Q$;":IF Z=147 THEN Z$=";Q$;"Insufficient RAM";Q$
1041 ? #1;"? ";Q$;"↰";Q$;":IF Z=150 THEN Z$=";Q$;"Serial Port Already Open";Q$
1042 ? #1;"? ";Q$;"↰";Q$;":IF Z=151 THEN Z$=";Q$;"Concurrent Mode Not Enabled";Q$
1043 ? #1;"? ";Q$;"↰";Q$;":IF Z=152 THEN Z$=";Q$;"Illegal User-Supplied Buffer";Q$
1044 ? #1;"? ";Q$;"↰";Q$;":IF Z=153 THEN Z$=";Q$;"Active Concurrent Mode Error";Q$
1045 ? #1;"? ";Q$;"↰";Q$;":IF Z=154 THEN Z$=";Q$;"Concurrent Mode Not Active";Q$
1050 ? #1;"? ";Q$;"↰";Q$;":IF Z=160 THEN Z$=";Q$;"Device Number Error";Q$
1060 ? #1;"? ";Q$;"↰";Q$;":IF Z=161 THEN Z$=";Q$;"Too Many OPEN Files";Q$
1070 ? #1;"? ";Q$;"↰";Q$;":IF Z=162 THEN Z$=";Q$;"Disk Full";Q$
1080 ? #1;"? ";Q$;"↰";Q$;":IF Z=163 THEN Z$=";Q$;"Fatal System Error";Q$
1090 ? #1;"? ";Q$;"↰";Q$;":IF Z=164 THEN Z$=";Q$;"File Number Mismatch";Q$
1100 ? #1;"? ";Q$;"↰";Q$;":IF Z=165 THEN Z$=";Q$;"Bad File Name";Q$
1110 ? #1;"? ";Q$;"↰";Q$;":IF Z=166 THEN Z$=";Q$;"POINT Data Length Error";Q$
1120 ? #1;"? ";Q$;"↰";Q$;":IF Z=167 THEN Z$=";Q$;"File Locked";Q$
1130 ? #1;"? ";Q$;"↰";Q$;":IF Z=168 THEN Z$=";Q$;"Invalid XIO Command";Q$
1140 ? #1;"? ";Q$;"↰";Q$;":IF Z=169 THEN Z$=";Q$;"Directory Full";Q$
1150 ? #1;"? ";Q$;"↰";Q$;":IF Z=170 THEN Z$=";Q$;"File Not Found";Q$
1160 ? #1;"? ";Q$;"↰";Q$;":IF Z=171 THEN Z$=";Q$;"POINT Invalid";Q$
1170 ? #1;"? ";Q$;"↰";Q$;":IF Z=172 THEN Z$=";Q$;"DOS 1 File";Q$
1180 ? #1;"? ";Q$;"↰";Q$;":IF Z=173 THEN Z$=";Q$;"Bad Sector";Q$
1190 ? #1;"? ";Q$;"↰";Q$;":IF Z=255 THEN Z$=";Q$;"FORMATTING Error (DOS 2.5)";Q$
1200 ? #1;"? ";Q$;"↰ERROR ";Q$;";Z;";Q$;" = ";Q$;";Z$:? ";Q$;"↓↓↓↓↓";Q$
1210 ? #1;"? ";Q$;"↑↑Press SPACE BAR to Continue.";Q$;":? ";Q$;"Any Other KEY to QUIT.";Q$
1220 ? #1;"OPEN #1,4,0,";Q$;"K:";Q$;":? ";Q$;"↑↑";Q$;":GET #1,Z:CLOSE #1:IF Z=32 THEN ENTER DN$"
1230 CLOSE #1:? "ERROR Completed.":? :RETURN
1300 ? "Creating HEX":CLOSE #1:OPEN #1,8,0,"D:HEX"
1310 ? #1;"CLOSE #1:CLR :DN= PEEK(769):DIM DN$(6),Z$(4),ZZ$(4):? ";Q$;
1315 ? #1;"↰Enter HEX Number to Convert.";Q$;":OPEN #1,4,0,";Q$;"K:";Q$
1320 ? #1;"? ";Q$;"↑↑";Q$;":DN$=";Q$;"D1:HEX";Q$;":DN$(2,2)=STR$(DN)"
1330 ? #1;"? ";Q$;"↑↑";Q$;
1335 ? #1;":FOR I=1 TO 4:GET #1,Z:IF Z>47 AND Z<58 OR Z>64 AND Z<71 THEN Z$(I,I)=CHR$(Z):? CHR$(Z);:NEXT I"
1340 ? #1;"? ";Q$;"↰";Q$;":CLOSE #1:ZZ$=";Q$;"0000";Q$;":Z=LEN(Z$)"
1350 ? #1;"? ";Q$;"↰";Q$;":ZZ$(1+4-Z)=Z$:Z$=ZZ$(1,1):Z=0:ZZ=0"
1360 ? #1;"? ";Q$;"↰";Q$;":Z=Z$=";Q$;"F";Q$;"*15+Z$=";Q$;"E";Q$;"*14+Z$=";Q$;"D";Q$;"*13+Z$=";
1361 ? #1;Q$;"C";Q$;
1365 ? #1;"*12+Z$=";Q$;"B";Q$;"*11+Z$=";Q$;"A";Q$;"*10+Z$=";Q$;"9";Q$;"*9+Z$=";Q$;"8";Q$;"*8"
1370 ? #1;"? ";Q$;"↰";Q$;":Z=Z+Z$=";Q$;"7";Q$;"*7+Z$=";Q$;"6";Q$;"*6+Z$=";Q$;
1372 ? #1;"5";Q$;"*5+Z$=";Q$;"4";Q$;"*4+Z$=";Q$;"3";Q$;"*3+Z$=";Q$;"2";Q$;"*2+Z$=";Q$;"1";
1373 ? #1;Q$;
1374 ? #1;":Z=Z*4096:ZZ=ZZ+Z:Z$=ZZ$(2,2)"
1380 ? #1;"? ";Q$;"↰";Q$;":Z=Z$=";Q$;"F";Q$;"*15+Z$=";Q$;"E";Q$;"*14+Z$=";Q$;"D";
1381 ? #1;Q$;"*13+Z$=";Q$;
1385 ? #1;"C";Q$;"*12+Z$=";Q$;"B";Q$;"*11+Z$=";Q$;"A";Q$;"*10+Z$=";Q$;"9";Q$;"*9+Z$=";
1386 ? #1;Q$;"8";Q$;"*8"
1390 ? #1;"? ";Q$;"↰";Q$;":Z=Z+Z$=";Q$;"7";Q$;"*7+Z$=";Q$;"6";Q$;"*6+Z$=";Q$;"5";Q$;
1391 ? #1;"*5+Z$=";Q$;"4";Q$;
1395 ? #1;"*4+Z$=";Q$;"3";Q$;"*3+Z$=";Q$;"2";Q$;"*2+Z$=";Q$;"1";Q$;":Z=Z*256:ZZ=ZZ+Z:Z$=ZZ$(3,3)"
1400 ? #1;"? ";Q$;"↰";Q$;":Z=Z$=";Q$;"F";Q$;"*15+Z$=";Q$;"E";Q$;"*14+Z$=";Q$;"D";Q$;
1401 ? #1;"*13+Z$=";Q$;"C";Q$;
1405 ? #1;"*12+Z$=";Q$;"B";Q$;"*11+Z$=";Q$;"A";Q$;"*10+Z$=";Q$;"9";Q$;"*9+Z$=";Q$;"8";Q$;"*8"
1410 ? #1;"? ";Q$;"↰";Q$;":Z=Z+Z$=";Q$;"7";Q$;"*7+Z$=";Q$;"6";Q$;"*6+Z$=";Q$;"5";Q$;
1411 ? #1;"*5+Z$=";Q$;"4";Q$;
1415 ? #1;"*4+Z$=";Q$;"3";Q$;"*3+Z$=";Q$;"2";Q$;"*2+Z$=";Q$;"1";Q$;":Z=Z*16:ZZ=ZZ+Z:Z$=ZZ$(4,4)"
1420 ? #1;"? ";Q$;"↰";Q$;":Z=Z$=";Q$;"F";Q$;"*15+Z$=";Q$;"E";Q$;"*14+Z$=";Q$;"D";Q$;
1421 ? #1;"*13+Z$=";Q$;"C";Q$;
1425 ? #1;"*12+Z$=";Q$;"B";Q$;"*11+Z$=";Q$;"A";Q$;"*10+Z$=";Q$;"9";Q$;"*9+Z$=";Q$;"8";Q$;"*8"
1430 ? #1;"? ";Q$;"↰";Q$;":Z=Z+Z$=";Q$;"7";Q$;"*7+Z$=";Q$;"6";Q$;"*6+Z$=";Q$;"5";Q$;
1431 ? #1;"*5+Z$=";Q$;"4";Q$;
1435 ? #1;"*4+Z$=";Q$;"3";Q$;"*3+Z$=";Q$;"2";Q$;"*2+Z$=";Q$;"1";Q$;":ZZ=ZZ+Z"
1440 ? #1;"? ";Q$;"↑↑HEX ";Q$;";ZZ$;";Q$;" = ";Q$;";ZZ;";Q$;" DECIMAL";Q$
1450 ? #1;"? ";Q$;"↑↑↓Press SPACE BAR to continue,";Q$;":? ";Q$;
1455 ? #1;"D to Convert DECIMAL Numbers,";Q$;":? ";Q$;"Any Other Key to Quit.";Q$
1460 ? #1;"? ";Q$;"↑↑";Q$;":OPEN #1,4,0,";Q$;"K:";Q$;":GET #1,Z:CLOSE #1:IF Z=32 THEN ENTER DN$"
1470 ? #1;"IF Z=68 THEN DN$(4)=";Q$;"DEC";Q$;":ENTER DN$"
1480 CLOSE #1:? "HEX Completed.":? :RETURN
1500 TRAP 40000:? "Creating DRIVES":CLOSE #1:OPEN #1,8,0,"D:DRIVES"
1510 ? #1;"IF PEEK(1801)>16 OR PEEK(1801)=0 THEN ? ";Q$;"↰NOT COMPATIBLE with this DOS.";Q$;":STOP "
1520 ? #1;"CLOSE #1:CLR :DIM Z$(11),Z(8):Z$=";Q$;"NOT Enabled";Q$
1530 ? #1;"FOR Z=1 TO 8:Z(Z)=1:NEXT Z:Z=PEEK(1802)"
1540 ? #1;"? ";Q$;"↰";Q$;":IF Z>=128 THEN Z(8)=4:Z=Z-128"
1550 ? #1;"? ";Q$;"↰";Q$;":IF Z>=64 THEN Z(7)=4:Z=Z-64"
1560 ? #1;"? ";Q$;"↰";Q$;":IF Z>=32 THEN Z(6)=4:Z=Z-32"
1570 ? #1;"? ";Q$;"↰";Q$;":IF Z>=16 THEN Z(5)=4:Z=Z-16"
1580 ? #1;"? ";Q$;"↰";Q$;":IF Z>=8 THEN Z(4)=4:Z=Z-8"
1590 ? #1;"? ";Q$;"↰";Q$;":IF Z>=4 THEN Z(3)=4:Z=Z-4"
1600 ? #1;"? ";Q$;"↰";Q$;":IF Z>=2 THEN Z(2)=4:Z=Z-2"
1610 ? #1;"? ";Q$;"↰";Q$;":IF Z>=1 THEN Z(1)=4"
1620 ? #1;"? ";Q$;"↰";Q$;":FOR Z=1 TO 8:? ";Q$;"Drive ";Q$;";Z;";Q$;" is ";Q$;";Z$(Z(Z)):NEXT Z"
1630 ? #1;"? ";Q$;"↑Would you like to change this set up?";Q$;":OPEN #1,4,0,";Q$;"K:";Q$;":GET #1,Z:";
1635 ? #1;"CLOSE #1:IF Z<>89 THEN STOP "
1640 ? #1;"? ";Q$;"↰Press Numbers of Drives to Enable.";Q$;":FOR Z=1 TO 8:Z(Z)=0:NEXT Z"
1650 ? #1;"?";Q$;"↑↑";Q$;":FOR I=1 TO 4:OPEN #1,4,0,";Q$;"K:";Q$;":GET#1,Z:CLOSE #1:";
1655 ? #1;"IF Z<57 AND Z>48 THEN Z(Z-48)=1:? ";Q$;"DRIVE ";Q$;";Z-48;Z$(4):NEXT I"
1660 ? #1;"Z=1:FOR I=1 TO 8:Z(I)=Z(I)*Z:Z=Z*2:NEXT I:Z=0:FOR I=1 TO 8:Z=Z+Z(I):NEXT I:IF Z>0";
1665 ? #1;" THEN POKE 1802,Z"
1670 ? #1;"Z=USR(58484)"
1680 CLOSE #1:? "DRIVES Completed.":? :RETURN
1700 TRAP 40000:? "Creating LOCK":CLOSE #1:OPEN #1,8,0,"D:LOCK"
1710 ? #1;"CLOSE #1:CLR :DIM Z$(18):? ";Q$;"↰Which File to LOCK?";Q$
1720 ? #1;"? ";Q$;"↑   Ex. D2:DATA.EXE";Q$;":INPUT #16,Z$:? ";Q$;"Locking ";Q$;";Z$:XIO 35,#1,0,0,Z$"
1730 CLOSE #1:? "LOCK Completed.":? :RETURN
1750 TRAP 40000:? "Creating UNLOCK":CLOSE #1:OPEN #1,8,0,"D:UNLOCK"
1760 ? #1;"CLOSE #1:CLR :DIM Z$(18):? ";Q$;"↰Which File to UNLOCK?";Q$
1770 ? #1;"? ";Q$;"↑   Ex. D2:DATA.EXE";Q$;":INPUT #16,Z$:? ";Q$;"Unlocking ";Q$;";Z$:XIO 36,#1,0,0,Z$"
1780 CLOSE #1:? "UNLOCK Completed.":? :RETURN
1800 TRAP 40000:? "Creating RENAME":CLOSE #1:OPEN #1,8,0,"D:RENAME"
1810 ? #1;"CLOSE #1:CLR :DIM Z$(18):? ";Q$;"↰Which File to RENAME?";Q$
1820 ? #1;"? ";Q$;"↑   Ex. D2:OLDNAME,NEWNAME";Q$;":INPUT #16,Z$:XIO 32,#1,0,0,Z$"
1830 CLOSE #1:? "RENAME Completed.":? :RETURN
1900 TRAP 40000:? "Creating ERROR.164":CLOSE #1:OPEN #1,8,0,"D:ERROR.164"
1910 ? #1;"IF PEEK(4149)<>44 AND PEEK(4149)<>234 THEN ? ";Q$;"↰NOT COMPATIBLE with this DOS.";Q$;":STOP "
1920 ? #1;"CLOSE #1:CLR :? ";Q$;"↰Press X to Disable ERROR 164.";Q$;":? ";Q$;"This will allow Loading ";
1930 ? #1;"files that    cause an ERROR 164.";Q$
1940 ? #1;"? ";Q$;"↑↑↓Be aware that the DATA will probably  not be 100% intact.";Q$
1950 ? #1;"? ";Q$;"↑↑↓↓Press any other Key to Enable Normal  ERROR 164 handling.";Q$;
1960 ? #1;":OPEN #1,4,0,";Q$;"K:";Q$;":GET #1,Z:CLOSE #1"
1970 ? #1;"POKE 4148,208:POKE 4149,44:IF Z=88 THEN POKE 4148,234:POKE 4149,234"
1980 CLOSE #1:? "ERROR.164 Completed.":? :RETURN
2000 TRAP 40000:? "Creating OPENFILE":CLOSE #1:OPEN #1,8,0,"D:OPENFILE"
2010 ? #1;"IF PEEK(1801)>16 OR PEEK(1801)=0 THEN ? ";Q$;"↰NOT COMPATIBLE with this DOS.";Q$;":STOP "
2020 ? #1;"CLOSE #1:CLR :Z=PEEK(1801):? ";Q$;"↰";Q$;";Z;";Q$;" Buffers are set up by this DOS.";Q$
2030 ? #1;"? ";Q$;"↑";Q$;";Z;";Q$;" Single Density or ";Q$;";INT(Z/2);";Q$;
2035 ? #1;" Double Density  Files may be opened at the same time.";Q$
2040 ? #1;"? ";Q$;"↑Would you like to change this?";Q$;":OPEN #1,4,0,";Q$;"K:";Q$;
2045 ? #1;":GET #1,Z:CLOSE #1:IF Z<>89 THEN STOP "
2050 ? #1;"? ";Q$;"↰How many Buffers would you like DOS   to set up?";Q$;
2055 ? #1;":OPEN #1,4,0,";Q$;"K:";Q$;":GET #1,Z:CLOSE #1:IF Z<49 OR Z>57 THEN STOP "
2060 ? #1;"POKE 1801,Z-48:Z=USR(58484)"
2070 CLOSE #1:? "OPENFILE Completed.":? :RETURN
2100 TRAP 40000:? "Creating WRITEDOS":CLOSE #1:OPEN #1,8,0,"D:WRITEDOS"
2105 ? #1;"CLOSE #1:CLR :DIM Z$(10):Z$=";Q$;"D1:DOS.SYS";Q$
2110 ? #1;"? ";Q$;"↰Write DOS.SYS to which drive?";Q$;":OPEN #1,4,0,";Q$;"K:";Q$;
2115 ? #1;":GET #1,Z:CLOSE #1:IF Z<49 OR Z>56 THEN STOP "
2120 ? #1;"? ";Q$;"↑↑Put Disk in Drive ";Q$;";Z-48;";Q$;" and Press RETURN.";Q$;
2125 ? #1;":Z$(2,2)=STR$(Z-48):OPEN #1,4,0,";Q$;"K:";Q$;":GET #1,Z:CLOSE #1"
2130 ? #1;"? ";Q$;"↑↑Writing DOS.SYS to Drive ";Q$;";Z$(2,2);";Q$;".   ";Q$;":OPEN #1,8,0,Z$:CLOSE #1"
2140 CLOSE #1:? "WRITEDOS Completed.":? :RETURN