Talking Math Wizard (MATHWIZ.BAS)

Talking Math Wizard by Matthew Ratcliff, 223 (BASIC, text)

Description

Talking Math Wizard by Matthew Ratcliff, 223 (BASIC, text)

From the Antic disk of January 1989 (Vol. 7 No. 9).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 10.0 KB

Dialect
Atari BASIC
Lines
250
Variables
K, L, Z, GTX$, B$, CX$, ML$, PBA(, PBB(, SPEECHLEN, SPEECH$, IO, AD, CMND, NM, SPEAK, CX, GX, PNT(, ANS(, MIX(, A$, C$, W$, MIN, MAX, TYPE, PCNT, ROUNDS, BPCT, DIF, TH, HSCR, SCORE, W, X, ROUND, A, Y, I, Q, B, C, J, ANSW, XX, X1, TOK, PC, SEL, WAIT, HOLDS, PROB, II, SPEECH, IOCB, ADH, ADL, NMH, NML, ERR
BASIC listing (250 lines)
2 REM MATH WIZARD
4 REM BY MATTHEW RATCLIFF
6 REM (c)1988, ANTIC PUBLISHING
7 GOTO 10
8 K=USR(ADR("h)p┐♣▔▂R)♥┐M◆")):RETURN
10 L=1:Z=0:DIM GTX$(333),B$(40),CX$(55),ML$(402),PBA(6),PBB(6)
20 GTX$(L)=" ":CX$(L)=" ":ML$(L)=" "
30 GTX$(333,333)=" ":CX$(55,55)=" ":ML$(402,402)=" "
40 GTX$(2)=GTX$:CX$(2)=CX$:ML$(2)=ML$
50 SPEECHLEN=12000:DIM SPEECH$(SPEECHLEN)
60 GRAPHICS Z:GOSUB 8
70 CLOSE #L:OPEN #L,4,Z,"D:MATH.SYS"
80 ? "LOADING USR ROUTINES"
90 IO=L:AD=ADR(GTX$):CMND=7:NM=333:GOSUB 2390
100 AD=ADR(CX$):NM=55:GOSUB 2390
110 AD=ADR(ML$):NM=402:GOSUB 2390
120 CLOSE #L
130 SPEAK=ADR(ML$):CX=ADR(CX$):GX=ADR(GTX$)
140 ? "LOADING SPEECH DATA"
150 SPEECH$="D:WIZTALK.SPK":GOSUB 2280
160 GOSUB 2210
170 DIM PNT(6),ANS(6),MIX(6),A$(40),C$(40),W$(10)
180 MIN=5:MAX=10:TYPE=L:PCNT=6:ROUNDS=4:BPCT=Z:DIF=2:TH=L:HSCR=Z:SCORE=Z
190 GOTO 990
200 FOR W=15 TO Z STEP -3:SOUND Z,25*(X+1),10,W:NEXT W:RETURN
210 A$="ROUND # ":A$(9)=STR$(ROUND)
220 A=USR(GX,ADR(A$),LEN(A$),48,48)
230 A=USR(GX,ADR("COMPLETED"),9,48,56)
240 A$="BONUS = ":A$(9)=STR$(176-Y)
250 SCORE=SCORE+176-Y
260 A=USR(GX,ADR(A$),LEN(A$),48,72)
270 A$="SCORE = ":A$(9)=STR$(SCORE):A=USR(GX,ADR(A$),LEN(A$),48,84)
280 FOR I=L TO 50
290 A=240*RND(Z):FOR Q=Z TO 15 STEP 5
300 SOUND Z,A,10,Q:SOUND L,A+5,10,Q:NEXT Q:NEXT I
310 SOUND Z,Z,Z,Z:SOUND L,Z,Z,Z:RETURN
320 ON TYPE GOTO 330,340,350
330 B$="   +     +     +     +     +     +   ":GOTO 360
340 B$="   -     -     -     -     -     -   ":GOTO 360
350 B$="   x     x     x     x     x     x   "
360 FOR I=L TO 6:MIX(I)=I
370 A=INT(MAX*RND(Z))+MIN:IF A>MAX THEN 370
380 B=INT(MAX*RND(Z))+MIN:IF B>MAX THEN 380
390 IF B>A THEN C=A:A=B:B=C
400 IF I=L THEN 440
410 FOR J=L TO I
420 IF PBA(J)=A AND PBB(J)=B THEN 370
430 NEXT J
440 ON TYPE GOTO 450,460,470
450 ANS(I)=A+B:GOTO 480
460 ANS(I)=A-B:GOTO 480
470 ANS(I)=A*B
480 C=6*(I-L)+2:B$(C,C+L)=STR$(A):B$(C+3,C+4)=STR$(B)
490 PBA(I)=A:PBB(I)=B
500 NEXT I
510 FOR I=6 TO L STEP -L:PNT(I)=L
520 A=INT(I*RND(Z))+L
530 B=MIX(A):MIX(A)=MIX(I):MIX(I)=B:NEXT I
540 RETURN
550 GRAPHICS 24:GOSUB 8:POKE 710,Z:A=USR(CX,INT(255*RND(Z)))
560 ON TYPE GOTO 570,580,590
570 A=USR(GX,ADR("+ ADDITION +"),12,112,Z):GOTO 600
580 A=USR(GX,ADR("- SUBTRACTION -"),15,96,Z):GOTO 600
590 A=USR(GX,ADR("x MULTIPLICATION x"),18,88,Z)
600 FOR J=Z TO 6:FOR I=16 TO 176 STEP 8
610 A=USR(GX,ADR(" "),L,J*48,I)
620 NEXT I:NEXT J
630 RETURN
640 SCORE=SCORE+ANSW:PNT(X+L)=Z
650 W$=B$(6*X+L,6*X+7):FOR I=Y TO 16 STEP -2
660 SOUND Z,I,10,5:SOUND Z,I+5,10,5
670 A=USR(GX,ADR(W$),7,XX-24,I):COLOR 1:PLOT XX+4,I+8
680 NEXT I
690 W$="=":W$(2)=STR$(ANSW):IF ANSW<10 THEN W$(LEN(W$)+L)="   ":GOTO 720
700 IF ANSW<100 THEN W$(LEN(W$)+L)="  ":GOTO 720
710 W$(LEN(W$)+L)=" "
720 A=USR(GX,ADR(W$),LEN(W$),XX-16,24):B$(6*X+2,6*X+6)="     ":GOSUB 310
730 COLOR Z:PLOT XX+4,184
740 DRAWTO XX+4,32
750 A=240*RND(Z):FOR Q=Z TO 15 STEP 5
760 SOUND Z,A,10,Q:SOUND L,A+5,10,Q:NEXT Q:GOSUB 310
770 NM=PBA(X+L):GOSUB 2110
780 A=USR(SPEAK,TYPE+27,15,2,34)
790 NM=PBB(X+L):GOSUB 2110
800 A=USR(SPEAK,31,15,2,34)
810 NM=ANSW:GOSUB 2110
820 RETURN
830 X1=X:FOR I=15 TO Z STEP -0.2:SOUND Z,256*RND(Z),8,I:NEXT I
840 FOR W=1 TO 6:IF PNT(W)=Z THEN 870
850 X=W-L:XX=X*48+24:ANSW=ANS(W)
860 GOSUB 650:SCORE=SCORE-ANSW:TOK=TOK-L:GOSUB 950
870 NEXT W
880 XX=24+48*X1:X=X1:RETURN
890 A$="  ":A$(3)=STR$(PC):A$(LEN(A$)+1)="%"
900 A=USR(GX,ADR(A$),LEN(A$),48,48)
910 A=USR(GX,ADR("*REPEAT ROUND*"),14,48,56)
920 FOR I=15 TO Z STEP -0.05
930 SOUND Z,15*I,6,I:NEXT I
940 RETURN
950 PC=INT(100*(TOK/6))
960 A=USR(GX,ADR("%"),L,301,128):A$=STR$(PC):A$(LEN(A$)+L)=" "
970 FOR I=Z TO LEN(A$)-L:A=USR(GX,ADR(A$)+I,L,301,136+8*I):NEXT I
980 RETURN
990 GRAPHICS Z:GOSUB 8
1000 POKE 710,Z:POKE 752,L
1010 POSITION 4,Z:? "* MATH WIZARD II * By Mat Rat"
1020 ? "SCORE ";SCORE;" HIGH ";HSCR;" TYPE ";TH
1030 POSITION 2,2:? CHR$(17);:FOR I=3 TO 37:? CHR$(18);:NEXT I:? CHR$(5);
1040 POSITION 2,3:? CHR$(124);"USE STICK 0 ";CHR$(27);CHR$(31)
1050 POSITION 28,3:? CHR$(124);"UP/DN";CHR$(124);"L/R";CHR$(124);
1060 POSITION 2,4:? CHR$(1);:FOR I=3 TO 37:? CHR$(18);:NEXT I:? CHR$(4);
1070 FOR I=5 TO 19:POSITION 2,I:? CHR$(124);
1080 POSITION 28,I:? CHR$(124);:POSITION 34,I:? CHR$(124);
1090 POSITION 38,I:? CHR$(124);:NEXT I
1100 POSITION 2,20:? CHR$(26);:FOR I=3 TO 37:? CHR$(18);:NEXT I:? CHR$(3);
1110 RESTORE
1120 FOR I=L TO 12:READ X,Y,B$:POSITION X,Y:? B$;:NEXT I
1130 DATA 4,5,Minimum Starting #
1140 DATA 4,7,Maximum Starting #
1150 DATA 3,9,% Correct to Advance
1160 DATA 3,11,Difficulty Increment
1170 DATA 6,13,Rounds Per Game
1180 DATA 3,15,Problem Type
1190 DATA 4,17,(1) Addition
1200 DATA 4,18,(2) Subtraction
1210 DATA 4,19,(3) Multiplication
1220 DATA 2,21,Move STICK 0 UP/DOWN to Select Item
1230 DATA 2,22,Left-Decrease Right-Increase Value
1240 DATA 2,23,Press FIRE to Begin Game ESC to quit
1250 X=35:Y=5:SEL=L:WAIT=50
1260 FOR I=L TO 6
1270 POSITION X,Y
1280 ON I GOTO 1290,1300,1310,1320,1330,1340
1290 ? MIN;:GOTO 1350
1300 ? MAX;:GOTO 1350
1310 ? INT(100*PCNT/6);:GOTO 1350
1320 ? DIF;:GOTO 1350
1330 ? ROUNDS;:GOTO 1350
1340 ? TYPE;
1350 Y=Y+2:NEXT I
1360 FOR I=L TO 3:POSITION 4,16+I:? " ";:NEXT I
1370 POSITION 4,16+TYPE:? CHR$(27);CHR$(31);
1380 POSITION 30,2*SEL+3:? CHR$(148);
1390 A=STICK(Z):IF  NOT (STRIG(Z)) THEN 1720
1400 IF PEEK(764)=28 THEN POKE 764,255:GRAPHICS Z:END
1410 IF A=15 THEN POSITION 30,2*SEL+3:? CHR$(20);:WAIT=25:FOR I=L TO 15:NEXT I:GOTO 1380
1420 GOSUB 8:IF A=13 THEN B=SEL+L:GOTO 1460
1430 IF A=14 THEN B=SEL-L:GOTO 1460
1440 B=(A=7)-(A=11):IF B<>Z THEN GOTO 1500
1450 GOTO 1390
1460 POSITION 30,2*SEL+3:? " ";:SEL=B:IF SEL<1 THEN SEL=6
1470 IF SEL>6 THEN SEL=L
1480 FOR I=L TO 15:NEXT I:WAIT=50
1490 FOR W=15 TO Z STEP -5:SOUND Z,80,10,W:NEXT W:GOTO 1380
1500 ON SEL GOTO 1510,1540,1570,1600,1630,1660
1510 MIN=MIN+B:IF MIN<=Z THEN MIN=L
1520 IF MIN>MAX-5 THEN MIN=MAX-5
1530 POSITION X,5:? "  ";:POSITION X,5:? MIN;:GOTO 1690
1540 MAX=MAX+B:IF MAX>99 THEN MAX=99
1550 IF MAX<MIN+5 THEN MAX=MIN+5
1560 POSITION X,7:? "  ";:POSITION X,7:? MAX;:GOTO 1690
1570 PCNT=PCNT+B:IF PCNT>6 THEN PCNT=6
1580 IF PCNT<L THEN PCNT=L
1590 POSITION X,9:? "   ";:POSITION X,9:? INT(100*PCNT/6);:GOTO 1690
1600 DIF=DIF+B:IF DIF<L THEN DIF=L
1610 IF DIF>20 THEN DIF=20
1620 POSITION X,11:? "  ";:POSITION X,11:? DIF;:GOTO 1690
1630 ROUNDS=ROUNDS+B:IF ROUNDS>99 THEN ROUNDS=99
1640 IF ROUNDS<L THEN ROUNDS=L
1650 POSITION X,13:? "  ";:POSITION X,13:? ROUNDS;:GOTO 1690
1660 FOR I=L TO 3:POSITION 4,16+I:? " ";:NEXT I:TYPE=TYPE+B:IF TYPE<L THEN TYPE=L
1670 IF TYPE>3 THEN TYPE=3
1680 POSITION X,15:? TYPE;:POSITION 4,16+TYPE:? CHR$(27);CHR$(31);
1690 WAIT=WAIT-5:IF WAIT<L THEN WAIT=L
1700 SOUND Z,60,10,15:SOUND Z,Z,Z,Z
1710 FOR I=L TO WAIT:NEXT I:GOTO 1380
1720 SCORE=Z:X=2:XX=120:PCNT=INT(100*PCNT/6)
1730 ON TYPE GOTO 1740,1750,1760
1740 C$="  +  =":GOTO 1770
1750 C$="  -  =":GOTO 1770
1760 C$="  x  ="
1770 FOR ROUND=L TO ROUNDS
1780 GOSUB 550:GOSUB 320:A$="PROB 1  ROUND":Y=32:HOLDS=Z
1790 FOR I=Z TO LEN(A$)-L:A=USR(GX,ADR(A$)+I,L,301,8*I):NEXT I
1800 A$=STR$(ROUND):FOR I=Z TO LEN(A$)-L:A=USR(GX,ADR(A$)+I,L,301,112+8*I):NEXT I
1810 TOK=6:GOSUB 950
1820 FOR PROB=L TO 6:A$=STR$(PROB):A=USR(GX,ADR(A$),L,301,40)
1830 ANSW=ANS(MIX(PROB)):C$(7)="    ":C$(7)=STR$(ANSW):C$(LEN(C$)+L)="    "
1840 A=USR(GX,ADR(C$),LEN(C$),112,8)
1850 SOUND Z,60,10,10:W=L^L^L:SOUND Z,80,10,10:W=L^L^L:NM=ANSW:SOUND Z,Z,Z,Z:GOSUB 2110
1860 A=USR(GX,ADR(B$),37,Z,Y)
1870 A=USR(GX,ADR("♠"),L,XX,184)
1880 A=STICK(Z):GOSUB 8:IF A=15 THEN 1960
1890 IF A<>13 THEN 1930:REM THINKING?
1900 HOLDS=HOLDS+1
1910 IF STICK(0)=13 THEN 1910
1920 GOTO 1880
1930 X1=XX:X=X+(A=6 OR A=5 OR A=7)-(A=10 OR A=11 OR A=9):IF X<Z THEN X=Z
1940 IF X>5 THEN X=5
1950 XX=24+48*X:A=USR(GX,ADR(" "),L,X1,184):A=USR(GX,ADR("♠"),L,XX,184):GOSUB 200
1960 A=USR(GX,ADR("♠"),L,XX,184):IF STRIG(0) THEN 2010
1970 COLOR L:PLOT XX+4,184:DRAWTO XX+4,Y+8
1980 IF ANS(X+L)=ANSW AND PNT(X+L)=L THEN GOSUB 640:GOTO 2030
1990 COLOR Z:PLOT XX+4,184:DRAWTO XX+4,Y+8:TOK=TOK-1:GOSUB 950
2000 FOR I=15 TO Z STEP -0.2:SOUND Z,255*RND(Z),8,I:NEXT I
2010 Y=Y+L:IF Y>176 THEN Y=176:GOSUB 830:GOTO 2040
2020 GOTO 1860
2030 GOSUB 8:NEXT PROB
2040 GOSUB 950:IF PC<PCNT THEN GOSUB 890:GOTO 1780
2050 GOSUB 210:MAX=MAX+DIF:MIN=MIN+INT(DIF*RND(Z)+L)
2060 PC=100:NEXT ROUND
2070 SCORE=SCORE-HOLDS*10:IF SCORE<Z THEN SCORE=Z
2080 IF SCORE>HSCR THEN HSCR=SCORE:TH=TYPE
2090 PCNT=6:GOTO 990
2100 REM SPEAK A NUMBER
2110 IF NM<=20 THEN A=USR(SPEAK,NM,15,2,34):GOTO 2200
2120 IF NM>99 THEN 2170
2130 II=INT(NM/10):A=USR(SPEAK,II+18,15,2,34)
2140 II=NM-II*10
2150 IF II<>Z THEN GOSUB 2200:A=USR(SPEAK,II,15,2,34)
2160 GOTO 2200
2170 II=INT(NM/100):A=USR(SPEAK,II,15,2,34):GOSUB 2200
2180 NM=NM-100*II:IF NM<10 THEN A=USR(SPEAK,Z,15,2,34):II=Z:GOTO 2140
2190 GOTO 2110
2200 FOR J=L TO 5:NEXT J:RETURN
2210 J=SPEECH/256
2220 IF J=Z OR J<>INT(J) THEN ? "INVALID ADDR FOR SPEECH STRING":END
2230 FOR I=SPEECH+L TO SPEECH+257 STEP 2
2240 IF PEEK(I) THEN POKE I,PEEK(I)-PEEK(256)+J
2250 NEXT I
2260 POKE 256,J
2270 RETURN
2280 TRAP 2290:OPEN #L,4,Z,SPEECH$:GOTO 2310
2290 ? "ERR ";PEEK(195);" AT ";PEEK(186)+256*PEEK(187)
2300 END
2310 SPEECH=256*(INT((ADR(SPEECH$)+255)/256))
2320 J=SPEECHLEN-(SPEECH-ADR(SPEECH$))
2330 IF J<258 THEN ? "NOT ENOUGH ROOM FOR SPEECH HEADER":END
2340 NM=4:AD=SPEECH:IO=L:CMND=7:GOSUB 2390:POKE 256,PEEK(SPEECH+L):? "SPEECH LOAD PAGE ";PEEK(SPEECH+L)
2350 NM=PEEK(SPEECH+2)+256*PEEK(SPEECH+3):IF NM>J THEN ? "NOT ENOUGH ROOM FOR SPEECH DATA":END
2360 AD=SPEECH:IO=L:CMND=7:GOSUB 2390
2370 CLOSE #L
2380 RETURN
2390 IO=IO*16:IOCB=832+IO:POKE IOCB+2,CMND
2400 ADH=INT(AD/256):ADL=AD-256*ADH
2410 NMH=INT(NM/256):NML=NM-256*NMH
2420 POKE IOCB+4,ADL:POKE IOCB+5,ADH
2430 POKE IOCB+8,NML:POKE IOCB+9,NMH
2440 I=USR(ADR("hhh*LVd"),IO):ERR=PEEK(IOCB+3)
2450 POKE 195,ERR:IO=IO/16:RETURN