The Flower Program (FLOWER.BAS)

The Flower Program by Allan Moose And Marian Lorenz, 22

Description

The Flower Program by Allan Moose And Marian Lorenz, 22

From the Antic disk of November 1988 (Vol. 7 No. 7).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.6 KB

Dialect
Atari BASIC
Lines
74
Variables
GRAPH$, FN$, N, ALPHA, COUNT, DELTA, DELTAINC, COUNTSTOP, ASPECT, THETA, R, OLDX, OLDY, NTHETA, XNEW, YNEW, KEYP, SCRNMEM, MEMORY, HIBYTE, LOBYTE, COLUMN, DUMP, K, ML, IO, JNK, X
BASIC listing (74 lines)
10 REM THE FLOWER PROGRAM
20 REM BY ALLAN MOOSE AND MARIAN LORENZ
30 REM (c)1988, ANTIC PUBLISHING
50 DIM GRAPH$(200),FN$(16)
60 ? "  PLEASE WAIT..."
80 GOSUB 720
100 REM INPUT & INITIALIZATION
120 ? "↰  Enter N ":INPUT N
130 IF N=0 THEN ? "Must Be Non-Zero↰↰↰":GOTO 120
140 ?
150 ? " Enter the incremental angle, ALPHA ":INPUT ALPHA
170 COUNT=0:DELTA=0:DELTAINC=2
180 COUNTSTOP=180:ASPECT=320/192
200 REM THE MAIN PROGRAM
210 GRAPHICS 24:POKE 710,12:POKE 712,12:POKE 709,2:COLOR 1:DEG
220 THETA=DELTA
230 R=80*SIN(N*THETA)
240 OLDX=R*COS(THETA):OLDY=R*SIN(THETA)
250 THETA=THETA+ALPHA
260 IF THETA>=360 THEN GOSUB 450
270 NTHETA=THETA*N
280 GOSUB 500
290 R=80*SIN(NTHETA)
300 XNEW=R*COS(THETA):YNEW=R*SIN(THETA)
310 PLOT ASPECT*OLDX+160,90-OLDY
320 DRAWTO ASPECT*XNEW+160,90-YNEW
330 COUNT=COUNT+1
340 IF THETA=DELTA THEN 370
350 OLDX=XNEW:OLDY=YNEW
360 GOTO 250
370 IF COUNT>=COUNTSTOP THEN 550
380 DELTA=DELTA+DELTAINC
390 GOTO 220
400 REM THE SUBROUTINES
410 REM MOD FUNCTION FOR THETA
450 THETA=THETA-(INT(THETA/360))*360
460 RETURN
480 REM MOD FUNCTION FOR NTHETA
500 NTHETA=NTHETA-(INT(NTHETA/360))*360:RETURN
530 REM THE SCREEN DUMP
550 GOSUB 1000
555 IF KEYP=35 THEN GRAPHICS 0:GOTO 120
556 IF KEYP=10 THEN 560
557 GOTO 800
560 GRAPH$(1)=CHR$(0):GRAPH$(200)=CHR$(0):GRAPH$(2)=GRAPH$
570 LPRINT CHR$(27);CHR$(65);CHR$(8)
580 SCRNMEM=PEEK(88)+PEEK(89)*256
590 MEMORY=SCRNMEM+40*191
600 HIBYTE=INT(ADR(GRAPH$)/256)
610 LOBYTE=ADR(GRAPH$)-HIBYTE*256
620 POKE 203,LOBYTE:POKE 204,HIBYTE
630 FOR COLUMN=MEMORY TO MEMORY+39
640 DUMP=USR(1536,COLUMN)
650 LPRINT CHR$(27);CHR$(75);CHR$(200);CHR$(0);GRAPH$
660 NEXT COLUMN
670 GOTO 550
690 REM M/L SCREEN DUMP ROUTINE
720 RESTORE 760
730 FOR K=0 TO 43
740 READ ML:POKE 1536+K,ML
750 NEXT K
760 DATA 104,104,141,15,6,104,141,14,6,160,4,162,192,173,0,0,202,240,24
770 DATA 145,203,200,216,173,14,6,56,233,40,141,14,6
780 DATA 144,3,76,13,6,206,15,6,76,13,6,96
790 RETURN
800 IO=848:CLOSE #1:OPEN #1,8,0,"D:PICTURE":POKE IO+2,11:POKE IO+4,PEEK(88):POKE IO+5,PEEK(89)
810 POKE IO+8,0:POKE IO+9,30:JNK=USR(ADR("hhh*LVd"),16)
820 PUT #1,PEEK(712):FOR X=708 TO 710:PUT #1,PEEK(X):NEXT X:CLOSE #1:GOTO 550
1000 GRAPHICS 8+32:POKE 710,12:POKE 712,12:POKE 709,2:POKE 752,1
1010 ? "↰    Save     Print     New image"
1020 POKE 764,255
1030 KEYP=PEEK(764):IF  NOT (KEYP=10 OR KEYP=62 OR KEYP=35) THEN 1030
1040 POKE 764,255
1050 GRAPHICS 8+16+32:POKE 710,12:POKE 712,12:POKE 709,2:RETURN