Baker Solitaire (BAKER.BAS)

Baker Solitaire, game by Tom Cline, 110

Description

Baker Solitaire, game by Tom Cline, 110

From the Antic disk of March 1989 (Vol. 7 No. 11) — disk A.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 13.5 KB

Dialect
Atari BASIC
Lines
302
Variables
WIN, SUITS, X, BAND, SCR, TL, TR, CARD$, TEMCRD$, CN(, BR(, A$, B$, C$, D$, F$, BLINK$, UNSHUF$, BEFCOL$, BEFROW$, AFTCOL$, AFTROW$, CRDREM$, MARK(, BAN$, K, BYTE, R, ST, MOVE, ER, PLACE, BL, TRUE, FALSE, MOVGRP, GRAPH, MARK, DMA, DL, S, FL, PL, PR, LASTCD, I, ROW, COL, FILLNU, CDSBOT, KEY, OLDKEY, A, B, COLB, COLA, ROWA, CODEA, EC, J, L, CODEB, KG, ROWB, AA, M, BR, BC, AR, AC, CR, STAR, CODECH, GRPROW, TEMCOD, CODEG, LASTJ, CODEH, P
BASIC listing (302 lines)
10 REM BAKER SOLITAIRE
12 REM BY TOM CLINE
15 REM (c)1988, ANTIC PUBLISHING
20 CLOSE #1:OPEN #1,4,0,"K:":GOTO 30
22 WIN=0:ON SUITS-1 GOTO 24,25,26
24 X=USR(BAND,PEEK(SCR+TL),63):WIN=(X=43):RETURN
25 X=USR(BAND,PEEK(SCR+13),PEEK(SCR+TR),63):WIN=(X=43):RETURN
26 X=USR(BAND,PEEK(SCR+TL),PEEK(SCR+13),PEEK(SCR+TR),63):WIN=(X=43):RETURN
30 DIM CARD$(52),TEMCRD$(1),CN(254),BR(20),A$(20),B$(20),C$(20),D$(20),F$(20),BLINK$(20),UNSHUF$(52)
40 DIM BEFCOL$(300),BEFROW$(300),AFTCOL$(300),AFTROW$(300),CRDREM$(300),MARK(10),BAN$(22)
45 BAN$="h*)▶┐T┐Uh%U┐Uh%T┐TJPs◆":BAND=ADR(BAN$)
50 CARD$="A23456789TJQKa─┼●▄▎┬┴▌tjqkA23456789TJQKa─┼●▄▎┬┴▌tjqk":UNSHUF$=CARD$:REM DECK OF UNSHUFFLED CARDS
60 FOR K=1 TO 52:CN(ASC(CARD$(K,K)))=K:NEXT K:REM POSITION OF A CARD IN CARD$
70 IF PEEK(1536)=72 THEN 120
80 RESTORE 80:FOR K=0 TO 61:READ BYTE:POKE 1536+K,BYTE:NEXT K:REM DLI FOR LOWER CASE LETTERS
90 DATA 72,169,12,141,10,212,141,22,208,169,86,141,23,208,169,0,141,24,208,169,226,141,9,212,169
100 DATA 31,141,0,2,104,64,72,169,224,141,10,212,141,9,212,169,36,141,22,208,169,198,141,23,208
110 DATA 169,148,141,24,208,169,0,141,0,2,104,64
120 GRAPHICS 17:POKE 712,224
130 REM NUMBER OF SUITS
140 D$="▔":D$(13)=D$:D$(2)=D$
150 POSITION 3,4:? #6;D$:POSITION 3,5:? #6;"enter ─▘┼▘or ●"
160 POSITION 3,6:? #6;"for the number":POSITION 3,7:? #6;"of suits▂":POSITION 3,8:? #6;D$
170 GET #1,R:GOSUB 1160
180 IF R<50 OR R>52 THEN 120
190 SUITS=R-48:ST=SUITS:REM ST IS NUMBER OF EMPTY PARKING SPACES (GOLD STARS)
200 REM DLI FOR L.CASE LETTERS
210 GRAPHICS 17:POKE 712,12:POKE 708,36:POKE 709,198:POKE 711,8
220 MOVE=1:ER=-1:PLACE=0:BL=0:TRUE=1:FALSE=0:MOVGRP=FALSE:GRAPH=FALSE:MARK=FALSE
230 DMA=PEEK(559):POKE 559,0:SCR=PEEK(88)+PEEK(89)*256
240 DL=PEEK(560)+256*PEEK(561):POKE DL+6,134:POKE DL+9,134
250 POKE 512,0:POKE 513,6:POKE 54286,192
260 REM INIT & DISPLAY LC LETTERS & STARS
270 S=SUITS
280 IF S=4 THEN A$="    ****   ◣◣◣◣":B$="  P             t ":C$="    jklm   wxyz":F$="  a b c d e f g h"
290 IF S=4 THEN D$="  ─────────────── "
300 IF S=4 THEN FL=2:REM L.COL. OF FIELD
310 IF S=4 THEN TL=11:TR=14:REM L.&R. COLS. OF TERM
320 IF S=4 THEN PL=4:PR=7:REM L.&R. COLS. OF PARKING
330 IF S=3 THEN A$="      ***   ◣◣◣":B$="    P           t":C$="      jkl   wxy":F$="    a b c d e f g"
340 IF S=3 THEN D$="    ─────────────"
350 IF S=3 THEN FL=4:TL=12:TR=14:PL=6:PR=8
360 IF S=2 THEN A$="      **   ◣◣":B$="    P         t":C$="      jk   wx":F$="    a b c d e f"
370 IF S=2 THEN D$="    ───────────"
380 IF S=2 THEN FL=4:TL=11:TR=12:PL=6:PR=7
390 ? #6;A$:? #6;B$:? #6;C$:? #6;D$:? #6;F$
400 REM SHUFFLE
410 LASTCD=13*SUITS
420 FOR I=LASTCD TO 1 STEP -1:X=INT(I*RND(0))+1
430 TEMCRD$=CARD$(X,X):CARD$(X,X)=CARD$(I,I):CARD$(I,I)=TEMCRD$:NEXT I
440 REM DISPLAY CARDS
450 FOR ROW=0 TO SUITS+1
460 POSITION FL,ROW+6
470 FOR COL=0 TO SUITS+3
480 ? #6;CARD$((SUITS+4)*ROW+COL+1,(SUITS+4)*ROW+COL+1);" ";
490 NEXT COL:NEXT ROW
500 FILLNU=(COL)*(ROW):REM # OF CARDS IN FILLED ROWS (BEFORE BOTTOM ROW)
510 POSITION FL,ROW+6
520 FOR K=FILLNU+1 TO LASTCD
530 ? #6;CARD$(K,K);" ";
540 NEXT K
550 CDSBOT=LASTCD-FILLNU:REM # OF CARDS IN BOTTOM ROW
560 FOR K=0 TO SUITS+3
570 IF K<CDSBOT THEN BR(FL+2*K)=8+SUITS:REM BR(COL) IS BOTTOM ROW OF COL
580 IF K>=CDSBOT THEN BR(FL+2*K)=7+SUITS
590 NEXT K
600 POKE 559,DMA:REM TURN ON SCREEN
610 REM 1ST KEY
620 X=USR(BAND,PEEK(SCR+12),63):IF X=43 THEN GOSUB 22:IF WIN THEN 20000
625 IF PEEK(764)=255 THEN POKE 77,0:GOTO 620:REM DISABLES ATTRACT MODE
630 GET #1,KEY:OLDKEY=KEY:GOSUB 1160:A=KEY
640 IF OLDKEY=155 THEN ER=3:GOSUB 1210:ER=-1:GOTO 620:REM ER IS ROW OF ERROR
650 IF A>=74 AND A<=74+SUITS-1 THEN 800:REM CARD TO BE MOVED IS FROM PARKING
660 IF A=84 THEN GOSUB 2360:IF ER<>-1 THEN ER=-1:GOTO 620
670 IF A=84 AND MOVGRP=FALSE THEN POSITION TR+2,1:? #6;"T":MOVGRP=TRUE:GOTO 620
680 IF A=84 AND MOVGRP THEN POSITION TR+2,1:? #6;"t":MOVGRP=FALSE:GOTO 620
690 IF A=27 THEN CLR :GOTO 20
700 IF A=80 THEN GOSUB 1100:GOTO 620
710 IF A=32 AND MOVE<>1 THEN GOSUB 1920:GOTO 620:REM RESTORES PREVIOUS POSITIONS.
720 IF (A>=87 AND A<=90+SUITS-4) THEN B=A:COLB=A-87+TL:ER=2:GOSUB 1210:ER=-1:GOTO 620
730 IF (A<65 OR A>(77+SUITS-4)) OR (A>=(73+SUITS-4) AND A<=73) THEN ER=3:GOSUB 1210:ER=-1:GOTO 620
740 COLA=2*(A-65)+FL:REM COLUMN OF CARD TO MOVE (FROM FIELD)
750 IF (A>=65 AND A<=72+SUITS-4) AND BR(COLA)=5 THEN B=A:COLB=COLA:ER=4:GOSUB 1210:ER=-1:GOTO 620
760 ROWA=BR(COLA):REM ROW OF CARD TO MOVE
770 COLOR A+128:PLOT COLA,4
780 LOCATE COLA,ROWA,CODEA:REM CODEA IS ATASCII FOR CARD TO BE MOVED (FROM FIELD)
790 GOTO 850:REM GET 2ND KEY
800 COLA=A-74+FL+2:ROWA=0:REM COLUMN AND ROW OF CARD TO MOVE (FROM PARKING)
810 LOCATE COLA,ROWA,CODEA
820 IF (A>=74 AND A<=77+SUITS-4) AND CODEA=42 THEN B=A:COLB=A-74+PL:ER=2:GOSUB 1210:ER=-1:GOTO 620
830 COLOR A+128:PLOT COLA,2
840 REM 2ND KEY
850 IF PEEK(764)=255 THEN POKE 77,0:GOTO 850
860 GET #1,KEY:OLDKEY=KEY:GOSUB 1160:B=KEY
870 IF OLDKEY=155 THEN ER=3:GOSUB 1210:ER=-1:GOTO 620
880 IF B=27 THEN CLR :GOTO 20
890 IF B=80 THEN GOSUB 1100:GOTO 850
900 IF B=84 AND MOVGRP THEN POSITION TR+2,1:? #6;"t":MOVGRP=FALSE:COLOR A+32:PLOT COLA,4:GOTO 620
910 IF B=84 AND MOVGRP=FALSE THEN ER=1:COLB=TR+2:GOSUB 1210:ER=-1:GOTO 850
920 S=4-SUITS
930 IF B<65 OR (B>77-S AND B<87) OR B>90-S OR (B>=73-S AND B<=73) THEN ER=3:GOSUB 1210:ER=-1:GOTO 850
940 IF B=A AND (B>=65 AND B<=72-S) THEN COLOR A+32:PLOT COLA,4:GOTO 620
950 IF B=A AND (B>=74 AND B<=74+SUITS-1) THEN COLOR A+32:PLOT COLA,2:GOTO 620
960 IF (A>=74 AND A<=77+SUITS-4) AND (B>=74 AND B<=77+SUITS-4) THEN COLB=B-74+PL:ER=2:GOSUB 1210:ER=-1:GOTO 850
970 IF MOVGRP THEN GOSUB 2380:IF ER=-1 THEN 620
980 IF MOVGRP THEN ER=-1:GOTO 850
990 IF (B>=65 AND B<=72) AND A>=65 AND A<=72 THEN GOSUB 1300
1000 IF (B>=74 AND B<=77) AND A>=65 AND A<=72 THEN GOSUB 1430
1010 IF (B>=87 AND B<=90) AND A>=65 AND A<=72 THEN GOSUB 1550
1020 IF (B>=65 AND B<=72) AND (A>=74 AND A<=77) THEN GOSUB 1600
1030 IF (B>=87 AND B<=90) AND (A>=74 AND A<=77) THEN GOSUB 1740
1040 IF ER=-1 THEN 620
1050 IF ER<>-1 THEN ER=-1:GOTO 850
1060 REM MARKS POSITION
1070 PLACE=PLACE+1:IF PLACE>10 THEN PLACE=10:REM CAN MARK TEN PLACES ONLY
1080 MARK(PLACE)=MOVE:MARK=FALSE
1090 RETURN
1100 IF MARK THEN MARK=FALSE:POSITION FL,1:? #6;"P":RETURN
1110 MARK=TRUE
1120 POSITION FL,1:? #6;"P"
1130 SOUND 0,100,10,12:FOR K=1 TO 100:NEXT K:SOUND 0,0,0,0
1140 RETURN
1150 REM LOWER & INV TO UPPER CASE
1160 IF KEY>=128 THEN KEY=KEY-128
1170 IF PEEK(702)=0 AND KEY>96 THEN KEY=KEY-32
1180 POKE 702,64:POKE 694,0
1190 RETURN
1200 REM PLOT ERRORS
1210 IF ER<>3 THEN EC=COLB:BLINK$=CHR$(B+32)
1220 IF ER=3 THEN EC=0:BLINK$=D$:REM LINE BETWEEN LETTERS
1230 FOR K=0 TO 6
1240 POSITION EC,ER
1250 IF ER=3 THEN ? #6;"                  "
1260 IF ER<>3 THEN ? #6;" "
1270 FOR J=1 TO 20:NEXT J:POSITION EC,ER:? #6;BLINK$
1280 FOR L=1 TO 20:NEXT L:NEXT K:RETURN
1290 REM FIELD TO FIELD
1300 COLB=2*(B-65)+FL
1310 LOCATE COLB,BR(COLB),CODEB
1320 IF CN(CODEB)<>CN(CODEA)+1 AND BR(COLB)<>5 THEN ER=4:GOSUB 1210:RETURN
1330 KG=CN(CODEA):IF (KG=13 OR KG=26 OR KG=39) AND CN(CODEB)=KG+1 THEN ER=4:GOSUB 1210:RETURN
1340 ROWB=BR(COLB)+1
1350 POSITION COLA,ROWA:? #6;" "
1360 COLOR CODEA:PLOT COLB,ROWB
1370 BR(COLA)=BR(COLA)-1:BR(COLB)=BR(COLB)+1
1380 COLOR A+32:PLOT COLA,4
1390 IF BR(COLA)=5 THEN BL=BL+1:REM 5 IS THE TOP ROW OF FIELD, BL IS NUMBER OF BLANK (EMPTY) COLUMNS
1400 IF BR(COLB)=6 THEN BL=BL-1
1410 GOSUB 1840:RETURN
1420 REM FIELD TO PARKING
1430 COLB=B-74+PL:ROWB=0
1440 LOCATE COLB,ROWB,CODEB
1450 AA=CN(CODEA):IF AA=1 OR AA=14 OR AA=27 OR AA=40 OR CODEB<>42 THEN ER=2:GOSUB 1210:RETURN
1460 ST=ST-1:REM # OF EMPTY PARKING SPACES
1470 POSITION COLA,ROWA:? #6;" ":COLOR CODEA
1480 COLOR CODEA:PLOT COLB,ROWB
1490 BR(COLA)=BR(COLA)-1
1500 COLOR A+32:PLOT COLA,4
1510 IF BR(COLA)=5 THEN BL=BL+1
1520 GOSUB 1840
1530 RETURN
1540 REM FIELD TO TERMINAL
1550 COLB=B-87+TL:ROWB=0:LOCATE COLB,ROWB,CODEB
1560 AA=CN(CODEA):IF (AA=1 OR AA=14 OR AA=27 OR AA=40) AND CODEB=10 THEN GOSUB 1470:RETURN
1570 IF (CN(CODEB)<>CN(CODEA)-1) OR CODEB=10 THEN ER=2:GOSUB 1210:RETURN
1580 GOSUB 1470:RETURN
1590 REM PARKING TO FIELD
1600 COLB=2*(B-65)+FL
1610 LOCATE COLB,BR(COLB),CODEB
1620 IF CN(CODEB)<>CN(CODEA)+1 AND BR(COLB)<>5 THEN ER=4:GOSUB 1210:RETURN
1630 KG=CN(CODEA):IF (KG=13 OR KG=26 OR KG=39) AND CN(CODEB)=KG+1 THEN ER=4:GOSUB 1210:RETURN
1640 ROWB=BR(COLB)+1
1650 POSITION COLA,0:? #6;"*"
1660 COLOR CODEA:PLOT COLB,ROWB
1670 BR(COLB)=BR(COLB)+1
1680 COLOR A+32:PLOT COLA,2
1690 IF BR(COLB)=6 THEN BL=BL-1
1700 ST=ST+1
1710 GOSUB 1840
1720 RETURN
1730 REM PARKING TO TERMINAL
1740 COLB=B-87+TL:ROWB=0
1750 LOCATE COLB,ROWB,CODEB
1760 IF CN(CODEB)<>CN(CODEA)-1 OR CODEB=10 THEN ER=2:GOSUB 1210:RETURN
1770 POSITION COLA,ROWA:? #6;"*"
1780 COLOR CODEA:PLOT COLB,ROWB
1790 COLOR A+32:PLOT COLA,2
1800 ST=ST+1
1810 GOSUB 1840
1820 RETURN
1830 REM RECORD OF MOVES
1840 SOUND 0,100,10,12:M=MOVE
1850 CRDREM$(M,M)=CHR$(CODEA):BEFCOL$(M,M)=CHR$(COLA):BEFROW$(M,M)=CHR$(ROWA)
1860 AFTCOL$(M,M)=CHR$(COLB):AFTROW$(M,M)=CHR$(ROWB)
1870 FOR K=1 TO 10:NEXT K:SOUND 0,0,0,0
1880 IF MARK THEN GOSUB 1070:POSITION FL,1:? #6;"P"
1890 MOVE=MOVE+1:IF MOVE>300 THEN MOVE=300:REM CAN RECORD 300 MOVES
1900 RETURN
1910 REM RESTORE PREVIOUS POSITION
1920 MOVE=MOVE-1:M=MOVE:MARK=FALSE:POSITION FL,1:? #6;"P"
1930 BR=ASC(BEFROW$(M,M)):BC=ASC(BEFCOL$(M,M)):REM BR IS BEFORE ROW
1940 AR=ASC(AFTROW$(M,M)):AC=ASC(AFTCOL$(M,M)):CR=ASC(CRDREM$(M,M))
1950 IF BR>=6 AND AR>=6 THEN GOSUB 2030:REM FIELD TO FIELD
1960 IF BR>=6 AND (AR=0 AND (AC>=PL AND AC<=PR)) THEN STAR=42:GOSUB 2130
1970 IF (BR=0 AND (BC>=PL AND BC<=PR)) AND AR>=6 THEN GOSUB 2200
1980 IF (BR=0 AND (BC>=PL AND BC<=PR)) AND (AR=0 AND (AC>=TL AND AC<=TR)) THEN GOSUB 2270
1990 IF BR>=6 AND (AR=0 AND (AC>=TL AND AC<=TR)) THEN GOSUB 2300
2000 IF MARK(PLACE)=MOVE THEN GOSUB 1120:MARK(PLACE)=0:PLACE=PLACE-1:POSITION FL,1:? #6;"P"
2010 RETURN
2020 REM RESTORE FIELD TO FIELD
2030 POSITION AC,AR:? #6;" "
2040 COLOR CR:PLOT BC,BR
2050 BR(BC)=BR(BC)+1:BR(AC)=BR(AC)-1
2060 LOCATE AC,AR+1,CODECH
2070 IF CODECH<>32 AND BR=6 THEN BL=BL-1
2080 IF CODECH<>32 THEN AR=AR+1:BR=BR+1:CR=CODECH:GOTO 2030:REM GROUP MOVES
2090 IF BR(BC)=6 THEN BL=BL-1
2100 IF BR(AC)=5 THEN BL=BL+1
2110 RETURN
2120 REM RESTORE PARKING TO FIELD
2130 COLOR STAR:PLOT AC,AR
2140 COLOR CR:PLOT BC,BR
2150 BR(BC)=BR(BC)+1
2160 IF BR(BC)=6 THEN BL=BL-1
2170 ST=ST+1
2180 RETURN
2190 REM RESTORE FIELD TO PARKING
2200 POSITION AC,AR:? #6;" "
2210 COLOR CR:PLOT BC,BR
2220 BR(AC)=BR(AC)-1
2230 IF BR(AC)=5 THEN BL=BL+1
2240 ST=ST-1
2250 RETURN
2260 REM RESTORE TERMINAL TO PARKING
2270 COLOR ASC(UNSHUF$(CN(CR)-1,CN(CR)-1)):PLOT AC,AR:COLOR CR:PLOT BC,BR:ST=ST-1
2280 RETURN
2290 REM RESTORE TERMINAL TO FIELD
2300 IF CN(CR)=1 OR CN(CR)=14 OR CN(CR)=27 OR CN(CR)=40 THEN COLOR 10:PLOT AC,AR:GOTO 2320
2310 COLOR ASC(UNSHUF$(CN(CR)-1,CN(CR)-1)):PLOT AC,AR
2320 BR(BC)=BR(BC)+1:IF BR(BC)=6 THEN BL=BL-1
2330 COLOR CR:PLOT BC,BR
2340 RETURN
2350 REM GROUP MOVE
2360 IF BL+ST<1 THEN ER=1:COLB=TR+2:B=116-32:GOSUB 1210
2370 RETURN
2380 IF B>=74 AND B<=74+SUITS-1 THEN COLB=B-74+PL:ER=2:GOSUB 1210:RETURN
2390 IF B>=87 AND B<=87+SUITS-1 THEN COLB=B-87+TL:ER=2:GOSUB 1210:RETURN
2400 COLB=2*(B-65)+FL
2410 LOCATE COLB,BR(COLB),CODEB
2420 GOSUB 2480:REM DETERMINES NUMBER OF CARDS TO BE MOVED
2430 IF CODEB<>32 THEN GOSUB 2640
2440 IF ER=-1 AND CODEB=32 THEN GOSUB 2780
2450 IF ER=-1 AND CODEB<>32 AND GRAPH THEN GOSUB 2780
2460 RETURN
2470 REM # OF CARDS TO MOVE
2480 J=1:GRPROW=ROWA:TEMCOD=CODEA
2490 LOCATE COLA,GRPROW-1,CODEG:LASTJ=J
2500 IF CN(CODEG)=CN(TEMCOD)+1 THEN J=J+1:TEMCOD=CODEG:GRPROW=GRPROW-1
2510 IF J=1 THEN ER=4:COLB=COLA:B=A+128-32:GOSUB 1210:RETURN
2520 IF CODEB<>32 AND LASTJ<J THEN 2490
2530 IF CODEB<>32 THEN RETURN
2540 IF CODEB=32 AND J=LASTJ THEN LOCATE COLA,GRPROW,CODEG:LOCATE COLA,GRPROW-1,CODEH:IF CODEH<>32 THEN RETURN
2550 IF CODEB=32 AND CODEH=32 THEN ER=4:CODEH=-1:GOSUB 1210:RETURN
2560 IF BL=1 AND ST=0 THEN ER=4:GOSUB 1210:RETURN
2570 IF BL=1 AND J<ST+1 THEN 2490
2580 IF BL=2 AND J<2+2*ST THEN 2490
2590 IF BL=3 AND ST=0 AND J<4 THEN 2490
2600 IF ((BL=3 AND ST=1) OR (BL=4 AND ST=0)) AND J<7 THEN 2490
2610 IF ((BL>=3 AND ST>=2) OR (BL>=4 AND ST>=1) OR BL>=5) AND J<12 THEN 2490
2620 LASTJ=J:GOTO 2540
2630 REM GROUP MOVE FOR CODEB<>32
2640 LOCATE COLA,GRPROW,CODEG
2650 IF CN(CODEB)<>CN(CODEG)+1 THEN ER=4:GOSUB 1210:RETURN
2660 IF BL=0 AND J<=ST+1 THEN GRAPH=TRUE:RETURN
2670 IF BL+ST=1 AND J=2 THEN GRAPH=TRUE:RETURN
2680 IF ((BL=1 AND ST=1) OR (BL=2 AND ST=0)) AND J<=4 THEN GRAPH=TRUE:RETURN
2690 IF (BL=1 AND ST=2) AND J<=6 THEN GRAPH=TRUE:RETURN
2700 IF ((BL=2 AND ST=1) OR (BL=3 AND ST=0)) AND J<=7 THEN GRAPH=TRUE:RETURN
2710 IF (BL=1 AND ST=3) AND J<=8 THEN GRAPH=TRUE:RETURN
2720 IF (BL=1 AND ST=4) AND J<=10 THEN GRAPH=TRUE:RETURN
2730 IF (BL=2 AND ST=2) AND J<=11 THEN GRAPH=TRUE:RETURN
2740 IF ((BL>=3 AND ST>=1) OR (BL>=4 AND ST>=0)) AND J<=11 THEN GRAPH=TRUE:RETURN
2750 GRAPH=FALSE:ER=4:GOSUB 1210
2760 RETURN
2770 REM MOVES GROUP
2780 FOR L=0 TO J-1
2790 POSITION COLA,GRPROW+L:? #6;" ":P=CN(TEMCOD):ROWB=BR(COLB)+1
2800 COLOR ASC(UNSHUF$(P-L,P-L)):PLOT COLB,ROWB+L
2810 NEXT L
2820 COLOR A+32:PLOT COLA,4
2830 POSITION TR+2,1:? #6;"t"
2840 BR(COLA)=BR(COLA)-J:BR(COLB)=BR(COLB)+J
2850 IF BR(COLA)=5 THEN BL=BL+1
2860 IF CODEB=32 THEN BL=BL-1
2870 ROWA=GRPROW:CODEA=CODEG:GOSUB 1840
2880 MOVGRP=FALSE:GRAPH=FALSE
2890 RETURN
20000 GRAPHICS 18:POKE 712,66:POSITION 6,4:? #6;"WINNER":POSITION 8,5:? #6;"IN"
20010 POSITION 6,7:? #6;MOVE;" MOVES":POKE 764,255
20020 POKE 708,PEEK(20):X=USR(BAND,PEEK(20),63):SOUND 0,X,14,14
20030 IF PEEK(764)=255 THEN 20020
20040 POKE 764,255:SOUND 0,0,0,0:CLR :GOTO 20