Signboard and samples (SIGN.BAS)

Signboard and samples by Andrew R. Thomas, 191

Description

Signboard and samples by Andrew R. Thomas, 191

From the Antic disk of March 1989 (Vol. 7 No. 11) — disk A.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 21.8 KB

Dialect
Atari BASIC
Lines
810
Variables
IT, C1, C4, C0, C2, TEMP$, VAR, VAR1, TC, TR, BPOS, PAUSE, S$, SP, DL, ROW, VAR2, HI, C256, LO, SH, DUM, PPMOVE$, ITEM, QMENU$, IDIS, C5, I$, QMI$, MENUSEL, C3, TPOS, DCASE, LC, VAR4, UC, VAR3, COL, TEXT$, TRANS$, DLI, SL, IMEM, IS, BLANK$, CLICK, OLDCHAR$, OLDROW, OLDCOL, C6, MMI$, RMI$, FLAG, RESET, GI, C7, PCLEAR$, DIR, DIST, SPEED, IT1, SCRH$, SCRD$, SCRU$, CASE, CASEMENU$, FILE$, COLVAR, WMI$, WPMI$, PTR, CMI$, COLSEL, SPEEDMI$, SMENU$, SMI$, SLMENU$, SLMI$, DISTSEL, SPEEDSEL, SPEEDMENU$, OMI$, CASESEL, CASEMI$, OSP, EMI$, EDMI$, CIO$, MISCMI$, FADEMI$, RL, HILO
BASIC listing (810 lines)
10 REM SIGNBOARD
12 REM BY ANDREW R. THOMAS
14 REM (c)1988, ANTIC PUBLISHING
16 GOTO 12500
100 REM CLICK
110 FOR IT=C1 TO C4:SOUND C0,110-IT,10,C2:NEXT IT
115 SOUND C0,C0,C0,C0
120 RETURN
140 REM READ LOOP
145 TEMP$=""
150 FOR IT=C1 TO VAR:READ VAR1:TEMP$(IT,IT)=CHR$(VAR1):NEXT IT
155 RETURN
160 REM INSUFFICIENT MEMORY
165 TC=C0:TR=C0:GOSUB BPOS:? " Insufficient memory";
170 GOSUB PAUSE
175 GOSUB BPOS
180 RETURN
185 REM GET INSTRUCTION
190 TRAP 195:VAR=ASC(S$(SP,SP)):VAR1=VAR-47:SP=SP+C1
195 TRAP 40000:RETURN
200 REM D/L INFO
205 VAR=DL+ROW*3:VAR1=PEEK(VAR-C1):VAR2=PEEK(VAR)
210 RETURN
220 REM HI/LO
225 HI=INT(VAR/C256):LO=VAR-256*HI
230 RETURN
250 REM INSERT STEPS
255 VAR=LEN(S$):IF SP>VAR THEN RETURN
260 VAR1=VAR-SP+C1
265 S$(VAR+SH,VAR+SH)=" "
270 IF VAR1<255 THEN 290
275 VAR1=VAR1-255:DUM=USR(ADR(PPMOVE$),ADR(S$(SP+VAR1,SP+VAR1))-C1,ADR(S$(SP+VAR1,SP+VAR1))-C1+SH,255)
280 IF VAR1=0 THEN RETURN
285 GOTO 270
290 DUM=USR(ADR(PPMOVE$),ADR(S$(SP,SP))-C1,ADR(S$(SP,SP))-C1+SH,VAR1)
295 RETURN
300 REM Y/N ?
305 ITEM=C1
310 TC=C0:TR=C0:GOSUB BPOS:? QMENU$;
315 IDIS=C5:I$=QMI$:GOSUB MENUSEL
320 TC=C0:TR=C2:GOSUB BPOS
325 RETURN
330 REM SINGLE POINTER
335 GOSUB 750
340 IF VAR2=28 OR VAR2=12 THEN RETURN
345 GOTO 335
350 REM CHAR EQUIVS
351 TC=C0:TR=C2:GOSUB BPOS
352 ? "CTR ";:FOR IT=C1 TO 26:? CHR$(IT+64);:NEXT IT:FOR IT=28 TO 31:? CHR$(27);CHR$(IT);:NEXT IT
353 ? ".; ␛␛";
354 TC=C4:TR=C3:GOSUB TPOS
355 IF PEEK(DCASE)=LC THEN 358
356 FOR IT=33 TO 58:? CHR$(IT);:NEXT IT:FOR IT=60 TO 64:? CHR$(IT);:NEXT IT:? "[ ;";
357 RETURN
358 FOR IT=C1 TO 26:? CHR$(IT);:NEXT IT:FOR IT=28 TO 31:? CHR$(27);CHR$(IT);:NEXT IT
359 ? "◆♠ ␛␛";
360 RETURN
370 REM ONSCREEN WRITING
371 GOSUB 350
372 OPEN #1,C4,0,"K:":POKE 764,255
373 VAR4=(PEEK(DCASE)=UC)*-8+19
375 GOSUB 760
376 POKE 764,VAR2
377 GET #1,VAR3
378 IF VAR3=27 THEN GET #1,VAR3
380 IF VAR3=27 THEN CLOSE #1:? "↰";:RETURN
381 IF VAR3<>155 THEN 384
382 IF ROW<9 THEN ROW=ROW+C1:COL=0
383 GOTO 373
384 TEXT$="":TEXT$=CHR$(VAR3)
385 DUM=USR(ADR(TRANS$),ADR(TEXT$)-C1,ADR(TEXT$)-C1,C1)
386 VAR3=ASC(TEXT$(C1,C1))
388 GOSUB DLI:VAR1=VAR2*C256+VAR1+COL
390 POKE VAR1,VAR3
392 SH=C5:IF SP+SH>SL THEN GOSUB IMEM:RETURN
394 GOSUB IS
396 S$(SP,SP+C1)="03":S$(SP+C2,SP+C2)=CHR$(ROW):S$(SP+C3,SP+C3)=CHR$(COL):S$(SP+C4,SP+C4)=CHR$(VAR3)
398 SP=SP+SH
400 IF COL<19 THEN COL=COL+C1
402 GOTO 373
410 REM RESET
411 GOSUB 1350:POKE DCASE,UC
412 POKE 203,40:POKE 204,202:POKE 205,148:POKE 206,70:POKE 207,0:POKE 208,C0:POKE 708,40:POKE 711,70
413 POKE 712,0:RETURN
500 REM WINDOW POS
510 POKE 656,TR:POKE 657,TC
520 RETURN
530 REM PAUSE
535 TC=C0:TR=C3:GOSUB TPOS
540 POKE 764,255
545 ? "     ◣ press any key to continue ◢";
550 IF PEEK(764)=255 THEN 550
555 POKE 764,255
560 TC=C0:TR=C3:GOSUB TPOS:? BLANK$(C1,38);
565 RETURN
580 REM TEXT WINDOW POS & BLANK
585 GOSUB TPOS:? BLANK$;:GOSUB TPOS
590 RETURN
600 REM MENU SELECT
605 POKE 764,255
610 TC=ITEM*IDIS:TR=C0:GOSUB TPOS:? "␛▶";
620 IF PEEK(764)<255 THEN 700
625 IF STICK(C0)<15 THEN 640
630 IF  NOT STRIG(C0) THEN 740
635 GOTO 620
640 IF STICK(C0)<>7 THEN 660
645 IF ITEM<LEN(I$)-C1 THEN ITEM=ITEM+C1
650 GOSUB TPOS:? " ";
655 GOTO 675
660 IF STICK(C0)<>11 THEN 620
665 IF ITEM>C0 THEN ITEM=ITEM-C1
670 GOSUB TPOS:? " ";
675 TC=ITEM*IDIS:GOSUB TPOS:? "␛▶";
680 GOSUB CLICK:GOTO 620
700 VAR=PEEK(764):POKE 764,255
702 IF VAR=7 OR VAR=135 THEN 645
703 IF VAR=6 OR VAR=134 THEN 665
704 GOSUB CLICK
707 IF VAR=12 THEN 740
710 IF VAR=28 THEN ITEM=-1:RETURN
715 IF I$(C1,C1)="!" THEN 740
716 IT=C1
720 IF I$(IT,IT)=CHR$(VAR) THEN 735
725 IF IT=LEN(I$) THEN 620
730 IT=IT+C1:GOTO 720
735 ITEM=IT-C1:GOSUB TPOS:? " ";:TC=ITEM*IDIS:GOSUB TPOS:? "␛▶";
740 IF  NOT STRIG(C0) THEN 740
745 RETURN
750 REM PTR
755 POKE 764,255
760 GOSUB DLI:VAR1=VAR2*C256+VAR1+COL:VAR2=255:VAR3=15
765 OLDCHAR$=CHR$(PEEK(VAR1))
770 POKE VAR1,VAR4
775 IF PEEK(764)<255 THEN VAR2=PEEK(764):POKE 764,255:GOTO 790
780 IF STICK(C0)<15 THEN VAR3=STICK(0):GOTO 800
785 IF  NOT STRIG(C0) THEN VAR2=12:GOTO 870
786 GOTO 775
790 IF VAR2=28 THEN VAR4=-C1:GOTO 870
795 IF VAR2=12 THEN 870
800 OLDROW=ROW:OLDCOL=COL
801 GOSUB CLICK
805 IF (VAR2=6 OR VAR3=11) AND COL>C0 THEN COL=COL-C1:GOTO 850
810 IF (VAR2=7 OR VAR3=7) AND COL<19 THEN COL=COL+C1:GOTO 850
815 IF (VAR2=14 OR VAR3=14) AND ROW>C0 THEN ROW=ROW-C1:GOTO 850
820 IF (VAR2=15 OR VAR3=13) AND ROW<9 THEN ROW=ROW+C1:GOTO 850
825 IF VAR3=10 AND (COL>C0 AND ROW>C0) THEN COL=COL-C1:ROW=ROW-C1:GOTO 850
830 IF VAR3=6 AND (COL<19 AND ROW>C0) THEN COL=COL+C1:ROW=ROW-C1:GOTO 850
835 IF VAR3=9 AND (COL>C0 AND ROW<9) THEN COL=COL-C1:ROW=ROW+C1:GOTO 850
840 IF VAR3=5 AND (COL<19 AND ROW<9) THEN COL=COL+C1:ROW=ROW+C1:GOTO 850
845 IF  NOT (VAR3<15 OR VAR2=6 OR VAR2=7 OR VAR2=14 OR VAR2=15) THEN 870
850 POKE VAR1,ASC(OLDCHAR$(C1,C1))
865 GOTO 760
870 POKE VAR1,ASC(OLDCHAR$(C1,C1))
875 RETURN
900 REM MAIN MENU
905 ITEM=C0
910 TC=C0:TR=C0:GOSUB BPOS
915 ? " play  rec   edit  load  save  new   q";
920 IDIS=C6:I$=MMI$:GOSUB MENUSEL
925 IF ITEM=-C1 THEN ITEM=C0:GOTO 920
930 ON ITEM+C1 GOSUB 1000,950,10000,13000,13200,13400,30000
935 GOTO 910
950 REM RECORD
955 ITEM=C0
960 TC=C0:TR=C0:GOSUB BPOS
965 ? " write   scroll  pause   option  load"
970 IDIS=8:I$=RMI$:GOSUB MENUSEL
975 IF ITEM=-C1 THEN ITEM=C0:RETURN
980 ON ITEM+C1 GOSUB 4000,5000,4700,8000,9000
995 GOTO 960
1000 REM PLAY
1001 IF  NOT LEN(S$) THEN RETURN
1005 POKE 764,255
1010 SP=C1:FLAG=C0:POKE 559,0
1015 POKE DL+29,65:POKE DL+30,210:POKE DL+31,6
1020 GOSUB RESET:POKE 559,34
1025 GOSUB 1050:POKE 77,C0
1030 IF SP<LEN(S$) THEN 1025
1035 FOR IT=C1 TO 100:NEXT IT
1040 IF PEEK(764)=255 THEN 1010
1044 POKE 559,0:POKE DL+29,66:POKE DL+30,PEEK(660):POKE DL+31,PEEK(661):POKE 559,34
1045 POKE 764,255:SP=LEN(S$)+C1:RETURN
1050 REM PLAY 1 INSTRUCTION
1060 GOSUB GI
1070 ON VAR1 GOSUB 1100,2000,1400,3000,3100:RETURN
1100 GOSUB GI
1110 ON VAR1 GOSUB 1150,1200,1300,1500:RETURN
1150 TEMP$="ENTER: "
1155 TEXT$=" ":GOSUB GI:TEXT$(VAR,VAR)=" "
1160 DUM=USR(ADR(PPMOVE$),ADR(S$(SP,SP))-C1,ADR(TEXT$)-C1,VAR)
1165 VAR1=(VAR<25)*VAR+(VAR>=25)*25
1170 TEMP$(8)=TEXT$(1,VAR1):TEMP$(8+VAR1)=" ..."
1175 FOR IT=C1 TO C2:DUM=USR(ADR(TRANS$),ADR(TEMP$(8))-C1,ADR(TEMP$(8))-C1,VAR1):NEXT IT
1190 SP=SP+VAR
1195 RETURN
1200 REM PLACE
1205 GOSUB GI:VAR2=VAR1
1210 GOSUB GI:ROW=VAR
1211 TEMP$="PLACE LINE "
1212 TEMP$(12)=STR$(ROW)
1215 ON VAR2 GOSUB 1220,1240,1270:RETURN
1220 GOSUB DLI:TEMP$(13)=" LEFT OFFSCREEN"
1225 IF VAR1<LEN(TEXT$) THEN RETURN
1230 DUM=USR(ADR(PPMOVE$),ADR(TEXT$)-C1,VAR2*256+VAR1-LEN(TEXT$)-C1,LEN(TEXT$))
1235 RETURN
1240 TEMP$(13)=" ONSCREEN"
1241 GOSUB GI:COL=VAR
1245 GOSUB DLI
1250 IF VAR1+COL+LEN(TEXT$)>255 THEN RETURN
1255 DUM=USR(ADR(PPMOVE$),ADR(TEXT$)-1,VAR2*256+VAR1+COL-C1,LEN(TEXT$))
1260 RETURN
1270 GOSUB DLI:TEMP$(13)=" RIGHT OFFSCREEN"
1275 IF VAR1+19+LEN(TEXT$)>255 THEN RETURN
1280 DUM=USR(ADR(PPMOVE$),ADR(TEXT$)-C1,VAR2*256+VAR1+19,LEN(TEXT$))
1285 RETURN
1300 REM CLEAR
1305 GOSUB GI:TEMP$="CLEAR "
1310 ON VAR1 GOSUB 1360,1320,1350:RETURN
1320 GOSUB GI:ROW=VAR
1321 TEMP$(C7)="LINE ":TEMP$(12)=STR$(ROW)
1325 GOSUB DLI
1330 DUM=USR(ADR(PCLEAR$),VAR2)
1335 RETURN
1350 FOR ROW=C0 TO 9:GOSUB DLI:DUM=USR(ADR(PCLEAR$),VAR2):POKE VAR-C1,117:NEXT ROW:ROW=C0
1355 TEMP$(C7)="DISPLAY"
1356 RETURN
1360 GOSUB GI:ROW=VAR:GOSUB GI:COL=VAR
1365 GOSUB DLI
1370 POKE VAR2*256+VAR1+COL,C0
1375 TEMP$(C7)="CHAR LINE    COL ":TEMP$(17,17)=STR$(ROW):TEMP$(24)=STR$(COL)
1380 RETURN
1400 TEMP$="PAUSE "
1405 GOSUB GI:TEMP$(C7)=STR$(VAR-C1):IF FLAG THEN RETURN
1410 VAR1=INT((VAR+C1)/C2):POKE 20,128*(C2*VAR1-VAR):POKE 19,255-VAR1
1415 IF PEEK(19) THEN 1415
1420 RETURN
1500 TEMP$="ONSCREEN WRITING"
1505 ROW=ASC(S$(SP,SP)):COL=ASC(S$(SP+C1,SP+C1)):VAR1=ASC(S$(SP+C2,SP+C2)):SP=SP+C3
1510 VAR=DL+ROW*3:POKE PEEK(VAR)*256+PEEK(VAR-C1)+COL,VAR1
1515 RETURN
2000 GOSUB GI:TEMP$="SCROLL "
2020 ON VAR1 GOSUB 2050,2300:RETURN
2050 TEMP$(8)="LINE "
2060 GOSUB GI:VAR2=VAR1
2065 GOSUB GI:ROW=VAR:TEMP$(13)=STR$(ROW)
2070 GOSUB GI:DIR=VAR-C1:GOSUB GI:DIST=VAR:GOSUB GI:SPEED=VAR
2075 ON VAR2 GOSUB 2100,2200:RETURN
2100 IF DIR=-C1 THEN TEMP$(14)=" LEFT":GOTO 2110
2105 TEMP$(14)=" RIGHT"
2110 VAR=DL+ROW*C3:VAR1=PEEK(VAR-C1):VAR2=PEEK(VAR)
2120 FOR IT=C1 TO DIST
2130 VAR1=PEEK(VAR-C1)-DIR
2135 IF VAR1>-C1 AND VAR1<C256 THEN POKE VAR-C1,VAR1
2140 FOR IT1=C1 TO 60 STEP SPEED+C1:NEXT IT1
2150 NEXT IT
2160 RETURN
2200 REM U/D
2205 IF DIR=-C1 THEN TEMP$(14)=" UP":GOTO 2210
2206 TEMP$(14)=" DOWN"
2210 IT=C1
2220 VAR=DL+ROW*3:VAR1=PEEK(VAR-1):VAR2=PEEK(VAR)
2225 IF (ROW=C0 AND DIR=-C1) OR (ROW=9 AND DIR=C1) THEN 2270
2230 VAR3=VAR+3*DIR
2231 DUM=USR(ADR(PCLEAR$),PEEK(VAR3))
2235 POKE VAR,PEEK(VAR3):POKE VAR3-C1,VAR1:POKE VAR3,VAR2:POKE VAR-C1,117
2240 FOR IT1=C1 TO 60 STEP SPEED+C1:NEXT IT1
2245 ROW=ROW+DIR
2250 IT=IT+C1:IF IT<=DIST THEN 2220
2260 RETURN
2270 DUM=USR(ADR(PCLEAR$),VAR2):POKE VAR-C1,117:RETURN
2300 TEMP$(8)="DISPLAY "
2305 GOSUB GI:VAR2=VAR1
2310 GOSUB GI:DIR=VAR-C1:GOSUB GI:DIST=VAR:GOSUB GI:SPEED=VAR
2315 ON VAR2 GOSUB 2350,2500:RETURN
2350 IF DIR=-C1 THEN TEMP$(16)="LEFT":GOTO 2360
2355 TEMP$(16)="RIGHT"
2360 SCRH$(C4,C4)=CHR$(238-16*DIR)
2365 FOR IT=C1 TO DIST
2370 DUM=USR(ADR(SCRH$))
2385 FOR IT1=C1 TO 50 STEP SPEED+C1:NEXT IT1
2390 NEXT IT:RETURN
2500 VAR=(C3-DIR)/C2:IF DIR=-C1 THEN TEMP$(16)="UP":GOTO 2510
2505 TEMP$(16)="DOWN"
2510 FOR IT=C1 TO DIST
2515 ON VAR GOTO 2520,2530
2520 VAR1=PEEK(DL+27):DUM=USR(ADR(PCLEAR$),VAR1):DUM=USR(ADR(SCRD$)):POKE DL,VAR1:POKE DL-C1,117:GOTO 2540
2530 VAR1=PEEK(DL):DUM=USR(ADR(PCLEAR$),VAR1):DUM=USR(ADR(SCRU$)):POKE DL+27,VAR1:POKE DL+26,117
2540 FOR IT1=C1 TO 70 STEP SPEED+C1:NEXT IT1
2545 NEXT IT
2550 RETURN
3000 REM OPTION
3010 GOSUB GI:ON VAR1 GOSUB 3050,3070,3130,3150
3015 RETURN
3050 TEMP$="SHIFT"
3055 GOSUB GI:POKE DCASE,VAR:RETURN
3070 TEMP$="COLOR "
3075 GOSUB GI:CASE=VAR:GOSUB GI
3080 VAR2=C2+CASE*C7:TEMP$(C7,12)=CASEMENU$(VAR2,VAR2+C5):VAR2=INT(VAR/16)
3090 TEMP$(13,15)="   ":TEMP$(14)=STR$(VAR2):TEMP$(16)=" ":TEMP$(17)=STR$((VAR-VAR2*16)/C2+C1)
3095 POKE 203+CASE,VAR:POKE 708+CASE,VAR:RETURN
3100 TEMP$="LOAD "
3105 GOSUB GI:FILE$=S$(SP,SP+VAR-C1):TEMP$(C6,C5+VAR)=FILE$:SP=SP+VAR
3110 IF FLAG OR PEEK(764)<255 THEN RETURN
3120 GOSUB 13040
3125 RETURN
3130 TEMP$="BLINK "
3135 GOSUB GI:CASE=VAR:GOSUB GI:POKE 1721,VAR:POKE 208,CASE:IF  NOT CASE THEN TEMP$(7)="OFF":RETURN
3140 VAR=C2+(CASE-C1)*C7:TEMP$(7)=CASEMENU$(VAR,VAR+C6):RETURN
3150 REM MISC
3155 GOSUB GI:ON VAR1 GOSUB 3200
3160 RETURN
3200 TEMP$="FADE "
3205 GOSUB GI:DIR=VAR-1:GOSUB GI:CASE=VAR:GOSUB GI:SPEED=VAR+1
3210 IF DIR-C1 THEN TEMP$(6)="OUT ":GOTO 3220
3215 TEMP$(6)="IN  "
3220 VAR2=C2+CASE*C7:TEMP$(10)=CASEMENU$(VAR2,VAR2+C5):VAR4=203+CASE
3225 VAR3=PEEK(VAR4):COLVAR=INT(VAR3/16)
3230 VAR2=VAR3-COLVAR*16:IF (VAR2<C2 AND DIR=-C1) OR (VAR2>13 AND DIR=C1) THEN RETURN
3235 VAR3=VAR3+DIR*C2:POKE VAR4,VAR3:POKE 708+CASE,VAR3
3240 FOR IT=C1 TO 30 STEP SPEED:NEXT IT:GOTO 3225
4000 REM WRITE
4010 ITEM=C0
4020 TC=C0:TR=C0:GOSUB BPOS
4030 ? " enter   place   clear   onscreen"
4040 IDIS=8:I$=WMI$:GOSUB MENUSEL
4050 IF ITEM=-C1 THEN ITEM=C0:RETURN
4060 ON ITEM+C1 GOSUB 4100,4200,4400,370
4070 GOTO 4020
4100 REM W_TEXT
4110 ? CHR$(125);
4115 TC=C0:TR=C1:GOSUB BPOS
4116 ? "  2 4 6 8 0 2 4 6 8 0";
4120 GOSUB 350
4125 TC=C0:TR=C0:GOSUB BPOS
4126 POKE 752,C0:INPUT TEMP$:POKE 752,C1
4130 IF LEN(TEMP$)=C0 THEN ? CHR$(125);:RETURN
4135 TEXT$=TEMP$:ITEM=C1
4140 DUM=USR(ADR(TRANS$),ADR(TEXT$)-1,ADR(TEXT$)-C1,LEN(TEMP$))
4150 ? CHR$(125)
4155 VAR2=LEN(TEXT$)
4160 SH=VAR2+C3:IF SP+SH>SL THEN GOSUB IMEM:RETURN
4165 GOSUB IS
4170 S$(SP,SP+C1)="00":S$(SP+C2,SP+C2)=CHR$(VAR2)
4175 S$(SP+C3,SP+C3+VAR2-C1)=TEXT$:SP=SP+SH
4180 RETURN
4200 REM W_PLACE
4205 ITEM=C1
4210 TC=C0:TR=C0:GOSUB BPOS:? " left offscr  onscreen     right offscr"
4215 IDIS=13:I$=WPMI$:GOSUB MENUSEL
4220 IF ITEM=-C1 THEN ITEM=C1:RETURN
4225 ON ITEM+C1 GOSUB 4230,4280,4330
4226 GOTO 4210
4230 VAR4=(PEEK(DCASE)=UC)*60+C1:GOSUB PTR
4235 IF VAR4=-C1 THEN RETURN
4240 GOSUB DLI
4245 IF VAR1-LEN(TEXT$)<C0 THEN 4380
4250 DUM=USR(ADR(PPMOVE$),ADR(TEXT$)-C1,PEEK(VAR)*256+VAR1-LEN(TEXT$)-C1,LEN(TEXT$))
4255 SH=C4:IF SP+SH>SL THEN GOSUB IMEM:RETURN
4256 GOSUB IS
4260 S$(SP,SP+C2)="010"
4265 S$(SP+C3,SP+C3)=CHR$(ROW):SP=SP+SH
4275 RETURN
4280 IF LEN(TEXT$)>20 THEN 4285
4281 COL=10-INT(LEN(TEXT$)/C2)
4285 VAR4=52:GOSUB PTR:IF VAR4=-C1 THEN RETURN
4290 GOSUB DLI
4295 IF VAR1+COL+LEN(TEXT$)>255 THEN 4380
4300 DUM=USR(ADR(PPMOVE$),ADR(TEXT$)-C1,PEEK(VAR)*C256+VAR1+COL-C1,LEN(TEXT$))
4305 SH=C5:IF SP+SH>SL THEN GOSUB IMEM:RETURN
4310 GOSUB IS
4315 S$(SP,SP+C2)="011"
4320 S$(SP+C3,SP+C3)=CHR$(ROW):S$(SP+C4,SP+C4)=CHR$(COL):SP=SP+SH
4325 RETURN
4330 VAR4=(PEEK(DCASE)=UC)*55+C4:GOSUB PTR
4335 IF VAR4=-C1 THEN RETURN
4340 GOSUB DLI
4345 IF VAR1+19+LEN(TEXT$)>255 THEN 4380
4350 DUM=USR(ADR(PPMOVE$),ADR(TEXT$)-C1,PEEK(VAR)*C256+VAR1+19,LEN(TEXT$))
4355 SH=C4:IF SP+SH>SL THEN GOSUB IMEM:RETURN
4356 GOSUB IS
4360 S$(SP,SP+2)="012"
4365 S$(SP+C3,SP+C3)=CHR$(ROW):SP=SP+SH
4375 RETURN
4380 TC=C0:TR=C1:GOSUB BPOS
4381 ? "     Sorry, text will not fit there.    "
4382 ? "           Try CLEARing line.           ";
4383 GOSUB PAUSE
4384 GOTO 4210
4400 REM W_CLEAR
4405 ITEM=C1
4410 TC=C0:TR=C0:GOSUB BPOS
4415 ? " char     line     display";
4420 IDIS=9:I$=CMI$:GOSUB MENUSEL
4425 ON ITEM+C1 GOSUB 4500,4435,4455
4430 IF ITEM=-C1 THEN ITEM=C2:RETURN
4431 GOTO 4410
4435 VAR4=(PEEK(DCASE)=LC)*22+C3:GOSUB PTR:IF VAR4=-C1 THEN RETURN
4436 GOSUB DLI
4440 DUM=USR(ADR(PCLEAR$),VAR2)
4441 POKE VAR-C1,117
4442 SH=C4:IF SP+SH>SL THEN GOSUB IMEM:RETURN
4443 GOSUB IS
4445 S$(SP,SP+C2)="021"
4446 S$(SP+C3,SP+C3)=CHR$(ROW):SP=SP+SH
4450 RETURN
4455 TC=C0:TR=C2:GOSUB BPOS:? "Clear screen?";
4456 GOSUB 300
4459 IF ITEM=-C1 THEN ITEM=C1:RETURN
4460 ON ITEM+C1 GOTO 4465,4485
4465 GOSUB 1350
4470 SH=C3:IF SP+SH>SL THEN GOSUB IMEM:RETURN
4475 GOSUB IS
4480 S$(SP,SP+C2)="022":SP=SP+C3
4485 RETURN
4500 REM CLEAR CHAR
4510 VAR4=(PEEK(DCASE)=LC)*22+C3:GOSUB PTR:IF VAR4=-C1 THEN RETURN
4520 GOSUB DLI
4530 POKE VAR2*C256+VAR1+COL,0
4535 SH=C5:IF SP+SH>SL THEN GOSUB IMEM:RETURN
4540 GOSUB IS
4545 S$(SP,SP+C2)="020":S$(SP+C3,SP+C3)=CHR$(ROW):S$(SP+C4,SP+C4)=CHR$(COL):SP=SP+C5
4550 RETURN
4700 REM PAUSE
4705 TC=C0:TR=C2:GOSUB BPOS:? " Select time"
4710 ITEM=C7:GOSUB COLSEL:VAR2=ITEM:IF VAR2=-C1 THEN ITEM=C2:RETURN
4715 ITEM=C2:SH=C2:IF SP+SH>SL THEN GOSUB IMEM:RETURN
4720 GOSUB IS
4725 S$(SP,SP)="2":S$(SP+C1,SP+C1)=CHR$(VAR2+C1):SP=SP+SH
4730 RETURN
4900 TC=C0:TR=C0:GOSUB BPOS:? " 0 1 2 3 4 5 6 7 8 9 0 1 2 3 4 5":I$="!!!!!!!!!!!!!!!!"
4910 IDIS=C2:GOSUB MENUSEL
4920 TC=C0:TR=C2:GOSUB BPOS
4930 RETURN
4940 TC=C0:TR=C0:GOSUB BPOS:? " 1 2 3 4 5 6 7 8":I$=SPEEDMI$(1,8):GOTO 4910
5000 REM SCROLL
5005 ITEM=C0
5010 TC=C0:TR=C0:GOSUB BPOS
5020 ? SMENU$;
5030 IDIS=9:I$=SMI$:GOSUB MENUSEL
5040 IF ITEM=-C1 THEN ITEM=C1:RETURN
5050 ON ITEM+C1 GOSUB 5100,6000
5060 GOTO 5010
5100 REM S_LINE
5105 ITEM=C0
5110 TC=C0:TR=C0:GOSUB BPOS
5120 ? SLMENU$;
5130 IDIS=7:I$=SLMI$:GOSUB MENUSEL
5140 IF ITEM=-C1 THEN ITEM=C0:RETURN
5150 ON ITEM+C1 GOSUB 5200,5500,5500,5200
5160 GOTO 5110
5200 REM L/R
5205 TC=C0:TR=C0:GOSUB BPOS:? " Select line";
5210 DIST=C0
5215 DIR=(ITEM-1.5)/1.5
5220 IF PEEK(DCASE)=UC THEN VAR4=DIR+29:GOTO 5230
5225 VAR4=(DIR+C1)/C2+30
5230 GOSUB PTR:IF VAR4=-C1 THEN RETURN
5235 GOSUB BPOS:? " Select distance";
5240 POKE 764,255
5245 GOSUB DLI:OLDCOL=VAR1
5250 GOSUB DISTSEL
5260 IF VAR2=-C1 THEN POKE VAR-C1,OLDCOL:RETURN
5270 IF VAR2=12 THEN 5350
5300 GOSUB DLI:VAR1=VAR1-DIR
5310 IF VAR1>C0 AND VAR1<255 THEN POKE VAR-C1,VAR1:DIST=DIST+C1
5320 GOTO 5250
5350 IF  NOT DIST THEN RETURN
5355 GOSUB SPEEDSEL
5360 SH=C7:IF SP+SH>SL THEN GOSUB IMEM:RETURN
5370 GOSUB IS
5375 S$(SP,SP+C2)="100"
5380 S$(SP+C3,SP+C3)=CHR$(ROW):S$(SP+C4,SP+C4)=CHR$(DIR+C1):S$(SP+C5,SP+C5)=CHR$(DIST):S$(SP+C6,SP+C6)=CHR$(ITEM)
5390 SP=SP+SH:ITEM=(DIR+C1)*1.5:RETURN
5500 REM U/D
5505 TC=C0:TR=C0:GOSUB BPOS:? " Select line";
5510 DIST=C0:DIR=C3-(ITEM*C2)
5520 IF PEEK(DCASE)=UC THEN VAR4=-DIR*C4+58:GOTO 5525
5521 VAR4=(DIR+C1)/C2+28
5525 GOSUB PTR
5530 IF VAR4=-C1 THEN RETURN
5535 GOSUB BPOS:? " Select distance";
5540 POKE 764,255
5550 GOSUB DISTSEL
5560 IF VAR2=-C1 THEN 5550
5570 IF VAR2=12 THEN 5650
5600 GOSUB DLI
5605 DIST=DIST+1
5610 IF (ROW=C0 AND DIR=-C1) OR (ROW=9 AND DIR=C1) THEN 5640
5615 VAR3=VAR+C3*DIR
5616 DUM=USR(ADR(PCLEAR$),PEEK(VAR3))
5620 POKE VAR,PEEK(VAR3):POKE VAR3-C1,VAR1:POKE VAR3,VAR2:POKE VAR-C1,117
5625 ROW=ROW+DIR
5630 GOTO 5550
5640 DUM=USR(ADR(PCLEAR$),VAR2):POKE VAR-C1,117
5650 IF  NOT DIST THEN RETURN
5655 GOSUB SPEEDSEL
5660 SH=C7:IF SP+SH>SL THEN GOSUB IMEM:RETURN
5670 GOSUB IS
5675 S$(SP,SP+C2)="101"
5680 IF ROW-DIR*DIST<0 THEN DIST=DIST-1:GOTO 5680
5681 S$(SP+C3,SP+C3)=CHR$(ROW-DIR*DIST):S$(SP+C4,SP+C4)=CHR$(DIR+C1):S$(SP+C5,SP+C5)=CHR$(DIST)
5685 S$(SP+C6,SP+C6)=CHR$(ITEM):SP=SP+SH
5690 ITEM=(C3-DIR)/C2:RETURN
5800 REM DISTANCE
5810 VAR2=PEEK(764):IF VAR2<255 THEN POKE 764,255:GOTO 5850
5815 IF (STICK(C0)=11 AND ITEM=C0) OR (STICK(C0)=C7 AND ITEM=C3) THEN 5890
5820 IF (STICK(C0)=14 AND ITEM=C2) OR (STICK(C0)=13 AND ITEM=C1) THEN 5890
5830 IF  NOT STRIG(C0) THEN VAR2=12:GOTO 5890
5835 GOTO 5810
5850 IF VAR2=28 THEN VAR2=-C1:RETURN
5855 IF VAR2=12 THEN 5890
5860 IF VAR2=33 THEN 5890
5865 IF (VAR2=C6 AND ITEM=C0) OR (VAR2=C7 AND ITEM=C3) THEN 5890
5870 IF (VAR2=14 AND ITEM=C1) OR (VAR2=15 AND ITEM=C2) THEN 5890
5875 GOTO 5810
5890 GOSUB CLICK:RETURN
5900 REM SPEED MENU
5910 ITEM=SPEED:TC=C0:TR=C0:GOSUB BPOS:? SPEEDMENU$;
5930 TC=C0:TR=C2:GOSUB BPOS:? " Select speed"
5940 IDIS=C3:I$=SPEEDMI$:GOSUB MENUSEL:IF  NOT (ITEM+C1) THEN ITEM=C5:GOTO 5940
5950 SPEED=ITEM
5960 TC=C0:TR=C2:GOSUB BPOS
5970 RETURN
6000 REM S_SCREEN
6010 ITEM=C0
6020 TC=C0:TR=C0:GOSUB BPOS:? SLMENU$;
6030 IDIS=C7:I$=SLMI$:GOSUB MENUSEL
6040 IF ITEM=-C1 THEN ITEM=C1:RETURN
6050 ON ITEM+C1 GOSUB 6100,6500,6500,6100
6060 GOTO 6020
6100 REM L/R
6105 DIST=C0:DIR=(ITEM-1.5)/1.5:SCRH$(C4,C4)=CHR$(238-16*DIR)
6110 TC=C0:TR=C2:GOSUB BPOS:? " Select distance"
6115 GOSUB DISTSEL
6120 IF VAR2=-C1 THEN 6115
6125 IF VAR2=12 THEN 6150
6130 DUM=USR(ADR(SCRH$))
6135 DIST=DIST+C1:GOTO 6115
6150 IF  NOT DIST THEN RETURN
6160 GOSUB SPEEDSEL
6165 SH=C6:IF SP+SH>SL THEN GOSUB IMEM:RETURN
6170 GOSUB IS
6175 S$(SP,SP+C2)="110":S$(SP+C3,SP+C3)=CHR$(DIR+C1):S$(SP+C4,SP+C4)=CHR$(DIST):S$(SP+C5,SP+C5)=CHR$(ITEM)
6180 SP=SP+C6:ITEM=(DIR+1)*1.5:RETURN
6500 REM U/D
6505 DIST=C0:DIR=C3-ITEM*C2
6510 TC=C0:TR=C2:GOSUB BPOS:? " Select distance"
6515 GOSUB DISTSEL
6520 IF VAR2=-C1 THEN 6515
6525 IF VAR2=12 THEN 6600
6530 ON ITEM GOTO 6540,6560
6540 VAR1=PEEK(DL+27):DUM=USR(ADR(PCLEAR$),VAR1):DUM=USR(ADR(SCRD$)):POKE DL,VAR1:POKE DL-C1,117:GOTO 6580
6560 VAR1=PEEK(DL):DUM=USR(ADR(PCLEAR$),VAR1):DUM=USR(ADR(SCRU$)):POKE DL+27,VAR1:POKE DL+26,117
6580 DIST=DIST+C1:GOTO 6515
6600 IF  NOT DIST THEN RETURN
6605 GOSUB SPEEDSEL
6610 SH=C6:IF SP+SH>SL THEN GOSUB IMEM:RETURN
6615 GOSUB IS
6620 S$(SP,SP+C2)="111":S$(SP+C3,SP+C3)=CHR$(DIR+C1):S$(SP+C4,SP+C4)=CHR$(DIST):S$(SP+C5,SP+C5)=CHR$(ITEM)
6625 SP=SP+C6:ITEM=(C3-DIR)/C2:RETURN
8000 REM OPTIONS
8005 ITEM=C0
8010 TC=C0:TR=C0:GOSUB BPOS
8015 ? " shift  color  blink  misc";
8020 IDIS=C7:I$=OMI$:GOSUB MENUSEL
8025 IF ITEM=-C1 THEN ITEM=C3:RETURN
8030 ON ITEM+C1 GOSUB 8100,8200,8300,20000
8040 GOTO 8010
8100 REM CASE TOGGLE
8110 IF PEEK(DCASE)=UC THEN POKE DCASE,LC:GOTO 8125
8120 POKE DCASE,UC
8125 SH=C3:IF SP+SH>SL THEN GOSUB IMEM:RETURN
8130 GOSUB IS
8135 S$(SP,SP+C1)="30":S$(SP+C2,SP+C2)=CHR$(PEEK(DCASE)):SP=SP+C3
8140 GOSUB PAUSE
8145 RETURN
8200 REM COLOR
8205 GOSUB CASESEL:IF ITEM=-C1 THEN ITEM=C1:RETURN
8206 VAR3=PEEK(203+CASE):VAR4=INT(VAR3/16):ITEM=VAR4
8210 TC=C0:TR=C2:GOSUB BPOS:? " Select color";:GOSUB COLSEL:COLVAR=ITEM:IF ITEM=-C1 THEN ITEM=C1:RETURN
8211 ITEM=INT((VAR3-VAR4*16)/C2)
8215 TC=C0:TR=C2:GOSUB BPOS:? " Select luminance";:GOSUB 4940:IF ITEM=-C1 THEN ITEM=C1:RETURN
8220 VAR2=COLVAR*16+ITEM*C2:POKE 203+CASE,VAR2:POKE 708+CASE,VAR2
8225 SH=C4:IF SP+SH>SL THEN GOSUB IMEM:RETURN
8230 GOSUB IS
8235 S$(SP,SP+C1)="31":S$(SP+C2,SP+C2)=CHR$(CASE):S$(SP+C3,SP+C3)=CHR$(VAR2):SP=SP+SH
8240 ITEM=C1:RETURN
8300 REM BLINK
8310 IF PEEK(208)>0 THEN VAR4=-C1:VAR3=C1:GOTO 8370
8315 IF CASE>C3 THEN CASE=C3
8320 I$=CASEMI$(C1,C4):TC=C0:TR=C0:GOSUB BPOS:? CASEMENU$(C1,27):GOSUB 8910
8330 IF ITEM=-C1 THEN ITEM=C2:RETURN
8340 VAR4=ITEM:TC=C0:TR=C2:GOSUB BPOS:? " Blinking rate?":ITEM=C4:GOSUB 4940
8350 IF ITEM=-C1 THEN ITEM=C2:RETURN
8360 VAR3=2^(7-ITEM):POKE 1721,VAR3
8370 POKE 208,VAR4+C1
8375 SH=C4:IF SP+SH>SL THEN GOSUB IMEM:RETURN
8380 GOSUB IS
8385 S$(SP,SP+C1)="32":S$(SP+C2,SP+C2)=CHR$(VAR4+C1):S$(SP+C3,SP+C3)=CHR$(VAR3):SP=SP+SH
8390 ITEM=C2:GOSUB PAUSE:RETURN
8900 REM CASE SEL
8905 I$=CASEMI$:TC=C0:TR=C0:GOSUB BPOS:? CASEMENU$
8910 ITEM=CASE
8915 IDIS=C7:GOSUB MENUSEL:IF ITEM+C1 THEN CASE=ITEM
8920 RETURN
9000 REM SCRIPT LOAD
9005 ? "↰";:POKE 752,0:? "Load file";:INPUT FILE$:POKE 752,1
9010 TRAP 9050:OPEN #1,4,0,FILE$:TRAP 40000:CLOSE #1
9015 VAR2=LEN(FILE$):SH=C2+VAR2:IF SP+SH>SL THEN GOSUB IMEM:RETURN
9020 GOSUB IS
9025 S$(SP,SP)="4":S$(SP+C1,SP+C1)=CHR$(VAR2):S$(SP+C2,SP+C1+VAR2)=FILE$:SP=SP+C2+VAR2
9030 ITEM=C4:RETURN
9050 ? "↰";:TC=C0:TR=C1:GOSUB BPOS:? " Can't find ";FILE$:? " Proceed anyway?";
9055 GOSUB 300:IF ITEM THEN ITEM=4:RETURN
9060 GOTO 9015
10000 REM EDIT
10010 GOSUB RESET
10015 SP=C1:TEMP$=" BEGINNING":FLAG=C1
10020 TC=C0:TR=C2:GOSUB BPOS:? TEMP$;
10025 POKE 764,255:GOSUB 10240
10030 OSP=SP:GOSUB 1050
10035 GOSUB 10100
10040 IF ITEM=-C1 THEN GOSUB 1350:SP=LEN(S$)+C1:ITEM=C2:? "↰";:RETURN
10045 IF SP<LEN(S$) THEN 10030
10050 ITEM=C2:? "↰":RETURN
10100 TC=C0:TR=C2:GOSUB BPOS:? TEMP$;
10110 ITEM=C0
10115 TC=C0:TR=C0:GOSUB BPOS
10120 ? " continue  delete    insert";
10125 IDIS=10:I$=EMI$:GOSUB MENUSEL+10
10130 IF ITEM=-C1 OR  NOT ITEM THEN RETURN
10140 ON ITEM GOSUB 10200,950
10150 RETURN
10200 REM DELETE STEP
10205 IF SP=C1 THEN RETURN
10210 TC=C0:TR=C2:GOSUB BPOS:? " Delete last step?";
10215 GOSUB 300
10225 IF ITEM=-C1 OR ITEM THEN ITEM=C1:RETURN
10230 IF SP>LEN(S$) THEN S$(OSP)="":SP=OSP:RETURN
10235 S$(OSP)=S$(SP):SP=OSP
10240 TC=C0:TR=C0:GOSUB BPOS:? " continue            insert";
10250 IDIS=20:I$=EDMI$:ITEM=C0:GOSUB MENUSEL
10255 IF ITEM=-C1 OR  NOT ITEM THEN RETURN
10260 GOSUB 950:RETURN
12000 REM DATA
12100 REM ML CODE
12135 REM DLI#1
12136 DATA 72,169,224,141,9,212,165,204,141,23,208,165,205,141,24,208,169,174,141,0,2,104,64
12140 REM DLI#2
12141 DATA 72,138,72,165,208,170,240,19,165,20,41,32,240,5,165,207,157,21,208,76,201,6,181,202,157,21,208
12142 DATA 169,151,141,0,2,104,170,104,64
12190 REM DL
12192 DATA 112,112,128,208,71,117,0,71,117,0,71,117,0,71,117,0,71,117,0,71,117,0,71,117,0,71,117,0
12193 DATA 71,117,0,71,117,0,128,66,0,0,2,2,2,65,210,6
12300 REM MENU SEARCH LISTS
12309 DATA 10,40,42,0,62,35,47
12310 DATA 46,62,10,8,0
12311 DATA 42,10,18,8
12312 DATA 43,35
12313 DATA 0,8,40
12314 DATA 0,58
12315 DATA 0,58,11,40
12316 DATA 31,30,26,24,29,27,51,53,48,50
12317 DATA 62,18,21,37
12318 DATA 18,58,13
12319 DATA 18,0,58
12320 DATA 11,0,75,64,21
12321 DATA 56,31,30,26,24
12322 DATA 13,8
12323 DATA 18,13
12500 REM VARIABLES
12501 C0=0:C1=1:C2=2:C3=3:C4=4:C5=5:C6=6:C7=7:C256=256
12505 GRAPHICS C0:POKE 752,C1:POSITION 11,11:? "◢ Initializing ◢"
12510 DIM PCLEAR$(19),PPMOVE$(24),TRANS$(59),CIO$(6),SCRH$(12),SCRD$(21),SCRU$(24)
12520 DIM QMENU$(40),SMENU$(40),SLMENU$(40),SPEEDMENU$(29),CASEMENU$(39)
12530 DIM BLANK$(40),TEXT$(119),TEMP$(128),OLDCHAR$(1)
12540 DIM I$(16),MMI$(7),RMI$(5),WMI$(4),QMI$(2),WPMI$(3),SMI$(2),SLMI$(4),SPEEDMI$(10),OMI$(4)
12545 DIM EMI$(3),CMI$(3),CASEMI$(5),MISCMI$(5),FADEMI$(2),EDMI$(2)
12550 DIM S$(5000):SL=5000
12560 DIM FILE$(14)
12600 REM SETUP
12605 RL=140
12610 PCLEAR$="hhh┐↓)♥┐↑ ♥)♥┌↑HP♠◆"
12620 PPMOVE$="hh┐→h┐←h┐↓h┐↑hh(1←┌↑◢Py◆"
12630 TRANS$="hh┐↓h┐↑h┐→h┐←hh(1↑◣┴j*8i◆♣┘┴♣▖◣8i ♣┤*┴♣┐◣i@*┴◣◣*1↑◣◣j┌←◢PV◆"
12635 CIO$="h"♣LVd"
12640 SCRH$="h"←^T╱JJJPx◆"
12641 SCRD$="h"␛=U╱↓X╱=T╱↓W╱JJJPo◆"
12642 SCRU$="h"♥ ▗=[╱↓X╱=Z╱↓W╱hhh◢Pn◆"
12645 FOR IT=C0 TO 22:READ VAR:POKE 1664+IT,VAR:POKE 1687+IT,VAR:NEXT IT
12646 VAR=1687:POKE VAR+C6,169:POKE VAR+C7,202:POKE VAR+11,169:POKE VAR+12,148:POKE VAR+17,128
12650 FOR IT=C0 TO 35:READ VAR:POKE 1710+IT,VAR:NEXT IT
12690 FOR IT=C0 TO 43:READ VAR:POKE 1746+IT,VAR:NEXT IT
12700 BLANK$="                                        "
12705 VAR=C7:GOSUB RL:MMI$=TEMP$
12710 VAR=C5:GOSUB RL:RMI$=TEMP$
12715 VAR=C4:GOSUB RL:WMI$=TEMP$
12720 QMENU$=" yes  no"
12721 VAR=C2:GOSUB RL:QMI$=TEMP$
12725 VAR=C3:GOSUB RL:WPMI$=TEMP$
12730 SMENU$=" line     display"
12731 VAR=C2:GOSUB RL:SMI$=TEMP$
12735 SLMENU$=" left   down   up     right"
12736 VAR=C4:GOSUB RL:SLMI$=TEMP$
12740 SPEEDMENU$=" 1  2  3  4  5  6  7  8  9  0"
12741 VAR=10:GOSUB RL:SPEEDMI$=TEMP$
12745 VAR=C4:GOSUB RL:OMI$=TEMP$
12755 VAR=C3:GOSUB RL:EMI$=TEMP$
12760 VAR=C3:GOSUB RL:CMI$=TEMP$
12765 CASEMENU$=" upper  lower  Upper  Lower  background"
12766 VAR=C5:GOSUB RL:CASEMI$=TEMP$
12770 VAR=C5:GOSUB RL:MISCMI$=TEMP$
12775 VAR=C2:GOSUB RL:FADEMI$=TEMP$
12780 VAR=C2:GOSUB RL:EDMI$=TEMP$
12800 DL=1752:DCASE=1666
12805 ROW=C0:COL=C0
12810 SP=C1:CASE=C0:SPEED=C5
12850 TPOS=500:BPOS=580:PAUSE=530:MENUSEL=600:CLICK=100:PTR=330:IMEM=160:GI=185:DLI=200:HILO=220:IS=250
12855 SPEEDSEL=5900:DISTSEL=5800:COLSEL=4900:CASESEL=8900:RESET=410
12900 GRAPHICS C2
12905 REM POKE 559,C0
12910 VAR=PEEK(661)-10:VAR1=VAR-C2*INT(VAR/C2)
12915 POKE 741,255:POKE 742,VAR-C3-VAR1
12920 FOR IT=C0 TO 9:POKE DL+C3*IT,VAR+IT:NEXT IT
12925 POKE DL+30,PEEK(660):POKE DL+31,PEEK(661)
12930 POKE 560,210:POKE 561,C6
12935 POKE 82,C0
12940 FOR IT=C0 TO 9:DUM=USR(ADR(PCLEAR$),PEEK(DL+IT*C3)):NEXT IT
12945 POKE 752,C1
12950 LC=VAR-C2-VAR1
12955 FOR IT=C0 TO C1:DUM=USR(ADR(PPMOVE$),(PEEK(756)+C2+IT)*C256,(LC+IT)*C256,C0):NEXT IT
12960 FOR IT=LC*C256 TO LC*C256+C7:POKE IT+488,PEEK(IT):POKE IT,C0:NEXT IT
12970 POKE 54286,192
12971 POKE 512,128:POKE 513,C6
12972 UC=224:REM VAR=PEEK(756):POKE 1710+C2,VAR:POKE 1725+C2,VAR:UC=VAR
12975 FOR IT=C0 TO C4:POKE 203+IT,PEEK(708+IT):NEXT IT:POKE 208,C0
12990 POKE 559,34
12995 GOSUB CLICK:GOTO 900
13000 REM LOAD
13010 ? "↰";:FLAG=2
13020 POKE 694,C0:POKE 702,64:POKE 752,C0:? "Load file";:INPUT FILE$:POKE 752,C1
13030 IF FILE$="" THEN RETURN
13040 POKE 559,C0
13050 TRAP 13150:OPEN #1,C4,C0,FILE$:TRAP 40000
13060 S$=" ":SP=1:GOSUB RESET
13070 INPUT #1,VAR:GOSUB HILO:S$(VAR,VAR)=" "
13080 POKE 848+C2,C7
13090 POKE 848+8,LO:POKE 848+9,HI
13100 VAR=ADR(S$):GOSUB HILO
13110 POKE 848+C4,LO:POKE 848+C5,HI
13120 DUM=USR(ADR(CIO$))
13130 POKE 559,34:CLOSE #1:RETURN
13150 POKE 559,34:CLOSE #1:TRAP 40000:RETURN
13160 ? "↰";:? " Can't load ";FILE$
13170 GOSUB PAUSE
13180 ? "↰":RETURN
13200 REM SAVE
13210 ? "↰";
13220 POKE 694,C0:POKE 702,64:POKE 752,C0:? "Save file";:INPUT FILE$:POKE 752,C1
13230 IF FILE$="" THEN RETURN
13240 POKE 559,C0:TRAP 13350
13250 OPEN #1,8,C0,FILE$:TRAP 40000
13260 VAR=LEN(S$):GOSUB HILO
13270 ? #1,VAR
13280 POKE 848+C2,11
13290 POKE 848+8,LO:POKE 848+9,HI
13300 VAR=ADR(S$):GOSUB HILO
13310 POKE 848+C4,LO:POKE 848+C5,HI
13320 DUM=USR(ADR(CIO$))
13330 POKE 559,34:CLOSE #1:RETURN
13350 POKE 559,34:CLOSE #1:TRAP 40000
13360 ? "↰";:? " Can't save ";FILE$
13370 GOSUB PAUSE
13380 ? "↰":RETURN
13400 REM NEW
13405 TC=C0:TR=C2:GOSUB BPOS:? " Delete current script?";
13410 GOSUB 300
13430 IF ITEM THEN ITEM=C0:GOTO 13455
13440 GOSUB RESET
13450 S$="":SP=C1
13455 TC=C0:TR=C2:GOSUB BPOS
13460 RETURN
20000 REM MISC
20005 ITEM=C0
20010 TC=C0:TR=C0:GOSUB BPOS:? " fade   1User  2User  3User  4User";
20015 IDIS=7:I$=MISCMI$:GOSUB MENUSEL
20020 IF ITEM=-C1 THEN ITEM=C2:RETURN
20025 ON ITEM+C1 GOSUB 20050
20030 GOTO 20010
20050 REM FADE
20055 ITEM=C0
20060 TC=C0:TR=C0:GOSUB BPOS:? " in   out";
20065 IDIS=C5:I$=FADEMI$:GOSUB MENUSEL
20070 IF ITEM=-C1 THEN ITEM=C0:RETURN
20075 DIR=C1-ITEM*C2:VAR4=203+CASE
20080 GOSUB CASESEL:IF ITEM=-C1 THEN ITEM=C0:RETURN
20090 VAR4=203+CASE:VAR3=PEEK(VAR4):COLVAR=INT(VAR3/16)
20100 VAR2=VAR3-COLVAR*16:IF (VAR2<C2 AND DIR=-C1) OR (VAR2>13 AND DIR=C1) THEN 20110
20105 VAR3=VAR3+DIR*C2:POKE VAR4,VAR3:POKE 708+CASE,VAR3:GOTO 20100
20110 GOSUB SPEEDSEL
20115 SH=6:IF SP+SH>SL THEN GOSUB IMEM:ITEM=C0:RETURN
20120 GOSUB IS
20125 S$(SP,SP+C2)="330":S$(SP+C3,SP+C3)=CHR$(DIR+C1):S$(SP+C4,SP+C4)=CHR$(CASE):S$(SP+C5,SP+C5)=CHR$(SPEED)
20130 SP=SP+SH:ITEM=C0:RETURN
30000 REM EXIT
30010 TC=C0:TR=C2:GOSUB BPOS:? " Really quit?"
30020 GOSUB 300
30030 IF ITEM THEN ITEM=C0:RETURN
30110 GRAPHICS C0
30120 POKE 82,C2:POKE 752,C0