Version Detective (FILCOMP.BAS)
Version Detective by Jeffrey A. Summers and Charles Jackson, 26
Description
Version Detective by Jeffrey A. Summers and Charles Jackson, 26
From the Antic disk of December 1988 (Vol. 7 No. 8) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.1 KB
- Dialect
- Atari BASIC
- Lines
- 63
- Variables
BUFF1$,BUFF2$,FIL1$,FIL2$,HOLD$,TEMP$,BUFAD1,BUFAD2,BUF1HI,BUF1LO,BUF2HI,BUF2LO,IO1,IO2,BTOT1,BTOT2,FLAG,X,JNK,BYTRED1,BYTRED2,D,LT
BASIC listing (63 lines)
10 REM VERSION DETECTIVE
20 REM BY SUMMERS/JACKSON
30 REM (c)1988, ANTIC PUBLISHING
40 GRAPHICS 0:POKE 712,PEEK(710)
50 DIM BUFF1$(256),BUFF2$(256),FIL1$(18),FIL2$(18),HOLD$(18),TEMP$(18)
60 BUFF1$(1)="♥":BUFF1$(256)="♥":BUFF1$(2)=BUFF1$:BUFAD1=ADR(BUFF1$)
70 BUFF2$=BUFF1$:BUFAD2=ADR(BUFF2$)
80 BUF1HI=INT(BUFAD1/256):BUF1LO=((BUFAD1/256)-BUF1HI)*256
90 BUF2HI=INT(BUFAD2/256):BUF2LO=((BUFAD2/256)-BUF2HI)*256
100 GOSUB 7000:? :? "First file";:INPUT FIL1$:IF LEN(FIL1$)<1 THEN 100
110 TEMP$=FIL1$:GOSUB 8000:FIL1$=TEMP$:IF FIL1$(LEN(FIL1$))=":" THEN 100
120 TRAP 100:CLOSE #1:OPEN #1,4,0,FIL1$:CLOSE #1
130 POKE 710,152:POKE 712,152:POKE 709,0
140 GOSUB 7000:? :? "Second file";:INPUT FIL2$:IF LEN(FIL2$)<1 THEN 140
150 TEMP$=FIL2$:GOSUB 8000:FIL2$=TEMP$:IF FIL2$(LEN(FIL2$))=":" THEN 140
160 TRAP 140:CLOSE #2:OPEN #2,4,0,FIL2$
170 TRAP 40000:CLOSE #1:OPEN #1,4,0,FIL1$
180 IO1=848:IO2=864:BTOT1=0:BTOT2=0:FLAG=0:? :? "Working..."
190 POKE IO1+2,7:POKE IO2+2,7
200 POKE IO1+4,BUF1LO:POKE IO2+4,BUF2LO
210 POKE IO1+5,BUF1HI:POKE IO2+5,BUF2HI
220 POKE IO1+8,0:POKE IO2+8,0:POKE IO1+9,1:POKE IO2+9,1
230 FOR X=1 TO 2:JNK=USR(ADR("hhh*LVd"),16*X):NEXT X
240 BYTRED1=PEEK(IO1+8)+PEEK(IO1+9)*256:BYTRED2=PEEK(IO2+8)+PEEK(IO2+9)*256
241 IF (BYTRED1=BYTRED2) AND BYTRED1<>256 THEN FLAG=1
245 BUFF1$=BUFF1$(1,BYTRED1):BUFF2$=BUFF2$(1,BYTRED1)
250 BTOT1=BTOT1+BYTRED1:BTOT2=BTOT2+BYTRED2
260 IF BTOT1>BTOT2 THEN ? :? "File #1, ";FIL1$;", is longer.":GOTO 380
270 IF BTOT1<BTOT2 THEN ? :? "File #2, ";FIL2$;", is longer.":GOTO 380
280 IF FLAG=1 AND BUFF1$=BUFF2$ THEN 340
290 IF BUFF1$=BUFF2$ THEN 190
291 FOR X=1 TO 256:IF BUFF1$(X,X)=BUFF2$(X,X) THEN NEXT X
292 POP :D=X
300 POKE 82,21:POKE 83,39:? "↰":POKE 766,1:POSITION 21,0:? FIL2$;":":? "▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔":? BUFF2$
310 POKE 82,0:POKE 83,18:POKE 766,1:POSITION 0,0:? FIL1$;":":? "▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔":? BUFF1$:?
320 POKE 82,2:POKE 83,39:?
321 POKE 766,1:? BUFF1$(D,D),," ";BUFF2$(D,D):POKE 766,0:?
322 ? " Mismatch at byte #";INT(BTOT1/256)*256+D
323 ? "(Byte #";D;" in the window.)"
330 GOTO 380
340 ? "↰↓↓↓File #1 - ";FIL1$:? ,"(";BTOT1;" Bytes)"
350 ? :? "File #2 - ";FIL2$:? ,"(";BTOT2;" Bytes)"
360 ? :? :? "Files are identical."
370 GOTO 390
380 ? :? :? "Files are different."
390 END
6999 REM DISK DIRECTORY
7000 POKE 82,1:? "↰┌────────────────────────────────────┐"
7010 ? "| Directory D1: |"
7020 ? "├─────────────────┬┬─────────────────┤"
7030 CLOSE #1:OPEN #1,6,0,"D1:*.*":FLAG=0
7040 TRAP 7090:INPUT #1,HOLD$:IF LEN(HOLD$)<17 OR HOLD$(LEN(HOLD$))="S" THEN 7070
7050 ? "|";HOLD$;"|";:IF FLAG=1 THEN ?
7060 FLAG= NOT (FLAG):GOTO 7040
7070 IF FLAG=1 THEN ? "| |"
7080 ? "└─────────────────┴┴─────────────────┘":POKE 82,2:? " ";HOLD$
7090 CLOSE #1:TRAP 40000:RETURN
7999 REM CHECK FOR DX: ON FILENAMES
8000 LT=LEN(TEMP$):IF LT<3 THEN 8030
8010 IF TEMP$(1,2)="D:" THEN 8040
8020 IF LT>2 THEN D=ASC(TEMP$(2,2)):IF TEMP$(1,1)="D" AND TEMP$(3,3)=":" AND D>48 AND D<57 THEN 8040
8030 HOLD$="D1:":HOLD$(4)=TEMP$:TEMP$=HOLD$
8040 RETURN
