Basic Profiler (PROFILE3.BAS)

Basic Profiler (130XE owners refer to 89-10) by Stan Lackey, 51 (BASIC, MAC/65 source)

Description

Basic Profiler (130XE owners refer to 89-10) by Stan Lackey, 51 (BASIC, MAC/65 source)

From the Antic disk of April 1989 (Vol. 7 No. 12) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.4 KB

Dialect
Atari BASIC
Lines
50
Variables
L$, V$, I, J, K, L(, V(, MAX, X, TOTAL, FLAG, PF, CUM, PCT, Y, J1
BASIC listing (50 lines)
10 REM BASIC PROFILER, PART 3
20 REM BY STAN LACKEY
30 REM (c)1988, ANTIC PUBLISHING
40 POKE 40704,0:REM STOP PROFILING
100 DIM L(1000),V(1000):REM LINE#, VALUE
110 I=0:TOTAL=0
115 ? "Reading Counters..."
116 X=(PEEK(106)+4)*256
120 FOR J=0 TO 6550 STEP 2
130 REM READ EACH COUNTER
131 K=PEEK(J+X)+256*PEEK(J+X+1)
140 IF K=0 THEN 170
150 REM SAVE ALL NON-ZERO VALUES
155 I=I+1
160 L(I)=J*5:V(I)=K:TOTAL=TOTAL+K
170 NEXT J
175 MAX=I
180 ? "TOTAL COUNTS = ";TOTAL
185 ? "IN ";MAX;" PROGRAM LINES"
190 ? "SORTING..."
200 REM ROUTINE SORTS ALL ENTRIES
205 FOR J=1 TO MAX
210 FOR I=J TO MAX
220 IF V(I)<V(J) THEN 260
230 REM EXCHANGE L&V VALUES TO SORT
240 X=V(I):V(I)=V(J):V(J)=X
250 X=L(I):L(I)=L(J):L(J)=X
260 NEXT I
265 ? ".";
270 NEXT J
380 TRAP 450
390 PF=1
395 ?
400 ? "LINE","COUNTS","PERCENT","CUM PCT"
410 LPRINT "TOTAL COUNTS = ";TOTAL
420 LPRINT
430 LPRINT "LINE","COUNTS","PERCENT","CUM PCT"
440 GOTO 480
450 PF=0
480 REM PRINT TOP 20 IF TO SCREEN, OR
485 REM TOP 40 IF PRINTER IS ON
490 J=20+20*PF:IF MAX<J THEN J=MAX
500 CUM=0
510 FOR I=1 TO J
520 PCT=V(I)/TOTAL:CUM=CUM+PCT
530 Y=(INT(0.5+10000*CUM))/100
540 X=(INT(0.5+10000*PCT))/100
550 ? L(I),V(I),X,Y
560 IF PF THEN LPRINT L(I),V(I),X,Y
570 NEXT I