Master File Directory Maker (for Data-X) (MFD.BAS)

Master File Directory Maker (for Data-X) by Jeffrey A. Summers, 42

Description

Master File Directory Maker (for Data-X) by Jeffrey A. Summers, 42

From the Antic disk of December 1988 (Vol. 7 No. 8) — disk B.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 5.1 KB

Dialect
Atari BASIC
Lines
91
Variables
TPTR, K1, MCH, X, D, WINDEX, K2, TFIELD$, K0, WINDOC, ROW, PTR, K5, WINDOI, WINDOW$, WINDOO, F$, PROOF$, NCUR, IDFLG, ID$, PROOF1$, I, NCUR1, NREC, NREC1, NFLDS, DNAME$, SP$, F1$, J, FNAME$, WINDOI$, WINDOO$, WINDOC$, INP$, WINDEX$, K3, K4, K6, INP
BASIC listing (91 lines)
10 REM MASTER FILE DIRECTORY MAKER (FOR DATA-X)
20 REM BY J. SUMMERS
30 REM (c)1988, ANTIC PUBLISHING
60 GOSUB 10000:REM INITIALIZATION
99 GOTO 1000
400 FOR TPTR=K1 TO MCH:IF PEEK(85)=39 THEN ? :IF PEEK(84)=22 THEN ? "Press RETURN"
405 IF PEEK(84)=22 THEN GET #5,X:D=USR(WINDEX):POSITION K2,7
410 ? TFIELD$(TPTR,TPTR);:NEXT TPTR
420 RETURN
500 POSITION 0,0:? "→←";:RETURN
600 POSITION K0,K0:? "→←";:D=USR(WINDOC):RETURN
700 ROW=PEEK(84):X=PEEK(85):TFIELD$(1)="_":TFIELD$(MCH)="_":TFIELD$(2)=TFIELD$(1):GOSUB 400
710 POSITION X,ROW:? "→←";:PTR=K1:TFIELD$=" "
720 GET #K5,X:IF X=155 THEN 750
730 IF X<>126 THEN 740
735 IF PTR=K1 THEN 720
736 PTR=PTR-K1:? CHR$(X);"_←";:GOTO 720
740 TFIELD$(PTR,PTR)=CHR$(X):? CHR$(X);:PTR=PTR+K1:IF PEEK(85)=39 THEN ?
745 IF PTR<=MCH THEN 720
750 PTR=PTR-K1:IF PTR=K0 THEN PTR=K1:TFIELD$(K1,K1)=" "
760 RETURN
1000 D=USR(WINDOI,ADR(WINDOW$)):D=USR(WINDOO,3,5,35,15)
1010 POSITION 4,6:? "Master file directory maker":POSITION 4,8:? "Create new file or Add to old:";
1020 GET #5,X:IF X=65 THEN 2000
1030 IF X<>67 THEN 1020
1040 ? "C":POSITION 4,10:? "Enter filename: ";:MCH=15:GOSUB 700
1050 F$=TFIELD$:OPEN #1,8,0,F$:POSITION 5,7:? F$
1060 ? #1;PROOF$:PUT #1,0:PUT #1,0:PUT #1,3
1070 ? #1;"DISKNAME":? #1;"FILENAME":? #1;"DESC/KEYS"
1080 ? #1;20:? #1;12:? #1;80
1090 NCUR=0:GOTO 3000
2000 ? "A":POSITION 4,10:? "Enter filename: ";:MCH=15:GOSUB 700
2010 F$=TFIELD$:OPEN #1,12,0,F$:POSITION 5,7:? F$
2020 IDFLG=0:INPUT #1,ID$:IF ID$=PROOF$ THEN 2030
2021 IF ID$=PROOF1$ THEN IDFLG=1:GOTO 2026
2025 POSITION 6,12:? "File compatability error":FOR I=1 TO 1000:NEXT I:CLOSE #1:GOSUB 600:GOTO 1000
2026 GET #1,NCUR:GET #1,NCUR1:NCUR=256*NCUR1+NCUR:GET #1,NREC:GET #1,NREC1:NREC=256*NREC1+NREC:GOTO 2040
2030 GET #1,NCUR:GET #1,NREC
2040 GET #1,NFLDS:IF NFLDS<>3 THEN 2025
2050 CLOSE #1:OPEN #1,9,0,F$
3000 GOSUB 600:D=USR(WINDOO,1,3,39,9):POSITION 2,4:? "Master file Directory Maker":POSITION 2,5:? F$
3010 GOSUB 500:D=USR(WINDOO,3,7,39,13):POSITION 4,10:? "Enter name of disk:":POSITION 10,12:MCH=20
3020 GOSUB 700:DNAME$=TFIELD$:POSITION 4,8:? DNAME$
3025 IF LEN(DNAME$)<20 THEN DNAME$(LEN(DNAME$)+1)=SP$
3030 CLOSE #2:OPEN #2,6,0,"D:*.*":TRAP 4000
3035 D=USR(WINDOO,1,10,39,18)
3040 INPUT #2,F1$:J=1:FOR I=3 TO 10:IF F1$(I,I)<>" " THEN FNAME$(J,J)=F1$(I,I):J=J+1
3050 NEXT I:IF LEN(F1$)=16 THEN 4000
3055 NCUR=NCUR+1:NREC=NREC+1
3060 FNAME$(J,J)=".":J=J+1:FNAME$(J,J+2)=F1$(11,13):IF J<10 THEN FNAME$(J+3)=SP$
3070 POSITION 0,0:? "→←";:D=USR(WINDEX):POSITION 2,11:? "Describe file ";
3080 ? FNAME$;
3090 POSITION 2,14:MCH=80:GOSUB 700
3095 IF LEN(TFIELD$)<80 THEN TFIELD$(LEN(TFIELD$)+1)=SP$
3100 ? #1;DNAME$;FNAME$;TFIELD$(1,80);
3110 GOTO 3040
4000 CLOSE #2:GOSUB 600:GOSUB 600
4005 POSITION 7,7:? "Total records = ";NREC
4010 POSITION 7,8:? "Another disk? (Y/N): ";
4020 GET #5,X:IF X=89 THEN 3010
4030 IF X<>78 THEN 4020
4040 CLOSE #1:OPEN #1,12,0,F$:INPUT #1,ID$:IF IDFLG THEN 4045
4041 PUT #1,NCUR:PUT #1,NREC:CLOSE #1:GOTO 31000
4045 NCUR1=INT(NCUR/256):NCUR=NCUR-256*NCUR1:NREC1=INT(NREC/256):NREC=NREC-256*NREC1
4046 PUT #1,NCUR:PUT #1,NCUR1:PUT #1,NREC:PUT #1,NREC1:CLOSE #1
4050 GOTO 31000
10000 GRAPHICS 0:REM INITIALIZATION
10005 POKE 710,2:POKE 709,10:POKE 16,112:POKE 53774,112
10010 DIM WINDOW$(3000),WINDOI$(10),WINDOO$(244),WINDOC$(155),F$(20),F1$(20),SP$(300)
10011 DIM TFIELD$(301),INP$(39),WINDEX$(149),DNAME$(20),FNAME$(12)
10012 DIM ID$(18),PROOF$(18),PROOF1$(18)
10020 SP$(1)=" ":SP$(300)=" ":SP$(2)=SP$(1):PROOF$="\SUMMERS\DATA.BAS\":TFIELD$(300)=" "
10025 PROOF1$="\SUMMERS\DATA1BAS\"
10030 K0=0:K1=1:K2=K1+K1:K3=K2+K1:K4=K3+K1:K5=K4+K1:K6=K5+K1
10090 CLOSE #K5:OPEN #K5,K4,K0,"K:":POKE 752,K1
10100 GOSUB 11000
10130 WINDOI=ADR(WINDOI$):WINDOO=ADR(WINDOO$):WINDOC=ADR(WINDOC$):D=USR(WINDOI,ADR(WINDOW$)):WINDEX=ADR(WINDEX$)
10140 INP=ADR(INP$)
10160 RETURN
11000 WINDOI$(1,10)="hh▔├╱h▔♥╱◆"
11010 WINDOO$(1,80)="hhh┐X┐Uhh┐Y┐Thh┐Zhh┐[%X┐V%Y┐WFT%V┴i(┐V%Wi♥┐W%TI♥Pk%Y┐T-♥╱┐\-├╱┐])Q┐_$X1V┐^%_┌VIQ"
11020 WINDOO$(81,160)="P┤)R┐_I|P┤)♥┐_IZP┤)R┐_%^┤U ♥┌\%\┴i├┐\%]i♥┐]$UDZp┤H┴♣A)|┌V%TEYP┤)E┌VE[P┤)C┌V%V┴i("
11030 WINDOO$(161,240)="┐V%Wi♥┐W%TE[p▄)|┐_fT%TE[P┤)Z┐_$X┴♣┘ ♥%[┌\H%Z┌\H%Y┌\H%X┌\H-♥╱┌\H-├╱┌\%\┴i╱▔♥╱%]i♥"
11040 WINDOO$(241,244)="▔├╱◆"
11050 WINDOC$(1,80)="h-♥╱8i╱┐\-├╱i♥┐] ♥1\┐[H1\┐ZH1\┐Y┐TH1\┐X┐UH1\▔♥╱H1\▔├╱-♥╱┐\-├╱┐]%X┐V%Y┐WFT%V┴i(┐V"
11060 WINDOC$(81,155)="%Wi♥┐W%TI♥Pk%Y┐T ♥1\$U┌V%\┴i├┐\%]i♥┐]DZp┐fU┴♣b%TE[p▎fT%V┴i(┐V%Wi♥┐W%X┐U┴♣F◆"
11070 INP$(1,39)="hhh*h↓E┘h↓D┘h↓I┘h↓H┘)╲↓B┘ Vd=H┘┐T=I┘┐U◆"
11100 WINDEX$(1,80)="h-♥╱8i╱┐\-├╱i♥┐] ♥1\*J╱[H1\*J╱ZH1\*h╱Y╱TH1\*h╱X╱UH1\┐\H1\┐]%X┐V%Y┐WFT%V┴i(┐V%Wi♥"
11110 WINDEX$(81,149)="┐W%TI♥Pk%Y┐T)♥$U┌V%\┴i├┐\%]i♥┐]DZp┐fU┴♣d%TE[p▎fT%V┴i(┐V%Wi♥┐W%X┐U┴♣H◆"
12000 RETURN
31000 GRAPHICS 0:END