game (ROULETTE.BAS)
game by Michael Pemberton, 85
Description
game by Michael Pemberton, 85
From the Antic disk of February 1989 (Vol. 7 No. 10) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 10.4 KB
- Dialect
- Atari BASIC
- Lines
- 208
- Variables
COLR$,STR(,STREET(,LN6(,BET$,SQRE(,A$,SPLIT(,COL(,WHEEL(,GRIDFIX,CHECKCASH,PLACEBET,ZERO,X,I,J,PMMEM,CASH,OLDNO,HPOS,VPOS,K,BET,AMT,LN5,HI,LO,ODD,EVEN,RED,BLACK,DZN1,DZN2,DZN3,DELAY,NUM,WIN,STCNT,SQ
BASIC listing (208 lines)
2 REM ROULETTE
4 REM BY MICHAEL PEMBERTON
6 REM (c)1988, ANTIC PUBLISHING
10 GRAPHICS 2:? #6:? #6:? #6:? #6;" ROULETTE":? :? :? #6;" by":? #6;"michael a▂ pemberton"
20 ? " One Moment Please":? " Screen Will Go Blank For 10 Seconds"
100 DIM COLR$(36),STR(38),STREET(12),LN6(11),BET$(370),SQRE(22),A$(1),SPLIT(58),COL(3),WHEEL(38)
110 GRIDFIX=4110:CHECKCASH=4210:PLACEBET=4310:ZERO=4470
120 COLR$="RBRBRBRBRBBRBRBRBRRBRBRBRBRBBRBRBRBR"
130 REM BETTING MATRIX
140 BET$(1,74)="♥♥♥'eqfrgshhtiiujjvkkwllxmmynnzoo♠pp♥♥%%♥┘*╱-▗0▘▘3▖▖6──9▄▄<┴┴?␛␛B←←E!!H$$d"
141 BET$(75,148)="♥%%♥J◀L♥N▕PP┤RR╱TT◢VV◣XX▘ZZ▂\\♣^^─◆◆♥♥aa♥▕)┐,◢/▝▝2▂▂5┌┌8●●;┬┬>└└A↓↓D G##c"
142 BET$(149,222)="♥&&♥I↰K▶M├OO┘QQ┐SS╲UU▗WW▝YY▔[[▖]]┌__♥♥&&♥├(┤+╲.◣◣1▔▔4♣♣7┼┼:▎▎=▌▌@↑↑C→→FXXb"
143 BET$(223,296)="♥♥♥'eqfrgshhtiiujjvkkwllxmmynnzoo♠pp♥♥♥♥♥▌▌▌▌▌▌▌▌♥└└└└└└└└└└└♥XXXXXXXXXXX♥"
144 BET$(297,370)="♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥●●●●♥▎▎▎♥┬┬┬┬┬♥┴┴┴┴┴♥▄▄▄▄▄♥┼┼┼┼┼♥"
145 BET$(220,220)=CHR$(34):BET$(221,221)=CHR$(34):FOR X=285 TO 295:BET$(X,X)=CHR$(155):NEXT X
146 FOR I=1 TO 38:READ X:WHEEL(I)=X:NEXT I
150 REM CLEAR ARRAYS
160 GOSUB 4470
300 REM COLOR GAMEBOARD
305 POKE 559,0
310 FOR I=0 TO 3:POKE 53256+I,3:NEXT I:POKE 53260,1:I=PEEK(106):I=I-8:POKE 106,I
320 POKE 623,1:FOR J=0 TO 3:POKE 704+J,54:NEXT J:POKE 54279,I:PMMEM=I*256
350 FOR J=PMMEM TO PMMEM+2047:POKE J,0:NEXT J
370 FOR J=PMMEM+1061 TO PMMEM+1074:POKE J,207:POKE J+16,48:POKE J+32,204:POKE J+256,143:POKE J+272,112:NEXT J
380 FOR J=PMMEM+1349 TO PMMEM+1362:POKE J,15:POKE J+224,199:POKE J+240,56:POKE J+256,199:NEXT J
390 FOR J=PMMEM+1829 TO PMMEM+1842:POKE J,227:POKE J+16,28:POKE J+32,3:NEXT J
400 FOR J=PMMEM+805 TO PMMEM+818:POKE J,3:POKE J+32,3:NEXT J
410 GRAPHICS 0:POKE 710,196:POKE 559,62
420 POKE 53277,3
430 POKE 53248,70:POKE 53249,102:POKE 53250,134:POKE 53251,166:POKE 53252,198
440 REM GAME SETUP
450 CASH=500:OLDNO=0
460 HPOS=2:VPOS=0
500 GOSUB 5010
510 POSITION 2,12:? "CASH AVAILABLE: $";CASH
900 REM CURSOR MOVEMENT
1000 POSITION HPOS+1,VPOS:? "←";
1010 IF STICK(0)=14 THEN ? "↑";:VPOS=VPOS-1
1020 IF STICK(0)=13 THEN ? "↓";:VPOS=VPOS+1
1030 IF STICK(0)=7 THEN ? "→";:HPOS=HPOS+1
1040 IF STICK(0)=11 THEN ? "←";:HPOS=HPOS-1
1045 IF VPOS<0 THEN VPOS=9:POSITION HPOS,8:? "↓";
1047 IF VPOS>9 THEN VPOS=0:POSITION HPOS,1:? "↑";
1048 IF HPOS>38 THEN HPOS=2:POSITION 3,VPOS:? "←";
1049 IF HPOS<2 THEN HPOS=38:POSITION 37,VPOS:? "→";
1050 FOR I=1 TO 5:K=RND(0):NEXT I
1060 IF STRIG(0)=0 THEN X=PEEK(93):? "●";:GOTO 1080
1065 IF PEEK(53279)=6 THEN 2010
1070 GOTO 1010
1075 REM INTERPRET BETS
1080 I=VPOS*37+HPOS-1:BET=ASC(BET$(I,I))
1085 IF BET=0 THEN ? "↰":GOSUB 4110:? "←";:GOTO 1010
1090 IF BET<39 THEN 1200
1100 IF BET=39 THEN 1260
1110 IF BET>39 AND BET<98 THEN 1310
1120 IF BET>97 AND BET<101 THEN 1410
1130 IF BET>100 AND BET<113 THEN 1440
1140 IF BET>112 AND BET<125 THEN 1480
1150 IF BET>124 AND BET<147 THEN 1520
1160 BET=BET-146:ON BET GOTO 1550,1560,1570,1580,1590,1600,1610,1620,1630
1190 REM RECORD VARIOUS BETS
1200 REM STRAIGHT BET
1205 IF BET=37 THEN POSITION 2,15:? "↑↑BET ON 0 (Y/N)";:GOSUB 4310:GOTO 1240
1206 IF BET=38 THEN POSITION 2,15:? "↑↑BET ON 00 (Y/N)";:GOSUB 4310:GOTO 1240
1210 POSITION 2,15:? "↑↑BET ON ";BET;" (Y/N)";:GOSUB 4310
1240 STR(BET)=STR(BET)+AMT:GOTO 1000
1250 REM 5 LINE BET
1260 POSITION 2,15:? "↑↑LINE BET (5) (Y/N)";:GOSUB 4310
1290 LN5=LN5+AMT:GOTO 1000
1300 REM SPLIT BET
1310 POSITION 2,15:BET=BET-39
1320 IF BET<34 THEN ? "↑↑SPLIT BET ON ";BET;",";BET+3;" (Y/N)";:GOTO 1360
1330 IF BET=58 THEN ? "↑↑SPLIT BET ON 0,00 (Y/N)";:GOTO 1360
1340 J=BET-33:J=J+INT((J-1)/2)
1350 ? "↑↑SPLIT BET ON ";J;",";J+1;" (Y/N)";
1360 GOSUB 4310
1390 SPLIT(BET)=SPLIT(BET)+AMT:GOTO 1000
1400 REM COLUMN BET
1410 POSITION 2,15:? "↑↑BET ON COLUMN ";BET-97;" (Y/N)";:GOSUB 4310
1420 COL(BET-97)=COL(BET-97)+AMT:GOTO 1000
1430 REM STREET BET
1440 BET=BET-100:POSITION 2,15:? "↑↑BET ON STREET ";BET+2*BET-2;",";BET+2*BET-1;",";BET+2*BET;" (Y/N)";
1450 GOSUB 4310
1460 STREET(BET)=STREET(BET)+AMT:GOTO 1000
1470 REM LINE SIX BET
1480 BET=BET-112:J=BET+(BET-1)*2:POSITION 2,15
1485 ? "↑↑LINE BET ON ";J;",";J+1;",";J+2;",";J+3;",";J+4;",";J+5;" (Y/N)";
1490 GOSUB 4310
1500 LN6(BET)=LN6(BET)+AMT:GOTO 1000
1510 REM SQUARE BET
1520 BET=BET-124:J=BET+INT((BET-1)/2):POSITION 2,15:? "↑↑BET ON SQUARE ";J;",";J+1;",";J+3;",";J+4;" (Y/N)";
1530 GOSUB 4310
1540 SQRE(BET)=SQRE(BET)+AMT:GOTO 1000
1550 POSITION 2,15:? "↑↑BET ON 19-36 (Y/N)";:GOSUB 4310:HI=HI+AMT:GOTO 1000
1560 POSITION 2,15:? "↑↑BET ON 1-18 (Y/N)";:GOSUB 4310:LO=LO+AMT:GOTO 1000
1570 POSITION 2,15:? "↑↑BET ON ODD NUMBERS (Y/N)";:GOSUB 4310:ODD=ODD+AMT:GOTO 1000
1580 POSITION 2,15:? "↑↑BET ON EVEN NUMBERS (Y/N)";:GOSUB 4310:EVEN=EVEN+AMT:GOTO 1000
1590 POSITION 2,15:? "↑↑BET ON RED NUMBERS (Y/N)";:GOSUB 4310:RED=RED+AMT:GOTO 1000
1600 POSITION 2,15:? "↑↑BET ON BLACK NUMBERS (Y/N)";:GOSUB 4310:BLACK=BLACK+AMT:GOTO 1000
1610 POSITION 2,15:? "↑↑BET ON 1ST DOZEN (Y/N)";:GOSUB 4310:DZN1=DZN1+AMT:GOTO 1000
1620 POSITION 2,15:? "↑↑BET ON 2ND DOZEN (Y/N)";:GOSUB 4310:DZN2=DZN2+AMT:GOTO 1000
1630 POSITION 2,15:? "↑↑BET ON 3RD DOZEN (Y/N)";:GOSUB 4310:DZN3=DZN3+AMT:GOTO 1000
2000 REM SPIN THE WHEEL
2010 POSITION 2,12:? "↑↑↑↑↑↑";:POKE 752,1
2020 X=INT(200*RND(0)):IF X<76 OR X>190 THEN 2020
2022 ? "WINNING NUMBER IS: ";
2024 FOR I=0 TO X-1:POSITION 21,12:J=((OLDNO+I)-38*INT((OLDNO+I)/38))+1:? " ←←";
2026 IF WHEEL(J)=37 THEN ? "0":GOTO 2032
2028 IF WHEEL(J)=38 THEN ? "00":GOTO 2032
2030 ? WHEEL(J)
2032 FOR DELAY=1 TO 5:NEXT DELAY:NEXT I
2040 NUM=WHEEL(J):OLDNO=J:POKE 752,0
3000 REM CALCULATE WINNINGS
3005 POSITION 2,14
3010 REM STRAIGHTS
3020 IF STR(NUM) THEN WIN=WIN+35*STR(NUM):CASH=CASH+STR(NUM):? "WIN STRAIGHT BET:";35*STR(NUM)
3030 REM FIVE LINE
3040 IF LN5 AND (NUM<4 OR NUM>36) THEN WIN=WIN+6*LN5:CASH=CASH+LN5:? "WIN LINE BET (5):";6*LN5
3050 REM SPLITS
3060 FOR I=1 TO 33
3062 IF NOT (SPLIT(I) AND (NUM=I OR NUM=I+3)) THEN 3065
3063 WIN=WIN+17*SPLIT(I):CASH=CASH+SPLIT(I):? "WIN SPLIT BET:";17*SPLIT(I)
3065 NEXT I
3067 FOR I=34 TO 57:J=I-33:J=J+INT((J-1)/2)
3070 IF NOT (SPLIT(I) AND (NUM=J OR NUM=J+1)) THEN 3072
3071 WIN=WIN+17*SPLIT(I):CASH=CASH+SPLIT(I):? "WIN SPLIT BET:";17*SPLIT(I)
3072 NEXT I
3075 IF NOT (SPLIT(58) AND (NUM=37 OR NUM=38)) THEN 3090
3077 WIN=WIN+17*SPLIT(58):CASH=CASH+SPLIT(58):? "WIN SPLIT:";17*SPLIT(58)
3080 REM DROP OUT 0 AND 00
3090 IF NUM>36 THEN 3410
3100 REM COLUMNS
3110 IF INT(NUM/3)=NUM/3 AND COL(3) THEN WIN=WIN+2*COL(3):CASH=CASH+COL(3):? "WIN COLUMN 3 BET:";2*COL(3)
3120 IF INT((NUM+1)/3)=(NUM+1)/3 AND COL(2) THEN WIN=WIN+2*COL(2):CASH=CASH+COL(2):? "WIN COLUMN 2 BET:";2*COL(2)
3130 IF INT((NUM+2)/3)=(NUM+2)/3 AND COL(1) THEN WIN=WIN+2*COL(1):CASH=CASH+COL(1):? "WIN COLUMN 1 BET:";2*COL(1)
3140 REM STREETS
3150 STCNT=NUM:I=0
3160 STCNT=STCNT-3:I=I+1:IF STCNT<1 THEN 3180
3170 GOTO 3160
3180 IF STREET(I) THEN WIN=WIN+11*STREET(I):CASH=CASH+STREET(I):? "WIN STREET BET:";11*STREET(I)
3190 REM SIX LINE
3200 FOR J=1 TO 11
3210 IF LN6(J) AND (I=J OR I=J+1) THEN WIN=WIN+5*LN6(J):CASH=CASH+LN6(J):? "WIN LINE BET:";5*LN6(J)
3220 NEXT J
3230 REM SQUARES
3240 FOR I=1 TO 22
3250 SQ=INT((I-1)/2)
3260 IF SQRE(I) AND (NUM=I+SQ OR NUM=I+SQ+1 OR NUM=I+SQ+3 OR NUM=I+SQ+4) THEN GOSUB 4430
3270 NEXT I
3280 REM HIGH/LOW
3290 IF HI AND NUM>18 AND NUM<37 THEN WIN=WIN+HI:CASH=CASH+HI:? "WIN 19-36 BET:";HI
3300 IF LO AND NUM<19 THEN WIN=WIN+LO:CASH=CASH+LO:? "WIN 1-18 BET:";LO
3310 REM ODD/EVEN
3320 IF ODD AND INT(NUM/2)<NUM/2 THEN WIN=WIN+ODD:CASH=CASH+ODD:? "WIN ODD BET:";ODD
3330 IF EVEN AND INT(NUM/2)=NUM/2 THEN WIN=WIN+EVEN:CASH=CASH+EVEN:? "WIN EVEN BET:";EVEN
3340 REM BLACK/RED
3350 IF RED AND COLR$(NUM,NUM)="R" THEN WIN=WIN+RED:CASH=CASH+RED:? "WIN RED BET:";RED
3360 IF BLACK AND COLR$(NUM,NUM)="B" THEN WIN=WIN+BLACK:CASH=CASH+BLACK:? "WIN BLACK BET:";BLACK
3370 REM DOZENS
3380 IF DZN1 AND NUM<13 THEN WIN=WIN+2*DZN1:CASH=CASH+DZN1:? "WIN 1ST DOZEN BET:";2*DZN1
3390 IF DZN2 AND NUM>11 AND NUM<25 THEN WIN=WIN+2*DZN2:CASH=CASH+DZN2:? "WIN 2ND DOZEN BET:";2*DZN2
3400 IF DZN3 AND NUM>24 THEN WIN=WIN+2*DZN3:CASH=CASH+DZN3:? "WIN 3RD DOZEN BET:";2*DZN3
3410 GOSUB 4470
3500 REM DISPLAY WINNINGS
3510 ? "CASH=";CASH;" WINNINGS=";WIN
3520 CASH=CASH+WIN:WIN=0:IF CASH=0 THEN 4400
3530 ? "PRESS RETURN TO CONTINUE":? "OR ENTER 'Q' TO QUIT";:INPUT A$
3540 IF A$<>"Q" THEN 500
3550 IF CASH>500 THEN ? :? "CONGRATULATIONS. YOU WON $";CASH-500:END
3560 IF CASH<500 THEN ? :? "SORRY. YOU LOST $";500-CASH:END
3570 ? :? "YOU BROKE EVEN. IT COULD BE WORSE.":END
4100 REM GRIDFIX SUBROUTINE
4110 IF X>64 AND X<91 THEN X=X-64:GOTO 4130
4120 IF X<64 THEN X=X+32
4130 POSITION HPOS,VPOS:? CHR$(X);:RETURN
4200 REM CHECK CASH SUBROUTINE
4210 IF CASH-AMT<0 THEN ? "↰NOT ENOUGH MONEY":GOSUB 4110:GOTO 4230
4220 CASH=CASH-AMT:POSITION 2,12:? "CASH AVAILABLE: $ ←←←←←";CASH
4230 RETURN
4300 REM PLACE BET SUBROUTINE
4305 TRAP 4520
4310 INPUT A$:IF A$<>"Y" THEN GOSUB 4110:? "←";:GOTO 1010
4320 ? "AMOUNT";:INPUT AMT:IF AMT=0 THEN GOSUB 4110:? "←";:GOTO 1010
4330 GOSUB 4210
4340 RETURN
4400 REM GONE BROKE
4410 ? "SORRY, YOU'RE BROKE":? "▶TRY AGAIN (Y/N)";:INPUT A$:IF A$="Y" THEN 440
4420 END
4430 REM SQUARE WIN SUBROUTINE
4440 WIN=WIN+8*SQRE(I):CASH=CASH+SQRE(I):? "WIN SQUARE BET:";8*SQRE(I)
4450 RETURN
4460 REM ZERO ALL BETS
4470 HI=0:LO=0:ODD=0:EVEN=0:BLACK=0:RED=0:DZN1=0:DZN2=0:DZN3=0:COL(1)=0:COL(2)=0:COL(3)=0:LN5=0
4480 FOR I=1 TO 38:STR(I)=0:NEXT I:FOR I=1 TO 12:STREET(I)=0:NEXT I:FOR I=1 TO 11:LN6(I)=0:NEXT I
4490 FOR I=1 TO 22:SQRE(I)=0:NEXT I:FOR I=1 TO 58:SPLIT(I)=0:NEXT I
4500 RETURN
4510 REM INPUT ERROR
4520 POP :GOSUB 4110:GOTO 1000
5000 REM DRAW BOARD
5010 ? "↰":POSITION 2,0:? "┌──┬─┬─┬─┬──┬──┬──┬──┬──┬──┬──┬──┬──┐ | |3|6|9|12|15|18|21|24|27|30|33|36|"
5020 POSITION 2,2:? "| 0├─┼─┼─┼──┼──┼──┼──┼──┼──┼──┼──┼──┤ ├──┤2|5|8|11|14|17|20|23|26|29|32|35|"
5030 POSITION 2,4:? "|00├─┼─┼─┼──┼──┼──┼──┼──┼──┼──┼──┼──┤ | |1|4|7|10|13|16|19|22|25|28|31|34|"
5040 POSITION 2,6:? "└──┼─┴─┴─┴──┼──┴──┴──┴──┼──┴──┴──┴──┤ | 1ST 12 | 2ND 12 | 3RD 12 |"
5050 POSITION 2,8:? " ├────┬───┼─────┬─────┼─────┬─────┤ |1-18|EVN| RED |BLACK| ODD |19-36|"
5060 POSITION 2,10:? " └────┴───┴─────┴─────┴─────┴─────┘":RETURN
6130 REM WHEEL CONFIGURATION
6140 DATA 38,27,10,25,29,12,8,19,31,18,6,21,33,16,4,23,35,14,2,37,28,9,26,30
6150 DATA 11,7,20,32,17,5,22,34,15,3,24,36,13,1
