Happyface Reversi (REVERSI.BAS)
Happyface Reversi by Edward Brown, 147
Description
Happyface Reversi by Edward Brown, 147
From the Antic disk of January 1989 (Vol. 7 No. 9).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 17.9 KB
- Dialect
- Atari BASIC
- Lines
- 341
- Variables
K,CY,Y,X,D,C,STRT,WAIT,BOARD(,VALUE(,SCORE(,GP$,PP$,MES$,HC$,C1,A,CRY,CRX,DL,S,C2,I,M,PMBAS,O,CXP,CYP,SWITCH,ST,TURN,CYT,XC,YC,LEGAL,ENEMY,X2,Y2,LAST,CHK,COL,TOP,YES,XT,YT,PF,B,AV,BV,AE,BE,V,E,EN,CXT,STK,BACK
BASIC listing (341 lines)
2 REM HAPPYFACE REVERSI
3 REM BY EDWARD BROWN
4 REM (c)1988, ANTIC PUBLISHING
5 GOTO 1535
10 REM DISABLE BREAK
15 RETURN :K=USR(ADR("h)p┐♣▔▂R)♥┐M◆")):RETURN
25 REM PURPLE THING
30 COLOR 1:FOR CY=Y TO Y-7 STEP -1:PLOT X,CY:DRAWTO X-8,CY:NEXT CY
35 COLOR 0:PLOT X-5,Y-6:PLOT X-5,Y-5:PLOT X-3,Y-6:PLOT X-3,Y-5
40 PLOT X-6,Y-1:DRAWTO X-2,Y-1:PLOT X-7,Y-2:PLOT X-6,Y-2:PLOT X-4,Y-2:DRAWTO X-1,Y-2
45 PLOT X-7,Y-3:PLOT X-1,Y-3:COLOR 0:LOCATE 155,89,D:RETURN
50 REM GREEN THING
55 COLOR 2:FOR CY=Y TO Y-7 STEP -1:PLOT X,CY:DRAWTO X-8,CY:NEXT CY
60 COLOR 0:PLOT X-5,Y-6:PLOT X-5,Y-5:PLOT X-3,Y-6:PLOT X-3,Y-5
65 PLOT X-5,Y-1:DRAWTO X-3,Y-1:PLOT X-5,Y-2:DRAWTO X-3,Y-2:PLOT X-6,Y-3:PLOT X-2,Y-3:COLOR 0:LOCATE 155,89,D
70 RETURN
75 REM TITLE SCREEN
80 GRAPHICS 7:GOSUB 1700:POKE 710,74
85 COLOR 3:PLOT 23,48:DRAWTO 42,21:DRAWTO 54,30:DRAWTO 34,34:DRAWTO 49,49:PLOT 65,35
90 DRAWTO 55,41:DRAWTO 65,48:PLOT 55,41:DRAWTO 65,41:PLOT 71,35:DRAWTO 75,47
95 DRAWTO 81,35:PLOT 94,35:DRAWTO 85,41:DRAWTO 93,48:PLOT 85,41:DRAWTO 94,41
100 PLOT 103,36:DRAWTO 98,49:PLOT 102,39:DRAWTO 109,37:DRAWTO 111,39:PLOT 123,38
105 DRAWTO 113,44:DRAWTO 122,42:DRAWTO 111,52:PLOT 128,49:DRAWTO 132,38:PLOT 135,33
110 POKE 752,1:? " |D|E|L|U|X|E ":? " by Edward Brown":? " press START"
115 C=1:STRT=0
120 Y=15:FOR X=31 TO 136 STEP 15:SOUND 0,28,6,8:IF C=1 THEN GOSUB 55:GOTO 130
125 GOSUB 30
130 IF PEEK(53279)=6 THEN STRT=1
135 WAIT=1:GOSUB 1460:SOUND 0,0,0,0:NEXT X
140 Y=75:FOR X=136 TO 31 STEP -15:SOUND 0,50,6,8:IF C=1 THEN GOSUB 30:GOTO 150
145 GOSUB 55
150 IF PEEK(53279)=6 THEN STRT=1
155 WAIT=1:GOSUB 1460:SOUND 0,0,0,0:NEXT X:IF STRT=0 THEN C=1-C:GOTO 120
160 RETURN
165 REM INITIALIZE
170 DIM BOARD(10,10),VALUE(10,10),SCORE(2),GP$(2),PP$(2),MES$(38),HC$(2)
175 RESTORE :FOR C=0 TO 9:FOR C1=0 TO 9:BOARD(C,C1)=0:READ A:VALUE(C,C1)=A:NEXT C1:NEXT C:CRY=1:CRX=1
180 BOARD(4,4)=1:BOARD(5,5)=1:BOARD(4,5)=2:BOARD(5,4)=2:SCORE(1)=2:SCORE(2)=2
185 DATA 0,0,0,0,0,0,0,0,0,0
190 DATA 0,0,6,2,3,3,2,6,0,0,0,6,6,4,4,4,4,6,6,0
195 DATA 0,2,4,1,2,2,1,4,2,0,0,3,4,2,7,7,2,4,3,0
200 DATA 0,3,4,2,7,7,2,4,3,0,0,2,4,1,2,2,1,4,2,0
205 DATA 0,6,6,4,4,4,4,6,6,0,0,0,6,2,3,3,2,6,0,0
210 DATA 0,0,0,0,0,0,0,0,0,0
215 RETURN
220 REM DRAW BOARD
225 GRAPHICS 23:GOSUB 1700
230 DL=PEEK(560)+PEEK(561)*256+4:POKE DL+93,2:POKE DL+94,65:POKE DL+137,PEEK(560):POKE DL+138,PEEK(561)
235 C=C-48:IF A=78 THEN 275
240 IF HC$="P" THEN S=1
245 IF HC$="G" THEN S=2
250 C1=1:C2=1
255 X=31+C1*12-2:Y=1+C2*11-2:BOARD(C1,C2)=S:SCORE(S)=SCORE(S)+1:IF S=1 THEN GOSUB 30
260 IF S=2 THEN GOSUB 55
265 C=C-1:IF C>0 THEN C2=C2+7:IF C2>8 THEN C2=1:C1=8
270 IF C>0 THEN 255
275 COLOR 3:FOR X=31 TO 127 STEP 12:PLOT X,1:DRAWTO X,89:NEXT X
280 FOR Y=1 TO 89 STEP 11:PLOT 31,Y:DRAWTO 127,Y:NEXT Y
285 X=31+(4*12)-2:Y=1+(4*11)-2:GOSUB 30:X=31+(5*12)-2:Y=1+(5*11)-2:GOSUB 30
290 X=31+(4*12)-2:Y=1+(5*11)-2:GOSUB 55:X=31+(5*12)-2:Y=1+(4*11)-2:GOSUB 55
295 I=PEEK(106)-8:POKE 54279,M
300 PMBAS=M*256
305 FOR C=PMBAS+512 TO PMBAS+640:POKE C,O:NEXT C
310 CXP=81:CYP=22:POKE 704,15:POKE 559,46:POKE 53277,3
315 POKE 623,0:POKE 53248,CXP:POKE PMBAS+512+CYP,12
320 RETURN
325 REM MOVE CURSOR
330 SWITCH=0:ST=STICK(TURN-1):CYT=CYP:IF ST=15 THEN 375
335 XC=(ST=5 OR ST=6 OR ST=7)-(ST=9 OR ST=10 OR ST=11):CRX=CRX+XC:CXP=CXP+12*XC
340 IF CXP>165 THEN CXP=81:CRX=1
345 IF CXP<81 THEN CXP=165:CRX=8
350 YC=(ST=5 OR ST=9 OR ST=13)-(ST=6 OR ST=10 OR ST=14):CRY=CRY+YC:CYP=CYP+11*YC
355 IF CYP>99 THEN CYP=22:CRY=1
360 IF CYP<22 THEN CYP=99:CRY=8
365 POKE PMBAS+512+CYT,0:POKE 53248,CXP:POKE PMBAS+512+CYP,12
370 SOUND 0,6,6,6:WAIT=10:GOSUB 1460:SOUND 0,0,0,0
375 IF STRIG(TURN-1)=1 AND PEEK(764)<>33 AND PEEK(53279)=7 THEN 330
380 IF PEEK(764)=33 THEN 395
385 IF PEEK(53279)<>7 THEN GOSUB 1480:SWITCH=1:GOTO 395
390 IF BOARD(CRX,CRY)<>0 THEN SOUND 0,41,2,6:WAIT=10:GOSUB 1460:SOUND 0,0,0,0:GOTO 330
395 RETURN
400 REM VALID? & SCORE
405 LEGAL=0:ENEMY=2:IF TURN=2 THEN ENEMY=1
410 IF BOARD(CRX,CRY)<>0 THEN 495
415 FOR C=-1 TO 1:FOR C1=-1 TO 1:IF C=0 AND C1=0 THEN 490
420 IF BOARD(CRX+C,CRY+C1)<>ENEMY THEN 490
425 X2=CRX+C:Y2=CRY+C1:LAST=0
430 IF BOARD(X2+C,Y2+C1)=ENEMY THEN X2=X2+C:Y2=Y2+C1:GOTO 430
435 IF BOARD(X2+C,Y2+C1)=0 THEN 490
440 IF CHK THEN 470
445 X=31+X2*12-2:Y=1+Y2*11-2:IF BOARD(X2,Y2)<>TURN THEN SCORE(TURN)=SCORE(TURN)+1
450 IF BOARD(X2,Y2)=ENEMY THEN SCORE(ENEMY)=SCORE(ENEMY)-1
455 BOARD(X2,Y2)=TURN
460 IF TURN=1 THEN GOSUB 30
465 IF TURN=2 THEN GOSUB 55
470 IF LAST THEN 485
475 X2=X2-C:Y2=Y2-C1:IF X2=CRX AND Y2=CRY THEN LAST=1:GOTO 440
480 GOTO 440
485 LEGAL=1
490 NEXT C1:NEXT C
495 RETURN
500 REM TURN INDICATOR
505 COLOR 0:IF TURN=2 THEN 520
510 PLOT 130,35:DRAWTO 140,45:DRAWTO 130,55:PLOT 130,45:DRAWTO 140,45
515 COLOR 1:PLOT 28,35:DRAWTO 18,45:DRAWTO 28,55:PLOT 18,45:DRAWTO 28,45:GOTO 530
520 PLOT 28,35:DRAWTO 18,45:DRAWTO 28,55:PLOT 18,45:DRAWTO 28,45
525 COLOR 2:PLOT 130,35:DRAWTO 140,45:DRAWTO 130,55:PLOT 130,45:DRAWTO 140,45
530 COLOR 0:LOCATE 155,89,D:RETURN
535 REM WINNER!
540 IF SCORE(1)>SCORE(2) THEN COL=7:MES$=" Purple wins! "
545 IF SCORE(2)>SCORE(1) THEN COL=12:MES$=" Green wins! "
550 IF SCORE(2)=SCORE(1) THEN COL=5:MES$=" Tie Score! "
555 GOSUB 585:POSITION 0,0:? SCORE(1);MES$;SCORE(2):GOSUB 605
560 FOR C=15 TO 0 STEP -1:SETCOLOR 2,COL,C
565 FOR C1=1 TO 6:SOUND 0,253+C1,2,C:NEXT C1:NEXT C
570 IF STRIG(0)=1 AND STRIG(1)=1 THEN 560
575 SOUND 0,0,0,0:RETURN
580 REM TEXT WINDOW
585 POKE 87,0:TOP=PEEK(88)+PEEK(89)*256
590 TOP=TOP+3681:POKE 88,TOP-(INT(TOP/256)*256):POKE 89,INT(TOP/256):POSITION 0,0
595 RETURN
600 REM GRAPHICS WINDOW
605 POKE 87,7:TOP=TOP-3681:POKE 88,TOP-(INT(TOP/256)*256):POKE 89,INT(TOP/256):POSITION 0,0
610 RETURN
615 REM CHK FOR LEGAL MOVES
620 YES=0:CHK=1:XT=CRX:YT=CRY:GOSUB 585:? " Checking... ":GOSUB 605
625 FOR CRX=1 TO 8:FOR CRY=1 TO 8:IF BOARD(CRX,CRY)=0 THEN GOSUB 405:IF LEGAL THEN YES=1
630 NEXT CRY:NEXT CRX
635 IF NOT YES THEN 650
640 IF YES THEN GOSUB 585:POSITION 0,0:? " Yes you do! ":GOSUB 605
645 SOUND 0,41,2,6:WAIT=160:GOSUB 1460:SOUND 0,0,0,0
650 CRX=XT:CRY=YT:RETURN
655 REM RECALC. VALUE & COMPUTER MOVE
660 GOSUB 585:POSITION 0,0:? " Thinking... ":GOSUB 605
665 ENEMY=3-TURN:FOR C=1 TO 8:FOR C1=1 TO 8 STEP 7:IF BOARD(C,C1)<>0 THEN PF=PF+1
670 IF BOARD(C1,C)<>0 THEN PF=PF+1
675 NEXT C1:NEXT C:IF PF=0 THEN 1390
680 REM CORNER BORDERS
685 FOR C=2 TO 7 STEP 5:FOR C1=1 TO 8 STEP 7:VALUE(C,C1)=6:VALUE(C1,C)=6:NEXT C1:NEXT C
690 REM OPPONENT BORDERS
695 FOR C=3 TO 6:FOR C1=1 TO 8 STEP 7:IF BOARD(C-1,C1)=TURN OR BOARD(C+1,C1)=TURN THEN VALUE(C,C1)=5
700 IF BOARD(C1,C-1)=TURN OR BOARD(C1,C+1)=TURN THEN VALUE(C1,C)=5
705 NEXT C1:NEXT C
710 REM IN BETWEEN MOVES
715 FOR C=3 TO 6:FOR C1=1 TO 8 STEP 7:IF BOARD(C,C1)<>0 THEN 880
720 IF BOARD(C-1,C1)<>TURN OR BOARD(C+1,C1)<>TURN THEN 770
725 S=0:FOR C2=C-2 TO 1 STEP -1:IF BOARD(C2,C1)=0 AND S=0 THEN S=1
730 IF BOARD(C2,C1)=ENEMY AND BOARD(C2-1,C1)=TURN AND S=0 THEN S=1
735 NEXT C2:IF S=1 THEN S=0:GOTO 745
740 GOTO 880
745 FOR C2=C+2 TO 8:IF BOARD(C2,C1)=0 AND S=0 THEN S=1
750 IF BOARD(C2,C1)=ENEMY AND BOARD(C2+1,C)=TURN AND S=0 THEN S=1
755 NEXT C2:IF S=1 THEN VALUE(C,C1)=2:GOTO 880
760 VALUE(C,C1)=5:GOTO 880
765 REM CHECK IN-BETWEEN DEFENSE
770 IF BOARD(C-1,C1)<>ENEMY OR BOARD(C+1,C1)<>TURN THEN 825
775 S=0:FOR C2=C+2 TO 8:IF BOARD(C2,C1)=0 AND S=0 THEN S=1
780 IF BOARD(C2,C1)=ENEMY AND S=0 THEN S=2
785 IF BOARD(C2,C1)=0 AND S=2 THEN S=3
790 IF BOARD(C2,C1)=TURN AND S=2 THEN S=1
795 NEXT C2:IF S=1 THEN S=0:GOTO 805
800 GOTO 880
805 FOR C2=C-2 TO 1 STEP -1:IF BOARD(C2,C1)=TURN AND S=0 THEN S=1
810 IF BOARD(C2,C1)=0 AND S=0 THEN S=2
815 NEXT C2:IF S=1 THEN VALUE(C,C1)=1:GOTO 825
820 VALUE(C,C1)=5
825 IF BOARD(C+1,C1)<>ENEMY OR BOARD(C-1,C1)<>TURN THEN 880
830 S=0:FOR C2=C-2 TO 1 STEP -1:IF BOARD(C2,C1)=0 AND S=0 THEN S=1
835 IF BOARD(C2,C1)=ENEMY AND S=0 THEN S=2
840 IF BOARD(C2,C1)=0 AND S=2 THEN S=3
845 IF BOARD(C2,C1)=TURN AND S=2 THEN S=1
850 NEXT C2:IF S=1 THEN S=0:GOTO 860
855 GOTO 880
860 FOR C2=C+2 TO 8:IF BOARD(C2,C1)=TURN AND S=0 THEN S=1
865 IF BOARD(C2,C1)=0 AND S=0 THEN S=2
870 NEXT C2:IF S=1 THEN VALUE(C,C1)=1:GOTO 880
875 VALUE(C,C1)=S
880 IF BOARD(C1,C)<>0 THEN 1030
885 IF BOARD(C1,C-1)<>TURN OR BOARD(C1,C+1)<>TURN THEN 930
890 S=0:FOR C2=C-2 TO 1 STEP -1:IF BOARD(C1,C2)=0 AND S=0 THEN S=1
895 IF BOARD(C1,C2)=ENEMY AND BOARD(C1,C2-1)=TURN AND S=0 THEN S=1
900 NEXT C2:IF S<>1 THEN 1030
905 S=0:FOR C2=C+2 TO 8:IF BOARD(C1,C2)=0 AND S=0 THEN S=1
910 IF BOARD(C1,C2)=ENEMY AND BOARD(C1,C2+1)=TURN AND S=0 THEN S=1
915 NEXT C2:IF S=1 THEN VALUE(C1,C)=2:GOTO 925
920 VALUE(C1,C)=5
925 GOTO 1030
930 IF BOARD(C1,C-1)<>ENEMY OR BOARD(C1,C+1)<>TURN THEN 980
935 S=0:FOR C2=C+2 TO 8:IF BOARD(C1,C2)=0 AND S=0 THEN S=1
940 IF BOARD(C1,C2)=ENEMY AND S=0 THEN S=2
945 IF BOARD(C1,C2)=0 AND S=2 THEN S=3
950 IF BOARD(C1,C2)=TURN AND S=2 THEN S=1
955 NEXT C2:IF S<>1 THEN 1030
960 S=0:FOR C2=C-2 TO 1 STEP -1:IF BOARD(C1,C2)=TURN AND S=0 THEN S=1
965 IF BOARD(C1,C2)=0 AND S=0 THEN S=2
970 NEXT C2:IF S=1 THEN VALUE(C1,C)=1:GOTO 980
975 VALUE(C1,C)=5
980 IF BOARD(C1,C+1)<>ENEMY OR BOARD(C1,C-1)<>TURN THEN 1030
985 S=0:FOR C2=C-2 TO 1 STEP -1:IF BOARD(C1,C2)=0 AND S=0 THEN S=1
990 IF BOARD(C1,C2)=ENEMY AND S=0 THEN S=2
995 IF BOARD(C1,C2)=0 AND S=2 THEN S=3
1000 IF BOARD(C1,C2)=TURN AND S=2 THEN S=1
1005 NEXT C2:IF S<>1 THEN 1030
1010 S=0:FOR C2=C+2 TO 8:IF BOARD(C1,C2)=TURN AND S=0 THEN S=1
1015 IF BOARD(C1,C2)=0 AND S=0 THEN S=2
1020 NEXT C2:IF S=1 THEN VALUE(C1,C)=1:GOTO 1030
1025 VALUE(C1,C)=5
1030 NEXT C1:NEXT C
1035 REM EDGE UNDER ATTACK?
1040 FOR C=3 TO 6:FOR C1=1 TO 8 STEP 7:IF BOARD(C,C1)<>ENEMY OR BOARD(C-1,C1)<>TURN THEN 1075
1045 S=0:FOR C2=C+1 TO 8:IF BOARD(C2,C1)=0 AND S=0 THEN S=1
1050 IF BOARD(C2,C1)=TURN AND S=0 THEN S=2
1055 NEXT C2:IF S<>1 THEN 1075
1060 S=0:FOR C2=C-2 TO 2 STEP -1:IF BOARD(C2,C1)=ENEMY AND S=0 THEN S=1
1065 IF BOARD(C2,C1)=0 AND BOARD(C2-1,C1)<>TURN AND S=0 THEN S=1:VALUE(C2,C1)=1
1070 NEXT C2
1075 IF BOARD(C,C1)<>ENEMY OR BOARD(C+1,C1)<>TURN THEN 1110
1080 S=0:FOR C2=C-1 TO 1 STEP -1:IF BOARD(C2,C1)=0 AND S=0 THEN S=1
1085 IF BOARD(C2,C1)=TURN AND S=0 THEN S=2
1090 NEXT C2:IF S<>1 THEN 1110
1095 S=0:FOR C2=C+2 TO 7:IF BOARD(C2,C1)=ENEMY AND S=0 THEN S=1
1100 IF BOARD(C2,C1)=0 AND BOARD(C2+1,C1)<>TURN AND S=0 THEN S=1:VALUE(C2,C1)=1
1105 NEXT C2
1110 IF BOARD(C1,C)<>ENEMY OR BOARD(C1,C-1)<>TURN THEN 1145
1115 S=0:FOR C2=C+1 TO 8:IF BOARD(C1,C2)=0 AND S=0 THEN S=1
1120 IF BOARD(C1,C2)=TURN AND S=0 THEN S=2
1125 NEXT C2:IF S<>1 THEN 1145
1130 S=0:FOR C2=C-2 TO 2 STEP -1:IF BOARD(C1,C2)=ENEMY AND S=0 THEN S=1
1135 IF BOARD(C1,C2)=0 AND BOARD(C1,C2-1)<>TURN AND S=0 THEN S=1:VALUE(C1,C2)=1
1140 NEXT C2
1145 IF BOARD(C1,C)<>ENEMY OR BOARD(C1,C+1)<>TURN THEN 1180
1150 S=0:FOR C2=C-1 TO 1 STEP -1:IF BOARD(C1,C2)=0 AND S=0 THEN S=1
1155 IF BOARD(C1,C2)=TURN AND S=0 THEN S=2
1160 NEXT C2:IF S<>1 THEN 1180
1165 S=0:FOR C2=C+2 TO 7:IF BOARD(C1,C2)=ENEMY AND S=0 THEN S=1
1170 IF BOARD(C1,C2)=0 AND BOARD(C1,C2+1)<>TURN AND S=0 THEN S=1:VALUE(C1,C2)=1
1175 NEXT C2
1180 NEXT C1:NEXT C
1185 REM COMPUTER HOLDS CORNERS?
1190 A=1:B=1:AV=1:BV=1:AE=7:BE=7
1195 IF BOARD(A,B)<>0 THEN VALUE(A+AV,B+BV)=4
1200 IF BOARD(A,B)<>ENEMY THEN 1250
1205 S=0:FOR C2=A+AV TO AE STEP AV:IF BOARD(C2,B)=0 AND S=0 THEN VALUE(C2,B)=2:S=1
1210 IF BOARD(C2,B)=TURN AND S=0 THEN S=2
1215 IF BOARD(C2,B)=ENEMY AND S=2 THEN S=1
1220 IF BOARD(C2,B)=0 AND S=2 THEN VALUE(C2,B)=2:S=1
1225 NEXT C2:S=0:FOR C2=B+BV TO BE STEP BV:IF BOARD(A,C2)=0 AND S=0 THEN VALUE(A,C2)=2:S=1
1230 IF BOARD(A,C2)=TURN AND S=0 THEN S=2
1235 IF BOARD(A,C2)=ENEMY AND S=2 THEN S=1
1240 IF BOARD(A,C2)=0 AND S=2 THEN VALUE(A,C2)=2:S=1
1245 NEXT C2
1250 IF A=1 AND B=1 THEN B=8:BV=-1:BE=2:GOTO 1195
1255 IF A=1 AND B=8 THEN A=8:AV=-1:AE=2:GOTO 1195
1260 IF A=8 AND B=8 THEN B=1:BV=1:BE=7:GOTO 1195
1265 REM CORNER IN-BETWEEN MOVES?
1270 A=1:B=1:V=1:E=7
1275 IF BOARD(A,B)<>0 THEN 1310
1280 IF BOARD(A,B-V)<>TURN OR BOARD(A,B+V)<>TURN THEN 1310
1285 S=0:FOR C2=B+2*V TO E STEP V:IF BOARD(A,C2)=0 AND S=0 THEN S=1
1290 IF BOARD(A,C2)=ENEMY AND S=0 THEN S=2
1295 IF BOARD(A,C2)=TURN AND S=2 THEN S=1
1300 IF BOARD(A,C2)=0 AND S=2 THEN S=3
1305 NEXT C2:IF S<2 THEN VALUE(A,B)=2
1310 IF BOARD(B,A)<>0 THEN 1340
1315 S=0:FOR C2=B+2*V TO E STEP V:IF BOARD(C2,A)=0 AND S=0 THEN S=1
1320 IF BOARD(C2,A)=ENEMY AND S=0 THEN S=2
1325 IF BOARD(C2,A)=TURN AND S=2 THEN S=1
1330 IF BOARD(C2,A)=0 AND S=2 THEN S=3
1335 NEXT C2:IF S<2 THEN VALUE(B,A)=2
1340 IF A=1 AND B=2 THEN B=7:V=-1:E=2:GOTO 1275
1345 IF A=1 AND B=7 THEN A=8:V=1:E=7:GOTO 1275
1350 IF A=8 AND B=2 THEN B=7:V=-1:E=2:GOTO 1275
1355 REM CORNERS VULNERABLE?
1360 EN=ENEMY
1365 IF BOARD(1,1)=0 AND BOARD(2,2)=TURN THEN IF BOARD(1,3)=EN OR BOARD(3,1)=EN THEN VALUE(1,3)=5:VALUE(3,1)=5
1370 IF BOARD(1,8)=0 AND BOARD(2,7)=TURN THEN IF BOARD(1,6)=EN OR BOARD(3,8)=EN THEN VALUE(1,6)=5:VALUE(3,8)=5
1375 IF BOARD(8,1)=0 AND BOARD(7,2)=TURN THEN IF BOARD(6,1)=EN OR BOARD(8,3)=EN THEN VALUE(6,1)=5:VALUE(8,3)=5
1380 IF BOARD(8,8)=0 AND BOARD(7,7)=TURN THEN IF BOARD(6,8)=EN OR BOARD(8,6)=EN THEN VALUE(6,8)=5:VALUE(8,6)=5
1385 REM FIGURE COMPUTER MOVE
1390 GOSUB 1445:CXT=CRX:CYT=CRY:V=0:ENEMY=3-TURN:CRX=1:CRY=1
1395 IF VALUE(CRX,CRY)<>V THEN 1415
1400 IF BOARD(CRX,CRY)<>0 THEN 1415
1405 S=0:FOR C=-1 TO 1:FOR C1=-1 TO 1:IF BOARD(CRX+C,CRY+C1)=ENEMY THEN S=S+1
1410 NEXT C1:NEXT C:IF S>0 THEN CHK=0:GOSUB 405:IF LEGAL THEN STK=0:GOTO 1435
1415 CRY=CRY+1:IF CRY>8 THEN CRY=1:CRX=CRX+1
1420 IF CRX>8 THEN CRY=1:CRX=1:V=V+1
1425 IF V<7 THEN 1395
1430 GOSUB 585:POSITION 0,0:? "↰ I have no valid move ":WAIT=160:GOSUB 1460:GOSUB 605:STK=STK+1
1435 CRX=CXT:CRY=CYT:RETURN
1440 REM RESET ATTRACT MODE
1445 IF PEEK(77)>50 THEN BACK=PEEK(559):POKE 77,0:POKE 559,0:POKE 559,BACK
1450 RETURN
1455 REM WAIT
1460 POKE 20,0
1465 IF PEEK(20)<WAIT THEN 1465
1470 RETURN
1475 REM SWITCH PLAYERS
1480 OPEN #4,4,0,"K:":GOSUB 585
1485 POSITION 0,0:? " Switch Purple to ";
1490 IF PP$="H" THEN ? "Computer (Y,N)? ":GET #4,A:IF A=89 THEN PP$="C":GOTO 1500
1495 IF PP$="C" THEN ? "Human (Y,N)? ":GET #4,A:IF A=89 THEN PP$="H"
1500 IF A<>89 AND A<>78 THEN 1485
1505 POSITION 0,0:? " Switch Green to ";
1510 IF GP$="H" THEN ? "Computer (Y,N)? ":GET #4,A:IF A=89 THEN GP$="C":GOTO 1520
1515 IF GP$="C" THEN ? "Human (Y,N)? ":GET #4,A:IF A=89 THEN GP$="H"
1520 IF A<>89 AND A<>78 THEN 1505
1525 GOSUB 605:CLOSE #4:RETURN
1530 REM MAIN PROGRAM
1535 CLR :GOSUB 170:M=PEEK(106):M=M-16:POKE 106,M
1540 GOSUB 80
1545 OPEN #4,4,0,"K:"
1550 GRAPHICS 17:GOSUB 1700:POKE 711,24:POKE 712,96
1555 POSITION 0,5:? #6;"PURPLE player Human or Computer?"
1560 GET #4,A:PP$=CHR$(A):IF PP$<>"H" AND PP$<>"C" THEN 1550
1565 POSITION 0,8:? #6;"green player human or computer?"
1570 GET #4,A:GP$=CHR$(A):IF GP$<>"H" AND GP$<>"C" THEN 1565
1575 GRAPHICS 17:GOSUB 1700
1580 POSITION 0,5:? #6;"HANDICAP (Y OR N)?":GET #4,A:IF A<>78 AND A<>89 THEN 1580
1585 IF A=78 THEN 1600
1590 POSITION 0,8:? #6;"IN FAVOR OF PURPLE OR gREEN?":GET #4,A:HC$=CHR$(A):IF A<>80 AND A<>71 THEN 1590
1595 POSITION 0,11:? #6;"HOW MANY CORNERS (1-4)?":GET #4,C:IF C<49 OR C>52 THEN 1595
1600 CLOSE #4:GOSUB 225
1605 TURN=1:IF PP$="C" THEN GOSUB 505:GOSUB 660:GOTO 1640
1610 GOSUB 585:POSITION 0,0:? " Press SPACE BAR if no legal move":GOSUB 605
1615 GOSUB 505:GOSUB 330:IF PEEK(764)=33 THEN POKE 764,255:GOSUB 620:IF NOT YES THEN CHK=0:STK=STK+1:GOTO 1640
1620 IF CHK THEN CHK=0:GOTO 1605
1625 IF SWITCH THEN 1605
1630 GOSUB 405:IF NOT LEGAL THEN SOUND 0,41,2,6:FOR C=1 TO 30:NEXT C:SOUND 0,0,0,0:GOTO 1615
1635 STK=0
1640 IF SCORE(1)+SCORE(2)=64 OR SCORE(1)=0 OR SCORE(2)=0 OR STK=2 THEN 1685
1645 TURN=2:IF GP$="C" THEN GOSUB 505:GOSUB 660:GOTO 1680
1650 GOSUB 585:POSITION 0,0:? " Press SPACE BAR if no legal move":GOSUB 605
1655 GOSUB 505:GOSUB 330:IF PEEK(764)=33 THEN POKE 764,255:GOSUB 620:IF NOT YES THEN CHK=0:STK=STK+1:GOTO 1680
1660 IF CHK THEN CHK=0:GOTO 1645
1665 IF SWITCH THEN 1645
1670 GOSUB 405:IF NOT LEGAL THEN SOUND 0,41,2,6:FOR C=1 TO 30:NEXT C:SOUND 0,0,0,0:GOTO 1655
1675 STK=0
1680 IF SCORE(1)+SCORE(2)<>64 AND SCORE(1)<>0 AND SCORE(2)<>0 AND STK<2 THEN 1690
1685 POKE 53248,0:GOSUB 540:GOSUB 175:GOTO 1545
1690 GOTO 1605
1700 POKE 708,86:POKE 709,196:POKE 710,232:GOSUB 15:RETURN
