Antic-Pak, programming utilities (ANTICPAK.BAS)

Antic-Pak, programming utilities by Eugene Koh, 63

Description

Antic-Pak, programming utilities by Eugene Koh, 63

From the Antic disk of March 1989 (Vol. 7 No. 11) — disk A.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 7.8 KB

Dialect
Atari BASIC
Lines
130
Variables
DL, WVFLG, JNK, QQ$, F$, N$, X$, FNS, SEL, PSN, OK, A, B, A$, B$, V, C$, JUNK, LN, I, PZ, DA, N, PCT, AD
BASIC listing (130 lines)
10 REM ANTIC-PAK
12 REM BY EUGENE KOH
14 REM (c)1988, ANTIC PUBLISHING
16 GRAPHICS 0:POKE 559,0:DL=256*PEEK(561)+PEEK(560):POKE DL+3,71:POKE DL+6,6:POKE DL+7,6:POKE 710,144
18 POKE 712,102:POKE DL+8,7:POKE DL+22,5:POKE DL+23,6:POKE DL+24,6:POKE DL+25,6
20 POKE DL+26,65:POKE DL+27,PEEK(560):POKE DL+28,PEEK(561):? "  ANTIC-PAK":? "BY V. EUGENE KOH"
22 WVFLG=PEEK(1913)
24 ? "↓↓▕Convert File to BASIC Loader":?
26 ? "▕DIR Command Creator":?
28 ? "▕Eighty-Column Disk Directory":?
30 ? "▕File Management Helper":?
32 ? "▕Garbage Remover":?
43 ?
46 ? "↓↓   your choice  ":POKE 708,206:POKE 709,14:POKE 711,78:? " (C)1988 ANTIC":POKE 559,34
48 OPEN #1,4,0,"K:":GET #1,JNK:CLOSE #1
50 IF JNK<67 OR JNK>71 THEN ? "↰";:GOTO 48
52 JNK=JNK-66:ON JNK GOTO 1100,200,1000,300,800
200 GRAPHICS 0:? :? "DIR COMMAND MAKER":CLOSE #3:OPEN #3,8,0,"D1:DIR":DIM QQ$(68)
202 QQ$="CLR:DIMA$(50):?:?:OP.#1,7,0,XD:*.*X:F.A=1TO99:IN.#1;A$:?A$;X  X;:N.A"
204 QQ$(29,29)=CHR$(34):QQ$(35,35)=CHR$(34):QQ$(60,60)=CHR$(34):QQ$(63,63)=CHR$(34)
206 ? #3;QQ$:CLOSE #3
208 ? "Use ENTER";CHR$(34);"D:DIR to get a":? "disk diretory anytime. When you see"
210 ? "the ERROR 136, type END or CLOSE #1.":END
300 GOSUB 362:POKE 1913,87:POKE 65,0:DIM F$(50),N$(50),X$(50)
302 ? "D = Delete File";CHR$(127);"L = Lock File"
304 ? "R = Rename File";CHR$(127);"U = Unlock File"
306 ? "ESC = Go back    RETURN = No Changes"
308 ? :? :? "Insert work disk into drive one and":? "press START to begin... ";:POKE 559,34
310 ON PEEK(53279)<>6 GOTO 310:OPEN #2,4,0,"K:":JNK=1
312 GOSUB 362:? "L Filename Ext Size":? :OPEN #1,7,0,"D:*.*"
314 FOR FNS=1 TO JNK:INPUT #1,F$:NEXT FNS
316 ON F$(7,9)="EE " GOTO 352:JNK=JNK+1:? F$(1,10);CHR$(46);F$(11);"    ";:POKE 559,34
318 GET #2,SEL:IF SEL=155 THEN GOSUB 362:? "L Filename Ext Size":? :INPUT #1,F$:GOTO 316
320 IF SEL=27 THEN JNK=JNK-2:IF JNK<1 THEN JNK=1
322 IF SEL=27 THEN CLOSE #1:GOTO 312
324 ON SEL<>68 AND SEL<>76 AND SEL<>82 AND SEL<>85 GOTO 318
326 POKE 559,0:N$="D:":FOR PSN=3 TO 10:IF F$(PSN,PSN)=CHR$(32) THEN NEXT PSN:GOTO 330
328 N$(LEN(N$)+1)=CHR$(ASC(F$(PSN,PSN))):NEXT PSN
330 ON F$(11,13)="   " GOTO 336:N$(LEN(N$)+1)=CHR$(46)
332 FOR PSN=11 TO 13:IF F$(PSN,PSN)=CHR$(32) THEN NEXT PSN:GOTO 336
334 N$(LEN(N$)+1)=CHR$(ASC(F$(PSN,PSN))):NEXT PSN
336 IF SEL=68 THEN ? "DELETE":? :? "Okay to delete? ";:POKE 559,34:GET #2,OK:ON OK<>89 GOTO 344:POKE 559,0
338 ON SEL=82 GOTO 346:IF SEL=68 THEN XIO 33,#3,0,0,N$:JNK=JNK-1:GOTO 344
340 IF SEL=76 THEN XIO 35,#3,0,0,N$:GOTO 344
342 XIO 36,#3,0,0,N$
344 CLOSE #1:GOTO 312
346 POKE 559,34:? "RENAME":? :? "Enter new filename:":INPUT #16,X$
348 POKE 559,0:N$(LEN(N$)+1)=CHR$(44):N$(LEN(N$)+1)=X$
350 XIO 32,#3,0,0,N$:CLOSE #1:GOTO 312
352 GOSUB 362:CLOSE #1:OPEN #1,7,0,"D:*.*":TRAP 358:? "CURRENT FILE DIRECTORY:"
354 ? :? "L Name    Ext Size L Name    Ext Size":? :POKE 559,34
356 INPUT #1,F$:? F$;CHR$(32);CHR$(32);:GOTO 356
358 CLOSE #1:? :? :? "DONE! Press RESET to quit, or"
360 ? "SELECT to restart this program... ";:POKE 1913,WVFLG:GOTO 376
362 GRAPHICS 0:POKE 559,0:POKE 710,192:POKE 712,146
364 ? :? "       FILE MANAGEMENT HELPER"
366 ?
368 ? :? :TRAP 370:RETURN
370 ON PEEK(195)=136 GOTO 352
372 GOSUB 362:? "ERROR # ";PEEK(195);CHR$(253)
374 ? :? "Press SELECT to restart program... ";:POKE 559,34:POKE 1913,WVFLG
376 ON PEEK(53279)<>5 GOTO 376:RUN
800 GRAPHICS 0:TRAP 830:POKE 559,0:RESTORE 802:FOR A=708 TO 712:READ B:POKE A,B:NEXT A
802 A=PEEK(560)+PEEK(561)*256:DATA 70,12,160,198,160
804 POKE A+6,7:POKE A+7,6:POKE 65,0:? :DIM F$(50)
806 ? "GARBAGE REMOVER      by eugene koh":? :?
808 ? "File to process: ":POKE 559,34:INPUT #16,F$:IF F$="" THEN RUN
810 POKE 752,1:? :? :? "Press START to begin."
812 ON PEEK(53279)<>6 GOTO 812:GRAPHICS 0:POKE 559,0:POKE 77,128:POKE 1913,87
814 ? :? :? "LOAD ";CHR$(34);F$
816 ? :? :? "LIST ";CHR$(34);F$
818 ? :? :? :? "NEW ":? :? :? "ENTER";CHR$(34);F$
820 ? :? :? "SAVE ";CHR$(34);F$
822 ? :? :? "POKE 77,0:POKE 65,3:POKE 1913,87"
824 ? :? :? "POKE 842,12:GR.0:NEW"
826 POSITION 2,0
828 POKE 842,13:POKE 1913,WVFLG:END
830 GRAPHICS 0:? :? "Error # ";PEEK(195)
832 POKE 77,0:POKE 842,12:POKE 710,0
834 ? :? "↰↰Press OPTION to start over..."
836 ON PEEK(53279)<>3 GOTO 836:RUN
1000 GRAPHICS 0:? :? "Enter disk title:":? :? ">>> ";:DIM A$(100),B$(100):INPUT #16;A$:LPRINT A$:LPRINT
1002 CLOSE #1:OPEN #1,7,0,"D:*.*"
1004 FOR V=1 TO 4:INPUT #1;A$:B$(LEN(B$)+1)=A$:IF A$(5,9)="FREE " THEN POP :LPRINT B$:CLOSE #1:END
1006 B$(LEN(B$)+1)="  ":NEXT V:LPRINT B$:B$="":GOTO 1004
1100 DIM A$(100),B$(100),C$(100):CLOSE #1:OPEN #1,4,0,"K:"
1102 GOSUB 1176:? "Insert disk into drive":? "and press <RETURN>... ";:GET #1,JUNK
1104 GOSUB 1176:TRAP 1108:OPEN #2,7,0,"D1:*.*"
1106 INPUT #2,A$:? A$;"  ";:GOTO 1106
1108 IF PEEK(195)<>136 THEN 1182
1110 CLOSE #2:? :? :? :? "Press <SPACEBAR> to continue... ";:GET #1,JUNK
1112 GOSUB 1176
1114 ? "Enter filename of program to convert:":INPUT #16,B$:A$="D1:":A$(4)=B$
1116 IF B$="" THEN ? "↑↑";:GOTO 1114
1118 ? :? "Enter filename for new program:":INPUT #16,C$:B$="D1:":B$(4)=C$
1120 IF C$="" THEN ? "↑↑↑";:GOTO 1118
1122 ? :? "Enter line number to start at:":INPUT #16,LN:IF LN<0 OR LN>10000 THEN ? "↑↑↑";:GOTO 1122
1124 ? :? "Enter increment: 10←←";:INPUT #16,I:IF I<1 OR I>50 THEN ? "↑↑↑";:GOTO 1124
1126 ? :? "Press <RETURN> when ready to begin. ";:GET #1,JUNK
1128 GRAPHICS 18:POSITION 5,4:? #6;"wORkiNG.▂▂":POKE 65,0
1130 OPEN #2,4,0,A$:OPEN #3,8,0,B$
1132 ? #3;LN;"GR.0:?:?";CHR$(34);"CHECKSUM LOADER BY EUGENE KOH";CHR$(34);":OPEN #3,8,0,";CHR$(34);A$:LN=LN+I
1134 ? #3;LN;" READ A:IF A=-1 THEN CLOSE #3:GOTO ";LN+I+I:PZ=LN+I+I:LN=LN+I
1136 ? #3;LN;" PUT #3,A:CNT=CNT+A:GOTO ";LN-I:LN=LN+I+I+I
1138 TRAP 1144:? #3;LN;" DATA ";
1140 FOR DA=1 TO 15:GET #2,N:PCT=PCT+N:? #3;N;:IF DA<15 THEN ? #3;",";
1142 NEXT DA:LN=LN+I:? #3:GOTO 1138
1144 IF PEEK(195)<>136 THEN CLOSE #2:CLOSE #3:POP :GOTO 1182
1146 ? #3;"-1":? #3;PZ;" IF CNT<>";PCT;" THEN ?CHR$(253);";CHR$(34);"ERROR IN DATA STATEMENTS!";CHR$(34);":END"
1148 ? #3;PZ+I;" ?";CHR$(34);"NO ERRORS."
1150 CLOSE #2:CLOSE #3:POP
1152 GOSUB 1176:? " ALL DONE! ":? :? "Please choose:":?
1154 ? "▕A▎Exit to DOS":? "▕B▎Exit to BASIC":? "▕C▎Start over":?
1156 ? "Please enter your choice:▕ ▎←←";
1158 GET #1,AD:IF AD<65 OR AD>67 THEN 1158
1160 ? CHR$(AD+128);"→";:AD=AD-64:ON AD GOTO 1162,1164,1186
1162 CLOSE #1:DOS
1164 CLOSE #1:GRAPHICS 0
1166 GRAPHICS 0:? :? "Enter disk title:":? :? ">>> ";:DIM A$(100),B$(100):INPUT #16;A$:LPRINT A$:LPRINT
1168 OPEN #1,7,0,"D:*.*"
1170 FOR V=1 TO 4:INPUT #1;A$:B$(LEN(B$)+1)=A$:IF A$(5,9)="FREE " THEN POP :LPRINT B$:CLOSE #1:END
1172 B$(LEN(B$)+1)="  ":NEXT V:LPRINT B$:B$="":GOTO 1170
1174 END
1176 GRAPHICS 0:POKE 710,196:POKE 712,196:POKE 709,15
1178 ? "        TRANSFER FILE TO DATA  ":? "        By Eugene Koh"
1180 ? "─────────────────────────────────────":? :TRAP 1182:RETURN
1182 GOSUB 1176:? "ERROR # ";PEEK(195);"↰":?
1184 ? "Press <SPACEBAR> to restart... ";:GET #1,JUNK
1186 RUN
1188 END