Talking Math Wizard voice editor (WIZTALK.BAS)

Talking Math Wizard voice editor, 11

Description

Talking Math Wizard voice editor, 11

From the Antic disk of January 1989 (Vol. 7 No. 9).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.3 KB

Dialect
Atari BASIC
Lines
37
Variables
LEARN, SSAVE, I, SPEAK, J, CLEAR, BASE, TM, A$
BASIC listing (37 lines)
2 REM MATH WIZARD VOCABULARY LEARNER
4 REM BY MATTHEW RATCLIFF
6 REM (c)1988, ANTIC PUBLISHING
10 GRAPHICS 0:? "MATH WIZARD VOCABULARY LEARNER."
20 ? "A joystick should be in Port 1."
30 ? "Press [FIRE] to accept word."
40 ? "Pull back on stick to relearn a word.":? "(VM800 MUST be loaded FIRST)"
50 CLEAR=USR(1682):REM CLEAR
60 I=0:BASE=16384:DIM A$(40)
70 RESTORE 280
80 READ A$:IF A$="END" THEN GOTO 100
90 GOSUB 180:GOTO 80
100 ? :? "SPEECH DATA INPUT COMPLETE.":? "SAVING DATA FILE."
110 SSAVE=USR(1766,ADR("D:WIZTALK.SPK")):REM SSAVE "D:WIZTALK.SPK"
120 ? "FINAL ";:GOSUB 250
130 FOR I=0 TO 31
140 SPEAK=USR(1676,I):REM SPEAK(I)
150 FOR J=1 TO 20:NEXT J
160 NEXT I
170 END
180 ? "LEARN WORD '";A$;"'":POKE 77,0
190 LEARN=USR(1670,(I)):REM LEARN(I)
200 FOR J=1 TO 50:NEXT J
210 SPEAK=USR(1676,(I)):REM SPEAK(I)
220 IF  NOT (STRIG(0)) THEN I=I+1:GOTO 250
230 IF STICK(0)<>15 THEN ? "RE-";:GOTO 180
240 GOTO 220
250 TM=PEEK(BASE+256)+256*PEEK(BASE+257)
260 ? "SPEECH DATA SIZE = ";TM-BASE+256
270 RETURN
280 DATA ZERO,ONE,TWO,THREE,FOUR,FIVE
290 DATA SIX,SEVEN,EIGHT,NINE,TEN
300 DATA ELEVEN,TWELVE,THIRTEEN,FOURTEEN,FIFTEEN
310 DATA SIXTEEN,SEVENTEEN,EIGHTEEN,NINETEEN,TWENTY
320 DATA THIRTY,FOURTY,FIFTY,SIXTY,SEVENTY
330 DATA EIGHTY,NINETY,PLUS,MINUS,TIMES,EQUALS
340 DATA END