The Newsroom Converter (NEWSCON.BAS)
The Newsroom Converter by John French, 55
Description
The Newsroom Converter by John French, 55
From the Antic disk of December 1988 (Vol. 7 No. 8) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 6.8 KB
- Dialect
- Atari BASIC
- Lines
- 143
- Variables
SEC$,DIR$,HDR1$,HDR2$,HDR3$,NAME$,ML$,PATH$,K,LO,HI,CMD,AL,AH,LL,LH,X,I,SEC,P,N,PIC,S,L,W,H,DH,D,JNK,XHI,A,OX,SZ,SH,SL
BASIC listing (143 lines)
1 REM THE NEWSROOM CONVERTER
2 REM BY JOHN FRENCH
3 REM (c)1988, ANTIC PUBLISHING
10 DIM SEC$(129),DIR$(32),HDR1$(14),HDR2$(14),HDR3$(14),NAME$(20),ML$(40),PATH$(8)
15 HDR1$="▶▶♥ C"<▕♥3◢_♥▶"
16 HDR2$="▶▶♥ ▶$x┤♥g◢_♥▶"
17 HDR3$="▶▶♥ ▖3◢┼♥'◢o♥▶"
18 ML$="hh┐Lh┐Kh┐Mh*$M1KI▶┌K◢♣w%K┴i(┐K%Li♥┐LJPe◆"
20 GRAPHICS 0:PATH$="D1:*.*":POKE 710,0:POKE 675,0:POKE 676,129
21 ? "▶┌────────────────────────┐"
22 ? "▶| The |"
23 ? "▶| Newsroom Converter |"
24 ? "▶| by John French |"
25 ? "▶| |"
26 ? "▶|(c)1988 Antic Publishing|"
27 ? "▶└────────────────────────┘"
30 ? "↓↓↓[1] GR.8 File to Newsroom"
40 ? :? "[2] Print Shop to Newsroom"
50 ? :? "[3] Newsroom to GR.8 File"
60 ? :? "[4] Quit"
70 POKE 752,0:POSITION 2,20:? "↑Your Choice: ";:CLOSE #2:OPEN #2,4,0,"K:":GET #2,K:CLOSE #2
80 POKE 752,1:? CHR$(K):K=K-48:IF K<1 OR K>4 THEN POKE 712,66:K=2^2:POKE 712,0:GOTO 70
90 ON K GOTO 200,300,400,100
100 GRAPHICS 0:END
199 REM GR.8 -> NEWSROOM
200 GRAPHICS 0:POKE 710,0:GOSUB 1000
210 ? :? :? "GR.8 File to Load - D1:";:INPUT #16,NAME$
220 IF NAME$="" THEN 20
221 DIR$="D1:":DIR$(LEN(DIR$)+1)=NAME$
225 TRAP 250:CLOSE #1:OPEN #1,4,0,DIR$
230 GRAPHICS 8+16:POKE 710,12:POKE 709,0:LO=PEEK(88):HI=PEEK(89)
240 CMD=7:AL=LO:AH=HI:LL=0:LH=30:GOSUB 2000
245 CLOSE #1:GOTO 260
250 CLOSE #1:GOSUB 5000:ON K GOTO 200,20
260 GOSUB 3000:GRAPHICS 8+32
270 POKE 710,0:? "↰NEWSROOM Filename to Save - D1:PH";:INPUT #16,NAME$
280 IF NAME$="" THEN 20
290 DIR$="D1:PH":DIR$(LEN(DIR$)+1)=NAME$
291 TRAP 298:CLOSE #1:OPEN #1,8,0,DIR$
292 ? #1;HDR3$;
293 CMD=11:AL=LO:AH=HI:LL=29:LH=0:AL=AL+X
294 IF AL>255 THEN AL=AL-256:AH=AH+1
295 FOR I=0 TO 167:GOSUB 2000:IF PEEK(851)<>1 THEN POKE 195,PEEK(851):GOTO 298
296 AL=AL+40:IF AL>255 THEN AL=AL-256:AH=AH+1
297 NEXT I:CLOSE #1:GOTO 20
298 CLOSE #1:GOSUB 5000:ON K GOTO 270,20
299 REM PRINT SHOP -> NEWSROOM
300 GRAPHICS 0:POKE 710,0:? "↓↓Load Print Shop Data Disk in Drive":? :? " Press [RETURN]";
310 INPUT #16;NAME$:? :? :SEC=362:P=1
320 GOSUB 4000
330 FOR I=1 TO 97 STEP 32:DIR$=SEC$(I,I+31)
340 IF DIR$="♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥" THEN POP :GOTO 350
345 ? P;" - ";DIR$(1,16):P=P+1:NEXT I:SEC=SEC+1:GOTO 320
350 ? :? "Your Choice";:TRAP 350:INPUT N
351 IF N=0 THEN 20
355 IF N<1 OR N>=P THEN 350
360 P=INT((N-1)/4):I=(N-(P*4)-1)*32+1
370 SEC=362+P:GOSUB 4000:DIR$=SEC$(I,I+31)
371 GRAPHICS 8:POKE 710,0:LO=PEEK(88):HI=PEEK(89):PIC=LO+HI*256:? "Loading ";DIR$(1,16)
372 SEC=ASC(DIR$(17,17))+ASC(DIR$(18,18))*256:P=0:S=1:L=1:GOSUB 4000
373 POKE PIC+P,ASC(SEC$(S,S)):S=S+1:IF S>126 THEN S=1:SEC=SEC+1:GOSUB 4000
374 P=P+1:IF P>10 THEN P=0:L=L+1:PIC=PIC+40
375 IF L<53 THEN 373
376 W=10:H=52:GOSUB 3500
377 ? "↰NEWSROOM Filename to Save - D1:PH";:INPUT #16,NAME$:IF NAME$="" THEN 20
378 DIR$="D1:PH":DIR$(LEN(DIR$)+1)=NAME$
379 ? :? :? "Double Height (Y/N)";:INPUT NAME$:DH=1:IF NAME$(1,1)="Y" THEN DH=2
380 TRAP 390:CLOSE #1:OPEN #1,8,0,DIR$
381 IF DH=1 THEN ? #1;HDR1$;:GOTO 383
382 ? #1;HDR2$;
383 CMD=11:AL=LO:AH=HI:LL=11:LH=0
384 FOR I=1 TO 52:FOR D=1 TO DH:GOSUB 2000:IF PEEK(851)<>1 THEN POKE 195,PEEK(851):POP :POP :GOTO 390
385 NEXT D:AL=AL+40:IF AL>255 THEN AL=AL-256:AH=AH+1
386 NEXT I:CLOSE #1:GOTO 20
390 GOSUB 5000:ON K GOTO 377,20
399 REM NEWSROOM -> GR.8
400 ? "↰":PATH$="D1:PH*.*":GOSUB 1000:? "NEWSROOM Filename to Load - D1:PH";:INPUT #16,NAME$
410 IF NAME$="" THEN 20
420 DIR$="D1:PH":DIR$(LEN(DIR$)+1)=NAME$
430 TRAP 500:CLOSE #1:OPEN #1,4,0,DIR$:GRAPHICS 8+16:POKE 710,0
435 LO=PEEK(88):HI=PEEK(89)
440 FOR I=1 TO 7:GET #1,JNK:NEXT I:GET #1,XHI:FOR I=9 TO 14:GET #1,JNK:NEXT I:DH=INT(XHI/2)
441 LPRINT "DH=";DH
450 CMD=7:AL=LO:AH=HI:LL=29:LH=0:AL=AL+6
460 IF AL>255 THEN AL=AL-256:AH=AH+1
462 IF DH>2 THEN 470
463 LL=11:LH=0
464 FOR I=1 TO 52:FOR D=1 TO DH:GOSUB 2000:IF PEEK(851)>5 THEN POKE 195,PEEK(851):POP :POP :GOTO 500
465 NEXT D:GOTO 480
470 FOR I=0 TO 167:GOSUB 2000:IF PEEK(851)>5 THEN POKE 195,PEEK(851):GOTO 500
480 AL=AL+40:IF AL>255 THEN AL=AL-256:AH=AH+1
490 NEXT I:CLOSE #1:GOTO 510
500 CLOSE #1:GOSUB 5000:ON K GOTO 400,20
510 GRAPHICS 8+32:POKE 710,0
520 ? :? :? "GR.8 File to Save - D1:";:INPUT #16,NAME$
530 IF NAME$="" THEN 20
540 DIR$="D1:":DIR$(LEN(DIR$)+1)=NAME$
550 TRAP 590:CLOSE #1:OPEN #1,8,0,DIR$
560 GRAPHICS 8+48:POKE 710,0
570 CMD=11:AL=LO:AH=HI:LL=0:LH=30:GOSUB 2000
580 CLOSE #1:GOTO 600
590 CLOSE #1:GOSUB 5000:ON K GOTO 510,20
600 GOTO 20
999 END
1000 REM DOS DIRECTORY
1005 TRAP 1050
1010 CLOSE #1:OPEN #1,6,0,PATH$:?
1020 TRAP 1040
1030 INPUT #1,DIR$:? DIR$:GOTO 1030
1040 CLOSE #1:TRAP 40000:RETURN
1050 CLOSE #1:GOSUB 5000:ON K GOTO 1000
1060 POP :GOTO 20
1999 REM LOAD DOS FILE
2000 POKE 850,CMD:POKE 852,AL:POKE 853,AH:POKE 856,LL:POKE 857,LH
2010 A=USR(ADR("hhh*LVd"),16)
2020 RETURN
3000 X=0:W=0:H=168:CLOSE #2:OPEN #2,4,0,"K:":GOSUB 3400
3005 GRAPHICS 8+32:POKE 710,12:POKE 709,2:? "↰↓Use ␛← & ␛→ to Frame Picture"
3006 ? " Press RETURN to Save"
3007 GET #2,K:GRAPHICS 8+48:POKE 710,12:POKE 709,2:GOTO 3020
3010 GET #2,K:IF K=43 OR K=42 THEN K=73-K
3020 IF K=31 AND X<11 THEN GOSUB 3400:X=X+1:GOSUB 3400:GOTO 3010
3030 IF K=30 AND X>0 THEN GOSUB 3400:X=X-1:GOSUB 3400:GOTO 3010
3040 IF K=155 THEN CLOSE #2:GOTO 3060
3050 GOTO 3010
3060 W=26:X=X+1:GOSUB 3500:X=X-1
3070 RETURN
3400 GOSUB 3500:OX=X:X=X+28:GOSUB 3500:X=OX:RETURN
3500 PIC=LO+HI*256+X
3510 SZ=W*256+H
3520 A=USR(ADR(ML$),PIC,SZ)
3530 RETURN
4000 SEC$(129)="♥":AH=INT(ADR(SEC$)/256):AL=ADR(SEC$)-AH*256:SH=INT(SEC/256):SL=SEC-SH*256
4010 POKE 772,AL:POKE 773,AH:POKE 778,SL:POKE 779,SH:POKE 769,1:POKE 770,82
4020 A=USR(ADR("h Sd◆"))
4030 IF PEEK(771)=1 THEN RETURN
4040 POKE 195,PEEK(771):GOSUB 5000
4050 POP :ON K GOTO 300,20
5000 POKE 712,66:? "↰↓Error - ";PEEK(195);"↰"
5010 ? :? "[1] Retry [2] Cancel ";
5030 CLOSE #1:CLOSE #2:OPEN #2,4,0,"K:":GET #2,K:CLOSE #2
5040 IF K<49 OR K>50 THEN 5030
5050 POKE 712,0:K=K-48:RETURN
