by John Ferguson (LOTTOPIK.BAS)
by John Ferguson, 13
Description
by John Ferguson, 13
From the Antic disk of November 1988 (Vol. 7 No. 7).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 1.5 KB
- Dialect
- Atari BASIC
- Lines
- 46
- Variables
X,B(,Q$,P$,P1$,P2$,T,N,A,R,C,P
BASIC listing (46 lines)
1 REM LOTTOPIK
2 REM BY JOHN FERGUSON
3 REM (c)1988, ANTIC PUBLISHING
5 X=49:REM THE HIGHEST NUMBER IN YOUR STATE'S LOTTO
10 DIM B(6),Q$(3),P$(30),P1$(30),P2$(5)
20 GOTO 320
30 POKE 82,6:? CHR$(125):?
35 ? " LOTTO NUMBERS"
40 ? " ▔▔▔▔▔ ▔▔▔▔▔▔▔"
50 FOR T=1 TO 5
60 FOR N=0 TO 5:B(N)=-1:NEXT N
70 A=INT(RND(0)*X)+1
80 FOR N=0 TO 5
90 IF A=B(N) THEN 70
100 IF B(N)=-1 THEN B(N)=A:GOTO 70
110 IF B(5)<>-1 THEN 130
120 NEXT N
130 ?
140 R=0
150 FOR N=0 TO 4
160 IF B(N)>B(N+1) THEN C=B(N):B(N)=B(N+1):B(N+1)=C
170 NEXT N
180 R=R+1:IF R<6 THEN 150
190 P$=" "
200 FOR N=0 TO 5
210 P1$=STR$(B(N)):IF LEN(P1$)=1 THEN P2$=P1$:P1$="0":P1$(2)=P2$
220 P$(LEN(P$)+1)=" ":P$(LEN(P$)+1)=P1$
230 NEXT N
240 ? :? P$
250 IF P=1 THEN ? #2,P$:? #2
260 NEXT T
270 ? :? :? "More";
280 IF P=1 THEN ? #2:? #2:? #2
290 INPUT Q$
300 IF Q$="N" OR Q$="NO" THEN POKE 82,2:? CHR$(125):END
310 GOTO 30
320 ? CHR$(125):? :? :POKE 82,2
325 ? " LOTTOPIK"
330 ? :? :? "Do you want the results printed?"
340 ? :? :INPUT Q$:FOR T=1 TO PEEK(20):P=RND(0):NEXT T
350 P=0:IF Q$="Y" OR Q$="YES" THEN P=1
360 TRAP 400
370 IF P=1 THEN CLOSE #2:OPEN #2,8,0,"P:"
380 IF P=1 THEN ? #2," LOTTO NUMBERS":? #2:? #2
390 GOTO 30
400 ? :? :? "PRINTER NOT RESPONDING!":? :? :GOTO 330
