Mighty Lister (LISTER.BAS)
Mighty Lister by Philip Bate, Ph.D., 55
Description
Mighty Lister by Philip Bate, Ph.D., 55
From the Antic disk of January 1989 (Vol. 7 No. 9).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 6.7 KB
- Dialect
- Atari BASIC
- Lines
- 155
- Variables
FILELEN,FILE$,SUB$,RAND$,FILENAME$,EOL$,IO$,MSG1$,MSG2$,MSG3$,ML,RAND,A,START,I,GAP,READ,X,MAXLEN,SADR,TRUELEN,ICCOM,ICBADR,ICBLEN,ICSTAT,H,L
BASIC listing (155 lines)
5 REM MIGHTY LISTER
10 REM BY PHILIP BATE, Ph.D.
20 REM (c) 1988, ANTIC PUBLISHING
30 FILELEN=FRE(0)-1100:DIM FILE$(FILELEN)
33 GRAPHICS 2:POKE 710,186:POKE 712,186:POKE 708,3:POKE 709,3:POSITION 6,3:? #6;"MIGHTY"
36 POSITION 6,5:? #6;"LISTER"
40 DIM SUB$(255),RAND$(260),FILENAME$(14),EOL$(2),IO$(7),MSG1$(28),MSG2$(24),MSG3$(36)
50 EOL$(1)=CHR$(155):EOL$(2)=CHR$(155):MSG1$=" PRESS RETURN FOR MAIN MENU ":MSG2$=" PRESS NUMBER OF CHOICE "
60 MSG3$="IF PRINTER READY PRESS 'A' TO PRINT"
70 IO$="hhh*LVd"
80 RAND$(1,86)=")♥┐T┐UhI┐p─▔♥┤"♥l♥┤P├◆hhh)♥psh▔┐┤h▔┤┤h▔┘┤h┴m┤┤▔▕┤-┘┤m┐┤▔┘┤h┐Lh┐Khh▔├┤h┐Nh┴m┤┤┐M%Nm┐┤┐N"
82 RAND$(87,172)="%M8i├┐M%Ni♥┐N"♥ ♥1MQKp%-▕┤8eM▔♥┤-┘┤eN▔♥┤P├◆%M┴i├┐M%Ni♥┐N)♥pQhl├┤P┤)♥p6H1MQKp%-▕┤8eM▔♥┤"
83 RAND$(173,260)="-┘┤eN▔♥┤P├◆%M┴i├┐M%Ni♥┐N)♥p*hl├┤p┤)♥pJ-▕┤8eM▔♥┤-┘┤eN▔♥┤♣←p↑%M8m┤┤┐T%Nm┐┤┐U%T┴i├┐T%Ui♥┐U◆"
84 RAND$(200,200)=CHR$(155):ML=ADR(RAND$)
90 REM
100 REM
110 CLOSE #1:OPEN #1,4,0,"K"
120 FILENAME$="D:INVNTORY":GOSUB 1330
130 REM MAIN MENU
135 GRAPHICS 0:POKE 752,1:POKE 764,255:POKE 82,2:POKE 756,226:POKE 702,64:POKE 710,204:POKE 709,0:RAND=0
140 ? :? " MAIN MENU "
150 ? :? :? " 1 - LOCATE ITEM & PRINT"
160 ? :? " 2 - SCROLL & PRINT"
170 ? :? " 3 - PRINT LIST"
180 ? :? " 4 - SCREEN LIST"
190 ? :? " 5 - CHANGE MENU"
200 ? :? " 6 - DIR & LOAD"
210 ? :? " 7 - MAKE NEW LIST"
220 ? :? :? " ";MSG2$
230 A=PEEK(764):IF A=255 THEN POKE 77,0:GOTO 230
240 GET #1,A:IF A=255 THEN 240
250 ON A-48 GOTO 270,360,430,490,530,1270,940
260 GOTO 130
270 REM FIND ENTRY & PRINT ENVELOPES
280 ? "↰":POKE 702,0:POKE 752,0:POSITION 2,10:? "Locator for item to display":INPUT SUB$
282 ? :? "Do you want automatic printout of all locators Y/N":POKE 702,64:GET #1,A:IF A<>89 THEN 290
284 A=65:GOSUB 1070:GOSUB 1160:? FILE$(START,RAND+1)
286 GOTO 284
290 GOSUB 1070
300 GOSUB 1160
310 POKE 702,64:? "↰":? :? MSG3$
320 ? :? "Press SPACEBAR to get next locator":? :? FILE$(START,RAND+1)
330 POKE 702,64:GOSUB 1000
340 IF A=32 THEN 290
350 GOTO 130
360 REM SERIALLY PRINT ENVELOPES
370 START=RAND+2:GOSUB 1120
380 POKE 702,64:? "↰":? MSG3$
390 ? :? "Press SPACEBAR to scroll not print":? :? FILE$(START,RAND)
400 GOSUB 1000
410 IF A=32 OR A=65 THEN 370
420 GOTO 130
430 REM PRINT COMPLETE LIST
440 ? "↰":? :? MSG3$:POKE 764,255
441 IF PEEK(764)<>63 THEN 441
450 REM
460 REM
470 POKE 764,255:CLOSE #4:OPEN #4,8,0,"P":PRINT #4;FILE$:CLOSE #4
480 GOTO 130
490 REM SCREEN COMPLETE
500 FOR I=1 TO 200:NEXT I:? :? FILE$:FOR I=1 TO 250:NEXT I
510 IF LEN(FILE$)=0 THEN ? "NO LIST LOADED":FOR I=1 TO 250:NEXT I
520 GOTO 130
530 REM CHANGE MENU
540 ? "↰":POSITION 10,2:? " CHANGE MENU "
550 ? :? :? "1 - Add items":? :? "2 - Delete items":? :? "3 - Save Updated List"
560 ? :? "4 - Main Menu (Without saving list)":?
570 POSITION 3,20:? "SAVE BEFORE RETURNING TO MAIN MENU"
580 POSITION 8,18:? MSG2$:GOSUB 1020
590 POKE 702,0:POKE 752,0:? "↰":ON A-48 GOTO 620,720,840,130
600 GOTO 130
610 REM ADD NAME
620 ? "↰":IF LEN(FILE$)=0 THEN FILE$(LEN(FILE$)+1)=EOL$:POSITION 2,1:? " NEW LIST"
630 ? :? " FILE LOADED IS ";FILENAME$
640 ? :? FILELEN-LEN(FILE$);" FREE CHARACTERS IN MEMORY":POSITION 2,22:? "PRESS RETURN FOR CHANGE MENU"
650 POKE 752,0:POSITION 2,7:? "FIRST LINE";:INPUT SUB$
660 IF LEN(SUB$)=0 THEN 540
670 FILE$(LEN(FILE$)+1)=SUB$:FILE$(LEN(FILE$)+1)=CHR$(155)
680 ? :? "NEXT LINE";:INPUT SUB$
690 IF LEN(SUB$)=0 THEN FILE$(LEN(FILE$)+1)=CHR$(155):? "↰":GOTO 630
700 GOTO 670
710 REM DELETE A NAME
720 POSITION 2,22:? "PRESS RETURN FOR CHANGE MENU"
730 POKE 702,0:POSITION 2,6:? "Item to Delete";:INPUT SUB$:IF LEN(SUB$)=0 THEN 540
740 GOSUB 1070
750 GOSUB 1160
760 ? :? "PRESS SPACE BAR TO DELETE":? FILE$(START,RAND+1)
770 GET #1,A:IF A=255 THEN 770
780 IF A<>32 THEN 540
790 GAP=RAND-START+2
800 FILE$(START,LEN(FILE$))=FILE$(RAND+2,LEN(FILE$))
810 FILE$=FILE$(1,LEN(FILE$)-GAP)
820 GOTO 540
830 REM SAVE ROUTINE
840 POKE 702,64
850 IF LEN(FILENAME$)=0 THEN 890
860 ? :? "DEVICE.FILENAME IS ";FILENAME$:? :? "Press SPACEBAR to add changes to this file. Press 'S' to change ";
865 REM
870 ? "to a new":? "DEVICE.FILENAME":GOSUB 1000
880 IF A=32 THEN 900
890 ? "↰":POSITION 1,10:? "DEVICE.FILENAME TO SAVE":INPUT FILENAME$
900 IF LEN(FILENAME$)=0 THEN 130
910 TRAP 930:CLOSE #2:OPEN #2,8,0,FILENAME$:LET READ=0:X=32:MAXLEN=LEN(FILE$):SADR=ADR(FILE$):GOSUB 1370
920 CLOSE #2:TRAP 40000:GOTO 130
930 POSITION 5,10:? "I/O ERROR #";PEEK(195):CLOSE #2:TRAP 40000
940 REM MAKE NEW LIST
950 ? "↰":? :? " MAKING NEW FILES "
960 ? :? "If you have a word processor use it tomake new files. Separate entrieswith two RETURN's."
970 ? :? "You can also use this program to make lists. Follow directions below."
980 POKE 702,64:FILE$="":? :? "NEW DEVICE:FILENAME TO USE";:INPUT FILENAME$:POKE 702,0:GOTO 620
990 REM PAUSE SUBROUTINE
1000 POSITION 6,22:? MSG1$
1010 A=PEEK(764):IF A=255 THEN POKE 77,0:GOTO 1010
1020 GET #1,A:IF A=255 THEN 1020
1030 IF A=155 THEN 130
1040 IF A=65 THEN GOSUB 1220
1050 RETURN
1060 REM RAND SUBROUTINE
1070 IF LEN(SUB$)=0 THEN 130
1080 START=RAND+1
1090 RAND=USR(ML,ADR(FILE$),LEN(FILE$),ADR(SUB$),LEN(SUB$),START)
1100 IF RAND=0 THEN POP :? "↰":? :? "INVALID NAME OR LIST ENDED":FOR I=1 TO 200:NEXT I:GOTO 130
1110 START=RAND
1120 RAND=USR(ML,ADR(FILE$),LEN(FILE$),ADR(EOL$),LEN(EOL$),START)
1130 IF RAND=0 THEN 1100
1140 RETURN
1150 REM SEARCH SUBROUTINE
1160 START=START-10:IF START<0 THEN START=1
1170 X=0:X=USR(ML,ADR(FILE$),LEN(FILE$),ADR(EOL$),LEN(EOL$),START)
1180 IF X=RAND THEN 1160
1190 START=X
1200 RETURN
1210 REM PRINTER SUBROUTINE
1220 TRAP 1230:CLOSE #4:OPEN #4,8,0,"P:":GOTO 1240
1230 ? "↰":? :? "I/O ERROR #";PEEK(195):TRAP 40000:CLOSE #4:GOTO 130
1240 REM
1250 IF A=65 THEN PRINT #4;CHR$(27);"l";CHR$(10);FILE$(START,RAND-1):CLOSE #4:RETURN
1260 GOTO 130
1270 REM LOAD MENU
1280 TRAP 1290:? "↰":CLOSE #2:OPEN #2,6,0,"D:*.*":FOR X=1 TO 10000:GET #2,A:? CHR$(A);:NEXT X
1290 CLOSE #2:? MSG1$:TRAP 40000
1300 REM LOAD ROUTINE
1310 POKE 752,0:? :? "DEVICE.FILENAME TO LOAD":INPUT FILENAME$
1320 IF LEN(FILENAME$)=0 THEN 130
1330 TRAP 1360:CLOSE #2:OPEN #2,4,0,FILENAME$:LET READ=1:X=32:MAXLEN=FILELEN:SADR=ADR(FILE$):GOSUB 1370
1340 CLOSE #2:FILE$(TRUELEN)=CHR$(155):TRAP 40000:GOTO 130
1350 ? "↰":POSITION 5,10:? "I/O ERROR #";PEEK(195):CLOSE #2:TRAP 40000
1360 GOTO 130
1370 REM I/O LOAD & SAVE
1380 ICCOM=834:ICBADR=836:ICBLEN=840:ICSTAT=835
1390 H=INT(SADR/256):L=SADR-H*256:POKE ICBADR+X,L:POKE ICBADR+X+1,H
1400 H=INT(MAXLEN/256):L=MAXLEN-H*256:POKE ICBLEN+X,L:POKE ICBLEN+X+1,H
1410 POKE ICCOM+X,11-4*READ:A=USR(ADR(IO$),X)
1420 TRUELEN=PEEK(ICBLEN+X)+256*PEEK(ICBLEN+X+1)
1430 RETURN
