Error-Trapping Demo (TRAPPING.BAS)
Error-Trapping Demo by Heidi Brumbaugh, 16
Description
Error-Trapping Demo by Heidi Brumbaugh, 16
From the Antic disk of February 1989 (Vol. 7 No. 10) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.0 KB
- Dialect
- Atari BASIC
- Lines
- 54
- Variables
ERR,OPT
BASIC listing (54 lines)
10 REM ERROR-TRAPPING DEMO
20 REM BY HEIDI BRUMBAUGH
30 REM (c)1988, ANTIC PUBLISHING
100 TRAP 30000
110 CLOSE #1:OPEN #1,8,0,"D:DUCKS.DAT"
120 ? #1,"Donald"
130 ? #1,"The, Howard"
140 ? #1,"Daffy"
145 ? #1,"Sitting"
150 CLOSE #1
160 ? "Names entered."
170 END
30000 TRAP 30000:REM RESET TRAP
30010 CLOSE #1:? :REM CLOSE CHANNEL
30015 ERR=PEEK(195)
30020 IF ERR=144 THEN 30150:REM DISK IS WRITE-PROTECTED
30030 IF ERR=138 THEN 30200:REM DEVICE DOES NOT RESPOND
30040 IF ERR=139 OR ERR=164 THEN 30250:REM HAVING ODD PROBLEMS
30050 IF ERR=140 OR ERR=142 OR ERR=143 THEN 30300:REM DISK MAY BE DAMAGED
30060 IF ERR=162 THEN 30350:REM DISK FULL
30070 IF ERR=167 THEN 30400:REM FILE LOCKED
30080 IF ERR=169 THEN 30450:REM DIRECTORY FULL
30090 ? "Error number ";ERR;" has occurred.":GOTO 30500:REM DON'T KNOW WHAT HAPPENED
30150 ? "Disk is write-protected.":?
30160 ? "Please remove write-protect tab and"
30170 ? "put disk back in drive."
30180 GOTO 30500
30200 ? "Device is not responding."
30210 ? "Check disk drive cables and try again."
30220 GOTO 30500
30250 ? "I'm having trouble opening file."
30260 ? "I suggest you check disk drive"
30270 ? "and try again."
30280 GOTO 30500
30300 ? "Your disk may be damaged."
30310 ? "I suggest you try again or use"
30320 ? "another disk."
30330 GOTO 30500
30350 ? "Disk is full."
30360 ? "Please insert a new disk & try again."
30370 GOTO 30500
30400 ? "You already have a DUCKS.DAT file"
30410 ? "and it is locked. Insert new disk"
30420 ? "and try again or abort operation."
30430 GOTO 30500
30450 ? "You can only have 64 files on a disk."
30460 ? "Please insert new disk and try again"
30470 ? "or abort operation."
30500 ? :? "Press R to retry; A to abort."
30510 CLOSE #1:OPEN #1,4,0,"K:":REM OPEN KEYBOARD FOR INPUT
30515 GET #1,OPT:CLOSE #1:REM ASCERTAIN USERS SELECTED CHOICE AND THEN CLOSE THE OPENED CHANNEL.
30520 IF OPT=65 OR OPT=97 THEN 170:REM ABORT
30530 IF OPT=82 OR OPT=114 THEN 110:REM TRY AGAIN
30540 GOTO 30500:REM WAIT FOR A OR R
