String Equivalence Demo (EQUIV2.BAS)
String Equivalence Demo by Doug White, 35
Description
String Equivalence Demo by Doug White, 35
From the Antic disk of February 1989 (Vol. 7 No. 10) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 4.2 KB
- Dialect
- Atari BASIC
- Lines
- 171
- Variables
ASIZE,S$,M(,V$,DELAY$,VNTST,VNTEND,VVTST,STARP,SVNUM,VNUM,AVNUM,AOFFSETLO,OFFSETLO,AOFFSETHI,OFFSETHI,ADIM1LO,VDIM1LO,ADIM1HI,VDIM1HI,ADIM2LO,VDIM2LO,ADIM2HI,VDIM2HI,FIRSTDIM,SECONDIM,SSIZE,HBYTE,LBYTE,VVLOC,I,N,SEC,J,CH,AD,ADHI,ADLO
BASIC listing (171 lines)
10 REM STRING EQUIVALENCE, LISTING 2
20 REM BY DOUG WHITE
30 REM (c)1988, ANTIC PUBLISHING
40 ? "↰":? " STRING EQUIVALENCE DEMO"
50 ? :? "INPUT ARRAY SIZE ( < 4000 ) ";
60 INPUT ASIZE
65 IF ASIZE>3999 THEN 50
67 IF ASIZE<10 THEN ASIZE=10
70 REM
80 DIM S$(1),M(ASIZE)
90 DIM V$(20)
100 DIM DELAY$(1)
110 REM
120 REM . FIND MEMORY LOCATIONS
130 REM . FOR THE STRING AND THE
140 REM . ARRAY THAT ARE TO BE
150 REM . EQUIVALENCED.
160 REM
170 VNTST=PEEK(130)+256*PEEK(131)
180 VNTEND=PEEK(132)+256*PEEK(133)-1
190 VVTST=PEEK(134)+256*PEEK(135)
200 STARP=PEEK(140)+256*PEEK(141)
210 REM
220 V$="S$":REM . THE DATA 'STRING'
230 GOSUB 2000
240 SVNUM=VNUM
250 REM
260 V$="M(":REM . THE DATA 'ARRAY'
270 GOSUB 2000
280 AVNUM=VNUM
290 AOFFSETLO=OFFSETLO
300 AOFFSETHI=OFFSETHI
310 ADIM1LO=VDIM1LO:ADIM1HI=VDIM1HI
320 ADIM2LO=VDIM2LO:ADIM2HI=VDIM2HI
330 REM
340 REM . REDIMENSION THE STRING &
350 REM . SET THE STRING OFFSET
360 REM . EQUAL TO THE ARRAY OFFSET
370 REM
380 FIRSTDIM=ADIM1LO+256*ADIM1HI
390 SECONDIM=ADIM2LO+256*ADIM2HI
400 SSIZE=6*FIRSTDIM*SECONDIM
410 HBYTE=INT(SSIZE/256)
420 LBYTE=SSIZE-256*HBYTE
430 REM
440 VVLOC=VVTST+(SVNUM)*8
450 POKE VVLOC+2,AOFFSETLO
460 POKE VVLOC+3,AOFFSETHI
470 POKE VVLOC+4,LBYTE
480 POKE VVLOC+5,HBYTE
490 POKE VVLOC+6,LBYTE
500 POKE VVLOC+7,HBYTE
510 REM
520 ? :? "FILL M() WITH #'S 1 TO ASIZE"
530 REM
540 FOR I=0 TO ASIZE:M(I)=I:NEXT I
550 REM
560 ? :? "WRITE M() TO DISK"
570 REM
580 CLOSE #1
590 OPEN #1,8,0,"D1:ARRAY.DAT"
600 POKE 18,0:POKE 19,0:POKE 20,0
610 FOR I=0 TO ASIZE
620 N=M(I)
630 ? #1;N
635 REM . FOR TURBO BASIC, USE:
640 REM %PUT #1,N
650 NEXT I
660 GOSUB 1500:REM GET TIME
670 REM
680 ? :? "WRITE S$ TO DISK"
690 REM
700 CLOSE #1
710 OPEN #1,8,0,"D1:STRING.DAT"
720 POKE 18,0:POKE 19,0:POKE 20,0
730 ? #1;S$
735 REM . FOR TURBO BASIC, USE:
740 REM BPUT #1,ADR(S$),SSIZE
750 GOSUB 1500:REM GET TIME
760 REM
770 CLOSE #1
780 ? :? "PRESS RETURN TO CONTINUE"
790 INPUT DELAY$
800 REM
810 ? :? "FILL M() WITH ONES"
820 REM
830 POKE 18,0:POKE 19,0:POKE 20,0
840 FOR I=0 TO ASIZE:M(I)=1:NEXT I
850 GOSUB 1500:REM GET TIME
860 GOSUB 1600:REM PRINT M(1 TO 5)
870 REM
880 ? :? "FILL M() WITH 3'S"
890 ? "BY COPYING SUBSTRINGS IN S$"
900 REM
910 POKE 18,0:POKE 19,0:POKE 20,0
920 M(0)=3:REM M(0) = S$(1,6)
930 S$(7)=S$(1)
940 GOSUB 1500:REM GET TIME
950 GOSUB 1600:REM PRINT M(1 TO 5)
960 REM
970 ? :? "PRESS RETURN TO CONTINUE"
980 INPUT DELAY$
990 REM
1000 REM
1010 ? :? "REFILL M() WITH DATA BY "
1020 ? "READING 'D1:ARRAY.DAT' INTO M()"
1030 REM
1040 OPEN #1,4,0,"D1:ARRAY.DAT"
1050 POKE 18,0:POKE 19,0:POKE 20,0
1060 FOR I=0 TO ASIZE
1070 INPUT #1;N
1075 REM . FOR TURBO BASIC, USE:
1080 REM %GET #1,N
1090 M(I)=N
1100 NEXT I
1110 GOSUB 1500:REM GET TIME
1120 CLOSE #1
1130 REM
1140 ? :? "REFILL M() WITH DATA BY "
1150 ? "READING 'D1:STRING.DAT' INTO S$"
1160 REM
1170 OPEN #1,4,0,"D1:STRING.DAT"
1180 POKE 18,0:POKE 19,0:POKE 20,0
1190 TRAP 1220:I=0
1200 GOSUB 3000:REM CIO METHOD
1205 REM . FOR TURBO BASIC, USE:
1210 REM BGET #1,ADR(S$),SSIZE
1220 GOSUB 1500:REM GET TIME
1230 GOSUB 1600:REM PRINT M(1 TO 5)
1240 CLOSE #1
1250 END
1500 REM $ GET TIME
1510 REM
1520 SEC=(PEEK(20)+256*PEEK(19))/60
1530 ? :? INT(1000*SEC)/1000;
1540 ? " SECONDS"
1550 RETURN
1600 REM $ PRINT M(1 TO 5)
1610 ?
1620 FOR I=1 TO 5
1630 ? "M(";I;") = ";M(I)
1640 NEXT I
1650 RETURN
2000 REM $ FIND VARIABLE #
2010 REM
2020 J=0:VNUM=-1
2030 FOR I=VNTST TO VNTEND
2040 CH=PEEK(I)
2050 J=J+1
2060 IF CH>128 THEN CH=CH-128:VNUM=VNUM+1
2070 IF CHR$(CH)<>V$(J,J) THEN J=0:GOTO 2090
2080 IF J=LEN(V$) THEN 2100
2090 NEXT I
2100 REM
2110 REM FIND VARIABLE LOCATION
2120 REM
2130 VVLOC=VVTST+(VNUM)*8
2140 OFFSETLO=PEEK(VVLOC+2)
2150 OFFSETHI=PEEK(VVLOC+3)
2160 VDIM1LO=PEEK(VVLOC+4)
2170 VDIM1HI=PEEK(VVLOC+5)
2180 VDIM2LO=PEEK(VVLOC+6)
2190 VDIM2HI=PEEK(VVLOC+7)
2200 ? :? "V$ = ";V$;" VNUM = ";VNUM
2210 RETURN
2999 REM CIO METHOD
3000 AD=ADR(S$):ADHI=INT(AD/256):ADLO=AD-ADHI*256
3010 I=848:POKE I+2,7:POKE I+4,ADLO:POKE I+5,ADHI:POKE I+8,255:POKE I+9,255
3030 N=USR(ADR("hhh*LVd"),16)
3040 N=PEEK(I+9)*256+PEEK(I+8)
3050 RETURN
