Cribbage Atari! (CRIBBAGE.BAS)
Cribbage Atari! by David C. Osborn, 148
Description
Cribbage Atari! by David C. Osborn, 148
From the Antic disk of May 1989 (Vol. 8 No. 1) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 18.1 KB
- Dialect
- Atari BASIC
- Lines
- 313
- Variables
DBUG,P,C,D,LP,XX,AA,BB,EE,L3$,L4$,NC,CR,C(,V(,S(,K(,F(,M(,LL,HH,N(,NN,CC,YY,TW,WO,DD,CR(,WH,PT,RC,P$,TT,PL,JJ,MM,FF,CO,RO,CT,TM,CL1,RW1,ZZ,RE,L1$,L2$,CE,ST,STICK,SC,RP,PT(,CS,PR,II,PL(,CU,DC,SD,GG,X,RW,CL,SC(,BD,AD,NW,VV,DY,W,N,QQ,H
BASIC listing (313 lines)
2 REM CRIBBAGE ATARI!
4 REM BY DAVID C. OSBORN
6 REM (c)1989, ANTIC PUBLISHING INC.
10 GRAPHICS 2:DBUG=0:P=0:C=P:POKE 710,P:GOSUB 2560:REM TITLE
20 ? :? :? " Enter Timing Delay 0-9 ( 0 = Fast, 9 = Slow ) ";
30 TRAP 20
40 INPUT D
50 GOSUB 2430:D=D^2
60 RESTORE 2970:LP=XX:GRAPHICS 18:GOSUB 505:POKE 756,AA:FOR BB=708 TO 712:READ EE:POKE BB,EE:NEXT BB
65 RESTORE 2620
70 POSITION 4,4:? #6;"()L*! !_P-,":L3$="1& 3' 5( 7(":L4$="2F 4( 6( 8(":POSITION 16,7:? #6;"$$"
80 POSITION 4,1:? #6;"!_P:.#":POSITION 2,2:? #6;"1& 2F 3' 4( 5( 6(":POSITION 2,3:? #6;"$$ $$ $$ $$ $$ $$"
90 NC=CR:GOSUB 840:FOR AA=0 TO 12
100 C(AA)=INT(RND(0)*52)+1:V(AA)=C(AA):S(AA)=0
110 IF AA THEN FOR BB=0 TO AA-1:IF C(BB)=C(AA) OR C(AA)>52 THEN 100
120 IF AA THEN NEXT BB
130 IF V(AA)>13 THEN V(AA)=V(AA)-13:S(AA)=S(AA)+1:GOTO 130
140 K(AA)=V(AA)+16:IF V(AA)<9 AND V(AA)-1 THEN 200
150 IF V(AA)=1 THEN K(AA)=97
160 IF V(AA)=10 THEN K(AA)=31
170 IF V(AA)=11 THEN K(AA)=98
180 IF V(AA)=12 THEN K(AA)=27
190 IF V(AA)=13 THEN K(AA)=100
200 F(AA)=S(AA)+123:IF S(AA)=2 THEN F(AA)=96
210 IF S(AA)<2 THEN K(AA)=K(AA)+96:F(AA)=F(AA)+96:IF K(AA)<192 THEN K(AA)=K(AA)+64
220 NEXT AA:FOR AA=0 TO 12:M(AA)=AA:NEXT AA:LL=0:HH=5:GOSUB 1140
230 FOR AA=0 TO 12:N(AA)=V(AA):IF N(AA)>10 THEN N(AA)=10
240 REM COMPUTER'S CRIB PICK
250 NEXT AA:LL=0:HH=5:GOSUB 2390:GOSUB 1140:GOSUB 870:POSITION 18,5:? #6;"$":SOUND 0,5,6,10:AA=AA^1
260 SOUND 0,0,0,0
270 REM COUNT POINTS
280 REM PLAYER'S CRIB PICK
290 NN=16:FOR CC=0 TO 1:GOSUB 700:POSITION XX+1,YY:? #6;" ":POSITION 14+CC,5:? #6;"$":TW=XX*CC:WO=XX+WO-TW
300 FOR DD=1 TO 61:SOUND 0,DD,10,8:NEXT DD:SOUND 0,0,0,0
310 GOSUB 2060:NEXT CC:IF WO=TW THEN HH=5:POSITION 14,5:? #6;" ":WO=0:TW=0:LL=0:GOSUB 1140:GOTO 290
320 WO=INT((WO+1)/3):TW=(TW-1)/3:CR(1)=M(WO):CR(2)=M(TW):LL=0:HH=3:GOSUB 2390:BB=-1:FOR AA=0 TO 5
330 IF M(AA)-CR(1) AND M(AA)-CR(2) THEN BB=BB+1:M(BB)=M(AA)
340 NEXT AA:LL=0:HH=3:GOSUB 2390:POSITION 13,2:? #6;" ":GOSUB 1140:COLOR K(12):PLOT 16,7:COLOR F(12)
350 PLOT 17,7:IF V(12)=11 THEN WH=CR:PT=2:GOSUB 2090:POSITION 3,10:? #6;"FK EP 2":GOSUB 2060
360 HH=1:RC=CR:FOR AA=4 TO 7:M(AA)=M(AA+2):NEXT AA:FOR AA=8 TO 11:M(AA)=CR(AA-7):NEXT AA
370 REM THE PLAY
380 P$=" ":FOR AA=6 TO 7:POSITION 1,AA:? #6;P$:NEXT AA:TT=0:PL=0:JJ=1:GOSUB 840
390 MM=1:BB=0:POSITION 9,10:NC= NOT RC:FOR AA=0 TO 7
400 IF N(M(AA))>10 THEN NEXT AA:WH=RC:BB=1:PT=1:? #6;" I":MM=0:GOSUB 2090:GOTO 520
410 FOR AA=NC*4 TO NC*4+3
420 IF TT+N(M(AA))>31 THEN NEXT AA:POSITION 9,10:WH=RC:NC=RC:? #6;" I":GOSUB 2060:POSITION 9,10
430 FOR AA=NC*4 TO NC*4+3:IF TT+N(M(AA))>31 THEN NEXT AA:FF=1:? #6;" I":PT=1:GOSUB 2090:GOSUB 2060:GOTO 380
440 HH=1:POSITION 1,10:? #6;P$:POSITION 9,10:? #6;TT:IF RC=NC THEN RC= NOT RC:CO=CO+3:PL=PL+1:HH=0:GOTO 460
450 PL=PL+1:CO=3*INT((PL+1)/2)-2:RO=7
460 IF RC THEN RO=6:JJ=0:GOSUB 1390:? #6;" ":GOSUB 2060
470 IF NC THEN GOSUB 1160
480 GOSUB 1430:GOSUB 1460:RC=NC:CT=0:N(M(AA))=N(M(AA))+50:JJ=TM:GOSUB 2060:POSITION 1,9:TM=JJ
490 IF TT<31 THEN 390
500 POSITION 1,CL1:? #6;L3$:POSITION 1,RW1:? #6;L4$:GOTO 380
505 IF DBUG=0 THEN POKE 16,112:POKE 53774,112
506 RETURN
510 REM PLAY IS OVER
520 GOSUB 2070:P$=" ":ZZ=0
530 REM CLEAR SCREEN
540 FOR AA=0 TO 7:N(M(AA))=N(M(AA))-50:NEXT AA:FOR AA=1 TO 10:POSITION 1,AA:? #6;P$:NEXT AA:NC=ABS(CR-1)
550 REM IF ZZ THEN ALL THREE COUNTED AND WE'RE READY FOR THE NEXT HAND
560 IF ZZ THEN ZZ=0:POP :POP :GOTO 70
570 FOR AA=0 TO 12:C(AA)=M(AA):NEXT AA:FOR AA=5 TO 8:M(AA)=C(AA-1):NEXT AA:LL=10:HH=13
580 FOR AA=10 TO 13:M(AA)=C(AA-2):NEXT AA:FOR AA=0 TO 2:BB=AA*5+4:M(BB)=C(12):NEXT AA:GOSUB 2390
590 REM SET UP SCREEN
600 RE=0:L1$=" !_P :.#":L2$=" %! :.#":IF NC THEN P$=L1$:L1$=L2$:L2$=P$:RE=5:P$=" "
610 POSITION 3,1:? #6;L1$:POSITION 3,3:? #6;L2$:POSITION 5,5:? #6;"() -,"
620 POSITION 14,4:? #6;"&./P":CO=15:RO=5:AA=14:TT=100:GOSUB 1430:POSITION 1,10:? #6;P$
630 REM COUNT HAND
640 RO=2:WH=NC:LL=RE:GOSUB 1670:WH=CR:RE=ABS(RE-5):POSITION 1,10
650 REM COUNT SECOND HAND
660 RO=4:LL=RE:WH=CR:GOSUB 1670
670 REM COUNT CRIB HAND
680 RO=6:LL=10:GOSUB 1670
690 CR=NC:ZZ=1:GOTO 540
700 CE=0:XX=1:YY=3:BB=0:COLOR 130:PLOT 1,3:DD=0
710 POKE 694,0:POKE 702,64:IF LP=75 THEN CLOSE #1:OPEN #1,4,0,"K:":GET #1,DD:CLOSE #1:GOTO 760
720 ST=STICK(0):IF ST>8 AND STICK<12 THEN DD=43
730 IF ST<8 THEN DD=42
740 POKE 77,0:IF STRIG(0)=0 THEN DD=62
750 IF ST=15 AND DD-62 THEN 720
760 IF DD>42 THEN BB=0
770 FOR ZZ=1 TO NN STEP 3:COLOR 128:PLOT 1,3:IF ZZ-CE THEN COLOR 128:PLOT ZZ,YY
780 NEXT ZZ:IF DD=62 THEN RETURN
790 IF STRIG(0)=0 THEN DD=62
800 IF DD<43 THEN BB=6
810 CE=XX:XX=XX+BB-3:IF XX<1 THEN XX=NN
820 IF XX>NN THEN XX=1
830 SOUND 0,DD*3,10,6:COLOR 130:PLOT XX,YY:XX=XX^1:SOUND 0,0,0,0:GOTO 710
840 REM DISPLAY PLAY ORDER INDICATORS
850 CL1=5:RW1=8:POSITION 15,6:? #6;"&./P":IF NC THEN POSITION 14,4:? #6;"%! ":CL1=8:RW1=5
860 POSITION 1,CL1:? #6;L4$:POSITION 1,RW1:? #6;L3$:RETURN
870 REM ASSIGN POSSIBLES & SORT THEM
880 RESTORE 2590:SC=0:FOR RP=0 TO 14:CT=1:FOR BB=6 TO 11:READ CC:M(BB)=CC:NEXT BB:LL=6:HH=9:GOSUB 2390
890 IF RP=7 THEN POSITION 17,5:? #6;"$";:SOUND 0,5,6,2:AA=AA^1:SOUND 0,0,0,0
900 REM PAIRS
910 FOR BB=6 TO 8:IF V(M(BB))=V(M(BB+1)) THEN CT=CT*CT+2
920 REM CHECK FOR STRAIGHTS
930 NEXT BB:BB=V(M(6)):CC=V(M(7)):DD=V(M(8)):EE=V(M(9)):IF BB=CC-1 AND BB=DD-2 THEN CT=CT+3
940 IF BB=DD-1 AND BB=EE-2 THEN CT=CT+3
950 IF CC=DD-1 AND CC=EE-2 THEN CT=CT+3
960 IF BB=CC-1 AND BB=DD-2 AND BB=EE-3 THEN CT=CT-2
970 REM VALUE OF CRIBS CARDS
980 FF=0:BB=V(M(10)):CC=V(M(11)):IF BB=CC OR BB+CC=15 THEN FF=2
990 IF BB+CC=5 OR BB=5 OR CC=5 THEN FF=FF+2
1000 IF BB=CC-1 THEN FF=FF+0.5
1010 IF CR THEN FF=-FF
1020 REM 15'S
1030 BB=N(M(6)):CC=N(M(7)):DD=N(M(8)):EE=N(M(9)):IF BB+CC+DD=15 OR BB+CC=15 THEN CT=CT+2
1040 IF BB+CC+EE=15 OR BB+EE=15 THEN CT=CT+2
1050 IF CC+DD+EE=15 OR CC+DD=15 THEN CT=CT+2
1060 IF BB+CC+DD+EE=15 OR BB+DD=15 THEN CT=CT+2
1070 IF CC+EE=15 THEN CT=CT+2
1080 IF DD+EE=15 THEN CT=CT+2
1090 REM FLUSH
1100 FOR BB=6 TO 9:IF F(M(BB))=F(M(BB+1)) THEN NEXT BB:CT=CT+4
1110 CT=(CT-FF)*2:FOR BB=6 TO 9:IF N(M(BB))<6 THEN CT=CT+1:IF N(M(AA))=5 THEN CT=CT+2
1120 NEXT BB:IF CT>=SC THEN SC=CT:FOR BB=6 TO 11:PT(BB)=M(BB):NEXT BB
1130 NEXT RP:FOR BB=6 TO 11:M(BB)=PT(BB):NEXT BB:WO=0:CR(3)=M(10):CR(4)=M(11):RETURN
1140 P$=" ":POSITION 1,3:? #6;P$:FOR AA=LL TO HH:BB=3*AA+2:SOUND 2,BB*3,10,6
1150 COLOR K(M(AA)):PLOT BB,3:COLOR F(M(AA)):PLOT BB+1,3:NEXT AA:SOUND 2,0,0,0:RETURN
1160 CS=-100:FOR AA=4 TO 7:CT=0:BB=TT+N(M(AA)):IF BB>31 THEN 1380
1170 IF BB=31 THEN CT=CT+5
1180 IF BB=15 THEN CT=CT+4
1190 IF BB>15 THEN CT=CT+1
1200 IF BB<5 THEN CT=CT+1
1210 IF BB=5 OR BB=21 THEN CT=CT-2
1220 IF BB=10 THEN CT=CT-1
1230 IF V(M(AA))=1 OR (BB>5 AND BB<9) THEN CT=CT-1
1240 FOR CC=4 TO 7:IF CC=AA OR N(M(CC))>10 THEN NEXT CC:GOTO 1340
1250 IF V(M(CC))=1 AND BB=30 THEN CT=CT+1
1260 IF V(M(CC))=1 AND BB=29 THEN CT=CT+1
1270 IF V(M(CC))=2 AND BB=29 THEN CT=CT+1
1280 IF V(M(CC))=3 AND BB=28 THEN CT=CT+1
1290 IF V(M(CC))=9 AND BB=6 THEN CT=CT+3
1300 IF V(M(CC))=8 AND BB=7 THEN CT=CT+3
1310 IF V(M(CC))=7 AND BB=8 THEN CT=CT+3
1320 IF V(M(CC))=6 AND BB=9 THEN CT=CT+3
1330 NEXT CC
1340 IF PL<2 THEN 1370
1350 GOSUB 1590:GOSUB 1640:CT=CT+(ST+PR)*1.5
1360 PL=PL-1:II=M(AA):M(AA)=C(PL):FOR BB=1 TO PL-1:PT(BB)=PL(BB):NEXT BB:GOSUB 1590:M(AA)=II:PL=PL+1
1370 IF CT>=CS THEN CS=CT:CU=AA
1380 NEXT AA:AA=CU:RETURN
1390 NN=10:GOSUB 700:POSITION XX+1,YY:AA=INT((XX+2)/3)-1:IF TT+N(M(AA))>31 THEN PL=PL-1:POP :GOTO 450
1400 IF JJ<3 THEN RETURN
1410 FOR AA=1+CR TO JJ-2 STEP 2:IF AA=JJ THEN 1390
1420 NEXT AA:RETURN
1430 COLOR K(M(AA)):PLOT CO,RO:COLOR F(M(AA)):PLOT CO+1,RO:TT=TT+N(M(AA))
1440 IF TT<32 AND HH-100 THEN POSITION 9,10:? #6;TT
1450 FOR DC=4 TO 0 STEP -1:FOR SD=200 TO 190 STEP -1:SOUND 0,SD,10,DC:NEXT SD:NEXT DC:RETURN
1460 GOSUB 1590:PT=ST:IF PT THEN GOSUB 1560
1470 GOSUB 1640:PT=PR:IF ZZ THEN GOSUB 1520+(ZZ-1)*10
1480 IF TT=15 THEN PT=2:GOSUB 1520
1490 IF TT=31 THEN PT=2:GOSUB 1510:RC=NC
1500 RETURN
1510 L1$="31 EP ":GOTO 1570
1520 L1$="15 EP ":GOTO 1570
1530 L1$="LMP EP ":GOTO 1570
1540 L1$="3 EP ":GOTO 1570
1550 L1$="4 EP ":GOTO 1570
1560 L1$="J< EP "
1570 WH=NC:GOSUB 2090:POSITION 5,10:? #6;L1$;PT:GOSUB 2060:GOSUB 2070:POSITION 1,10:? #6;P$
1580 POSITION 9,10:? #6;TT:RETURN
1590 ST=0:PL(PL)=V(M(AA)):C(PL)=M(AA):IF PL<3 THEN RETURN
1600 FOR BB=1 TO PL-2:ST=1:FOR CC=BB TO PL:PT(CC)=PL(CC):NEXT CC
1610 FOR CC=BB TO PL-1:IF PT(CC)>PT(CC+1) THEN DD=PT(CC):PT(CC)=PT(CC+1):PT(CC+1)=DD:GOTO 1610
1620 NEXT CC:FOR CC=PL-1 TO BB STEP -1:IF PT(PL)=PT(CC)+PL-CC THEN ST=ST+1:NEXT CC:RETURN
1630 NEXT BB:ST=0:RETURN
1640 ZZ=0:PR=0:IF PL<2 THEN RETURN
1650 FOR BB=1 TO PL-1:IF V(C(PL))-V(C(PL-BB)) THEN RETURN
1660 PR=BB*(BB+1):ZZ=BB+1:NEXT BB:RETURN
1670 DD=3:TT=50:CO=2:FOR AA=LL TO LL+3:GOSUB 1430:CO=CO+3:NEXT AA:IF LL=10 THEN DD=4
1680 REM FLUSH
1690 PT=0:FOR NN=4 TO DD STEP -1:POSITION 2,10:FOR AA=LL+1 TO LL+NN
1700 IF F(M(LL))=F(M(AA)) THEN NEXT AA:PT=NN+1:? #6;" QTREP ";PT:GOSUB 2090:PT=0:GOSUB 1970:GOTO 1730
1710 NEXT NN
1720 REM 5 CARD RUN
1730 GG=0:RESTORE 3010:FOR FF=0 TO 4:FOR AA=0 TO 4:READ CC:C(AA)=CC:NEXT AA
1740 POSITION 2,9:FOR AA=1 TO 4:IF V(M(LL+C(0)))=V(M(LL+C(AA)))-AA THEN NEXT AA:PT=5:GOSUB 1980:GOTO 1830
1750 REM 4 CARD RUN
1760 NEXT FF:GG=0:PT=0:FOR AA=0 TO 16:FOR BB=0 TO 3:READ CC:C(BB)=CC:NEXT BB:FOR BB=1 TO 3
1770 IF V(M(LL+C(0)))=V(M(LL+C(BB)))-BB THEN NEXT BB:PT=4:GOSUB 1980:GG=1
1780 NEXT AA:IF GG THEN 1830
1790 RESTORE 3040:REM 3 CARD RUN
1800 FOR AA=0 TO 21:FOR BB=0 TO 2:READ CC:C(BB)=CC:NEXT BB:FOR BB=1 TO 2
1810 IF V(M(LL+C(0)))=V(M(LL+C(BB)))-BB THEN NEXT BB:PT=3:GOSUB 1980
1820 NEXT AA
1830 REM 5 CARD 15
1840 TT=0:FOR AA=LL TO LL+4:TT=TT+N(M(AA)):NEXT AA:BB=5:GOSUB 1990:EE=4:RESTORE 2980
1850 REM 15 FOR 2
1860 FOR GG=3 TO 1 STEP -1
1870 FOR AA=0 TO EE:FOR BB=0 TO GG:READ CC:C(BB)=CC:NEXT BB:TT=0:FOR BB=0 TO GG:TT=TT+N(M(LL+C(BB))):NEXT BB
1880 GOSUB 1990:NEXT AA:EE=9:NEXT GG
1890 REM PAIRS
1900 RESTORE 3000:FOR AA=0 TO 9:FOR BB=0 TO 1:READ CC:C(BB)=CC:NEXT BB
1910 PT=0:IF V(M(LL+C(0)))=V(M(LL+C(1))) THEN PT=2:POSITION 4,10:? #6;"LMP EP 2":GOSUB 2090:GOSUB 1970
1920 NEXT AA
1930 REM JACK OF STARTER
1940 PT=1:X=-1:FOR BB=LL TO LL+3:X=X+1
1950 IF V(M(BB))=11 AND S(M(BB))=S(M(4)) THEN POSITION 5,10:? #6;"HK EP 1":GOSUB 2090:GOSUB 2010:PT=0:GOTO 1970
1960 NEXT BB:PT=0
1970 GOSUB 2020:POSITION 1,10:? #6;P$:RETURN
1980 GOSUB 2090:POSITION 4,10:? #6;"J< EP ";PT:GOSUB 1970:RETURN
1990 IF TT=15 THEN PT=2:GOSUB 2090:POSITION 4,10:? #6;"15 EP 2":GOSUB 1970
2000 TT=0:RETURN
2010 COLOR 130:PLOT X*3+1,RO:GOSUB 2060:COLOR 0:PLOT X*3+1,RO:RETURN
2020 REM ARROWS ->
2030 FOR FF=0 TO BB-1:RW=RO:CO=C(FF)*3+1:CL=CO:IF CO>10 THEN RO=5:CO=14
2040 HH=0:IF PT THEN HH=130
2050 COLOR HH:PLOT CO,RO:RO=RW:CO=CL:NEXT FF:GOSUB 2060:IF HH THEN PT=0:BB=5:GOSUB 2060:GOTO 2020
2060 FOR ZZ=0 TO D:POSITION 1,9:? #6;"!_PNO)";SC(0)+BD;:POSITION 10,9:? #6;"%! NO)";SC(1)+AD:NEXT ZZ:RETURN
2070 FOR ZZ=0 TO D*3:NEXT ZZ
2080 RETURN
2090 NW=ABS(WH-1):FOR VV=1 TO PT:SC(WH)=SC(WH)+1:GOSUB 2100:COLOR DY:PLOT CL,RW:SOUND 3,0,0,0:NEXT VV:RETURN
2100 IF SC(WH)>SC(NW) THEN 2160
2110 IF SC(WH)<20 THEN CL=SC(WH)-1:RW=0:DY=216
2120 IF SC(WH)>19 THEN CL=19:RW=SC(WH)-20:DY=221:IF SC(WH)=20 THEN DY=211
2130 IF SC(WH)>30 THEN CL=50-SC(WH):RW=11:DY=216:IF SC(WH)=31 THEN DY=171
2140 IF SC(WH)>49 THEN CL=0:RW=61-SC(WH):DY=221:IF SC(WH)=50 THEN DY=213
2150 SOUND 3,9,8+WH*2,10+WH*2:RETURN
2160 IF SC(WH)>50 THEN CL=0:RW=61-SC(WH):DY=217:IF WH THEN DY=218
2170 IF SC(WH)<51 THEN RW=11:CL=50-SC(WH):DY=215:IF WH THEN DY=214
2180 IF SC(WH)<32 THEN CL=19:RW=SC(WH)-20:DY=218:IF WH THEN DY=217
2190 IF SC(WH)<21 THEN RW=0:CL=SC(WH)-1:DY=214:IF WH THEN DY=215
2200 REM IF SC(WH)=61
2210 IF SC(WH)-61 THEN SOUND 3,9,8+WH*2,10+WH*2:RETURN
2220 W=WH:N=NW:FOR SD=0 TO 16 STEP 0.25:SOUND 0,1,6,SD:NEXT SD
2230 COLOR 0:PLOT 0,0:DRAWTO 19,0:DRAWTO 19,11:DRAWTO 0,11:DRAWTO 0,0
2240 IF NW THEN BD=BD+60
2250 IF WH THEN AD=AD+60
2260 IF AD>70 OR BD>70 THEN 2310
2270 SC(WH)=0:QQ=PT-VV+1:PT=SC(NW):WH=NW:SC(WH)=0
2280 IF PT THEN GOSUB 2090
2290 IF QQ THEN PT=QQ:WH=NW:GOTO 2090
2300 PT=0:WH=W:NW=N:RETURN
2310 GRAPHICS 18:GOSUB 505:FOR AA=0 TO 3:SETCOLOR AA,5*AA,(AA+4)*2:NEXT AA:IF NOT WH THEN 2350
2320 ? #6;" GOOD GAME!!!!","YOU DID AS WELL AS";" could be expected.","like to try again?"," y/n"
2330 GOSUB 2570:IF LP=89 THEN RUN
2340 GOTO 2330
2350 ? #6;" WHAT CAN I SAY?"," I BELIEVE I KNOW"," what went wrong.","what a day i've had! ";
2360 ? #6;"now that i realize","WHO I'M UP AGAINST HOW ABOUT ANOTHER GAME? Y/N"
2365 GOSUB 2570:IF LP=89 THEN RUN
2370 POSITION 4,5:? #6;" CHICKEN!!! "
2380 GOTO 2380
2390 FOR AA=LL TO HH
2400 FOR BB=LL TO AA-1:IF V(M(AA))<V(M(BB)) THEN CC=M(BB):M(BB)=M(AA):M(AA)=CC:GOTO 2400
2410 NEXT BB:NEXT AA:H=D:D=0:GOSUB 2060:D=H:RETURN
2420 REM KEYBOARD OPTION, TITLE, INSTRUCTIONS, CHANGE CHARACTER SET,FROM LINE 10
2430 GRAPHICS 18:GOSUB 505:GOSUB 2560:AA=PEEK(106)-4:BB=AA*256:RESTORE 2620:CR=INT(RND(0)*2)
2440 DIM P$(18),L1$(11),L2$(11),C(14),V(14),S(14),K(14),F(14),M(14),N(14),PT(14),CR(4),SC(2),PL(8),L3$(11)
2450 DIM L4$(11)
2460 READ DD
2465 IF DD=72 THEN ? #6;"PRESS K FOR KEYBOARDpress j for joystick":GOSUB 2580:XX=LP:POKE 77,126
2470 IF DD=72 AND XX-74 AND XX-75 THEN XX=LP:GOTO 2465
2480 REM
2490 IF DD-280 THEN GOSUB 2560:GOTO 2520
2500 FF=PEEK(756)*256:FOR GG=128 TO 200 STEP 8:FOR CC=0 TO 7:EE=PEEK(FF+GG+CC):POKE GG+CC+BB,EE:NEXT CC:NEXT GG
2510 POSITION 1,5:? #6;" PRESS ARROWS FOR"," SELECTION,"," INSERT FOR CHOICE":SC(0)=0:SC(1)=0
2520 IF XX=74 THEN POSITION 2,5:? #6;"MOVE JOYSTICK FOR"," SELECTION"," FIRE FOR CHOICE PLUG INTO #1"
2530 IF DD+1 THEN FOR CC=0 TO 7:READ EE:POKE DD+CC+BB,EE:NEXT CC:GOTO 2460
2540 POKE 77,0:RETURN
2550 REM TITLE
2560 POSITION 6,3:? #6;"CRIBBAGE ATARI!":GOSUB 505:RETURN
2570 REM GET AN ANSWER
2580 POKE 694,0:POKE 702,64:OPEN #1,4,12,"K:":GET #1,LP:CLOSE #1:? #6;CHR$(125):RETURN
2590 DATA 6,7,8,9,10,11,6,7,8,10,9,11,6,7,8,11,9,10,6,7,9,10,8,11,6,7,9,11,8,10,6,7,10,11,8,9,6,8,9,10,7,11
2600 DATA 6,8,9,11,7,10,6,8,10,11,7,9,6,9,10,11,7,8,7,8,9,10,6,11,7,8,9,11,6,10,7,8,10,11,6,9,7,9,10,11,6,8
2610 DATA 8,9,10,11,6,7
2620 REM CHARACTER SET
2630 DATA 8,0,0,34,20,8,8,8,0,16,0,16,8,12,126,12,8,16,24,0,0,99,84,82,81,102,0
2640 DATA 32,0,60,60,60,60,60,60,0,40,0,0,27,27,21,17,17,0,48,0,0,55,66,34,18,98,0
2650 DATA 56,0,0,236,170,202,170,172,0,64,0,0,234,74,78,74,74,0,72,0,0,112,64,96,64,112,0
2660 DATA 80,0,0,66,69,71,69,117,0,88,0,102,102,6,6,126,126,0,96,0,0,119,37,38,37,119,0
2670 DATA 104,0,0,39,85,70,85,37,0,112,0,0,39,85,118,85,85,0,120,0,0,119,36,38,36,39,0
2680 DATA 208,0,0,4,10,8,10,4,0,216,0,60,66,66,78,66,61,0,224,0,0,173,173,171,171,233,0
2690 DATA 232,0,0,238,132,196,132,228,0,240,0,96,96,0,0,6,6,0,248,0,68,202,74,74,74,228,0
2700 DATA 256,0,28,28,127,119,8,28,0,264,0,8,20,20,62,34,119,0,272,0,14,4,4,116,36,60,0
2710 DATA 280,0,0,215,210,178,178,146,0,288,0,36,40,48,40,44,36,0,296,0,0,114,69,101,69,66,0
2720 DATA 304,0,0,214,213,181,181,150,0,312,0,0,83,84,98,81,86,0,320,0,0,210,213,181,181,146,0
2730 DATA 328,0,0,98,133,133,181,98,0
2740 DATA 336,0,0,14,10,12,10,10,0
2750 DATA 344,0,0,115,84,98,81,118,0
2760 DATA 352,0,0,14,10,14,8,8,0
2770 DATA 360,0,0,39,82,114,82,87,0
2780 DATA 368,0,0,50,69,36,21,98,0
2790 DATA 376,0,0,39,85,86,85,37,0
2800 DATA 384,0,0,112,80,96,80,80,0
2810 DATA 392,0,0,116,68,100,68,71,0
2820 DATA 400,0,0,80,80,112,80,80,0
2830 DATA 408,0,126,126,6,6,102,102,0
2840 DATA 416,0,0,83,84,82,81,118,0
2850 DATA 424,0,102,102,96,96,126,126,0
2860 DATA 432,0,126,126,0,0,0,0,0
2870 DATA 440,0,0,0,0,0,126,126,0
2880 DATA 448,0,126,126,0,0,126,126,0
2890 DATA 456,0,96,96,96,96,96,96,0
2900 DATA 464,0,6,6,6,6,6,6,0
2910 DATA 472,0,54,119,127,62,28,8,0
2920 DATA 480,0,24,60,126,126,60,24,0
2930 DATA 488,0,102,102,102,102,102,102,0
2940 DATA 496,0,24,60,126,126,24,60,0
2950 DATA 504,0,0,74,170,170,170,68,0
2960 DATA -1
2970 DATA 162,0,66,102,152
2980 DATA 0,1,2,3,0,1,2,4,0,1,3,4,0,2,3,4,1,2,3,4
2990 DATA 0,1,2,0,1,3,0,1,4,0,2,3,0,2,4,0,3,4,1,2,3,1,2,4,1,3,4,2,3,4
3000 DATA 0,1,0,2,0,3,0,4,1,2,1,3,1,4,2,3,2,4,3,4
3010 DATA 0,1,2,3,4,0,1,2,4,3,0,1,4,2,3,0,4,1,2,3,4,0,1,2,3
3020 DATA 0,1,2,3,0,1,2,4,0,1,4,2,0,4,1,2,4,0,1,2,0,1,3,4,0,1,4,3,0,4,1,3,4,0,1,3,0,2,3,4,0,2,4,3,0,4,2,3,4,0,2,3
3030 DATA 1,2,3,4,1,2,4,3,1,4,2,3,4,1,2,3
3040 DATA 0,1,2,0,1,3,0,1,4,0,4,1,4,0,1,0,2,3,0,2,4,0,4,2,4,0,2,0,3,4,0,4,3,4,0,3,1,2,3,1,2,4,1,4,2,4,1,2
3050 DATA 1,3,4,1,4,3,4,1,3,2,3,4,2,4,3,4,2,3
