World Interface (INTRFACE.BAS)

World Interface by John W. Little, 71 (BASIC, MAC/65 source)

Description

World Interface by John W. Little, 71 (BASIC, MAC/65 source)

From the Antic disk of February 1989 (Vol. 7 No. 10) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 6.2 KB

Dialect
Atari BASIC
Lines
154
Variables
A800, X, BYTE, YN$, ON, OFF, PORTA, PACTL, ORIG, CONSOL, HOUR, MIN, SEC, T, TIMEON, EARLYHOUR, LATEHOUR, ONOFF, SECON, MINON, HR, HRON, SECOFF, MINOFF, HROFF, STARTMINS, STARTSECS, STARTHOUR, ENDSEC, ENDMIN, ENDHOUR, TIMEOFF
BASIC listing (154 lines)
1 REM REAL-WORLD INTERFACE
2 REM BY JOHN W. LITTLE
3 REM (c)1988, ANTIC PUBLISHING
5 A800=0:REM CHANGE TO A 1 FOR PORTB ON AN ATARI 400/800
6 IF  NOT (A800=0 OR A800=1) THEN ? "TYPING ERROR LINE 5!↰":END
10 GRAPHICS 2+16:? #6:? #6:? #6;"    REAL":? #6:? #6;"    WORLD":? #6:? #6;"    INTERFACE"
12 RESTORE 7000:FOR X=1664 TO 1761:READ BYTE:POKE X,BYTE:NEXT X:X=USR(1664)
20 POKE 752,1:REM KILL CURSOR
30 REM DECLARATIONS
50 DIM YN$(1):LET ON=0:OFF=1
60 PORTA=54016:PACTL=54018:ORIG=PEEK(54018+A800):CONSOL=53279
80 REM INITIALIZE CLOCK
100 ? "↰":POSITION 4,2:? "DO YOU WISH TO RESET THE CLOCK";:YN$=" ":INPUT YN$
110 IF ASC(YN$)<>89 THEN IF ASC(YN$)<>121 THEN 130:REM Y OR y
120 GOTO 150
130 IF ASC(YN$)<>78 THEN IF ASC(YN$)<>110 THEN 100:REM N or n
140 GOTO 300
150 ? "↰":POSITION 11,2:? "SET REALTIME CLOCK":? :? :?
160 HOUR=0:MIN=0:SEC=0
170 ? "Correct Hour(0-23)";:TRAP 180:INPUT HOUR:?
180 ? "Correct Minute";:TRAP 190:INPUT MIN:?
190 ? "Correct Second";:TRAP 200:INPUT SEC
200 ? "↰":POSITION 13,2:? "REALTIME CLOCK"
210 POSITION 9,23:? "Press START to continue"
220 POKE 18,MIN:POKE 19,SEC:POKE 20,0:POKE 209,0:POKE 208,0:POKE 207,HOUR:X=USR(1664)
224 REM DISPLAY CLOCK
230 POSITION 16,10:POKE 752,1
231 T=PEEK(207):IF T>9 THEN ? T;:? ":";:GOTO 233
232 ? "0";:? T;:? ":";
233 T=PEEK(18):IF T>9 THEN ? T;:? ":";:GOTO 235
234 ? "0";:? T;:? ":";
235 T=PEEK(19):IF T>9 THEN ? T:GOTO 240
236 ? "0";:? T
240 IF PEEK(CONSOL)=7 THEN 230
270 REM MAIN PROGRAM
300 ? "↰":POKE 710,0:POKE 82,1:REM SETUP SCREEN
320 REM CONFIG. PORT FOR OUTPUT
340 POKE PACTL+A800,ORIG-4:POKE PORTA+A800,255:POKE PACTL+A800,ORIG
360 REM GET TIMING PARAMETERS
380 GOSUB 880
390 IF TIMEON=0 THEN 1260:REM MANUAL OPERATION
400 GOSUB 1110
403 REM START TIMING
410 POSITION 5,23:? "Press any key to begin timing";:POKE 764,255:POKE 752,1
411 IF PEEK(764)=255 THEN GOSUB 840:GOSUB 1410:GOTO 411
412 POSITION 5,23:? "                             ";
420 REM IS CURRENT TIME BETWEEN EARLIEST AND LATEST START TIMES?
440 IF EARLYHOUR>PEEK(207) THEN GOSUB 1410:GOSUB 840:GOTO 440
450 IF LATEHOUR>PEEK(207) THEN 500
460 GOSUB 840:GOSUB 1410:GOTO 440
480 REM RELAY OPERATION LOOP
500 LET ONOFF=ON:SEC=SECON:MIN=MINON:HR=HRON:GOSUB 600
510 LET ONOFF=OFF:SEC=SECOFF:MIN=MINOFF:HR=HROFF:GOSUB 600
520 GOTO 440
580 REM TIMING SUBROUTINE
600 STARTMINS=PEEK(18):STARTSECS=PEEK(19):STARTHOUR=PEEK(207):REM GET CURRENT TIME
610 POKE PORTA+A800,ONOFF:REM CLOSE OR OPEN RELAY
620 REM ADJUST COUNTER IF #OF SECS TO COUNT + #OF SECS CURRENTLY ON CLOCK > 59
640 IF SEC+STARTSECS>59 THEN STARTMINS=STARTMINS+1:LET ENDSEC=SEC+STARTSECS-60:GOTO 690
650 LET ENDSEC=SEC+STARTSECS
670 REM ADJUST COUNTER IF #OF SECS TO COUNT + #OF SECS CURRENTLY ON CLOCK > 59
690 IF MIN+STARTMINS>59 THEN STARTHOUR=STARTHOUR+1:LET ENDMIN=MIN+STARTMINS-60:GOTO 705
700 LET ENDMIN=MIN+STARTMINS
705 LET ENDHOUR=HR+STARTHOUR
710 IF ENDHOUR<24 THEN 770
720 LET ENDHOUR=ENDHOUR-24
729 REM WAIT FOR CURRENT HOUR TO CROSS MIDNIGHT AND BECOME "0".
730 IF PEEK(207)>ENDHOUR THEN GOSUB 840:GOSUB 1410:GOTO 730
750 REM WAIT FOR HOURS, MINS, SECS TO COUNT DOWN
770 GOSUB 840:IF PEEK(CONSOL)<7 THEN 1410
780 IF ENDHOUR>PEEK(207) THEN 770
790 GOSUB 840:IF PEEK(CONSOL)<7 THEN 1410
800 IF ENDMIN>PEEK(18) THEN 790
810 GOSUB 840:IF PEEK(CONSOL)<7 THEN 1410
820 IF ENDSEC>PEEK(19) THEN 810
830 RETURN
835 REM DISPLAY TIME
840 POSITION 16,1
841 T=PEEK(207):IF T>9 THEN ? T;:? ":";:GOTO 843
842 ? "0";:? T;:? ":";
843 T=PEEK(18):IF T>9 THEN ? T;:? ":";:GOTO 845
844 ? "0";:? T;:? ":";
845 T=PEEK(19):IF T>9 THEN ? T:GOTO 847
846 ? "0";:? T
847 RETURN
860 REM INPUT DATA SUBROUTINES
880 POSITION 1,6:? "--------------------------------------"
881 POSITION 7,7:? "PRESS RETURN TO DISREGARD.":?
882 POSITION 1,8:? "--------------------------------------"
890 TRAP 940
900 ? "EARLIEST HOUR TO TURN WATER ON";:INPUT EARLYHOUR
910 TRAP 930
920 ? "LATEST HOUR TO TURN WATER ON";:INPUT LATEHOUR:GOTO 980
930 ? "↰":? "↰":GOTO 880
940 EARLYHOUR=0:LATEHOUR=24
950 ? "↰":POSITION 1,2:? "--------------------------------------"
960 POSITION 1,3:? "  NO EARLIEST AND LATEST START TIMES  "
970 ? "--------------------------------------":GOTO 1010
980 ? "↰":POSITION 1,2:? "--------------------------------------":POSITION 1,3:? " EARLIEST START:";EARLYHOUR;
990 POSITION 20,3:? "  LATEST START:";LATEHOUR;"  "
1000 ? "--------------------------------------"
1010 ? :? "PRESS RETURN 3 TIMES TO BYPASS TIMER.":?
1020 HRON=0:MINON=0:SECON=0
1021 TRAP 1030
1022 ? "NUMBER OF HOURS WATER WILL BE ON";
1023 INPUT HRON
1030 TRAP 1060
1040 ? "NUMBER OF MINUTES WATER WILL BE ON";
1050 INPUT MINON
1060 TRAP 1090
1070 ? "NUMBER OF SECONDS WATER WILL BE ON";
1080 INPUT SECON
1090 TIMEON=HRON+MINON+SECON:REM For test in line 390
1100 RETURN
1110 HROFF=0:MINOFF=0:SECOFF=0
1111 TRAP 1120
1112 ? :? "NUMBER OF HOURS WATER WILL BE OFF";
1113 INPUT HROFF
1120 TRAP 1150
1130 ? "NUMBER OF MINUTES WATER WILL BE OFF";
1140 INPUT MINOFF
1150 TRAP 1180
1160 ? "NUMBER OF SECONDS WATER WILL BE OFF";
1170 INPUT SECOFF
1180 TIMEOFF=HROFF+MINOFF+SECOFF:REM For test in line 1190
1190 IF TIMEOFF=0 THEN ? "↰";"↰":? "You must specify an 'OFF' period in    order to use the timer.":POP :GOTO 380
1200 ? :? "OPTION TO STOP CYCLE WITH WATER ON.":? "SELECT TO STOP CYCLE WITH WATER OFF."
1210 ? "START TO RE-START PROGRAM":? "WITHOUT RESETTING CLOCK."
1220 RETURN
1240 REM MANUAL ON/OFF ROUTINES
1260 LET ONOFF=ON
1270 TRAP 1270
1280 ? :? "Do you wish to turn the water on";
1290 GOSUB 1350
1300 TRAP 1300
1310 LET ONOFF=OFF
1320 ? "Do you wish to turn the water off";
1330 GOSUB 1350
1340 GRAPHICS 0:END
1350 YN$=" ":INPUT YN$
1360 IF ASC(YN$)<>89 THEN IF ASC(YN$)<>121 THEN 1390:REM Y OR y
1370 POKE PORTA+A800,ONOFF
1380 RETURN
1390 IF ASC(YN$)<>78 THEN IF ASC(YN$)<>110 THEN POP :GOTO 65536:REM N or n...65536 IS ERROR TO TRAP
1400 RETURN
1405 REM EARLY EXIT
1410 IF PEEK(CONSOL)=3 THEN POKE PORTA+A800,ON:POP :POSITION 1,20:POKE 752,0:END
1420 IF PEEK(CONSOL)=5 THEN POKE PORTA+A800,OFF:POP :POSITION 1,20:POKE 752,0:END
1430 IF PEEK(CONSOL)=6 THEN POP :GOTO 300
1440 RETURN
7000 DATA 104,162,6,160,139,169,7,32,92,228,96,230,208,208,2,230,209,165,208,201,15,144,26,165,209
7010 DATA 201,3,144,20,169,0,133,208,133,209,165,20,201,60,144,6,169,1,133,20,208,12,230,20,165
7020 DATA 20,201,60,144,40,169,0,133,20,230,19,165,19,201,60,144,28,169,0,133,19,230,18,165,18
7030 DATA 201,60,144,16,169,0,133,18,230,207,165,207,201,24,144,4,169,0,133,207,76,98,228