Data-X Utilities Program (DATAUTIL.BAS)

Data-X Utilities Program by Jeffrey A. Summers, 63

Description

Data-X Utilities Program by Jeffrey A. Summers, 63

From the Antic disk of December 1988 (Vol. 7 No. 8) — disk B.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 7.8 KB

Dialect
Atari BASIC
Lines
146
Variables
TPTR, K1, MCH, X, D, WINDEX, K2, TFIELD$, K0, WINDOC, ROW, PTR, K5, WINDOO, F$, F1$, ID$, PROOF$, PROOF1$, FNAME$, L, IDFLG, NCUR, NC, NRECORDS, NR, NFIELDS, I, F, FLEN(, J, INP, SP$, LN, F1LEN(, WINDOW$, WINDOI$, WINDOO$, WINDOC$, INP$, WINDEX$, DNAME$, K3, K4, K6, WINDOI
BASIC listing (146 lines)
10 REM DATA-X UTILITIES PROGRAM I, LETS YOU DO GLOBAL CHANGES & OTHER STUFF
20 REM BY J. SUMMERS
30 REM (c)1988, ANTIC PUBLISHING
60 GOSUB 10000:REM INITIALIZATION
99 GOTO 1000
400 FOR TPTR=K1 TO MCH:IF PEEK(85)=39 THEN ? :IF PEEK(84)=22 THEN ? "Press RETURN"
405 IF PEEK(84)=22 THEN GET #5,X:D=USR(WINDEX):POSITION K2,7
410 ? TFIELD$(TPTR,TPTR);:NEXT TPTR
420 RETURN
500 POSITION 0,0:? "→←";:RETURN
600 POSITION K0,K0:? "→←";:D=USR(WINDOC):RETURN
700 ROW=PEEK(84):X=PEEK(85):TFIELD$(1)="_":TFIELD$(MCH)="_":TFIELD$(2)=TFIELD$(1):GOSUB 400
710 POSITION X,ROW:? "→←";:PTR=K1:TFIELD$=" "
720 GET #K5,X:IF X=155 THEN 750
730 IF X<>126 THEN 740
735 IF PTR=K1 THEN 720
736 PTR=PTR-K1:? CHR$(X);"_←";:GOTO 720
740 TFIELD$(PTR,PTR)=CHR$(X):? CHR$(X);:PTR=PTR+K1:IF PEEK(85)=39 THEN ?
745 IF PTR<=MCH THEN 720
750 PTR=PTR-K1:IF PTR=K0 THEN PTR=K1:TFIELD$(K1,K1)=" "
760 RETURN
1000 D=USR(WINDOO,5,2,35,12):POSITION 6,3:? " Utilities I for DATA-X ":POSITION 6,4:? "by J. Summers"
1010 POSITION 6,6:? "Source file: ";:MCH=15:GOSUB 700:F$=TFIELD$:POSITION 6,7:? "Dest file: ";
1020 MCH=15:GOSUB 700:F1$=TFIELD$:TRAP 9000:OPEN #1,4,0,F$:TRAP 9100:OPEN #3,8,0,F1$
1021 IF F$=F1$ THEN 9500
1022 TRAP 9300:INPUT #1,ID$:IF ID$<>PROOF$ AND ID$<>PROOF1$ THEN 9300
1030 GOSUB 500:D=USR(WINDOO,6,5,35,20):POSITION 7,6:? "Source: ";F$:POSITION 7,7:? "Dest: ";F1$
1040 POSITION 8,9:? "Add field":POSITION 8,11:? "Delete field":POSITION 8,13:? "Change field length"
1050 POSITION 8,15:? "List fields":POSITION 8,17:? "Exit"
1060 GET #5,X:IF X>90 THEN X=X-32
1070 IF X=65 THEN 2000
1080 IF X=67 THEN 4000
1090 IF X=68 THEN 3000
1100 IF X=69 THEN 5000
1110 IF X=76 THEN 6000
1120 GOTO 1060
2000 D=USR(WINDOO,8,8,34,15):POSITION 10,10:? "Enter name of field: "
2005 POSITION 10,11:MCH=10:GOSUB 700:FNAME$=TFIELD$
2010 POSITION 10,12:? "Enter length of field: "
2015 POSITION 10,13:MCH=4:GOSUB 700
2020 TRAP 9200:L=VAL(TFIELD$):IF L<1 OR L>300 THEN 9200
2030 ? #3;ID$:IDFLG=0:IF ID$=PROOF1$ THEN IDFLG=1
2035 GET #1,NCUR:PUT #3,NCUR
2040 IF IDFLG THEN GET #1,NC:NCUR=NCUR+256*NC:PUT #3,NC
2050 GET #1,NRECORDS:PUT #3,NRECORDS
2060 IF IDFLG THEN GET #1,NR:NRECORDS=NRECORDS+256*NR:PUT #3,NR
2070 GET #1,NFIELDS:PUT #3,NFIELDS+1
2080 IF NFIELDS+1=21 THEN POSITION 10,14:? "Too many fields":FOR I=1 TO 1500:NEXT I:GOTO 5000
2090 FOR I=1 TO NFIELDS:INPUT #1,TFIELD$:? #3;TFIELD$:NEXT I
2100 ? #3;FNAME$:FOR I=1 TO NFIELDS:INPUT #1,F:FLEN(I)=F:? #3;F:NEXT I
2110 ? #3;L
2120 FOR I=1 TO NRECORDS:FOR J=1 TO NFIELDS:D=USR(INP,16,ADR(TFIELD$),FLEN(J))
2125 TFIELD$(301)=" "
2130 ? #3;TFIELD$(1,FLEN(J));:NEXT J
2140 ? #3;SP$(1,L);:NEXT I
2150 GOTO 5000
3000 D=USR(WINDOO,8,8,34,15):POSITION 10,10:? "Enter number of field: "
3005 POSITION 10,11:MCH=4:GOSUB 700
3010 TRAP 9400:L=VAL(TFIELD$):IF L<1 OR L>20 THEN 9400
3020 ? #3;ID$:IDFLG=0:IF ID$=PROOF1$ THEN IDFLG=1
3030 GET #1,NCUR:PUT #3,NCUR
3040 IF IDFLG THEN GET #1,NC:NCUR=NCUR+256*NC:PUT #3,NC
3050 GET #1,NRECORDS:PUT #3,NRECORDS
3060 IF IDFLG THEN GET #1,NR:NRECORDS=NRECORDS+256*NR:PUT #3,NR
3070 GET #1,NFIELDS:PUT #3,NFIELDS-1
3080 IF NFIELDS-1=1 THEN POSITION 10,14:? "Too few fields":FOR I=1 TO 1500:NEXT I:GOTO 5000
3090 IF L=1 THEN 3110
3100 FOR I=1 TO L-1:INPUT #1,TFIELD$:? #3;TFIELD$:NEXT I
3110 INPUT #1,TFIELD$:IF L=NFIELDS THEN 3130
3120 FOR I=L+1 TO NFIELDS:INPUT #1,TFIELD$:? #3;TFIELD$:NEXT I
3130 IF L=1 THEN 3150
3140 FOR I=1 TO L-1:INPUT #1,F:FLEN(I)=F:? #3;F:NEXT I
3150 INPUT #1,F:FLEN(L)=F:IF L=NFIELDS THEN 3170
3160 FOR I=L+1 TO NFIELDS:INPUT #1,F:FLEN(I)=F:? #3;F:NEXT I
3170 FOR I=1 TO NRECORDS:IF L=1 THEN 3200
3180 FOR J=1 TO L-1:D=USR(INP,16,ADR(TFIELD$),FLEN(J)):TFIELD$(301)=" "
3190 ? #3;TFIELD$(1,FLEN(J));:NEXT J
3200 D=USR(INP,16,ADR(TFIELD$),FLEN(J)):TFIELD$(301)=" "
3210 IF L=NFIELDS THEN 3300
3220 FOR J=L+1 TO NFIELDS:D=USR(INP,16,ADR(TFIELD$),FLEN(J)):TFIELD$(301)=" "
3230 ? #3;TFIELD$(1,FLEN(J));:NEXT J
3300 NEXT I:GOTO 5000
4000 D=USR(WINDOO,8,8,34,15):POSITION 10,10:? "Enter number of field: "
4005 POSITION 10,11:MCH=4:GOSUB 700
4010 TRAP 9400:L=VAL(TFIELD$):IF L<1 OR L>20 THEN 9400
4015 POSITION 10,12:? "Enter new length:":POSITION 10,13:MCH=4:GOSUB 700
4017 LN=VAL(TFIELD$):IF LN<1 OR LN>300 THEN 9400
4020 ? #3;ID$:IDFLG=0:IF ID$=PROOF1$ THEN IDFLG=1
4030 GET #1,NCUR:PUT #3,NCUR
4040 IF IDFLG THEN GET #1,NC:NCUR=NCUR+256*NC:PUT #3,NC
4050 GET #1,NRECORDS:PUT #3,NRECORDS
4060 IF IDFLG THEN GET #1,NR:NRECORDS=NRECORDS+256*NR:PUT #3,NR
4070 GET #1,NFIELDS:PUT #3,NFIELDS
4080 FOR I=1 TO NFIELDS:INPUT #1,TFIELD$:? #3;TFIELD$:NEXT I
4090 IF L=1 THEN 4110
4100 FOR I=1 TO L-1:INPUT #1,F:FLEN(I)=F:F1LEN(I)=F:? #3;F:NEXT I
4110 INPUT #1,F:FLEN(L)=F:F1LEN(L)=LN:? #3;LN
4120 IF L=NFIELDS THEN 4140
4130 FOR I=L+1 TO NFIELDS:INPUT #1,F:FLEN(I)=F:F1LEN(I)=F:? #3;F:NEXT I
4140 FOR I=1 TO NRECORDS:FOR J=1 TO NFIELDS:TFIELD$(1)=" ":TFIELD$(301)=" ":TFIELD$(2)=TFIELD$(1)
4150 D=USR(INP,16,ADR(TFIELD$),FLEN(J)):? #3;TFIELD$(1,F1LEN(J));:NEXT J:NEXT I
4160 GOTO 5000
5000 CLOSE #1:CLOSE #2:CLOSE #3:GOTO 31000
6000 D=USR(WINDOO,3,1,35,23):POSITION 5,2:? "Field          Length"
6010 IDFLG=0:IF ID$=PROOF1$ THEN GET #1,X:GET #1,X
6020 GET #1,X:GET #1,X:GET #1,NFIELDS
6030 FOR I=1 TO NFIELDS:INPUT #1,TFIELD$:POSITION 6,2+I:? I;" ";TFIELD$:NEXT I:FOR I=1 TO NFIELDS:INPUT #1,F
6035 POSITION 20,2+I:? F
6040 NEXT I:POSITION 5,22:? "Press RETURN"
6050 GET #5,X:GOSUB 600:CLOSE #1:OPEN #1,4,0,F$:INPUT #1,ID$
6060 GOTO 1060
9000 POSITION 6,10:? "Error opening source file":FOR I=1 TO 1000:NEXT I:CLOSE #1
9010 GOSUB 600:GOTO 1000
9100 POSITION 6,10:? "Error opening dest file":FOR I=1 TO 1000:NEXT I:CLOSE #3:CLOSE #1
9110 GOSUB 600:GOTO 1000
9200 POSITION 10,14:? "Illegal value":FOR I=1 TO 1000:NEXT I:GOSUB 600:GOTO 1030
9300 POSITION 6,10:? "File compatibility error":FOR I=1 TO 1000:NEXT I:CLOSE #1:CLOSE #3
9310 GOSUB 600:GOTO 1000
9400 POSITION 10,14:? "Illegal value":FOR I=1 TO 1000:NEXT I:GOSUB 600:GOTO 1030
9500 POSITION 6,10:? "Do not use same name":FOR I=1 TO 1000:NEXT I:CLOSE #3:CLOSE #1
9510 GOSUB 600:GOTO 1000
10000 GRAPHICS 0:REM INITIALIZATION
10005 POKE 710,2:POKE 709,10:POKE 16,112:POKE 53774,112
10010 DIM WINDOW$(3000),WINDOI$(10),WINDOO$(244),WINDOC$(155),F$(20),F1$(20),SP$(300)
10011 DIM TFIELD$(301),INP$(39),WINDEX$(149),DNAME$(20),FNAME$(12),FLEN(20),F1LEN(20)
10012 DIM ID$(18),PROOF$(18),PROOF1$(18)
10020 SP$(1)=" ":SP$(300)=" ":SP$(2)=SP$(1):PROOF$="\SUMMERS\DATA.BAS\":TFIELD$(300)=" "
10025 PROOF1$="\SUMMERS\DATA1BAS\"
10030 K0=0:K1=1:K2=K1+K1:K3=K2+K1:K4=K3+K1:K5=K4+K1:K6=K5+K1
10090 OPEN #K5,K4,K0,"K:":POKE 752,K1
10100 GOSUB 11000
10130 WINDOI=ADR(WINDOI$):WINDOO=ADR(WINDOO$):WINDOC=ADR(WINDOC$):D=USR(WINDOI,ADR(WINDOW$)):WINDEX=ADR(WINDEX$)
10140 INP=ADR(INP$)
10160 RETURN
11000 WINDOI$(1,10)="hh▔├╱h▔♥╱◆"
11010 WINDOO$(1,80)="hhh┐X┐Uhh┐Y┐Thh┐Zhh┐[%X┐V%Y┐WFT%V┴i(┐V%Wi♥┐W%TI♥Pk%Y┐T-♥╱┐\-├╱┐])Q┐_$X1V┐^%_┌VIQ"
11020 WINDOO$(81,160)="P┤)R┐_I|P┤)♥┐_IZP┤)R┐_%^┤U ♥┌\%\┴i├┐\%]i♥┐]$UDZp┤H┴♣A)|┌V%TEYP┤)E┌VE[P┤)C┌V%V┴i("
11030 WINDOO$(161,240)="┐V%Wi♥┐W%TE[p▄)|┐_fT%TE[P┤)Z┐_$X┴♣┘ ♥%[┌\H%Z┌\H%Y┌\H%X┌\H-♥╱┌\H-├╱┌\%\┴i╱▔♥╱%]i♥"
11040 WINDOO$(241,244)="▔├╱◆"
11050 WINDOC$(1,80)="h-♥╱8i╱┐\-├╱i♥┐] ♥1\┐[H1\┐ZH1\┐Y┐TH1\┐X┐UH1\▔♥╱H1\▔├╱-♥╱┐\-├╱┐]%X┐V%Y┐WFT%V┴i(┐V"
11060 WINDOC$(81,155)="%Wi♥┐W%TI♥Pk%Y┐T ♥1\$U┌V%\┴i├┐\%]i♥┐]DZp┐fU┴♣b%TE[p▎fT%V┴i(┐V%Wi♥┐W%X┐U┴♣F◆"
11070 INP$(1,39)="hhh*h↓E┘h↓D┘h↓I┘h↓H┘)╲↓B┘ Vd=H┘┐T=I┘┐U◆"
11100 WINDEX$(1,80)="h-♥╱8i╱┐\-├╱i♥┐] ♥1\*J╱[H1\*J╱ZH1\*h╱Y╱TH1\*h╱X╱UH1\┐\H1\┐]%X┐V%Y┐WFT%V┴i(┐V%Wi♥"
11110 WINDEX$(81,149)="┐W%TI♥Pk%Y┐T)♥$U┌V%\┴i├┐\%]i♥┐]DZp┐fU┴♣d%TE[p▎fT%V┴i(┐V%Wi♥┐W%X┐U┴♣H◆"
12000 RETURN
31000 GRAPHICS 0:END