Job Jar (JOBJAR.BAS)

Job Jar by Jeffrey A. Summers, 78

Description

Job Jar by Jeffrey A. Summers, 78

From the Antic disk of January 1989 (Vol. 7 No. 9).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 9.4 KB

Dialect
Atari BASIC
Lines
186
Variables
BRK, ZZZ, MCH, COUNT, X, FIELD$, NAME$, FNAME$, DOE$, DOC$, P1, P2, SIZE$, DESCR$, ADOE$, ADOC$, SPRIOR(, EPRIOR(, ASIZE$, ADESCR$, I, NJOBS, SPRIOR, EPRIOR, DCHANGE, J, ALGO, FILTER, DEVICE, ORDER(, RDATE$, CHANGE, T, TDAY, MLEN(, TC, TE, CPRIOR(, DLIST
BASIC listing (186 lines)
10 REM JOB JAR
20 REM BY JEFFREY A. SUMMERS, MD
30 REM (c)1988, ANTIC PUBLISHING
40 BRK=PEEK(53279)<>5
99 GOTO 10000
100 CLOSE #5:OPEN #5,4,0,"K:":FOR ZZZ=1 TO MCH:? "_";:NEXT ZZZ:FOR ZZZ=1 TO MCH:? "←";:NEXT ZZZ
105 COUNT=1
110 GET #5,X:IF X=155 THEN 150
120 IF X=126 THEN 140
130 ? CHR$(X);:FIELD$(COUNT)=CHR$(X):COUNT=COUNT+1:IF COUNT<=MCH THEN 110
131 GOTO 150
140 IF COUNT=1 THEN 110
141 COUNT=COUNT-1:? CHR$(X);:GOTO 110
150 COUNT=COUNT-1:CLOSE #5:RETURN
1000 REM GET PERSON
1010 POSITION 6,10:PRINT "Whose jar? ";:MCH=8:GOSUB 100
1020 IF COUNT=0 THEN 1010
1030 NAME$=FIELD$(1,COUNT):FNAME$="D:":FNAME$(3)=NAME$:FNAME$(LEN(FNAME$)+1)=".JAR"
1040 TRAP 1100
1050 CLOSE #1:OPEN #1,4,0,FNAME$
1060 TRAP 2010:COUNT=0
1070 INPUT #1,DOE$:INPUT #1,DOC$:INPUT #1,P1:INPUT #1,P2:INPUT #1,SIZE$:INPUT #1,DESCR$
1075 ADOE$(COUNT*6+1,COUNT*6+6)=DOE$:ADOC$(COUNT*6+1,COUNT*6+6)=DOC$:SPRIOR(COUNT+1)=P1:EPRIOR(COUNT+1)=P2
1076 ASIZE$(COUNT+1,COUNT+1)=SIZE$:ADESCR$(COUNT*37+1,COUNT*37+37)=DESCR$:COUNT=COUNT+1:GOTO 1070
1100 TRAP 1200:CLOSE #1
1110 CLOSE #1:OPEN #1,8,0,FNAME$:COUNT=0
1115 ? :? :? "New person"
1116 FOR I=1 TO 500:NEXT I
1120 GOTO 2010
1200 ? :? "Cannot open file.":? "Please check device"
1210 FOR I=1 TO 500:NEXT I:GOTO 30000
1500 POKE 77,0:IF BRK THEN POKE 16,112:POKE 53774,112
1510 RETURN
2000 REM GET TODAY'S DATE
2010 CLOSE #1:NJOBS=COUNT:? "↰    job jar             ";NAME$
2020 POSITION 6,10:? "Today's date? MMDDYY"
2030 POSITION 10,12:MCH=6:GOSUB 100
2040 IF COUNT<>6 THEN 2020
2041 LET DOE$=FIELD$(1,COUNT)
3010 REM MAIN MENU
3030 ? "↰    job jar             ";NAME$
3040 POSITION 12,8:? "Add a Job":POSITION 12,10:? "List jobs"
3050 POSITION 12,12:? "Delete a Job":POSITION 12,14:? "Exit"
3060 POSITION 0,0:? " ";:CLOSE #5:OPEN #5,4,0,"K:":GET #5,X:CLOSE #5
3070 IF X=65 THEN 4010:REM ADD
3080 IF X=68 THEN 5010:REM DELETE
3090 IF X=69 THEN 6010:REM EXIT
3100 IF X=76 THEN 7010:REM LIST
3110 GOTO 3060
4000 REM ADD JOB
4010 ? "↰    job jar             ";NAME$
4020 POSITION 6,6:? "Completion date (MMDDYY)"
4030 POSITION 12,7:MCH=6:GOSUB 100
4035 IF COUNT<>6 THEN 4020
4036 LET DOC$=FIELD$
4040 POSITION 6,8:? "Enter starting priority":POSITION 16,9:MCH=1:GOSUB 100
4045 TRAP 4040:SPRIOR=VAL(FIELD$(1,1))
4050 POSITION 6,10:? "Enter ending priority":POSITION 16,11:MCH=1:GOSUB 100
4055 TRAP 4050:EPRIOR=VAL(FIELD$(1,1))
4060 POSITION 6,12:? "Enter size of job (S/M/L)":POSITION 16,13:MCH=1:GOSUB 100
4065 SIZE$=FIELD$(1,1):IF SIZE$<>"S" AND SIZE$<>"M" AND SIZE$<>"L" THEN 4060
4070 POSITION 6,14:? "Enter job description":MCH=37:POSITION 2,15:GOSUB 100
4074 IF COUNT<1 THEN 4070
4075 DESCR$=FIELD$(1,COUNT)
4080 POSITION 6,16:? "Is this O.K. (Y/N) ";:MCH=1:GOSUB 100
4090 IF FIELD$(1,1)<>"Y" AND FIELD$(1,1)<>"N" THEN 4080
4100 IF FIELD$(1,1)="N" THEN 3030
4110 ADOE$(NJOBS*6+1,NJOBS*6+6)=DOE$:ADOC$(NJOBS*6+1,NJOBS*6+6)=DOC$:SPRIOR(NJOBS+1)=SPRIOR
4120 EPRIOR(NJOBS+1)=EPRIOR:ASIZE$(NJOBS+1)=SIZE$:ADESCR$(37*NJOBS+1,37*NJOBS+37)=DESCR$:NJOBS=NJOBS+1
4130 CLOSE #1:OPEN #1,9,0,FNAME$:? #1;DOE$:? #1;DOC$:? #1;SPRIOR
4140 ? #1;EPRIOR:? #1;SIZE$:? #1;DESCR$:CLOSE #1
4150 GOTO 3030
5000 REM DELETE JOB
5010 ? "↰    job jar             ";NAME$
5020 POSITION 3,8:? "Enter description of job to delete"
5030 ? :MCH=37:GOSUB 100
5035 IF COUNT=0 THEN 3030
5040 FOR I=0 TO NJOBS-1:IF ADESCR$(37*I+1,37*I+COUNT)=FIELD$(1,COUNT) THEN 5070
5050 NEXT I
5060 ? :? "No matching entry":? "Press RETURN":CLOSE #5:OPEN #5,4,0,"K:":GET #5,X:CLOSE #5
5061 GOTO 3030
5070 DCHANGE=1:? :? "       deleting..."
5080 POP :ADOE$(6*I+1)=ADOE$(6*I+7)
5090 ADOC$(6*I+1)=ADOC$(6*I+7)
5100 FOR J=I+1 TO NJOBS:SPRIOR(J)=SPRIOR(J+1):EPRIOR(J)=EPRIOR(J+1):NEXT J
5110 ASIZE$(I+1)=ASIZE$(I+2)
5120 ADESCR$(37*I+1)=ADESCR$(37*I+38)
5130 NJOBS=NJOBS-1:GOTO 3030
6000 REM EXIT
6010 IF DCHANGE=0 THEN 30000
6015 ADESCR$(3800)=" "
6020 CLOSE #1:OPEN #1,8,0,FNAME$:FOR I=1 TO NJOBS:? #1;ADOE$(6*(I-1)+1,6*I):? #1;ADOC$(6*(I-1)+1,6*I)
6030 ? #1;SPRIOR(I):? #1;EPRIOR(I):? #1;ASIZE$(I,I):? #1;ADESCR$(37*(I-1)+1,37*I)
6040 NEXT I
6050 CLOSE #1:GOTO 30000
7000 REM LIST JOBS
7010 ? "↰    job jar             ";NAME$
7020 POSITION 6,6:? "List by":POSITION 8,8:? "Size":POSITION 8,9:? "Priority"
7030 POSITION 8,10:? "Due date":POSITION 8,11:? "Entry date":POSITION 0,0:? " ";
7040 CLOSE #5:OPEN #5,4,0,"K:":GET #5,X:CLOSE #5:IF X<>68 AND X<>69 AND X<>80 AND X<>83 THEN 7040
7045 ALGO=X
7046 IF ALGO=83 THEN FILTER=65:GOTO 7100
7050 ? "↰    job jar             ";NAME$
7060 POSITION 6,6:? "List sizes":POSITION 8,8:? "Small":POSITION 8,10:? "Medium"
7070 POSITION 8,12:? "Large":POSITION 8,14:? "All":POSITION 0,0:? " ";
7080 CLOSE #5:OPEN #5,4,0,"K:":GET #5,X:CLOSE #5:IF X<>65 AND X<>76 AND X<>77 AND X<>83 THEN 7080
7090 FILTER=X
7100 ? "↰    job jar             ";NAME$
7110 POSITION 8,8:? "Output to":POSITION 8,10:? "Screen":POSITION 8,12:? "Printer"
7120 POSITION 0,0:? " ";:CLOSE #5:OPEN #5,4,0,"K:":GET #5,X:CLOSE #5:IF X<>80 AND X<>83 THEN 7120
7130 DEVICE=X
8000 IF DEVICE=80 THEN TRAP 8070:CLOSE #4:OPEN #4,8,0,"P:":GOTO 8010
8010 TRAP 40000:IF DEVICE=83 THEN CLOSE #4:OPEN #4,8,0,"E:":POKE 710,2:GOSUB 1500
8020 IF ALGO=68 THEN 8100
8030 IF ALGO=69 THEN 8200
8040 IF ALGO=80 THEN 8300
8050 IF ALGO=83 THEN 8400
8060 STOP :REM SHOULDN'T GET HERE
8070 ? :? :? " PRINTER OFFLINE!↰";:FOR X=1 TO 200:NEXT X:? "↰":GOTO 7110
8100 FOR I=1 TO NJOBS:ORDER(I)=I:NEXT I
8110 FOR I=0 TO NJOBS-1:IF NJOBS-1<0 THEN 8121
8112 RDATE$(6*I+1)=ADOC$(6*I+5,6*I+6):RDATE$(6*I+3)=ADOC$(6*I+1,6*I+2)
8120 RDATE$(6*I+5)=ADOC$(6*I+3,6*I+4)
8121 NEXT I
8130 FOR I=0 TO NJOBS-1:IF NJOBS-1<0 THEN 8170
8135 CHANGE=0:FOR J=1 TO NJOBS-1-I:IF NJOBS-1-I<1 THEN 8160
8140 IF VAL(RDATE$(6*ORDER(J)-5,6*ORDER(J)))<=VAL(RDATE$(6*ORDER(J+1)-5,6*ORDER(J+1))) THEN 8160
8150 T=ORDER(J):ORDER(J)=ORDER(J+1):ORDER(J+1)=T:CHANGE=1
8160 NEXT J:IF CHANGE=0 THEN POP :GOTO 9000
8170 NEXT I:GOTO 9000
8200 FOR I=1 TO NJOBS:ORDER(I)=I:NEXT I
8210 FOR I=0 TO NJOBS-1:IF NJOBS-1<0 THEN 8221
8211 RDATE$(6*I+1)=ADOE$(6*I+5,6*I+6):RDATE$(6*I+3)=ADOE$(6*I+1,6*I+2)
8220 RDATE$(6*I+5)=ADOE$(6*I+3,6*I+4)
8221 NEXT I
8230 FOR I=0 TO NJOBS-1:IF NJOBS-1<0 THEN 8270
8235 CHANGE=0:FOR J=1 TO NJOBS-1-I:IF NJOBS-1-I<1 THEN 8260
8240 IF VAL(RDATE$(6*ORDER(J)-5,6*ORDER(J)))<=VAL(RDATE$(6*ORDER(J+1)-5,6*ORDER(J+1))) THEN 8160
8250 T=ORDER(J):ORDER(J)=ORDER(J+1):ORDER(J+1)=T:CHANGE=1
8260 NEXT J:IF CHANGE=0 THEN POP :GOTO 9000
8270 NEXT I:GOTO 9000
8300 FOR I=1 TO NJOBS:ORDER(I)=I:NEXT I:TDAY=365*VAL(DOE$(5,6))+MLEN(VAL(DOE$(1,2)))+VAL(DOE$(3,4))
8310 FOR I=0 TO NJOBS-1:IF NJOBS-1<0 THEN 8350
8315 TC=365*VAL(ADOC$(6*I+5,6*I+6))+MLEN(VAL(ADOC$(6*I+1,6*I+2)))+VAL(ADOC$(6*I+3,6*I+4))
8320 TE=365*VAL(ADOE$(6*I+5,6*I+6))+MLEN(VAL(ADOE$(6*I+1,6*I+2)))+VAL(ADOE$(6*I+3,6*I+4))
8330 IF TDAY>TC THEN CPRIOR(I+1)=EPRIOR(I+1):GOTO 8350
8340 CPRIOR(I+1)=SPRIOR(I+1)+(EPRIOR(I+1)-SPRIOR(I+1))*((TDAY-TE)/(TC-TE))
8350 NEXT I
8360 FOR I=1 TO NJOBS:IF NJOBS<1 THEN 8395
8365 CHANGE=0:FOR J=1 TO NJOBS-I+1:IF NJOBS-I+1<1 THEN 8390
8370 IF CPRIOR(ORDER(J))>=CPRIOR(ORDER(J+1)) THEN 8390
8380 T=ORDER(J):ORDER(J)=ORDER(J+1):ORDER(J+1)=T:CHANGE=1
8390 NEXT J:IF CHANGE=0 THEN POP :GOTO 9000
8395 NEXT I:GOTO 9000
8400 FOR I=1 TO NJOBS:ORDER(I)=I:NEXT I
8410 FOR I=1 TO NJOBS:IF NJOBS<1 THEN 8460
8415 CHANGE=0:FOR J=1 TO NJOBS-I:IF NJOBS-I<1 THEN 8450
8420 IF ASIZE$(ORDER(J),ORDER(J))<=ASIZE$(ORDER(J+1),ORDER(J+1)) THEN 8450
8430 T=ORDER(J):ORDER(J)=ORDER(J+1):ORDER(J+1)=T:CHANGE=1
8450 NEXT J:IF CHANGE=0 THEN POP :GOTO 9000
8460 NEXT I
9000 FOR I=1 TO NJOBS:IF NJOBS<1 THEN ? #4;"No Jobs":GOTO 9070
9002 IF FILTER<>65 AND FILTER<>ASC(ASIZE$(ORDER(I),ORDER(I))) THEN 9070
9005 ? #4;ADESCR$(ORDER(I)*37-36,ORDER(I)*37)
9010 ? #4;"  Due date: ";ADOC$(ORDER(I)*6-5,ORDER(I)*6)
9020 ? #4;"  Date of entry: ";ADOE$(ORDER(I)*6-5,ORDER(I)*6)
9030 ? #4;"  Priority (S/E): ";SPRIOR(ORDER(I));"/";EPRIOR(ORDER(I))
9040 IF ALGO=80 THEN ? #4;"  Current Priority: ";INT(CPRIOR(ORDER(I))*1000+0.5)/1000
9050 ? #4;"  Size: ";ASIZE$(ORDER(I),ORDER(I))
9060 ? #4
9070 NEXT I:CLOSE #4
9075 IF DEVICE=80 THEN 3030
9080 ? "Press RETURN":POSITION 0,0:CLOSE #5:OPEN #5,4,0,"K:":GET #5,X:CLOSE #5
9090 POKE DLIST+3,71:POKE DLIST+6,6
9100 GOTO 3030
9999 STOP
10000 DIM NAME$(8),FNAME$(14),DOE$(6),DOC$(6),SPRIOR(100),EPRIOR(100),SIZE$(1),DESCR$(38),FIELD$(100)
10010 DIM ADOE$(600),ADOC$(600),ASIZE$(100),ADESCR$(3800),ORDER(100),RDATE$(600),CPRIOR(100)
10011 DIM MLEN(12):FOR I=1 TO 12:READ X:MLEN(I)=X:NEXT I
10012 DATA 0,31,59,90,120,151,181,212,243,273,304,334
10020 GRAPHICS 0:POKE 710,2:DLIST=PEEK(560)+256*PEEK(561):POKE DLIST+3,71:POKE DLIST+6,6:CHANGE=0:DCHANGE=0
10021 ADESCR$(1)=" ":ADESCR$(3800)=" ":ADESCR$(2)=ADESCR$(1):ADOE$=ADESCR$:ADOC$=ADESCR$:ASIZE$=ADESCR$
10022 FIELD$=ADESCR$:DESCR$=ADESCR$:GOSUB 1500
10030 ? "    job jar"
10040 GOTO 1010
30000 GRAPHICS 0:END