Spelling Flash Cards v5 with samples (SPELLING.BAS)
Spelling Flash Cards v5 with samples by Andy Barton, 138 (BASIC, MAC/65 source)
Description
Spelling Flash Cards v5 with samples by Andy Barton, 138 (BASIC, MAC/65 source)
From the Antic disk of February 1989 (Vol. 7 No. 10) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 13.6 KB
- Dialect
- Atari BASIC
- Lines
- 317
- Variables
JIFS,SEC,THI,TLOW,Z,NTS,T,L,TEMP,TRACK(,X,AW$,AWF$,XAW,AWL,VIEW,TFLAG,ANS$,BLANK$,CHC,C,CH,LIMIT,CHR,TOT,WTUNE,COR,BUZZ,FL,REPEAT,CHOICE(,CC,DD$,FILENAME$,Y,TEMP$,DL,SC,S1,S2,ADLON,STORAGE$,ADLDAT,TC,P1,AWC,T2,P2,ADLOFF,HFL,CHRSET,LTUNE,T2$,T1$,Z1,DVIEW,CHOICE$,DD,HDD,ERROR,DASH,T$
BASIC listing (317 lines)
10 REM SPELLING FLASH CARDS (VER.5)
20 REM BY ANDY BARTON
30 REM (c)1988, ANTIC PUBLISHING
80 GRAPHICS 18:POSITION 0,3:? #6;"SPELLING FLASH CARDS":? #6:? #6:? #6;" by andy barton"
90 GOTO 5500
100 REM SUBROUTINES
110 REM COUNTDOWN TIMER
120 JIFS=SEC*60:THI=(INT(JIFS/256)):TLOW=JIFS-THI*256
130 POKE 66,1:POKE 540,TLOW:POKE 541,THI:POKE 554,1:POKE 66,0
140 RETURN
150 REM TUNE
160 FOR Z=1 TO NTS
170 T=(INT(RND(0)*7)+1)*5+40
180 FOR L=14 TO 4 STEP -2
190 SOUND 0,T,10,L
200 NEXT L:NEXT Z
210 SOUND 0,0,0,0:RETURN
220 REM BUZZER
230 FOR Z=1 TO NTS
240 SOUND 0,50,6,10
250 NEXT Z
260 SOUND 0,0,0,0:RETURN
270 REM MAIN SUB 1
280 TEMP=TRACK(0,X)*15
290 AW$=AWF$(TEMP,TEMP+15-1)
300 GOSUB 820
310 XAW=9-INT((AWL+1)/2)
320 REM MAIN SUB 1A -- VIEW WORD
330 SEC=VIEW:GOSUB 110
340 POSITION XAW+1,5:? #6;AW$
350 IF PEEK(TFLAG) THEN 350
360 REM BLANK-OUT LETTERS
370 GOSUB 870
380 FOR Z=1 TO AWL:POSITION XAW+Z,6:? #6;"_";:NEXT Z
390 ANS$=BLANK$:REM 15 SPACES
400 RETURN
410 REM MAIN SUB 2
420 REM INPUT LETTERS
430 CHC=1:GOSUB 780
440 POSITION XAW+CHC,5:GET #6,C:IF C<>32 THEN CHC=CHC+1:GOTO 540
450 POKE CH,255:SEC=LIMIT:GOSUB 110:POSITION XAW+CHC,6:? #6;"_"
460 IF PEEK(CH)<>255 THEN GET #3,CHR:GOTO 490
470 IF PEEK(TFLAG)=0 THEN 580
480 GOTO 460
490 IF CHR=27 OR CHR=155 THEN POKE 712,68:GOSUB 760:TOT=TOT+1:GOSUB 330:GOTO 430:REM [ESC] OR RETURN
500 IF CHR=126 THEN 650:REM DELETE
510 IF CHR<>32 AND CHR<>45 AND CHR<>39 AND CHR<65 OR CHR>90 THEN 440:REM NOT " ","-",A-Z
520 POSITION XAW+CHC,6:? #6;"_":POSITION XAW+CHC,5:? #6;CHR$(CHR)
530 ANS$(CHC,CHC)=CHR$(CHR):CHC=CHC+1
540 IF CHC<=AWL THEN 440
550 REM CHECK SPELLING
560 IF ANS$(1,AWL)=AW$ THEN NTS=WTUNE:GOSUB 150:TOT=TOT+1:COR=COR+1:GOSUB 780:ANS$="":GOSUB 870:RETURN
570 REM MISSPELLED
580 POKE 712,68:TOT=TOT+1
590 NTS=BUZZ:GOSUB 220
600 GOSUB 760
610 FOR Z=1 TO AWL
620 IF AW$(Z,Z)<>ANS$(Z,Z) THEN POSITION XAW+Z,5:? #6;" "
630 NEXT Z
640 GOTO 430
650 IF CHC=1 THEN 440
660 POSITION XAW+CHC,6:? #6;"_":CHC=CHC-1:POSITION XAW+CHC,5:? #6;" ":ANS$(CHC,CHC)=" ":GOTO 440
670 REM TRACK SUB
680 POKE 712,58
690 FOR X=FL TO 1 STEP -1
700 IF TRACK(1,X) THEN TRACK(1,X)=TRACK(1,X)-1:GOSUB 280:GOSUB 430
710 NEXT X
720 FOR Z=1 TO FL:IF TRACK(1,Z) THEN 740
730 NEXT Z:TRACK(1,0)=0
740 RETURN
750 REM SET TRACK SUB
760 TRACK(1,0)=1:TRACK(1,X)=REPEAT
770 REM DISPLAY SCORE
780 POSITION 0,0:? #6;"TOTAL ";TOT:POSITION 0,1:? #6;"RIGHT ";COR
790 Z=CHOICE(CC):POSITION 11,0:? #6;"LIST #";Z
795 POSITION 11-2*(DD$(Z*11+9,Z*11+9)<>" "),1:? #6;DD$(Z*11,Z*11+10)
800 RETURN
810 REM SHORT
820 AWL=15
830 IF AW$(AWL,AWL)=" " THEN AWL=AWL-1:IF AWL>0 THEN 830
840 IF AWL>0 THEN AW$=AW$(1,AWL)
850 RETURN
860 REM BLANK-OUT
870 POSITION 0,5:? #6;BLANK$
880 RETURN
890 REM LOAD FILE
900 FILENAME$="D1:"
910 Y=4:Z=CHOICE(CC)*11:FOR X=0 TO 7:IF DD$(Z+X,Z+X)<>" " THEN FILENAME$(Y,Y)=DD$(Z+X,Z+X):Y=Y+1
920 NEXT X
930 FILENAME$(Y)=".":FILENAME$(Y+1)=DD$(Z+8,Z+10)
940 TRAP 980:CLOSE #1:OPEN #1,4,0,FILENAME$
950 INPUT #1;FL,VIEW
960 FOR X=1 TO FL:INPUT #1;TEMP$:Y=15*X:AWF$(Y,Y+15-1)=TEMP$:NEXT X:AWF$(Y+15)=" "
970 TRAP 40000:CLOSE #1:RETURN
980 NTS=BUZZ:GOSUB 220:? "ERROR -- ";FILENAME$;" is not a":? "Spelling Flash Card file"
990 FOR Z=1 TO 350:NEXT Z:POP :GOTO 4600
1000 REM SAVE LIST TO DISK
1010 IF FL=0 THEN POSITION 2,21:? BLANK$;BLANK$;"↑ ABORTED":GOTO 4510
1020 CLOSE #1:OPEN #1,8,0,FILENAME$
1030 ? #1;FL:? #1;VIEW
1040 FOR X=1 TO FL:Y=15*X:? #1;AWF$(Y,Y+15-1):NEXT X
1050 GOTO 4510
1060 REM ML SUBROUTINE
1070 POKE 752,1
1080 DL=PEEK(560)+PEEK(561)*256
1090 SC=PEEK(DL+4)+PEEK(DL+5)*256
1100 RETURN
1110 S1=PEEK(SC+704):S2=PEEK(SC+784)
1120 X=USR(ADLON,SC+400,ADR(STORAGE$),160,1700,SC+400,80,SC+560,SC+480,400,ADLDAT,DL+15,4)
1130 TC=1:P1=23:IF AWC=1 THEN T2=C*15:AW$=AWF$(T2,T2+15-1)
1140 POSITION P1-1-(C>9),10:? C;" ";AW$
1150 P2=SC+443:POKE P2+TC,255*(AWC=1):REM PUT BAR UNDER FIRST LSTTER IN GR.7
1160 RETURN
1170 X=USR(ADLOFF,SC+879,SC+959,400,ADR(STORAGE$),SC+400,160,DL+14,DL+15,4)
1180 POKE SC+704,S1:POKE SC+784,S2
1190 RETURN
3000 REM PROCESS CHOICES
3010 FOR CC=1 TO CHOICE(0)
3020 GOSUB 900
3030 REM RADOMIZE TRACKING ARRAY
3040 FOR X=0 TO FL:TRACK(0,X)=0:TRACK(1,X)=0:NEXT X
3050 FOR TC=1 TO FL
3060 X=INT(RND(0)*FL)+1
3070 IF TRACK(0,X)=0 THEN TRACK(0,X)=TC:GOTO 3100
3080 X=X+1:IF X>FL THEN X=1
3090 GOTO 3070
3100 NEXT TC
3110 REM LIST WORDS
3120 POKE 752,0
3130 GRAPHICS 2*(FL<11)+1*(FL>10 AND FL<21)+0*(FL>20):POKE 752,1
3140 IF FL>20 THEN 3160
3150 FOR X=1 TO FL:POSITION 2,X-1:GOSUB 3190:NEXT X:GOTO 3210
3160 HFL=INT((FL+1)/2)
3170 FOR X=1 TO HFL:POSITION 4,X-1:GOSUB 3190:NEXT X:IF X>FL THEN 3210
3180 FOR X=X TO FL:POSITION 20,X-HFL-1:GOSUB 3190:NEXT X:IF X>FL THEN 3210
3190 IF X<10 THEN ? #6;" ";
3200 ? #6;X;" ";:Y=15*X:? #6;AWF$(Y,Y+15-1):RETURN
3210 ? :? " PRESS ANY KEY"
3220 GET #3,Z
3230 REM MAIN LOOP
3240 GRAPHICS 2+16:POKE 708,214:TC=1:TOT=0:COR=0:GOSUB 780
3250 POKE 756,CHRSET/256
3260 FOR AWC=1 TO FL
3270 IF TRACK(1,0) THEN GOSUB 680
3280 POKE 712,0:X=AWC
3290 GOSUB 280:GOSUB 430
3300 NEXT AWC
3310 IF TRACK(1,0) THEN GOSUB 680:GOTO 3310
3320 REM REWARD SCREEN
3330 POKE 712,0:? #6;" ";BLANK$
3340 POSITION 5,5:? #6;"GOOD WORK":NTS=LTUNE:GOSUB 150
3350 NEXT CC
3360 POKE CH,255:POSITION 2,8:? #6;"ANY KEY TO GO ON":GET #3,CHR:GOTO 4510
3500 REM ADD NEW LISTS
3510 GRAPHICS 2:T2$=BLANK$:Z=0
3520 POSITION 2,0:? #6;"type in new list"
3530 POSITION 2,3:? #6;"TITLE:":INPUT T1$:IF T1$=" " OR T1$="" THEN ? "↰":? :? :? "ABORTED":GOTO 4510
3540 IF T1$(1,1)<"A" OR T1$(1,1)>"Z" THEN ? :? "Must start with a LETTER":FOR X=1 TO 100:NEXT X:GOTO 3510
3545 IF LEN(T1$)>8 THEN ? "↰":? :? "Too Long!":FOR X=1 TO 100:NEXT X:GOTO 3510
3550 Y=1:FOR X=1 TO LEN(T1$)
3560 IF Z=0 AND T1$(X,X)="." THEN T2$(Y)=T1$(X,X):Z=Y+3:Y=Y+1
3570 IF T1$(X,X)>="0" AND T1$(X,X)<="9" OR T1$(X,X)>="A" AND T1$(X,X)<="Z" THEN T2$(Y)=T1$(X,X):Y=Y+1
3580 NEXT X:IF LEN(T2$)>12 THEN T2$=T2$(1,12)
3585 IF Z>0 AND LEN(T2$)>Z THEN T2$=T2$(1,Z)
3586 Z1=LEN(T2$):FOR X=1 TO LEN(T2$):IF T2$(X,X)="." THEN Z1=X-1:Z=0
3587 NEXT X:T2$=T2$(1,Z1)
3590 IF Z=0 THEN T2$(LEN(T2$)+1)=".DAT"
3595 POSITION 2,5:? #6;T2$:POSITION 2,7:? #6;"ACCEPT? (N)":GET #3,Z:IF Z=78 THEN 3510
3600 FILENAME$="D1:":FILENAME$(4)=T2$
3610 POSITION 0,7:? #6;"HOW LONG TO PREVIEW?"
3620 TRAP 3630:VIEW=DVIEW:INPUT Z:VIEW=Z
3630 TRAP 40000:POSITION 2,9:? #6;VIEW;" SECONDS":SEC=VIEW:GOSUB 110
3640 IF PEEK(TFLAG) THEN 3640
3650 GOTO 3820
3660 REM EDIT LIST
3670 TRAP 5000:CHOICE(1)=VAL(CHOICE$(2)):CC=1
3680 GOSUB 900:TRAP 40000
3690 AWC=1:X=0:GRAPHICS 0:GOSUB 1070
3700 ? :? "This file is set to preview words for ";VIEW;" Seconds":? :? "Enter new time or press RETURN "
3710 TRAP 3740:INPUT Z:VIEW=Z:TRAP 40000
3720 ? :? VIEW;" Seconds":SEC=VIEW:GOSUB 110
3730 IF PEEK(TFLAG) THEN 3730
3740 ? "↰":IF FL>20 THEN 3760
3750 FOR X=1 TO FL:POSITION 2,X-1:GOSUB 3790:NEXT X:GOTO 3830
3760 HFL=INT((FL+1)/2)
3770 FOR X=1 TO HFL:POSITION 2,X-1:GOSUB 3790:NEXT X
3780 FOR X=X TO FL:POSITION 21,X-HFL-1:GOSUB 3790:NEXT X:GOTO 3830
3790 IF X<10 THEN ? " ";
3800 ? X;" ";:Y=15*X:? AWF$(Y,Y+15-1):RETURN
3810 REM INPUT NEW WORDS
3820 GRAPHICS 0:GOSUB 1070:FL=0
3830 POSITION 2,21:? " Type word or # to Edit RETURN TO SAVE";
3840 POKE CH,255:GET #3,CHR
3850 IF CHR=155 THEN 1010:REM SAVE FILE
3860 IF CHR<48 OR CHR>57 THEN 3920:REM NOT 0-9
3870 AWC=1:C=VAL(CHR$(CHR)):SEC=0.5:GOSUB 110
3880 IF PEEK(CH)=255 THEN IF PEEK(TFLAG) THEN 3880
3890 IF PEEK(CH)<>255 THEN GET #3,Z:IF Z>47 AND Z<58 THEN C=C*10+VAL(CHR$(Z))
3900 IF NOT (C<1 OR C>FL) THEN 3910
3905 POSITION 4,23:? C;" Is too large";:FOR X=1 TO 99:NEXT X:POSITION 0,23:? BLANK$;:GOTO 3830
3910 GOTO 3950
3920 IF CHR<65 OR CHR>90 THEN 3840:REM NOT A-Z
3930 FL=FL+1:IF FL>40 THEN FL=40:POSITION 2,23:? " MAXIMUN OF 40 WORDS ":FOR X=1 TO 150:NEXT X:GOTO 3740
3940 C=FL:T2=C*15:AW$=BLANK$:AW$(1,1)=CHR$(CHR):AWC=0
3950 POSITION 2,21:? BLANK$;BLANK$;:POKE 752,1:POSITION 2,21:? " Type word and press RETURN ";
3960 GOSUB 1110
3970 IF AWC=0 THEN TC=TC+1:POKE P2+TC,255
3980 GET #3,CHR
3990 IF CHR=155 THEN 4090:REM RETURN
4000 IF CHR=254 THEN 4190:REM CTRL DELEAT
4010 IF CHR=126 THEN IF TC<>1 THEN 4220:REM DELETE
4020 IF CHR=30 OR CHR=43 THEN 4230:REM "←"
4030 IF CHR=31 OR CHR=42 THEN 4250:REM "→"
4040 IF CHR>64 AND CHR<91 OR CHR=32 OR CHR=45 OR CHR=39 THEN GOTO 4060:REM A-Z OR SPACE OR - OR '
4050 GOTO 3980
4060 POSITION P1+TC,10:? CHR$(CHR):AW$(TC,TC)=CHR$(CHR):POKE P2+TC,0
4070 TC=TC+1:IF TC>15 THEN TC=15
4080 POKE P2+TC,255:GOTO 3980
4090 POKE CH,255:GOSUB 820:POKE 94,PEEK(DL+4):POKE 95,PEEK(DL+5):GOSUB 1170:IF AWL=0 THEN 4160
4100 T2$(1,15)=BLANK$:T2$(1,AWL)=AW$:AWF$(T2,T2+15-1)=T2$
4120 IF AWC=0 THEN 3740
4130 X=C:IF FL<21 THEN POSITION 2,C-1:GOSUB 3790:GOTO 3830
4140 IF C>INT((FL+1)/2) THEN POSITION 21,C-HFL-1:GOSUB 3790:GOTO 3830
4150 POSITION 2,C-1:GOSUB 3790:GOTO 3830
4160 IF FL<2 THEN POSITION 2,19:? BLANK$;" ABORTED";:GOTO 4510
4170 IF C=FL THEN AWF$=AWF$(1,T2-1):FL=FL-1:GOTO 3740
4180 AWF$(T2)=AWF$(T2+15):FL=FL-1:GOTO 3740
4190 IF TC=15 THEN AW$(15)=" ":GOTO 4210
4200 AW$(TC)=AW$(TC+1):AW$(15)=" "
4210 POSITION P1+1,10:? AW$:GOTO 3980
4220 POKE P2+TC,0:TC=TC-1:POKE P2+TC,255:POSITION P1+TC,10:? " ":AW$(TC,TC)=" ":GOTO 3980
4230 IF TC<>1 THEN POKE P2+TC,0:TC=TC-1:POKE P2+TC,255
4240 GOTO 3980
4250 IF TC<>15 THEN POKE P2+TC,0:TC=TC+1:POKE P2+TC,255
4260 GOTO 3980
4500 REM DISK DIRECTORY & CHOOSE WORD LIST(S)
4510 CLOSE #1:OPEN #1,6,0,"D1:*.DAT"
4520 DD$(1)=" ":DD$(65*11)=" ":DD$(2)=DD$
4530 DD=1
4540 INPUT #1,TEMP$
4560 IF TEMP$(5,16)="FREE SECTORS" THEN 4590
4570 DD$(11*DD,11*DD+10)=TEMP$(3,13):DD=DD+1
4580 GOTO 4540
4590 CLOSE #1:DD=DD-1
4600 GRAPHICS 2*(DD<11)+1*(DD>10 AND DD<21)+0*(DD>20):POKE 752,1:? "↰":IF DD=0 THEN 4740
4610 IF DD>20 THEN X=0:GOTO 4630
4620 FOR X=1 TO DD:POSITION 2,X-1:GOSUB 4710:NEXT X:GOTO 4740
4630 IF X=41 THEN 4680
4640 TEMP=DD*(DD<41)+40*(DD>40)
4650 HDD=INT((TEMP+1)/2)
4660 FOR X=1 TO HDD:POSITION 4,X-1:GOSUB 4710:NEXT X:IF X>TEMP THEN 4740
4670 FOR X=X TO TEMP:POSITION 20,X-HDD-1:GOSUB 4710:NEXT X:GOTO 4740
4680 HDD=INT((DD-40+1)/2)+40
4690 FOR X=X TO HDD:POSITION 4,X-41:GOSUB 4710:NEXT X:IF X>DD THEN 4740
4700 FOR X=X TO DD:POSITION 20,X-HDD-1:GOSUB 4710:NEXT X:GOTO 4740
4710 IF X<10 THEN ? #6;" ";
4720 ? #6;X;" ";DD$(X*11,X*11+10);:RETURN
4730 REM INPUT MESSAGES
4740 POKE 752,0
4750 POSITION 2,20:? "Choose # (EX. 3 or 3,5,9 or 2-7"
4760 ? " E # Edit a list N New list"
4770 IF DD>40 THEN ? " RETURN more choices"
4780 ERROR=5000
4790 INPUT CHOICE$
4800 L=LEN(CHOICE$)
4810 IF L=0 AND DD>40 THEN GRAPHICS 0:POKE 752,1:? "↰":GOTO 4630:REM MORE CHOICES
4820 IF L=0 THEN 4600
4830 IF CHOICE$(1,1)="N" THEN 3510
4840 IF CHOICE$(1,1)="E" THEN 3670
4850 IF CHOICE$(1,1)<"0" OR CHOICE$(1,1)>"9" THEN 5000
4860 CC=0:TEMP$=BLANK$:TC=0:DASH=0
4870 FOR Y=1 TO L
4880 IF CHOICE$(Y,Y)<"0" OR CHOICE$(Y,Y)>"9" THEN 4910
4890 TC=TC+1
4900 GOTO 4950:REM NEXT Y
4910 IF TC<>0 THEN CC=CC+1:CHOICE(CC)=VAL(CHOICE$(Y-TC)):TC=0:IF CHOICE(CC)>DD THEN GOTO 5000
4920 IF DASH=1 THEN GOSUB 4990:GOTO 4940
4930 IF CHOICE$(Y,Y)="-" THEN DASH=1:GOTO 4950
4940 IF CHOICE$(Y,Y)<>"," THEN 5000
4950 NEXT Y
4960 IF TC<>0 THEN CC=CC+1:CHOICE(CC)=VAL(CHOICE$(Y-TC)):IF CHOICE(CC)>DD THEN GOTO 5000
4970 IF DASH=1 THEN GOSUB 4990
4980 CHOICE(0)=CC:GOTO 3010
4990 DASH=0:CC=CC-1:X=CHOICE(CC):Z=CHOICE(CC+1)-X:FOR CC=CC TO CC+Z
4995 CHOICE(CC)=X:X=X+1:NEXT CC:CC=CC-1:RETURN
5000 NTS=BUZZ:GOSUB 220:? "ERROR -- Wrong Input Form";:SEC=2:GOSUB 110
5010 IF PEEK(TFLAG) THEN 5010
5020 GOTO 4600
5500 REM EQUATES TABLE
5510 REM VALUE VARIABLES
5520 WTUNE=20:REM LENGTH OF TUNE FOR WORD
5530 LTUNE=80:REM LENGTH OF TUNE FOR FINISHING LIST
5540 BUZZ=20:REM LENGTH OF BUZZER FOR ERROR
5550 DVIEW=0.75:REM SECONDS TO VIEW WORD (INITIAL DEFAULT VALUE)
5560 LIMIT=20:REM TIME LIMIT (SECONDS) TO TYPE EACH LETTER OF THE WORD
5570 REPEAT=3:REM NO. OF TIMES TO REPEAT A MISSED WORD
5730 REM INITIALIZE
5740 DIM STORAGE$(160):STORAGE$(1)=" ":STORAGE$(160)=" ":STORAGE$(2)=STORAGE$:DIM BLANK$(38)
5750 BLANK$=STORAGE$:DIM DD$(65*11):REM DISK DIRECTORY
5760 DIM FILENAME$(15),CHOICE$(120),TEMP$(32),T$(144),T1$(17),T2$(17),CHOICE(64)
5770 AWC=0:REM ACTIVE WORD COUNT VARIABLE
5780 TFLAG=554:REM FLAG FOR COUNTDOWN TIMER ROUTINE
5790 DIM AWF$((40*15)+15):REM ACTIVE WORD FILE - A STRING
5800 DIM TRACK(1,40):REM REM TRACKING MATRIX - LEVEL (0,X). 0=CORRECT NOT 0 = STILL TO DO
5810 REM - LEVEL (1,X) KEEPS TRACK OF NO. OF TIMES LEFT TO REPEAT A MISSED WORD
5820 DIM AW$(15):REM ACTIVE WORD
5830 DIM ANS$(15):REM ANSWER
5840 CH=764:REM LAST KEY PRESSED
5850 CLOSE #3:OPEN #3,4,0,"K:"
5860 T$(1,72)="h d╱ ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆h d╱ ▶╱ d╱ ▶╱ d╱ ┤╱ d╱ ▶╱◆h d╱ ♥1p┌TFTP▕F"
5870 T$(73,144)="UFpP▕FqFnPlFo♣h d╱ ▶╱ d╱ ▶╱◆h*h(h┐qh┐ph┐Uh┐Th┐oh┐n┴H◣H◆&n ♥1p┌THJPx◆╱╲◣◣"
5880 TEMP$="h":TEMP$(2,19)=T$(105,122):TEMP$(20,32)=T$(128,140):X=USR(ADR(TEMP$),ADR(T$),1536,144)
5890 ADLON=1567:ADLOFF=1593:ADLDAT=1676
5900 CHRSET=(PEEK(106)-8)*256:X=USR(1536,57344,CHRSET,512)
5910 RESTORE 5920:FOR Z=504 TO 511:READ X:POKE CHRSET+Z,X:NEXT Z:REM REDEFINE "_"
5920 DATA 0,126,0,0,0,0,0,0
5930 GOTO 4510
