Documentation Printer (DOCPRINT.BAS)

Documentation Printer by Roland Fetzer, 29

Description

Documentation Printer by Roland Fetzer, 29

From the Antic disk of November 1988 (Vol. 7 No. 7).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.4 KB

Dialect
Atari BASIC
Lines
59
Variables
A$, D$, K$, N$, P$, R$, FILE$, YN$, Q, T, P, K, R, L, C, KEY, M, S
BASIC listing (59 lines)
10 REM DOCUMENTATION PRINTER
20 REM BY ROLAND FETZER
30 REM (c)1988, ANTIC PUBLISHING
40 DIM A$(130),D$(25),K$(25),N$(3),P$(1),R$(14),FILE$(17),YN$(1)
50 ? CHR$(125):POSITION 6,6:? "What screen color do you want?":Q=0:R$="             "
60 ? :? :? :? R$;"1: Default":? R$;"2: Amber":? R$;"3: Green":? R$;"4: Grey"
70 TRAP 70:POSITION 10,17:? "↑        Select a number";:INPUT Q:TRAP 40000
80 IF Q<1 OR Q>4 OR Q<>INT(Q) THEN 70
90 ON Q GOTO 140,110,120,130
100 REM SET THE COLORS
110 POKE 710,58:POKE 709,0:GOTO 140
120 POKE 710,44:POKE 709,0:GOTO 140
130 POKE 710,14:POKE 709,0:GOTO 140
140 ? CHR$(125):POSITION 9,8:? "DOCUMENTATION READER":POSITION 9,9:? "===================="
150 YN$="":? :? "Did You Insert The Disk Which Has The Document On It(Y/N)";:INPUT YN$
160 T=0:P=0:K=0:R=0:IF YN$(1,1)="Y" THEN GOSUB 510
170 IF YN$(1,1)="N" THEN 140
180 ? :TRAP 550:? "What is the name of the document ":INPUT K$
190 ? CHR$(125):POSITION 5,9:? "DOCUMENTATION FOR ";K$
200 GOSUB 1000:POSITION 7,12:? "PRESS ANY KEY TO SCROLL"
210 POSITION 8,15:? "SCREEN OR PRINTER";:INPUT N$:? :?
220 IF N$(1,1)="S" OR N$(1,1)="s" THEN 240
230 IF N$(1,1)="P" OR N$(1,1)="p" THEN 320
240 POKE 752,1:CLOSE #1:OPEN #1,4,0,K$
250 TRAP 270:INPUT #1;A$:R=R+INT(LEN(A$)/38)+1:? A$:IF R>=18 THEN GOSUB 470
260 GOTO 250
270 IF PEEK(195)=136 THEN CLOSE #1:TRAP 40000
280 ? :? "---------------- END ---------------":POKE 752,0
290 YN$="":? :? "Do you want to read another document(Y/N)";:INPUT YN$
300 IF YN$(1,1)<>"N" THEN 160
310 GRAPHICS 0:END
320 ? CHR$(125):POSITION 2,10:? "DID YOU SET PAPER TO THE TOP OF ITS   FORM (Y/N)";:INPUT P$
330 IF P$(1,1)<>"Y" THEN 320
340 LPRINT :LPRINT :LPRINT :LPRINT :POKE 752,1
350 CLOSE #1:OPEN #1,4,0,K$:? CHR$(125):POSITION 15,12:? "PRINTING!"
360 TRAP 400:INPUT #1;A$:T=T+1
370 CLOSE #2:OPEN #2,8,0,"P:"
380 ? #2;"                   ";A$:IF T=57 THEN GOSUB 490
390 GOTO 360
400 IF PEEK(195)=136 THEN CLOSE #1:CLOSE #2:POKE 752,0:TRAP 40000
410 C=0:C=59-T:FOR K=1 TO C:LPRINT :NEXT K
420 LPRINT "                                   -";P+1;"-"
430 ? :? "--------------- END ----------------":POKE 752,0
440 YN$="":? :? "Do you want to print another document(Y/N)";:INPUT YN$
450 IF YN$(1,1)="Y" THEN 160
460 IF YN$(1,1)="N" THEN 310
470 CLOSE #2:OPEN #2,4,0,"K:":GET #2,KEY:IF KEY=ASC(" ") THEN 480
480 R=0:CLOSE #2:RETURN
490 T=0:P=P+1:? #2:? #2:? #2;"                                   -";P;"-"
500 FOR M=1 TO 6:? #2:NEXT M:RETURN
510 CLOSE #2:OPEN #2,6,0,"D1:*.*":? CHR$(125):?
520 INPUT #2,FILE$:IF ASC(FILE$(1,1))>47 THEN 540
530 ? FILE$;:INPUT #2,FILE$:? "  ";FILE$:IF ASC(FILE$(1,1))<47 THEN 520
540 CLOSE #2:? :? "         FILES ON DISK D1":POKE 752,0:? :RETURN
550 ? CHR$(125):POSITION 11,10:? ">BAD FILE NAME<":FOR S=1 TO 300:NEXT S:TRAP 40000:YN$="Y":GOTO 160
1000 IF LEN(K$)>3 THEN IF K$(1,1)="D" AND K$(3,3)=":" THEN 1050
1010 IF LEN(K$)>2 THEN IF K$(1,2)="D:" THEN 1050
1030 D$="D1:":L=LEN(K$):D$(4,L+3)=K$:K$=D$
1050 D$=K$:RETURN