The Antic Music Processor with AMS II convertor (CONVERT.BAS)

The Antic Music Processor with AMS II convertor by Steven Lashower (old, refer to 89-06) 95 (binary load, BASIC)

Description

The Antic Music Processor with AMS II convertor by Steven Lashower (old, refer to 89-06) 95 (binary load, BASIC)

From the Antic disk of December 1988 (Vol. 7 No. 8) — disk B.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.4 KB

Dialect
Atari BASIC
Lines
59
Variables
MEAS$, A(, VL(, LE(, S$, MUS$, D, MEA, A, MNUM, NC, V, CM, X, B, E, H1, H2, ATMP
BASIC listing (59 lines)
10 REM AMS II TO AMP CONVERTER
30 REM BY STEVEN LASHOWER
40 REM (c)1988, ANTIC PUBLISHING
50 REM Revision 5-24-88
70 DIM MEAS$(1025),A(10),VL(4),LE(4),S$(15),MUS$(FRE(0)-100)
80 ? "↰  AMS II to AMP 1.0 File Converter":TRAP 80
90 ? :? "Enter Source File name: ";:INPUT S$
100 CLOSE #1
110 OPEN #1,4,0,S$
120 FOR D=1 TO 10:INPUT #1,ATMP:A(D)=ATMP
130 NEXT D
140 MEA=A(1)+A(3)+A(5)+A(7)
150 FOR D=1 TO MEA
160 GET #1,A:MEAS$(D)=CHR$(A)
170 NEXT D
180 VL(1)=A(2)
190 VL(2)=A(4)-A(2)
200 VL(3)=A(6)-A(4)
210 VL(4)=A(8)-A(6)
220 MNUM=1:MUS$="AMP♥♥♥♥♥♥♥♥♥♥"
230 NC=0
240 FOR V=1 TO 4
250 CM=2
260 ? "Converting Notes For Voice #";V
270 MUS$(LEN(MUS$)+1)="V├♥":X=LEN(MUS$):IF VL(V)=0 THEN MUS$(LEN(MUS$)+1)="▶▶▶":GOTO 420
280 FOR D=1 TO VL(V) STEP 2
290 GET #1,A:GET #1,B:IF A=67 THEN A=85:REM ACCOUNT FOR AMS I
300 A=A-1:IF A=-1 THEN A=84
310 IF A=127 THEN A=88:REM TEMPO
320 IF A>127 THEN A=A-128:B=B+48:REM HANDLE ---)---
330 IF B>=192 THEN B=B-192:B=B+16:REM HANDLE ---'---
340 IF B>=128 THEN B=B-128:B=B+32:REM HANDLE ----"----
350 X=X+1
360 MUS$(X,X)=CHR$(A):X=X+2:MUS$(X,X)=CHR$(B)
370 NC=NC+1
380 IF NC=ASC(MEAS$(MNUM,MNUM)) THEN MUS$(LEN(MUS$)+1)=CHR$(86):GOSUB 610:X=LEN(MUS$):MNUM=MNUM+1:NC=0:CM=CM+1
390 NEXT D
400 MUS$(LEN(MUS$)-2)="▶▶▶":X=LEN(MUS$)+1
410 LE(V)=LEN(MUS$)-13
420 NEXT V
430 ? :? "Doing Durations..."
440 NC=0:MNUM=1
450 X=18
460 FOR E=1 TO 4:IF VL(E)=0 THEN X=X+3:GOTO 550
470 FOR D=1 TO VL(E) STEP 2
480 GET #1,A:GET #1,B:A=A+(256*B)
490 MUS$(X,X)=CHR$(A/5)
500 NC=NC+1
510 IF NC=ASC(MEAS$(MNUM,MNUM)) THEN X=X+3:NC=0:MNUM=MNUM+1
520 X=X+3
530 NEXT D
540 X=X+3
550 NEXT E
560 MUS$(LEN(MUS$)+1)="♥♥♥A♥♥┤0♥$♥"
570 FOR D=1 TO 4:CM=LE(D):X=D*2:GOSUB 610:NEXT D
580 CLOSE #1:? :? "Destination Filename: ";:INPUT S$:TRAP 580
590 CLOSE #1:OPEN #1,8,0,S$:? #1;MUS$:CLOSE #1
600 RUN
610 H1=INT(CM/256):H2=CM-256*H1:MUS$(X+2,X+2)=CHR$(H2):MUS$(X+3,X+3)=CHR$(H1):RETURN